CMakeLists.txt (view raw)
1cmake_minimum_required(VERSION 2.6)
2project(mGBA C)
3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
4set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -std=gnu99")
5set(USE_CLI_DEBUGGER ON CACHE BOOL "Whether or not to enable the CLI-mode ARM debugger")
6set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
7set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
8set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
9set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable ZIP support")
10set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
11set(USE_BLIP ON CACHE BOOL "Whether or not to enable blip_buf support")
12set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
13set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
14set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
15set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
16set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
17set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
18file(GLOB ARM_SRC ${CMAKE_SOURCE_DIR}/src/arm/*.c)
19file(GLOB GBA_SRC ${CMAKE_SOURCE_DIR}/src/gba/*.c)
20file(GLOB GBA_SV_SRC ${CMAKE_SOURCE_DIR}/src/gba/supervisor/*.c)
21file(GLOB UTIL_SRC ${CMAKE_SOURCE_DIR}/src/util/*.[cSs])
22file(GLOB VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/*.c)
23file(GLOB RENDERER_SRC ${CMAKE_SOURCE_DIR}/src/gba/renderers/video-software.c)
24file(GLOB THIRD_PARTY_SRC ${CMAKE_SOURCE_DIR}/src/third-party/inih/*.c)
25list(APPEND UTIL_SRC ${CMAKE_SOURCE_DIR}/src/platform/commandline.c)
26source_group("ARM core" FILES ${ARM_SRC})
27source_group("GBA board" FILES ${GBA_SRC} ${RENDERER_SRC})
28source_group("GBA supervisor" FILES ${GBA_SV_SRC})
29source_group("Utilities" FILES ${UTIL_SRC} ${VFS_SRC}})
30include_directories(${CMAKE_SOURCE_DIR}/src/arm)
31include_directories(${CMAKE_SOURCE_DIR}/src)
32
33if(NOT CMAKE_BUILD_TYPE)
34 set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
35endif()
36
37include(GNUInstallDirs)
38
39# Function definitions
40include(FindPkgConfig)
41function(find_feature FEATURE_NAME FEATURE_REQUIRES)
42 if (NOT ${FEATURE_NAME})
43 return()
44 endif()
45 foreach(REQUIRE ${FEATURE_REQUIRES})
46 if(NOT ${REQUIRE}_FOUND)
47 find_package(${REQUIRE} QUIET)
48 if(NOT ${REQUIRE}_FOUND)
49 pkg_search_module(${REQUIRE} ${REQUIRE})
50 if (NOT ${REQUIRE}_FOUND)
51 message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
52 set(${FEATURE_NAME} OFF PARENT_SCOPE)
53 return()
54 endif()
55 endif()
56 endif()
57 string(TOUPPER ${REQUIRE} UREQUIRE)
58 set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
59 set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
60 set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
61 set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
62 set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
63 set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
64 endforeach()
65endfunction()
66
67# Version information
68set(LIB_VERSION_MAJOR 0)
69set(LIB_VERSION_MINOR 2)
70set(LIB_VERSION_PATCH 0)
71set(LIB_VERSION_ABI 0.2)
72set(LIB_VERSION_STRING ${LIB_VERSION_MAJOR}.${LIB_VERSION_MINOR}.${LIB_VERSION_PATCH})
73
74# Advanced settings
75set(BUILD_PGO CACHE BOOL "Build with profiling-guided optimization")
76set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
77set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
78mark_as_advanced(BUILD_PGO PGO_STAGE_2 PGO_DIR)
79set(PGO_PRE_FLAGS "-pg -fprofile-generate=${PGO_DIR} -fprofile-arcs")
80set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
81
82if(BUILD_PGO AND NOT PGO_STAGE_2)
83 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
84 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
85 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
86elseif(BUILD_PGO AND PGO_STAGE_2)
87 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
88 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
89 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
90endif()
91
92add_definitions(-DBINARY_NAME="${BINARY_NAME}" -DPROJECT_NAME="${PROJECT_NAME}" -DPROJECT_VERSION="${LIB_VERSION_STRING}")
93
94# Feature dependencies
95if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
96 set(LIBEDIT_LIBRARIES -ledit)
97else()
98 find_feature(USE_CLI_DEBUGGER "libedit")
99endif()
100find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
101find_feature(USE_PNG "ZLIB;PNG")
102find_feature(USE_LIBZIP "libzip")
103find_feature(USE_MAGICK "MagickWand")
104
105# Platform support
106if(WIN32)
107 add_definitions(-D_WIN32_WINNT=0x0600)
108 list(APPEND OS_LIB ws2_32)
109 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/windows/*.c)
110 source_group("Windows-specific code" FILES ${OS_SRC})
111else()
112 add_definitions(-DUSE_PTHREADS)
113 if(NOT APPLE)
114 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
115 endif()
116 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/posix/*.c)
117 source_group("POSIX-specific code" FILES ${OS_SRC})
118endif()
119
120if(APPLE)
121 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
122endif()
123
124if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU")
125 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
126 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
127endif()
128
129if(BUILD_BBB OR BUILD_RASPI)
130 enable_language(ASM)
131 if(NOT BUILD_EGL)
132 add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
133 endif()
134endif()
135
136include(CheckFunctionExists)
137check_function_exists(strndup HAVE_STRNDUP)
138check_function_exists(snprintf_l HAVE_SNPRINTF_L)
139if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
140 # The strtof_l on Linux not actually exposed nor actually strtof_l
141 set(HAVE_STRTOF_L OFF)
142else()
143 check_function_exists(strtof_l HAVE_STRTOF_L)
144endif()
145check_function_exists(newlocale HAVE_NEWLOCALE)
146check_function_exists(freelocale HAVE_FREELOCALE)
147check_function_exists(uselocale HAVE_USELOCALE)
148
149if(HAVE_STRNDUP)
150 add_definitions(-DHAVE_STRNDUP)
151endif()
152
153if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE)
154 add_definitions(-DHAVE_LOCALE)
155 if (HAVE_STRTOF_L)
156 add_definitions(-DHAVE_STRTOF_L)
157 endif()
158 if (HAVE_SNPRINTF_L)
159 add_definitions(-DHAVE_SNPRINTF_L)
160 endif()
161endif()
162
163
164# Features
165set(DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/debugger.c ${CMAKE_SOURCE_DIR}/src/debugger/memory-debugger.c)
166set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
167
168if(USE_CLI_DEBUGGER)
169 add_definitions(-DUSE_CLI_DEBUGGER)
170 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/cli-debugger.c)
171 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/parser.c)
172 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/gba/supervisor/cli.c)
173 include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
174 link_directories(${LIBEDIT_LIBRARY_DIRS})
175 set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
176 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
177else()
178 set(DEBUGGER_LIB "")
179endif()
180
181if(USE_GDB_STUB)
182 add_definitions(-DUSE_GDB_STUB)
183 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/gdb-stub.c)
184endif()
185source_group("ARM debugger" FILES ${DEBUGGER_SRC})
186
187if(USE_FFMPEG)
188 add_definitions(-DUSE_FFMPEG)
189 pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
190 if(NOT LIBSWRESAMPLE_FOUND)
191 add_definitions(-DUSE_LIBAV)
192 endif()
193 include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
194 link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
195 list(APPEND UTIL_SRC "${CMAKE_SOURCE_DIR}/src/platform/ffmpeg/ffmpeg-encoder.c")
196 string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
197 string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
198 string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
199 string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
200 string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
201 list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
202 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR},libavformat${LIBAVFORMAT_VERSION_MAJOR},libavresample${LIBAVRESAMPLE_VERSION_MAJOR},libavutil${LIBAVUTIL_VERSION_MAJOR},libswscale${LIBSWSCALE_VERSION_MAJOR}")
203 set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra")
204endif()
205
206if(USE_BLIP)
207 list(APPEND UTIL_SRC "${CMAKE_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
208 add_definitions(-DRESAMPLE_LIBRARY=RESAMPLE_BLIP_BUF)
209else()
210 add_definitions(-DRESAMPLE_LIBRARY=RESAMPLE_NN)
211endif()
212
213if(USE_MAGICK)
214 add_definitions(-DUSE_MAGICK)
215 include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
216 link_directories(${MAGICKWAND_LIBRARY_DIRS})
217 list(APPEND UTIL_SRC "${CMAKE_SOURCE_DIR}/src/platform/imagemagick/imagemagick-gif-encoder.c")
218 list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
219 string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
220 if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
221 set(MAGICKWAND_DEB_VERSION "5")
222 else()
223 set(MAGICKWAND_DEB_VERSION "-6.q16-2")
224 endif()
225 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
226endif()
227
228if(USE_PNG)
229 add_definitions(-DUSE_PNG)
230 include_directories(AFTER ${PNG_INCLUDE_DIRS})
231 list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
232 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng12-0,zlib1g")
233endif()
234
235if(USE_LIBZIP)
236 include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
237 link_directories(${LIBZIP_LIBRARY_DIRS})
238 list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
239 add_definitions(-DENABLE_LIBZIP)
240 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
241endif()
242
243if (USE_LZMA)
244 include_directories(AFTER ${CMAKE_SOURCE_DIR}/third-party/lzma)
245 add_definitions(-D_7ZIP_PPMD_SUPPPORT)
246 set(LZMA_SRC
247 ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-lzma.c
248 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
249 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
250 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
251 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
252 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
253 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
254 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zDec.c
255 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
256 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
257 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
258 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bra.c
259 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bra86.c
260 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
261 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
262 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
263 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zFile.c
264 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
265 list(APPEND UTIL_SRC ${LZMA_SRC})
266 add_definitions(-DENABLE_LZMA)
267endif()
268
269# Binaries
270set(SRC
271 ${ARM_SRC}
272 ${GBA_SRC}
273 ${GBA_SV_SRC}
274 ${DEBUGGER_SRC}
275 ${RENDERER_SRC}
276 ${UTIL_SRC}
277 ${VFS_SRC}
278 ${OS_SRC}
279 ${THIRD_PARTY_SRC})
280
281if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
282 set(BUILD_SHARED ON)
283endif()
284
285if(BUILD_SHARED)
286 add_library(${BINARY_NAME} SHARED ${SRC})
287 if(BUILD_STATIC)
288 add_library(${BINARY_NAME}-static STATIC ${SRC})
289 install(TARGETS ${BINARY_NAME}-static DESTINATION lib COMPONENT lib${BINARY_NAME})
290 endif()
291else()
292 add_library(${BINARY_NAME} STATIC ${SRC})
293endif()
294
295target_link_libraries(${BINARY_NAME} m ${DEBUGGER_LIB} ${OS_LIB} ${DEPENDENCY_LIB})
296install(TARGETS ${BINARY_NAME} DESTINATION lib COMPONENT lib${BINARY_NAME})
297set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI})
298
299if(BUILD_SDL)
300 add_definitions(-DBUILD_SDL)
301 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/sdl ${CMAKE_BINARY_DIR}/sdl)
302endif()
303
304if(BUILD_QT)
305 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/qt ${CMAKE_BINARY_DIR}/qt)
306endif()
307
308if(BUILD_PERF)
309 set(PERF_SRC ${CMAKE_SOURCE_DIR}/src/platform/perf-main.c)
310 if(UNIX AND NOT APPLE)
311 list(APPEND PERF_LIB rt)
312 endif()
313
314 add_executable(${BINARY_NAME}-perf ${PERF_SRC})
315 target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB})
316 install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
317 install(FILES ${CMAKE_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
318endif()
319
320# Packaging
321set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
322set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
323set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
324set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_SOURCE_DIR}/LICENSE)
325set(CPACK_RESOURCE_FILE_README ${CMAKE_SOURCE_DIR}/README.md)
326
327set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
328set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
329set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
330set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_SOURCE_DIR}/README.md")
331set(CPACK_DEBIAN_PACKAGE_SECTION "games")
332
333SET(CPACK_DEB_COMPONENT_INSTALL ON)
334
335set(CPACK_STRIP_FILES ${BINARY_NAME})
336
337install(FILES ${CMAKE_SOURCE_DIR}/README.md ${CMAKE_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
338
339include(CPack)
340
341# Summaries
342message(STATUS "Feature summary:")
343message(STATUS " CLI debugger: ${USE_CLI_DEBUGGER}")
344message(STATUS " GDB stub: ${USE_GDB_STUB}")
345message(STATUS " Video recording: ${USE_FFMPEG}")
346message(STATUS " GIF recording: ${USE_MAGICK}")
347message(STATUS " Screenshot/advanced savestate support: ${USE_PNG}")
348message(STATUS " ZIP support: ${USE_LIBZIP}")
349message(STATUS " 7-Zip support: ${USE_LZMA}")
350message(STATUS " Better audio resampling: ${USE_BLIP}")
351message(STATUS "Frontend summary:")
352message(STATUS " Qt: ${BUILD_QT}")
353message(STATUS " SDL (${SDL_VERSION}): ${BUILD_SDL}")
354message(STATUS " Profiling: ${BUILD_PERF}")
355message(STATUS "Library summary:")
356message(STATUS " Static: ${BUILD_STATIC}")
357message(STATUS " Shared: ${BUILD_SHARED}")