CMakeLists.txt (view raw)
1cmake_minimum_required(VERSION 2.6)
2project(mGBA C)
3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
4if(NOT MSVC)
5 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -std=c99")
6else()
7 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_CRT_SECURE_NO_WARNINGS /wd4003 /wd4244 /wd4146")
8endif()
9set(USE_CLI_DEBUGGER ON CACHE BOOL "Whether or not to enable the CLI-mode ARM debugger")
10set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
11set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
12set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
13set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable ZIP support")
14set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
15set(USE_BLIP ON CACHE BOOL "Whether or not to enable blip_buf support")
16set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
17set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
18set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
19set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
20set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
21set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
22set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
23set(BUILD_GL ON CACHE STRING "Build with OpenGL")
24set(BUILD_GLES2 OFF CACHE STRING "Build with OpenGL|ES 2")
25file(GLOB ARM_SRC ${CMAKE_SOURCE_DIR}/src/arm/*.c)
26file(GLOB GBA_SRC ${CMAKE_SOURCE_DIR}/src/gba/*.c)
27file(GLOB GBA_CHEATS_SRC ${CMAKE_SOURCE_DIR}/src/gba/cheats/*.c)
28file(GLOB GBA_RR_SRC ${CMAKE_SOURCE_DIR}/src/gba/rr/*.c)
29file(GLOB GBA_SV_SRC ${CMAKE_SOURCE_DIR}/src/gba/supervisor/*.c)
30file(GLOB UTIL_SRC ${CMAKE_SOURCE_DIR}/src/util/*.[cSs])
31file(GLOB RENDERER_SRC ${CMAKE_SOURCE_DIR}/src/gba/renderers/*.c)
32file(GLOB SIO_SRC ${CMAKE_SOURCE_DIR}/src/gba/sio/lockstep.c)
33file(GLOB THIRD_PARTY_SRC ${CMAKE_SOURCE_DIR}/src/third-party/inih/*.c)
34list(APPEND UTIL_SRC ${CMAKE_SOURCE_DIR}/src/platform/commandline.c)
35set(VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-mem.c)
36source_group("ARM core" FILES ${ARM_SRC})
37source_group("GBA board" FILES ${GBA_SRC} ${RENDERER_SRC} ${SIO_SRC})
38source_group("GBA supervisor" FILES ${GBA_CHEATS_SRC} ${GBA_SV_SRC} ${GBA_RR_SRC})
39source_group("Utilities" FILES ${UTIL_SRC})
40include_directories(${CMAKE_SOURCE_DIR}/src/arm)
41include_directories(${CMAKE_SOURCE_DIR}/src)
42
43if(NOT CMAKE_BUILD_TYPE)
44 set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
45endif()
46
47set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${LIBDIR}")
48
49include(GNUInstallDirs)
50
51if (NOT DEFINED LIBDIR)
52 set(LIBDIR "lib")
53endif()
54
55if (NOT DEFINED MANDIR)
56 set(MANDIR ${CMAKE_INSTALL_MANDIR})
57endif()
58
59# Function definitions
60include(FindPkgConfig)
61function(find_feature FEATURE_NAME FEATURE_REQUIRES)
62 if (NOT ${FEATURE_NAME})
63 return()
64 endif()
65 foreach(REQUIRE ${FEATURE_REQUIRES})
66 if(NOT ${REQUIRE}_FOUND)
67 find_package(${REQUIRE} QUIET)
68 if(NOT ${REQUIRE}_FOUND)
69 pkg_search_module(${REQUIRE} ${REQUIRE})
70 if (NOT ${REQUIRE}_FOUND)
71 message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
72 set(${FEATURE_NAME} OFF PARENT_SCOPE)
73 return()
74 endif()
75 endif()
76 endif()
77 string(TOUPPER ${REQUIRE} UREQUIRE)
78 set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
79 set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
80 set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
81 set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
82 set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
83 set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
84 endforeach()
85endfunction()
86
87# Version information
88add_custom_target(version-info ALL ${CMAKE_COMMAND} -E touch ${CMAKE_SOURCE_DIR}/src/util/version.c.in
89 COMMAND ${CMAKE_COMMAND}
90 -DBINARY_NAME=${BINARY_NAME}
91 -DCONFIG_FILE=${CMAKE_SOURCE_DIR}/src/util/version.c.in
92 -DOUT_FILE=${CMAKE_CURRENT_BINARY_DIR}/version.c
93 -P ${CMAKE_SOURCE_DIR}/version.cmake
94 WORKING_DIRECTORY ${CMAKE_BINARY_DIR})
95
96include(${CMAKE_SOURCE_DIR}/version.cmake)
97configure_file(${CMAKE_SOURCE_DIR}/src/util/version.c.in ${CMAKE_CURRENT_BINARY_DIR}/version.c)
98list(APPEND UTIL_SRC ${CMAKE_BINARY_DIR}/version.c)
99source_group("Generated sources" FILES ${CMAKE_BINARY_DIR}/version.c)
100
101# Advanced settings
102set(BUILD_LTO ON CACHE BOOL "Build with link-time optimization")
103set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
104set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
105set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
106mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
107set(PGO_PRE_FLAGS "-fprofile-generate=${PGO_DIR} -fprofile-arcs")
108set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
109
110if(BUILD_PGO AND NOT PGO_STAGE_2)
111 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
112 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
113 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
114elseif(BUILD_PGO AND PGO_STAGE_2)
115 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
116 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
117 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
118endif()
119
120# Feature dependencies
121set(FEATURES)
122if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
123 set(LIBEDIT_LIBRARIES -ledit)
124 if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
125 list(APPEND LIBEDIT_LIBRARIES -ltermcap)
126 endif()
127else()
128 find_feature(USE_CLI_DEBUGGER "libedit")
129endif()
130if(BUILD_GL)
131 find_package(OpenGL QUIET)
132 if(NOT OPENGL_FOUND)
133 set(BUILD_GL OFF CACHE BOOL "OpenGL not found" FORCE)
134 endif()
135endif()
136if(BUILD_GLES2 AND NOT BUILD_RASPI)
137 find_path(OPENGLES2_INCLUDE_DIR NAMES GLES2/gl2.h)
138 find_library(OPENGLES2_LIBRARY NAMES GLESv2 GLESv2_CM)
139 if(NOT OPENGLES2_INCLUDE_DIR OR NOT OPENGLES2_LIBRARY)
140 set(BUILD_GLES2 OFF CACHE BOOL "OpenGL|ES 2 not found" FORCE)
141 endif()
142endif()
143find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
144find_feature(USE_PNG "ZLIB;PNG")
145find_feature(USE_LIBZIP "libzip")
146find_feature(USE_MAGICK "MagickWand")
147
148# Platform support
149if(WIN32)
150 set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
151 add_definitions(-D_WIN32_WINNT=0x0600)
152 list(APPEND OS_LIB ws2_32 shlwapi)
153 list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
154 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/windows/*.c)
155 source_group("Windows-specific code" FILES ${OS_SRC})
156elseif(UNIX)
157 add_definitions(-DUSE_PTHREADS)
158
159 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
160 add_definitions(-D_GNU_SOURCE)
161 endif()
162 if(NOT APPLE AND NOT HAIKU)
163 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
164 endif()
165
166 list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
167 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/posix/*.c)
168 source_group("POSIX-specific code" FILES ${OS_SRC})
169endif()
170
171if(APPLE)
172 add_definitions(-D_DARWIN_C_SOURCE)
173 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
174endif()
175
176if(NOT HAIKU AND NOT MSVC)
177 list(APPEND OS_LIB m)
178endif()
179
180if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
181 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
182 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
183 set_source_files_properties(${CMAKE_SOURCE_DIR}/src/arm/isa-arm.c ${CMAKE_SOURCE_DIR}/src/arm/isa-thumb.c PROPERTIES COMPILE_FLAGS -fno-lto)
184endif()
185
186if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
187 if(NOT BUILD_EGL)
188 add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
189 endif()
190endif()
191
192if(BUILD_RASPI)
193 set(BUILD_GL OFF CACHE BOOL "OpenGL not supported" FORCE)
194endif()
195
196if(BUILD_PANDORA)
197 add_definitions(-DBUILD_PANDORA)
198endif()
199
200if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
201 enable_language(ASM)
202endif()
203
204include(CheckFunctionExists)
205check_function_exists(strdup HAVE_STRDUP)
206check_function_exists(strndup HAVE_STRNDUP)
207check_function_exists(snprintf_l HAVE_SNPRINTF_L)
208if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
209 # The strtof_l on Linux not actually exposed nor actually strtof_l
210 set(HAVE_STRTOF_L OFF)
211else()
212 check_function_exists(strtof_l HAVE_STRTOF_L)
213endif()
214check_function_exists(newlocale HAVE_NEWLOCALE)
215check_function_exists(freelocale HAVE_FREELOCALE)
216check_function_exists(uselocale HAVE_USELOCALE)
217check_function_exists(setlocale HAVE_SETLOCALE)
218
219if(HAVE_STRDUP)
220 add_definitions(-DHAVE_STRDUP)
221endif()
222
223if(HAVE_STRNDUP)
224 add_definitions(-DHAVE_STRNDUP)
225endif()
226
227if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE)
228 add_definitions(-DHAVE_LOCALE)
229 if (HAVE_STRTOF_L)
230 add_definitions(-DHAVE_STRTOF_L)
231 endif()
232 if (HAVE_SNPRINTF_L)
233 add_definitions(-DHAVE_SNPRINTF_L)
234 endif()
235endif()
236
237if(HAVE_SETLOCALE)
238 add_definitions(-DHAVE_SETLOCALE)
239endif()
240
241# Features
242set(DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/debugger.c ${CMAKE_SOURCE_DIR}/src/debugger/memory-debugger.c)
243set(FEATURE_SRC)
244set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
245
246if(USE_CLI_DEBUGGER)
247 list(APPEND FEATURES CLI_DEBUGGER)
248 list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/debugger/cli-debugger.c)
249 list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/debugger/parser.c)
250 list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/gba/supervisor/cli.c)
251 include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
252 link_directories(${LIBEDIT_LIBRARY_DIRS})
253 set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
254 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
255else()
256 set(DEBUGGER_LIB "")
257endif()
258
259if(USE_GDB_STUB)
260 list(APPEND FEATURES GDB_STUB)
261 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/gdb-stub.c)
262endif()
263source_group("ARM debugger" FILES ${DEBUGGER_SRC})
264
265if(USE_FFMPEG)
266 list(APPEND FEATURES FFMPEG)
267 pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
268 if(NOT LIBSWRESAMPLE_FOUND)
269 list(APPEND FEATURES LIBAV)
270 endif()
271 include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
272 link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
273 list(APPEND FEATURE_SRC "${CMAKE_SOURCE_DIR}/src/platform/ffmpeg/ffmpeg-encoder.c")
274 string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
275 string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
276 string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
277 string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
278 string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
279 list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
280 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR}|libavcodec-extra-${LIBAVCODEC_VERSION_MAJOR},libavformat${LIBAVFORMAT_VERSION_MAJOR},libavresample${LIBAVRESAMPLE_VERSION_MAJOR},libavutil${LIBAVUTIL_VERSION_MAJOR},libswscale${LIBSWSCALE_VERSION_MAJOR}")
281 set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra")
282 if(APPLE)
283 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
284 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
285 endif()
286endif()
287
288if(USE_BLIP)
289 list(APPEND THIRD_PARTY_SRC "${CMAKE_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
290 add_definitions(-DRESAMPLE_LIBRARY=RESAMPLE_BLIP_BUF)
291else()
292 add_definitions(-DRESAMPLE_LIBRARY=RESAMPLE_NN)
293endif()
294
295if(USE_MAGICK)
296 list(APPEND FEATURES MAGICK)
297 include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
298 link_directories(${MAGICKWAND_LIBRARY_DIRS})
299 list(APPEND FEATURE_SRC "${CMAKE_SOURCE_DIR}/src/platform/imagemagick/imagemagick-gif-encoder.c")
300 list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
301 string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
302 if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
303 set(MAGICKWAND_DEB_VERSION "5")
304 else()
305 set(MAGICKWAND_DEB_VERSION "-6.q16-2")
306 endif()
307 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
308endif()
309
310if(USE_PNG)
311 list(APPEND FEATURES PNG)
312 include_directories(AFTER ${PNG_INCLUDE_DIRS})
313 list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
314 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng12-0,zlib1g")
315endif()
316
317if(USE_LIBZIP)
318 include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
319 link_directories(${LIBZIP_LIBRARY_DIRS})
320 list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
321 list(APPEND FEATURES LIBZIP)
322 list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
323 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
324endif()
325
326if (USE_LZMA)
327 include_directories(AFTER ${CMAKE_SOURCE_DIR}/third-party/lzma)
328 add_definitions(-D_7ZIP_PPMD_SUPPPORT)
329 list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-lzma.c)
330 set(LZMA_SRC
331 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
332 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
333 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
334 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
335 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
336 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
337 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zDec.c
338 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
339 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
340 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
341 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bra.c
342 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bra86.c
343 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
344 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
345 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
346 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zFile.c
347 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
348 list(APPEND FEATURE_SRC ${LZMA_SRC})
349 list(APPEND FEATURES LZMA)
350endif()
351
352set(FEATURE_DEFINES)
353foreach(FEATURE IN LISTS FEATURES)
354 list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
355endforeach()
356
357source_group("Virtual files" FILES ${VFS_SRC})
358source_group("Extra features" FILES ${FEATURE_SRC})
359source_group("Third-party code" FILES ${THIRD_PARTY_SRC})
360
361# Binaries
362set(CORE_SRC
363 ${ARM_SRC}
364 ${GBA_SRC}
365 ${GBA_CHEATS_SRC}
366 ${GBA_RR_SRC}
367 ${GBA_SV_SRC}
368 ${DEBUGGER_SRC}
369 ${RENDERER_SRC}
370 ${SIO_SRC}
371 ${UTIL_SRC}
372 ${VFS_SRC}
373 ${OS_SRC}
374 ${THIRD_PARTY_SRC})
375
376set(SRC
377 ${CORE_SRC}
378 ${FEATURE_SRC})
379
380if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
381 set(BUILD_SHARED ON)
382endif()
383
384if(BUILD_SHARED)
385 add_library(${BINARY_NAME} SHARED ${SRC})
386 set_target_properties(${BINARY_NAME} PROPERTIES SOVERSION ${LIB_VERSION_ABI})
387 if(BUILD_STATIC)
388 add_library(${BINARY_NAME}-static STATIC ${SRC})
389 set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${FEATURE_DEFINES}")
390 install(TARGETS ${BINARY_NAME}-static DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
391 add_dependencies(${BINARY_NAME}-static version-info)
392 endif()
393else()
394 add_library(${BINARY_NAME} STATIC ${SRC})
395endif()
396
397add_dependencies(${BINARY_NAME} version-info)
398
399target_link_libraries(${BINARY_NAME} ${DEBUGGER_LIB} ${DEPENDENCY_LIB} ${OS_LIB})
400install(TARGETS ${BINARY_NAME} LIBRARY DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME} NAMELINK_SKIP ARCHIVE DESTINATION ${LIBDIR} RUNTIME DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
401if(UNIX AND NOT APPLE)
402 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-16.png DESTINATION share/icons/hicolor/16x16/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
403 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-24.png DESTINATION share/icons/hicolor/24x24/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
404 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-32.png DESTINATION share/icons/hicolor/32x32/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
405 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-48.png DESTINATION share/icons/hicolor/48x48/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
406 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-64.png DESTINATION share/icons/hicolor/64x64/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
407 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-96.png DESTINATION share/icons/hicolor/96x96/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
408 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-128.png DESTINATION share/icons/hicolor/128x128/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
409 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-256.png DESTINATION share/icons/hicolor/256x256/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
410 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-512.png DESTINATION share/icons/hicolor/512x512/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
411endif()
412set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${FEATURE_DEFINES}")
413
414if(BUILD_GL)
415 add_definitions(-DBUILD_GL)
416endif()
417
418if(BUILD_GLES2)
419 add_definitions(-DBUILD_GLES2)
420endif()
421
422if(BUILD_LIBRETRO)
423 file(GLOB RETRO_SRC ${CMAKE_SOURCE_DIR}/src/platform/libretro/*.c)
424 add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
425 set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5")
426 target_link_libraries(${BINARY_NAME}_libretro ${OS_LIB})
427endif()
428
429if(BUILD_SDL)
430 add_definitions(-DBUILD_SDL)
431 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/sdl ${CMAKE_BINARY_DIR}/sdl)
432endif()
433
434if(BUILD_QT)
435 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/qt ${CMAKE_BINARY_DIR}/qt)
436endif()
437
438if(BUILD_PERF)
439 set(PERF_SRC ${CMAKE_SOURCE_DIR}/src/platform/perf-main.c)
440 if(UNIX AND NOT APPLE)
441 list(APPEND PERF_LIB rt)
442 endif()
443
444 add_executable(${BINARY_NAME}-perf ${PERF_SRC})
445 target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB})
446 install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
447 install(FILES ${CMAKE_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
448endif()
449
450# Packaging
451set(CPACK_PACKAGE_VERSION ${VERSION_STRING})
452set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
453set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
454set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
455set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_SOURCE_DIR}/LICENSE)
456set(CPACK_RESOURCE_FILE_README ${CMAKE_SOURCE_DIR}/README.md)
457
458set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
459set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
460set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
461set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_SOURCE_DIR}/README.md")
462set(CPACK_DEBIAN_PACKAGE_SECTION "games")
463
464SET(CPACK_DEB_COMPONENT_INSTALL ON)
465
466set(CPACK_STRIP_FILES ${BINARY_NAME})
467
468install(FILES ${CMAKE_SOURCE_DIR}/README.md ${CMAKE_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
469
470include(CPack)
471
472# Summaries
473message(STATUS "Feature summary:")
474message(STATUS " CLI debugger: ${USE_CLI_DEBUGGER}")
475message(STATUS " GDB stub: ${USE_GDB_STUB}")
476message(STATUS " Video recording: ${USE_FFMPEG}")
477message(STATUS " GIF recording: ${USE_MAGICK}")
478message(STATUS " Screenshot/advanced savestate support: ${USE_PNG}")
479message(STATUS " ZIP support: ${USE_LIBZIP}")
480message(STATUS " 7-Zip support: ${USE_LZMA}")
481message(STATUS " Better audio resampling: ${USE_BLIP}")
482message(STATUS "Frontend summary:")
483message(STATUS " Qt: ${BUILD_QT}")
484message(STATUS " SDL (${SDL_VERSION}): ${BUILD_SDL}")
485message(STATUS " Libretro core: ${BUILD_LIBRETRO}")
486message(STATUS " Profiling: ${BUILD_PERF}")
487message(STATUS "Library summary:")
488message(STATUS " Static: ${BUILD_STATIC}")
489message(STATUS " Shared: ${BUILD_SHARED}")