CMakeLists.txt (view raw)
1cmake_minimum_required(VERSION 2.8.11)
2project(mGBA)
3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
4if(NOT MSVC)
5 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wno-missing-field-initializers -std=c99")
6else()
7 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_CRT_SECURE_NO_WARNINGS /wd4003 /wd4244 /wd4146")
8endif()
9set(USE_DEBUGGERS ON CACHE BOOL "Whether or not to enable the debugging infrastructure")
10set(USE_EDITLINE ON CACHE BOOL "Whether or not to enable the CLI-mode debugger")
11set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
12set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
13set(USE_ZLIB ON CACHE BOOL "Whether or not to enable zlib support")
14set(USE_MINIZIP ON CACHE BOOL "Whether or not to enable external minizip support")
15set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
16set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable LIBZIP support")
17set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
18set(USE_SQLITE3 ON CACHE BOOL "Whether or not to enable SQLite3 support")
19set(M_CORE_GBA ON CACHE BOOL "Build Game Boy Advance core")
20set(M_CORE_GB ON CACHE BOOL "Build Game Boy core")
21set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
22set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
23set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
24set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
25if(APPLE)
26 set(BUILD_OPENEMU OFF CACHE BOOL "Build OpenEmu core")
27endif()
28set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
29set(BUILD_TEST OFF CACHE BOOL "Build testing harness")
30set(BUILD_SUITE OFF CACHE BOOL "Build test suite")
31set(BUILD_EXAMPLE OFF CACHE BOOL "Build example frontends")
32set(BUILD_PYTHON OFF CACHE BOOL "Build Python bindings")
33set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
34set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
35set(SKIP_LIBRARY OFF CACHE BOOL "Skip building the library (useful for only building libretro or OpenEmu cores)")
36set(BUILD_GL ON CACHE STRING "Build with OpenGL")
37set(BUILD_GLES2 OFF CACHE STRING "Build with OpenGL|ES 2")
38set(USE_EPOXY ON CACHE STRING "Build with libepoxy")
39set(DISABLE_DEPS OFF CACHE BOOL "Build without dependencies")
40file(GLOB ARM_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/*.c)
41file(GLOB ARM_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/test/*.c)
42file(GLOB LR35902_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/*.c)
43file(GLOB LR35902_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/test/*.c)
44file(GLOB GBA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/*.c)
45file(GLOB GBA_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/test/*.c)
46file(GLOB GB_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/*.c)
47file(GLOB GB_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/test/*.c)
48file(GLOB GBA_CHEATS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/cheats/*.c)
49file(GLOB GBA_RR_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/rr/*.c)
50file(GLOB CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/*.c)
51file(GLOB CORE_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/test/*.c)
52file(GLOB UTIL_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/*.[cSs])
53file(GLOB UTIL_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/test/*.c)
54file(GLOB GUI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/gui/*.c ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/gui/*.c)
55file(GLOB GBA_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/renderers/*.c)
56file(GLOB GBA_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/sio/lockstep.c)
57file(GLOB GBA_EXTRA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/extra/*.c)
58file(GLOB GB_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/sio/lockstep.c)
59file(GLOB GB_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/renderers/*.c)
60file(GLOB GB_EXTRA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/extra/*.c)
61file(GLOB THIRD_PARTY_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/inih/*.c)
62file(GLOB EXTRA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/*.c)
63set(CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-mem.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fifo.c)
64set(VFS_SRC)
65source_group("ARM core" FILES ${ARM_SRC})
66source_group("LR35902 core" FILES ${LR35902_SRC})
67source_group("GBA board" FILES ${GBA_SRC} ${GBA_RENDERER_SRC} ${GBA_SIO_SRC})
68source_group("GBA extra" FILES ${GBA_CHEATS_SRC} ${GBA_RR_SRC})
69source_group("GB board" FILES ${GB_SRC} ${GB_SIO_SRC})
70source_group("Utilities" FILES ${UTIL_SRC})
71include_directories(BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/include ${CMAKE_CURRENT_SOURCE_DIR}/src)
72
73if(NOT CMAKE_BUILD_TYPE)
74 set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
75endif()
76
77include(GNUInstallDirs)
78
79set(LIBDIR "${CMAKE_INSTALL_LIBDIR}" CACHE PATH "Installed library directory")
80mark_as_advanced(LIBDIR)
81
82if (BUILD_LIBRETRO)
83 set(LIBRETRO_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (Libretro)")
84 mark_as_advanced(LIBRETRO_LIBDIR)
85endif()
86
87if (BUILD_OPENEMU)
88 set(OE_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (OpenEmu)")
89 mark_as_advanced(OE_LIBDIR)
90endif()
91
92
93set(CMAKE_INSTALL_RPATH "${LIBDIR}")
94
95if (NOT DEFINED MANDIR)
96 set(MANDIR ${CMAKE_INSTALL_MANDIR})
97endif()
98
99# Function definitions
100include(FindPkgConfig)
101function(find_feature FEATURE_NAME FEATURE_REQUIRES)
102 if (NOT ${FEATURE_NAME})
103 return()
104 endif()
105 if (DISABLE_DEPS)
106 set(${FEATURE_NAME} OFF PARENT_SCOPE)
107 return()
108 endif()
109 foreach(REQUIRE ${FEATURE_REQUIRES})
110 if(NOT ${REQUIRE}_FOUND)
111 find_package(${REQUIRE} QUIET)
112 if(NOT ${REQUIRE}_FOUND)
113 pkg_search_module(${REQUIRE} ${REQUIRE})
114 if (NOT ${REQUIRE}_FOUND)
115 message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
116 set(${FEATURE_NAME} OFF PARENT_SCOPE)
117 return()
118 endif()
119 endif()
120 endif()
121 string(TOUPPER ${REQUIRE} UREQUIRE)
122 set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
123 set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
124 set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
125 if (APPLE)
126 set(IS_FRAMEWORK OFF)
127 set(LIBS)
128 foreach(LIB IN LISTS ${REQUIRE}_LIBRARIES)
129 if(LIB STREQUAL "-framework")
130 set(IS_FRAMEWORK ON)
131 elseif(IS_FRAMEWORK)
132 list(APPEND LIBS "-framework ${LIB}")
133 set(IS_FRAMEWORK OFF)
134 else()
135 list(APPEND LIBS ${LIB})
136 endif()
137 endforeach()
138 set(${UREQUIRE}_LIBRARIES ${LIBS} PARENT_SCOPE)
139 else()
140 set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
141 endif()
142 set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
143 set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
144 endforeach()
145endfunction()
146
147# Version information
148add_custom_target(version-info ALL
149 COMMAND ${CMAKE_COMMAND}
150 -DBINARY_NAME=${BINARY_NAME}
151 -DCONFIG_FILE=${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in
152 -DOUT_FILE=${CMAKE_CURRENT_BINARY_DIR}/version.c
153 -P ${CMAKE_CURRENT_SOURCE_DIR}/version.cmake
154 WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
155
156include(${CMAKE_CURRENT_SOURCE_DIR}/version.cmake)
157configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in ${CMAKE_CURRENT_BINARY_DIR}/version.c)
158
159list(APPEND UTIL_SRC ${CMAKE_CURRENT_BINARY_DIR}/version.c)
160source_group("Generated sources" FILES ${CMAKE_CURRENT_BINARY_DIR}/version.c)
161
162# Advanced settings
163if(NOT DEFINED 3DS)
164 # LTO appears to make 3DS binary slower
165 set(DEFAULT_LTO ON)
166else()
167 set(DEFAULT_LTO OFF)
168endif()
169
170set(BUILD_LTO ${DEFAULT_LTO} CACHE BOOL "Build with link-time optimization")
171set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
172set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
173set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
174mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
175set(PGO_PRE_FLAGS "-fprofile-generate=${PGO_DIR} -fprofile-arcs")
176set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
177
178if(BUILD_PGO AND NOT PGO_STAGE_2)
179 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
180 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
181 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
182elseif(BUILD_PGO AND PGO_STAGE_2)
183 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
184 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
185 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
186endif()
187
188# Platform support
189if(WIN32)
190 set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
191 add_definitions(-D_WIN32_WINNT=0x0600)
192 list(APPEND OS_LIB ws2_32 shlwapi)
193 list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/vfs-w32.c)
194 file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/*.c)
195 source_group("Windows-specific code" FILES ${OS_SRC})
196 if(MSVC)
197 add_definitions(-DNOMINMAX -DWIN32_LEAN_AND_MEAN)
198 set(CMAKE_WINDOWS_EXPORT_ALL_SYMBOLS TRUE)
199 endif()
200elseif(UNIX)
201 set(USE_PTHREADS ON)
202 add_definitions(-DUSE_PTHREADS)
203
204 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
205 add_definitions(-D_GNU_SOURCE)
206 endif()
207 if(NOT APPLE AND NOT HAIKU)
208 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
209 endif()
210
211 list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
212 file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/posix/*.c)
213 source_group("POSIX-specific code" FILES ${OS_SRC})
214endif()
215
216if(APPLE)
217 add_definitions(-D_DARWIN_C_SOURCE)
218 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
219endif()
220
221if(NOT HAIKU AND NOT MSVC AND NOT PSP2)
222 set(M_LIBRARY m)
223endif()
224list(APPEND OS_LIB ${M_LIBRARY})
225
226if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
227 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
228 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
229endif()
230
231if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
232 if(NOT BUILD_EGL)
233 add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
234 endif()
235endif()
236
237if(BUILD_RASPI)
238 set(BUILD_GL OFF CACHE BOOL "OpenGL not supported" FORCE)
239endif()
240
241if(BUILD_PANDORA)
242 add_definitions(-DBUILD_PANDORA)
243endif()
244
245if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
246 enable_language(ASM)
247endif()
248
249if(PSP2 OR WII)
250 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-format")
251endif()
252
253if(DEFINED 3DS OR DEFINED PSP2 OR DEFINED WII)
254 set(USE_DEBUGGERS OFF)
255 set(USE_SQLITE3 OFF)
256endif()
257
258if(NOT M_CORE_GBA)
259 set(USE_GDB_STUB OFF)
260endif()
261
262if(NOT USE_DEBUGGERS)
263 set(USE_EDITLINE OFF)
264 set(USE_GDB_STUB OFF)
265endif()
266
267if(WII)
268 add_definitions(-U__STRICT_ANSI__)
269endif()
270
271if(DEFINED 3DS)
272 add_definitions(-D_GNU_SOURCE)
273endif()
274
275include(CheckFunctionExists)
276check_function_exists(strdup HAVE_STRDUP)
277check_function_exists(strndup HAVE_STRNDUP)
278if(NOT DEFINED PSP2)
279 check_function_exists(localtime_r HAVE_LOCALTIME_R)
280endif()
281if(NOT CMAKE_SYSTEM_NAME STREQUAL "Generic")
282 check_function_exists(snprintf_l HAVE_SNPRINTF_L)
283 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
284 # The strtof_l on Linux not actually exposed nor actually strtof_l
285 set(HAVE_STRTOF_L OFF)
286 else()
287 check_function_exists(strtof_l HAVE_STRTOF_L)
288 endif()
289 check_function_exists(newlocale HAVE_NEWLOCALE)
290 check_function_exists(freelocale HAVE_FREELOCALE)
291 check_function_exists(uselocale HAVE_USELOCALE)
292 check_function_exists(setlocale HAVE_SETLOCALE)
293else()
294 if(DEFINED 3DS)
295 check_function_exists(snprintf_l HAVE_SNPRINTF_L)
296 check_function_exists(strtof_l HAVE_STRTOF_L)
297 check_function_exists(newlocale HAVE_NEWLOCALE)
298 check_function_exists(freelocale HAVE_FREELOCALE)
299 check_function_exists(uselocale HAVE_USELOCALE)
300 check_function_exists(setlocale HAVE_SETLOCALE)
301 endif()
302 if(NOT DEFINED 3DS AND NOT DEFINED PSP2 AND NOT DEFINED WII)
303 set(DISABLE_DEPS ON CACHE BOOL "This platform cannot build with dependencies" FORCE)
304 endif()
305 set(DISABLE_FRONTENDS ON)
306 set(MINIMAL_CORE ON)
307 set(ENABLE_EXTRA ON)
308endif()
309
310check_function_exists(chmod HAVE_CHMOD)
311check_function_exists(umask HAVE_UMASK)
312
313set(FUNCTION_DEFINES)
314
315if(HAVE_STRDUP)
316 list(APPEND FUNCTION_DEFINES HAVE_STRDUP)
317endif()
318
319if(HAVE_STRNDUP)
320 list(APPEND FUNCTION_DEFINES HAVE_STRNDUP)
321endif()
322
323if(HAVE_LOCALTIME_R)
324 list(APPEND FUNCTION_DEFINES HAVE_LOCALTIME_R)
325endif()
326
327if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE OR APPLE OR DEFINED 3DS)
328 list(APPEND FUNCTION_DEFINES HAVE_LOCALE)
329 if (HAVE_STRTOF_L)
330 list(APPEND FUNCTION_DEFINES HAVE_STRTOF_L)
331 endif()
332 if (HAVE_SNPRINTF_L)
333 list(APPEND FUNCTION_DEFINES HAVE_SNPRINTF_L)
334 endif()
335endif()
336
337if(HAVE_SETLOCALE)
338 list(APPEND FUNCTION_DEFINES HAVE_SETLOCALE)
339endif()
340
341if(HAVE_CHMOD)
342 list(APPEND FUNCTION_DEFINES HAVE_CHMOD)
343endif()
344
345if(HAVE_UMASK)
346 list(APPEND FUNCTION_DEFINES HAVE_UMASK)
347endif()
348
349# Feature dependencies
350set(FEATURE_DEFINES)
351set(FEATURES)
352if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
353 set(LIBEDIT_LIBRARIES -ledit)
354 if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
355 list(APPEND LIBEDIT_LIBRARIES -ltermcap)
356 endif()
357else()
358 find_feature(USE_EDITLINE "libedit")
359endif()
360if(BUILD_GL)
361 find_package(OpenGL QUIET)
362 if(NOT OPENGL_FOUND)
363 set(BUILD_GL OFF CACHE BOOL "OpenGL not found" FORCE)
364 endif()
365endif()
366if(NOT BUILD_GL)
367 set(OPENGLE_LIBRARY "" CACHE PATH "" FORCE)
368endif()
369if(BUILD_GLES2 AND NOT BUILD_RASPI)
370 find_path(OPENGLES2_INCLUDE_DIR NAMES GLES2/gl2.h)
371 find_library(OPENGLES2_LIBRARY NAMES GLESv2 GLESv2_CM)
372 if(NOT OPENGLES2_INCLUDE_DIR OR NOT OPENGLES2_LIBRARY)
373 set(BUILD_GLES2 OFF CACHE BOOL "OpenGL|ES 2 not found" FORCE)
374 endif()
375endif()
376if(NOT BUILD_GLES2)
377 set(OPENGLES2_LIBRARY "" CACHE PATH "" FORCE)
378endif()
379set(WANT_ZLIB ${USE_ZLIB})
380set(WANT_PNG ${USE_PNG})
381set(WANT_LIBZIP ${USE_LIBZIP})
382set(WANT_SQLITE3 ${USE_SQLITE3})
383set(USE_CMOCKA ${BUILD_SUITE})
384
385find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
386find_feature(USE_ZLIB "ZLIB")
387find_feature(USE_MINIZIP "minizip")
388find_feature(USE_PNG "PNG")
389find_feature(USE_LIBZIP "libzip")
390find_feature(USE_MAGICK "MagickWand")
391find_feature(USE_EPOXY "epoxy")
392find_feature(USE_CMOCKA "cmocka")
393find_feature(USE_SQLITE3 "sqlite3")
394
395# Features
396set(DEBUGGER_SRC
397 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/debugger.c
398 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/parser.c
399 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/symbols.c
400 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/cli-debugger.c)
401
402set(FEATURE_SRC)
403set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
404
405if(DISABLE_DEPS)
406 set(USE_GDB_STUB OFF)
407endif()
408
409if(USE_EDITLINE)
410 list(APPEND FEATURES EDITLINE)
411 include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
412 link_directories(${LIBEDIT_LIBRARY_DIRS})
413 set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
414 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
415 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/editline/cli-el-backend.c")
416else()
417 set(DEBUGGER_LIB "")
418endif()
419
420if(USE_GDB_STUB)
421 list(APPEND FEATURES GDB_STUB)
422 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/gdb-stub.c)
423endif()
424source_group("Debugger" FILES ${DEBUGGER_SRC})
425
426if(USE_FFMPEG)
427 list(APPEND FEATURES FFMPEG)
428 pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
429 if(NOT LIBSWRESAMPLE_FOUND)
430 list(APPEND FEATURES LIBAV)
431 endif()
432 include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
433 link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
434 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/ffmpeg/ffmpeg-encoder.c")
435 string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
436 string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
437 string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
438 string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
439 string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
440 list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
441 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR}|libavcodec-extra-${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
442 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavformat${LIBAVFORMAT_VERSION_MAJOR}|libavformat-ffmpeg${LIBAVFORMAT_VERSION_MAJOR}")
443 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavresample${LIBAVRESAMPLE_VERSION_MAJOR}|libavresample-ffmpeg${LIBAVRESAMPLE_VERSION_MAJOR}")
444 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavutil${LIBAVUTIL_VERSION_MAJOR}|libavutil-ffmpeg${LIBAVUTIL_VERSION_MAJOR}")
445 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libswscale${LIBSWSCALE_VERSION_MAJOR}|libswscale-ffmpeg${LIBSWSCALE_VERSION_MAJOR}")
446 set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
447 if(APPLE)
448 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
449 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
450 endif()
451endif()
452
453list(APPEND THIRD_PARTY_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
454
455if(USE_MAGICK)
456 list(APPEND FEATURES MAGICK)
457 include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
458 link_directories(${MAGICKWAND_LIBRARY_DIRS})
459 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/imagemagick/imagemagick-gif-encoder.c")
460 list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
461 string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
462 string(REGEX MATCH "^[0-9]+" MAGICKWAND_VERSION_MAJOR ${MagickWand_VERSION})
463 if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
464 set(MAGICKWAND_DEB_VERSION "5")
465 elseif(${MagickWand_VERSION} EQUAL "6.9.7")
466 set(MAGICKWAND_DEB_VERSION "-6.q16-3")
467 else()
468 set(MAGICKWAND_DEB_VERSION "-6.q16-2")
469 endif()
470 list(APPEND FEATURE_DEFINES MAGICKWAND_VERSION_MAJOR=${MAGICKWAND_VERSION_MAJOR})
471
472 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
473endif()
474
475if(WANT_ZLIB AND NOT USE_ZLIB)
476 set(SKIP_INSTALL_ALL ON)
477 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib zlib)
478 set_property(TARGET zlibstatic PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/zlib;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib)
479 set_property(TARGET zlib PROPERTY EXCLUDE_FROM_ALL ON)
480 set_property(TARGET example PROPERTY EXCLUDE_FROM_ALL ON)
481 set_property(TARGET minigzip PROPERTY EXCLUDE_FROM_ALL ON)
482 set(ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
483 set(ZLIB_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
484 set(ZLIB_LIBRARY zlibstatic)
485 list(APPEND DEPENDENCY_LIB zlibstatic)
486 set(USE_ZLIB ON)
487endif()
488
489if(USE_ZLIB)
490 list(APPEND FEATURES ZLIB)
491 include_directories(AFTER ${ZLIB_INCLUDE_DIRS})
492 list(APPEND DEPENDENCY_LIB ${ZLIB_LIBRARIES})
493 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},zlib1g")
494endif()
495
496if(WANT_PNG AND USE_ZLIB AND NOT USE_PNG)
497 set(PNG_STATIC ON CACHE BOOL "" FORCE)
498 set(PNG_SHARED OFF CACHE BOOL "" FORCE)
499 set(PNG_TESTS OFF CACHE BOOL "" FORCE)
500 set(SKIP_INSTALL_ALL ON)
501 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng libpng)
502 set_property(TARGET png16_static PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/libpng;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng;${ZLIB_INCLUDE_DIRS})
503 set(PNG_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng ${CMAKE_CURRENT_BINARY_DIR}/libpng)
504 list(APPEND DEPENDENCY_LIB png16_static)
505 set(USE_PNG ON)
506endif()
507
508if(USE_PNG)
509 list(APPEND FEATURES PNG)
510 include_directories(AFTER ${PNG_INCLUDE_DIRS})
511 list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
512 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng12-0")
513endif()
514
515if(WANT_SQLITE3 AND NOT USE_SQLITE3)
516 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/sqlite3.c)
517 include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/)
518 set(USE_SQLITE3 ON)
519endif()
520
521if(USE_LIBZIP)
522 include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
523 link_directories(${LIBZIP_LIBRARY_DIRS})
524 list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
525 list(APPEND FEATURES LIBZIP)
526 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
527 string(REGEX MATCH "^[0-9]+" LIBZIP_VERSION_MAJOR ${libzip_VERSION})
528 if (LIBZIP_VERSION_MAJOR LESS 1)
529 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
530 elseif(LIBZIP_VERSION_MAJOR EQUAL 1)
531 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip4")
532 else()
533 message(AUTHOR_WARNING Unknown version of libzip detected: ${libzip_VERSION})
534 endif()
535elseif(USE_MINIZIP)
536 include_directories(AFTER ${MINIZIP_INCLUDE_DIRS})
537 link_directories(${MINIZIP_LIBRARY_DIRS})
538 list(APPEND DEPENDENCY_LIB ${MINIZIP_LIBRARIES})
539 list(APPEND FEATURES MINIZIP)
540 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
541 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libminizip1")
542elseif(USE_ZLIB)
543 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c
544 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
545 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c)
546 if(NOT MSVC)
547 set_source_files_properties(
548 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
549 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c
550 PROPERTIES COMPILE_FLAGS "-Wno-unused-parameter -Wno-implicit-function-declaration")
551 endif()
552endif()
553
554if (USE_LZMA)
555 include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/third-party/lzma)
556 add_definitions(-D_7ZIP_PPMD_SUPPPORT)
557 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-lzma.c)
558 set(LZMA_SRC
559 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
560 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
561 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
562 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
563 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
564 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
565 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zDec.c
566 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
567 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Delta.c
568 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
569 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
570 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra.c
571 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra86.c
572 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/BraIA64.c
573 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
574 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
575 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
576 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zFile.c
577 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
578 list(APPEND VFS_SRC ${LZMA_SRC})
579 list(APPEND FEATURES LZMA)
580endif()
581
582if(USE_EPOXY)
583 add_definitions(-DBUILD_GL -DBUILD_GLES2)
584 list(APPEND FEATURES EPOXY)
585 include_directories(AFTER ${EPOXY_INCLUDE_DIRS})
586 set(OPENGLES2_LIBRARY ${EPOXY_LIBRARIES})
587 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libepoxy0")
588endif()
589
590if(USE_SQLITE3)
591 list(APPEND FEATURES SQLITE3)
592 include_directories(AFTER ${SQLITE3_INCLUDE_DIRS})
593 list(APPEND DEPENDENCY_LIB ${SQLITE3_LIBRARIES})
594 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libsqlite3-0")
595 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/sqlite3/no-intro.c")
596endif()
597
598set(TEST_SRC ${CORE_TEST_SRC})
599if(M_CORE_GB)
600 add_definitions(-DM_CORE_GB)
601 list(APPEND CORE_SRC
602 ${LR35902_SRC}
603 ${GB_SRC}
604 ${GB_RENDERER_SRC})
605 list(APPEND DEBUGGER_SRC
606 ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/cli-debugger.c
607 ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/debugger.c
608 ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/memory-debugger.c
609 ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/debugger/cli.c
610 ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/debugger/symbols.c)
611 list(APPEND TEST_SRC
612 ${LR35902_TEST_SRC}
613 ${GB_TEST_SRC})
614endif()
615
616if(M_CORE_GBA)
617 add_definitions(-DM_CORE_GBA)
618 list(APPEND CORE_SRC
619 ${ARM_SRC}
620 ${GBA_SRC}
621 ${GBA_CHEATS_SRC}
622 ${GBA_RENDERER_SRC})
623 list(APPEND DEBUGGER_SRC
624 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c
625 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/debugger.c
626 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/memory-debugger.c
627 ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/debugger/cli.c)
628 list(APPEND TEST_SRC
629 ${ARM_TEST_SRC}
630 ${GBA_TEST_SRC})
631 if(NOT M_CORE_GB)
632 list(APPEND CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/audio.c)
633 endif()
634endif()
635
636if(USE_DEBUGGERS)
637 list(APPEND FEATURE_SRC ${DEBUGGER_SRC})
638 list(APPEND FEATURES DEBUGGERS)
639endif()
640
641foreach(FEATURE IN LISTS FEATURES)
642 list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
643endforeach()
644
645source_group("Virtual files" FILES ${CORE_VFS_SRC} ${VFS_SRC})
646source_group("Extra features" FILES ${FEATURE_SRC})
647source_group("Third-party code" FILES ${THIRD_PARTY_SRC})
648
649# Platform binaries
650if(DEFINED 3DS)
651 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/3ds ${CMAKE_CURRENT_BINARY_DIR}/3ds)
652endif()
653
654if(DEFINED WII)
655 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/wii ${CMAKE_CURRENT_BINARY_DIR}/wii)
656endif()
657
658if(DEFINED PSP2)
659 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/psp2 ${CMAKE_CURRENT_BINARY_DIR}/psp2)
660endif()
661
662# Binaries
663list(APPEND CORE_SRC
664 ${UTIL_SRC}
665 ${CORE_VFS_SRC}
666 ${OS_SRC}
667 ${THIRD_PARTY_SRC})
668list(APPEND TEST_SRC ${UTIL_TEST_SRC})
669
670set(SRC ${CORE_SRC} ${VFS_SRC})
671if(NOT MINIMAL_CORE)
672 set(ENABLE_EXTRA ON)
673 if(M_CORE_GBA)
674 list(APPEND SRC
675 ${GBA_SIO_SRC})
676 endif()
677 if(M_CORE_GB)
678 list(APPEND SRC
679 ${GB_SIO_SRC})
680 endif()
681 list(APPEND SRC
682 ${FEATURE_SRC})
683endif()
684
685if(ENABLE_EXTRA)
686 if(M_CORE_GBA)
687 list(APPEND SRC
688 ${GBA_RR_SRC}
689 ${GBA_EXTRA_SRC})
690 endif()
691 if(M_CORE_GB)
692 list(APPEND SRC
693 ${GB_EXTRA_SRC})
694 endif()
695 list(APPEND SRC
696 ${EXTRA_SRC})
697endif()
698
699if(NOT SKIP_LIBRARY)
700 if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
701 set(BUILD_SHARED ON)
702 endif()
703
704 if(BUILD_SHARED)
705 add_library(${BINARY_NAME} SHARED ${SRC} ${VFS_SRC})
706 if(BUILD_STATIC)
707 add_library(${BINARY_NAME}-static STATIC ${SRC})
708 set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
709 install(TARGETS ${BINARY_NAME}-static DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
710 add_dependencies(${BINARY_NAME}-static version-info)
711 endif()
712 else()
713 add_library(${BINARY_NAME} STATIC ${SRC})
714 endif()
715
716 add_dependencies(${BINARY_NAME} version-info)
717 set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
718
719 target_link_libraries(${BINARY_NAME} ${DEBUGGER_LIB} ${DEPENDENCY_LIB} ${OS_LIB})
720 install(TARGETS ${BINARY_NAME} LIBRARY DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME} NAMELINK_SKIP ARCHIVE DESTINATION ${LIBDIR} RUNTIME DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
721 if(UNIX AND NOT APPLE)
722 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-16.png DESTINATION share/icons/hicolor/16x16/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
723 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-24.png DESTINATION share/icons/hicolor/24x24/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
724 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-32.png DESTINATION share/icons/hicolor/32x32/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
725 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-48.png DESTINATION share/icons/hicolor/48x48/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
726 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-64.png DESTINATION share/icons/hicolor/64x64/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
727 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-96.png DESTINATION share/icons/hicolor/96x96/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
728 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-128.png DESTINATION share/icons/hicolor/128x128/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
729 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-256.png DESTINATION share/icons/hicolor/256x256/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
730 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-512.png DESTINATION share/icons/hicolor/512x512/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
731 endif()
732else()
733 set(BUILD_SHARED OFF)
734 set(BUILD_STATIC OFF)
735 find_library(${BINARY_NAME} ${BINARY_NAME})
736 if(NOT ${BINARY_NAME}_FOUND)
737 set(DISABLE_FRONTENDS ON)
738 set(BUILD_PERF OFF)
739 set(BUILD_TEST OFF)
740 set(BUILD_SUITE OFF)
741 endif()
742endif()
743
744if(BUILD_GL)
745 add_definitions(-DBUILD_GL)
746endif()
747
748if(BUILD_GLES2)
749 add_definitions(-DBUILD_GLES2)
750endif()
751
752if(DISABLE_FRONTENDS)
753 set(BUILD_SDL OFF)
754 set(BUILD_QT OFF)
755endif()
756
757if(BUILD_LIBRETRO)
758 file(GLOB RETRO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/libretro/*.c)
759 add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
760 set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5;DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=2")
761 target_link_libraries(${BINARY_NAME}_libretro ${OS_LIB})
762 install(TARGETS ${BINARY_NAME}_libretro LIBRARY DESTINATION ${LIBRETRO_LIBDIR} COMPONENT ${BINARY_NAME}_libretro NAMELINK_SKIP)
763endif()
764
765if(BUILD_OPENEMU)
766 find_library(FOUNDATION Foundation)
767 find_library(OPENEMUBASE OpenEmuBase)
768 file(GLOB OE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/*.m)
769 add_library(${BINARY_NAME}-openemu MODULE ${CORE_SRC} ${OE_SRC})
770 set_target_properties(${BINARY_NAME}-openemu PROPERTIES
771 MACOSX_BUNDLE_INFO_PLIST ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/Info.plist.in
772 BUNDLE TRUE
773 BUNDLE_EXTENSION oecoreplugin
774 OUTPUT_NAME ${PROJECT_NAME}
775 COMPILE_DEFINITIONS "DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=1")
776 target_link_libraries(${BINARY_NAME}-openemu ${OS_LIB} ${FOUNDATION} ${OPENEMUBASE})
777 install(TARGETS ${BINARY_NAME}-openemu LIBRARY DESTINATION ${OE_LIBDIR} COMPONENT ${BINARY_NAME}.oecoreplugin NAMELINK_SKIP)
778endif()
779
780if(BUILD_SDL)
781 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/sdl ${CMAKE_CURRENT_BINARY_DIR}/sdl)
782 # The SDL platform CMakeLists could decide to disable SDL, so check again before adding the define.
783 if(BUILD_SDL)
784 add_definitions(-DBUILD_SDL)
785 endif()
786endif()
787
788if(BUILD_QT)
789 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/qt ${CMAKE_CURRENT_BINARY_DIR}/qt)
790endif()
791
792if(BUILD_PERF)
793 set(PERF_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/perf-main.c)
794 if(UNIX AND NOT APPLE)
795 list(APPEND PERF_LIB rt)
796 endif()
797
798 add_executable(${BINARY_NAME}-perf ${PERF_SRC})
799 target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB} ${OS_LIB})
800 set_target_properties(${BINARY_NAME}-perf PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
801 install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
802 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
803endif()
804
805if(BUILD_TEST)
806 add_executable(${BINARY_NAME}-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/fuzz-main.c)
807 target_link_libraries(${BINARY_NAME}-fuzz ${BINARY_NAME})
808 set_target_properties(${BINARY_NAME}-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
809 add_executable(tbl-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/tbl-fuzz-main.c)
810 target_link_libraries(tbl-fuzz ${BINARY_NAME})
811 set_target_properties(tbl-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
812 install(TARGETS ${BINARY_NAME}-fuzz tbl-fuzz DESTINATION bin COMPONENT ${BINARY_NAME}-test)
813endif()
814
815if(NOT USE_CMOCKA)
816 set(BUILD_SUITE OFF)
817endif()
818if(BUILD_SUITE)
819 enable_testing()
820 include_directories(AFTER ${CMOCKA_INCLUDE_DIRS})
821 link_directories(${CMOCKA_LIBRARY_DIRS})
822
823 add_executable(${BINARY_NAME}-suite ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/suite-main.c ${TEST_SRC})
824 target_link_libraries(${BINARY_NAME}-suite ${BINARY_NAME} ${PLATFORM_LIBRARY} cmocka)
825 set_target_properties(${BINARY_NAME}-suite PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
826 add_test(${BINARY_NAME}-suite ${BINARY_NAME}-suite)
827endif()
828
829if(BUILD_PYTHON)
830 enable_testing()
831 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/python ${CMAKE_CURRENT_BINARY_DIR}/python)
832endif()
833
834if(BUILD_EXAMPLE)
835 add_executable(${BINARY_NAME}-example-server ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/server.c)
836 target_link_libraries(${BINARY_NAME}-example-server ${BINARY_NAME})
837 set_target_properties(${BINARY_NAME}-example-server PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
838
839 if(BUILD_SDL)
840 add_executable(${BINARY_NAME}-example-client ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/client.c)
841 target_link_libraries(${BINARY_NAME}-example-client ${BINARY_NAME} ${SDL_LIBRARY} ${SDLMAIN_LIBRARY} ${OPENGL_LIBRARY} ${OPENGLES2_LIBRARY})
842 set_target_properties(${BINARY_NAME}-example-client PROPERTIES
843 COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}"
844 INCLUDE_DIRECTORIES "${SDL_INCLUDE_DIR};${CMAKE_CURRENT_SOURCE_DIR}/src;${CMAKE_CURRENT_SOURCE_DIR}/include")
845 endif()
846endif()
847
848configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/flags.h.in ${CMAKE_CURRENT_BINARY_DIR}/flags.h)
849install(FILES ${CMAKE_CURRENT_BINARY_DIR}/flags.h DESTINATION include/mgba COMPONENT lib${BINARY_NAME})
850
851# Packaging
852set(CPACK_PACKAGE_VERSION ${VERSION_STRING})
853set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
854set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
855set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
856set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
857set(CPACK_RESOURCE_FILE_README ${CMAKE_CURRENT_SOURCE_DIR}/README.md)
858
859set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
860set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
861set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
862set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README.md")
863set(CPACK_DEBIAN_PACKAGE_SECTION "games")
864
865SET(CPACK_DEB_COMPONENT_INSTALL ON)
866
867set(CPACK_STRIP_FILES ${BINARY_NAME})
868
869install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/README.md ${CMAKE_CURRENT_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
870
871include(CPack)
872
873# Summaries
874set(SUMMARY_GL_LIST)
875if(USE_EPOXY)
876 set(SUMMARY_GL_LIST "libepoxy")
877else()
878 if(BUILD_GL)
879 list(APPEND SUMMARY_GL_LIST "OpenGL")
880 endif()
881 if(BUILD_GLES2)
882 list(APPEND SUMMARY_GL_LIST "OpenGL|ES 2")
883 endif()
884endif()
885if(NOT SUMMARY_GL_LIST)
886 set(SUMMARY_GL OFF)
887else()
888 string(REPLACE ";" ", " SUMMARY_GL "${SUMMARY_GL_LIST}")
889endif()
890if(USE_LIBZIP)
891 set(SUMMARY_ZIP libzip)
892elseif(USE_MINIZIP)
893 set(SUMMARY_ZIP "minizip (external)")
894elseif(USE_ZLIB)
895 set(SUMMARY_ZIP "minizip (included)")
896else()
897 set(SUMMARY_ZIP OFF)
898endif()
899
900if(NOT QUIET)
901 message(STATUS "Build type: ${CMAKE_BUILD_TYPE}")
902 message(STATUS "Platforms:")
903 message(STATUS " Game Boy Advance: ${M_CORE_GBA}")
904 message(STATUS " Game Boy: ${M_CORE_GB}")
905 message(STATUS "Features:")
906 message(STATUS " Debuggers: ${USE_DEBUGGERS}")
907 message(STATUS " CLI debugger: ${USE_EDITLINE}")
908 message(STATUS " GDB stub: ${USE_GDB_STUB}")
909 message(STATUS " Video recording: ${USE_FFMPEG}")
910 message(STATUS " GIF recording: ${USE_MAGICK}")
911 message(STATUS " Screenshot/advanced savestate support: ${USE_PNG}")
912 message(STATUS " ZIP support: ${SUMMARY_ZIP}")
913 message(STATUS " 7-Zip support: ${USE_LZMA}")
914 message(STATUS " SQLite3 game database: ${USE_SQLITE3}")
915 message(STATUS " OpenGL support: ${SUMMARY_GL}")
916 message(STATUS "Frontends:")
917 message(STATUS " Qt: ${BUILD_QT}")
918 message(STATUS " SDL (${SDL_VERSION}): ${BUILD_SDL}")
919 message(STATUS " Profiling: ${BUILD_PERF}")
920 message(STATUS " Test harness: ${BUILD_TEST}")
921 message(STATUS " Test suite: ${BUILD_SUITE}")
922 message(STATUS " Python bindings: ${BUILD_PYTHON}")
923 message(STATUS " Examples: ${BUILD_EXAMPLE}")
924 message(STATUS "Cores:")
925 message(STATUS " Libretro core: ${BUILD_LIBRETRO}")
926 if(APPLE)
927 message(STATUS " OpenEmu core: ${BUILD_OPENEMU}")
928 endif()
929 message(STATUS "Libraries:")
930 message(STATUS " Static: ${BUILD_STATIC}")
931 message(STATUS " Shared: ${BUILD_SHARED}")
932endif()