CMakeLists.txt (view raw)
1cmake_minimum_required(VERSION 3.1)
2if(POLICY CMP0025)
3 cmake_policy(SET CMP0025 NEW)
4endif()
5project(medusa)
6set(BINARY_NAME medusa-emu CACHE INTERNAL "Name of output binaries")
7if(NOT MSVC)
8 set(GCC_STD "c99")
9 if(CMAKE_C_COMPILER_ID STREQUAL "GNU" AND CMAKE_COMPILER_VERSION VERSION_LESS "4.3")
10 set(GCC_STD "gnu99")
11 endif()
12 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wno-missing-field-initializers -std=${GCC_STD}")
13else()
14 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_CRT_SECURE_NO_WARNINGS /wd4003 /wd4244 /wd4146")
15endif()
16set(USE_DEBUGGERS ON CACHE BOOL "Whether or not to enable the debugging infrastructure")
17if (NOT WIN32)
18 set(USE_EDITLINE ON CACHE BOOL "Whether or not to enable the CLI-mode debugger")
19endif()
20set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
21set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
22set(USE_ZLIB ON CACHE BOOL "Whether or not to enable zlib support")
23set(USE_MINIZIP ON CACHE BOOL "Whether or not to enable external minizip support")
24set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
25set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable LIBZIP support")
26set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
27set(USE_SQLITE3 ON CACHE BOOL "Whether or not to enable SQLite3 support")
28set(USE_ELF ON CACHE BOOL "Whether or not to enable ELF support")
29set(M_CORE_GBA ON CACHE BOOL "Build Game Boy Advance core")
30set(M_CORE_GB ON CACHE BOOL "Build Game Boy core")
31set(M_CORE_DS ON CACHE BOOL "Build DS core")
32set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
33set(ENABLE_SCRIPTING ON CACHE BOOL "Whether or not to enable scripting support")
34set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
35set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
36set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
37if(APPLE)
38 set(BUILD_OPENEMU OFF CACHE BOOL "Build OpenEmu core")
39endif()
40set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
41set(BUILD_TEST OFF CACHE BOOL "Build testing harness")
42set(BUILD_SUITE OFF CACHE BOOL "Build test suite")
43set(BUILD_EXAMPLE OFF CACHE BOOL "Build example frontends")
44set(BUILD_PYTHON OFF CACHE BOOL "Build Python bindings")
45set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
46set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
47set(SKIP_LIBRARY OFF CACHE BOOL "Skip building the library (useful for only building libretro or OpenEmu cores)")
48set(BUILD_GL ON CACHE STRING "Build with OpenGL")
49set(BUILD_GLES2 OFF CACHE STRING "Build with OpenGL|ES 2")
50set(USE_EPOXY ON CACHE STRING "Build with libepoxy")
51set(DISABLE_DEPS OFF CACHE BOOL "Build without dependencies")
52set(DISTBUILD OFF CACHE BOOL "Build distribution packages")
53if(WIN32)
54 set(WIN32_UNIX_PATHS OFF CACHE BOOL "Use Unix-like paths")
55 mark_as_advanced(WIN32_UNIX_PATHS)
56endif()
57file(GLOB ARM_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/*.c)
58file(GLOB ARM_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/test/*.c)
59file(GLOB LR35902_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/*.c)
60file(GLOB LR35902_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/test/*.c)
61file(GLOB GBA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/*.c)
62file(GLOB GBA_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/test/*.c)
63file(GLOB GB_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/*.c)
64file(GLOB GB_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/test/*.c)
65file(GLOB DS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/ds/*.c)
66file(GLOB GBA_CHEATS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/cheats/*.c)
67file(GLOB GBA_RR_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/rr/*.c)
68file(GLOB CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/*.c)
69file(GLOB CORE_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/test/*.c)
70file(GLOB UTIL_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/*.[cSs])
71file(GLOB UTIL_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/test/*.c)
72file(GLOB GUI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/gui/*.c ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/gui/*.c)
73file(GLOB GBA_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/renderers/*.c)
74file(GLOB GBA_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/sio/*.c)
75file(GLOB GBA_EXTRA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/extra/*.c)
76file(GLOB GB_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/sio/*.c)
77file(GLOB GB_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/renderers/*.c)
78file(GLOB GB_EXTRA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/extra/*.c)
79file(GLOB DS_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/ds/renderers/*.c ${CMAKE_CURRENT_SOURCE_DIR}/src/ds/gx/*.c)
80file(GLOB THIRD_PARTY_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/inih/*.c)
81file(GLOB EXTRA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/*.c)
82set(CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-mem.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fifo.c)
83set(VFS_SRC)
84source_group("ARM core" FILES ${ARM_SRC})
85source_group("LR35902 core" FILES ${LR35902_SRC})
86source_group("GBA board" FILES ${GBA_SRC} ${GBA_RENDERER_SRC} ${GBA_SIO_SRC})
87source_group("GBA extra" FILES ${GBA_CHEATS_SRC} ${GBA_RR_SRC})
88source_group("GB board" FILES ${GB_SRC} ${GB_SIO_SRC})
89source_group("DS board" FILES ${DS_SRC})
90source_group("Utilities" FILES ${UTIL_SRC})
91include_directories(BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/include ${CMAKE_CURRENT_SOURCE_DIR}/src)
92
93if(NOT CMAKE_BUILD_TYPE)
94 set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
95endif()
96
97if(UNIX OR WIN32_UNIX_PATHS)
98 include(GNUInstallDirs)
99 string(REPLACE "${PROJECT_NAME}" "${BINARY_NAME}" CMAKE_INSTALL_DOCDIR "${CMAKE_INSTALL_DOCDIR}")
100else()
101 set(CMAKE_INSTALL_LIBDIR ".")
102 set(CMAKE_INSTALL_BINDIR ".")
103 set(CMAKE_INSTALL_DATADIR ".")
104 set(CMAKE_INSTALL_DOCDIR ".")
105 set(CMAKE_INSTALL_INCLUDEDIR "include")
106endif()
107
108set(LIBDIR "${CMAKE_INSTALL_LIBDIR}" CACHE PATH "Installed library directory")
109mark_as_advanced(LIBDIR)
110
111if (BUILD_LIBRETRO)
112 set(LIBRETRO_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (Libretro)")
113 mark_as_advanced(LIBRETRO_LIBDIR)
114endif()
115
116if (BUILD_OPENEMU)
117 set(OE_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (OpenEmu)")
118 mark_as_advanced(OE_LIBDIR)
119endif()
120
121if (DISTBUILD)
122 set(EXTRA_LICENSES "" CACHE FILEPATH "Extra licenses to include in distribution packaages")
123 mark_as_advanced(EXTRA_LICENSES)
124endif()
125mark_as_advanced(DISTBUILD)
126
127set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${LIBDIR}")
128
129if (NOT DEFINED MANDIR)
130 set(MANDIR ${CMAKE_INSTALL_MANDIR})
131endif()
132
133# Function definitions
134include(FindPkgConfig)
135function(find_feature FEATURE_NAME FEATURE_REQUIRES)
136 if (NOT ${FEATURE_NAME})
137 return()
138 endif()
139 if (DISABLE_DEPS)
140 set(${FEATURE_NAME} OFF PARENT_SCOPE)
141 return()
142 endif()
143 foreach(REQUIRE ${FEATURE_REQUIRES})
144 if(NOT ${REQUIRE}_FOUND)
145 find_package(${REQUIRE} QUIET)
146 if(NOT ${REQUIRE}_FOUND)
147 pkg_search_module(${REQUIRE} ${REQUIRE})
148 if (NOT ${REQUIRE}_FOUND)
149 message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
150 set(${FEATURE_NAME} OFF PARENT_SCOPE)
151 return()
152 endif()
153 endif()
154 endif()
155 string(TOUPPER ${REQUIRE} UREQUIRE)
156 set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
157 set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
158 set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
159 set(${UREQUIRE}_VERSION_STRING ${${REQUIRE}_VERSION_STRING} PARENT_SCOPE)
160 if (APPLE)
161 set(IS_FRAMEWORK OFF)
162 set(LIBS)
163 foreach(LIB IN LISTS ${REQUIRE}_LIBRARIES)
164 if(LIB STREQUAL "-framework")
165 set(IS_FRAMEWORK ON)
166 elseif(IS_FRAMEWORK)
167 list(APPEND LIBS "-framework ${LIB}")
168 set(IS_FRAMEWORK OFF)
169 else()
170 list(APPEND LIBS ${LIB})
171 endif()
172 endforeach()
173 set(${UREQUIRE}_LIBRARIES ${LIBS} PARENT_SCOPE)
174 else()
175 set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
176 endif()
177 set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
178 set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
179 endforeach()
180endfunction()
181
182# Version information
183add_custom_target(version-info ALL
184 COMMAND ${CMAKE_COMMAND}
185 -DBINARY_NAME=${BINARY_NAME}
186 -DCONFIG_FILE=${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in
187 -DOUT_FILE=${CMAKE_CURRENT_BINARY_DIR}/version.c
188 -P ${CMAKE_CURRENT_SOURCE_DIR}/version.cmake
189 WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
190
191include(${CMAKE_CURRENT_SOURCE_DIR}/version.cmake)
192configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in ${CMAKE_CURRENT_BINARY_DIR}/version.c)
193
194list(APPEND UTIL_SRC ${CMAKE_CURRENT_BINARY_DIR}/version.c)
195source_group("Generated sources" FILES ${CMAKE_CURRENT_BINARY_DIR}/version.c)
196
197# Advanced settings
198if(NOT DEFINED 3DS AND NOT (CMAKE_C_COMPILER_ID STREQUAL "GNU" AND CMAKE_COMPILER_VERSION VERSION_LESS "4.5"))
199 # LTO appears to make 3DS binary slower
200 set(DEFAULT_LTO ON)
201else()
202 set(DEFAULT_LTO OFF)
203endif()
204
205set(BUILD_LTO ${DEFAULT_LTO} CACHE BOOL "Build with link-time optimization")
206set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
207set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
208set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
209mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
210set(PGO_PRE_FLAGS "-fprofile-generate=${PGO_DIR} -fprofile-arcs")
211set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
212
213if(BUILD_PGO AND NOT PGO_STAGE_2)
214 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
215 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
216 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
217elseif(BUILD_PGO AND PGO_STAGE_2)
218 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
219 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
220 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
221endif()
222
223# Platform support
224if(WIN32)
225 set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
226 add_definitions(-D_WIN32_WINNT=0x0600)
227 list(APPEND OS_LIB ws2_32 shlwapi)
228 list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/vfs-w32.c)
229 file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/*.c)
230 source_group("Windows-specific code" FILES ${OS_SRC})
231 if(MSVC)
232 add_definitions(-DNOMINMAX -DWIN32_LEAN_AND_MEAN)
233 set(CMAKE_WINDOWS_EXPORT_ALL_SYMBOLS TRUE)
234 endif()
235elseif(UNIX)
236 set(USE_PTHREADS ON)
237 add_definitions(-DUSE_PTHREADS)
238
239 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
240 add_definitions(-D_GNU_SOURCE)
241 endif()
242 if(NOT APPLE AND NOT HAIKU)
243 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
244 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -pthread")
245 endif()
246
247 list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
248 file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/posix/*.c)
249 source_group("POSIX-specific code" FILES ${OS_SRC})
250endif()
251
252if(APPLE)
253 add_definitions(-D_DARWIN_C_SOURCE)
254 if(CMAKE_SYSTEM_VERSION VERSION_GREATER "10.5.8")
255 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
256 endif()
257endif()
258
259if(NOT HAIKU AND NOT MSVC AND NOT PSP2)
260 set(M_LIBRARY m)
261endif()
262list(APPEND OS_LIB ${M_LIBRARY})
263
264if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
265 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
266 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
267endif()
268
269if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
270 if(NOT BUILD_EGL)
271 add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
272 endif()
273endif()
274
275if(BUILD_RASPI)
276 set(BUILD_GL OFF CACHE BOOL "OpenGL not supported" FORCE)
277endif()
278
279if(BUILD_PANDORA)
280 add_definitions(-DBUILD_PANDORA)
281endif()
282
283if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
284 enable_language(ASM)
285endif()
286
287if(PSP2 OR WII)
288 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-format")
289endif()
290
291if(DEFINED 3DS OR DEFINED PSP2 OR DEFINED WII)
292 set(IS_EMBEDDED ON)
293 set(USE_DEBUGGERS OFF)
294 set(USE_SQLITE3 OFF)
295endif()
296
297if(DEFINED 3DS)
298 add_definitions(-DFIXED_ROM_BUFFER)
299endif()
300
301if(NOT M_CORE_GBA)
302 set(USE_GDB_STUB OFF)
303endif()
304
305if(NOT USE_DEBUGGERS)
306 set(USE_EDITLINE OFF)
307 set(USE_GDB_STUB OFF)
308endif()
309
310if(WII)
311 add_definitions(-U__STRICT_ANSI__)
312endif()
313
314if(DEFINED 3DS)
315 add_definitions(-D_GNU_SOURCE)
316endif()
317
318include(CheckFunctionExists)
319include(CheckIncludeFiles)
320check_function_exists(strdup HAVE_STRDUP)
321check_function_exists(strndup HAVE_STRNDUP)
322if(NOT DEFINED PSP2)
323 check_function_exists(localtime_r HAVE_LOCALTIME_R)
324endif()
325check_include_files("xlocale.h" HAVE_XLOCALE)
326if(NOT CMAKE_SYSTEM_NAME STREQUAL "Generic")
327 check_function_exists(snprintf_l HAVE_SNPRINTF_L)
328 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
329 # The strtof_l on Linux not actually exposed nor actually strtof_l
330 set(HAVE_STRTOF_L OFF)
331 else()
332 check_function_exists(strtof_l HAVE_STRTOF_L)
333 endif()
334 check_function_exists(newlocale HAVE_NEWLOCALE)
335 check_function_exists(freelocale HAVE_FREELOCALE)
336 check_function_exists(uselocale HAVE_USELOCALE)
337 check_function_exists(setlocale HAVE_SETLOCALE)
338else()
339 if(DEFINED 3DS OR DEFINED WII)
340 set(CMAKE_REQUIRED_FLAGS -Wl,--require-defined,snprintf_l)
341 check_function_exists(snprintf_l HAVE_SNPRINTF_L)
342 set(CMAKE_REQUIRED_FLAGS -Wl,--require-defined,strtof_l)
343 check_function_exists(strtof_l HAVE_STRTOF_L)
344 set(CMAKE_REQUIRED_FLAGS -Wl,--require-defined,newlocale)
345 check_function_exists(newlocale HAVE_NEWLOCALE)
346 set(CMAKE_REQUIRED_FLAGS -Wl,--require-defined,freelocale)
347 check_function_exists(freelocale HAVE_FREELOCALE)
348 set(CMAKE_REQUIRED_FLAGS -Wl,--require-defined,uselocale)
349 check_function_exists(uselocale HAVE_USELOCALE)
350 set(CMAKE_REQUIRED_FLAGS -Wl,--require-defined,setlocale)
351 check_function_exists(setlocale HAVE_SETLOCALE)
352 unset(CMAKE_REQUIRED_FLAGS)
353 endif()
354 if(NOT IS_EMBEDDED)
355 set(DISABLE_DEPS ON CACHE BOOL "This platform cannot build with dependencies" FORCE)
356 endif()
357 set(BUILD_STATIC ON CACHE BOOL "" FORCE)
358 set(BUILD_SHARED OFF CACHE BOOL "" FORCE)
359 set(DISABLE_FRONTENDS ON)
360 set(MINIMAL_CORE ON)
361 set(ENABLE_EXTRA ON)
362endif()
363
364check_function_exists(chmod HAVE_CHMOD)
365check_function_exists(umask HAVE_UMASK)
366
367set(FUNCTION_DEFINES)
368
369if(HAVE_STRDUP)
370 list(APPEND FUNCTION_DEFINES HAVE_STRDUP)
371endif()
372
373if(HAVE_STRNDUP)
374 list(APPEND FUNCTION_DEFINES HAVE_STRNDUP)
375endif()
376
377if(HAVE_LOCALTIME_R)
378 list(APPEND FUNCTION_DEFINES HAVE_LOCALTIME_R)
379endif()
380
381if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE OR APPLE)
382 list(APPEND FUNCTION_DEFINES HAVE_LOCALE)
383 if (HAVE_SNPRINTF_L)
384 list(APPEND FUNCTION_DEFINES HAVE_SNPRINTF_L)
385 endif()
386endif()
387
388if(HAVE_SETLOCALE)
389 list(APPEND FUNCTION_DEFINES HAVE_SETLOCALE)
390endif()
391
392if (HAVE_STRTOF_L)
393 list(APPEND FUNCTION_DEFINES HAVE_STRTOF_L)
394endif()
395
396if(HAVE_XLOCALE)
397 list(APPEND FUNCTION_DEFINES HAVE_XLOCALE)
398endif()
399
400if(HAVE_CHMOD)
401 list(APPEND FUNCTION_DEFINES HAVE_CHMOD)
402endif()
403
404if(HAVE_UMASK)
405 list(APPEND FUNCTION_DEFINES HAVE_UMASK)
406endif()
407
408# Feature dependencies
409set(FEATURE_DEFINES)
410set(FEATURE_FLAGS)
411set(FEATURES)
412set(ENABLES)
413if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
414 set(LIBEDIT_LIBRARIES -ledit)
415 if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
416 list(APPEND LIBEDIT_LIBRARIES -ltermcap)
417 endif()
418else()
419 find_feature(USE_EDITLINE "libedit")
420endif()
421if(BUILD_GL)
422 find_package(OpenGL QUIET)
423 if(NOT OPENGL_FOUND)
424 set(BUILD_GL OFF CACHE BOOL "OpenGL not found" FORCE)
425 endif()
426endif()
427if(NOT BUILD_GL)
428 set(OPENGLE_LIBRARY "" CACHE PATH "" FORCE)
429endif()
430if(BUILD_GLES2 AND NOT BUILD_RASPI)
431 find_path(OPENGLES2_INCLUDE_DIR NAMES GLES2/gl2.h)
432 find_library(OPENGLES2_LIBRARY NAMES GLESv2 GLESv2_CM)
433 if(NOT OPENGLES2_INCLUDE_DIR OR NOT OPENGLES2_LIBRARY)
434 set(BUILD_GLES2 OFF CACHE BOOL "OpenGL|ES 2 not found" FORCE)
435 endif()
436endif()
437if(NOT BUILD_GLES2)
438 set(OPENGLES2_LIBRARY "" CACHE PATH "" FORCE)
439endif()
440set(WANT_ZLIB ${USE_ZLIB})
441set(WANT_PNG ${USE_PNG})
442set(WANT_LIBZIP ${USE_LIBZIP})
443set(WANT_SQLITE3 ${USE_SQLITE3})
444set(USE_CMOCKA ${BUILD_SUITE})
445
446find_feature(USE_FFMPEG "libavcodec;libavformat;libavutil;libswscale")
447find_feature(USE_ZLIB "ZLIB")
448find_feature(USE_MINIZIP "minizip")
449find_feature(USE_PNG "PNG")
450find_feature(USE_LIBZIP "libzip")
451find_feature(USE_MAGICK "MagickWand")
452find_feature(USE_EPOXY "epoxy")
453find_feature(USE_CMOCKA "cmocka")
454find_feature(USE_SQLITE3 "sqlite3")
455find_feature(USE_ELF "libelf")
456find_feature(ENABLE_PYTHON "PythonLibs")
457
458if(USE_FFMPEG)
459 set(USE_LIBAVRESAMPLE ON)
460 set(USE_LIBSWRESAMPLE ON)
461 find_feature(USE_LIBAVRESAMPLE "libavresample")
462 find_feature(USE_LIBSWRESAMPLE "libswresample")
463endif()
464
465# Features
466set(DEBUGGER_SRC
467 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/debugger.c
468 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/parser.c
469 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/symbols.c
470 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/cli-debugger.c)
471
472file(GLOB DEBUGGER_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/test/*.c)
473
474set(FEATURE_SRC)
475set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
476
477if(DISABLE_DEPS)
478 set(USE_GDB_STUB OFF)
479endif()
480
481if(USE_EDITLINE)
482 list(APPEND FEATURES EDITLINE)
483 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/cli-debugger.c)
484 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/parser.c)
485 if(M_CORE_GBA)
486 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c)
487 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/debugger/cli.c)
488 endif()
489 if(M_CORE_GB)
490 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/cli-debugger.c)
491 endif()
492 if(M_CORE_DS)
493 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c)
494 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/ds/extra/cli.c)
495 endif()
496 include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
497 link_directories(${LIBEDIT_LIBRARY_DIRS})
498 set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
499 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
500 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/editline/cli-el-backend.c")
501else()
502 set(DEBUGGER_LIB "")
503endif()
504
505if(USE_GDB_STUB)
506 list(APPEND FEATURES GDB_STUB)
507 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/gdb-stub.c)
508endif()
509source_group("Debugger" FILES ${DEBUGGER_SRC})
510
511if(USE_FFMPEG)
512 list(APPEND FEATURES FFMPEG)
513 if(USE_LIBSWRESAMPLE)
514 list(APPEND FEATURES LIBSWRESAMPLE)
515 else()
516 list(APPEND FEATURES LIBAVRESAMPLE)
517 list(APPEND FEATURES LIBAV)
518 endif()
519 include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWRESAMPLE_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
520 link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWRESAMPLE_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
521 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/ffmpeg/ffmpeg-encoder.c")
522 string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
523 string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
524 string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
525 string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
526 list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES} ${LIBSWRESAMPLE_LIBRARIES})
527 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR}|libavcodec-extra-${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
528 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavformat${LIBAVFORMAT_VERSION_MAJOR}|libavformat-ffmpeg${LIBAVFORMAT_VERSION_MAJOR}")
529 if(USE_LIBSWRESAMPLE)
530 string(REGEX MATCH "^[0-9]+" LIBSWRESAMPLE_VERSION_MAJOR ${libswresample_VERSION})
531 math(EXPR LIBSWRESAMPLE_VERSION_DEBIAN "${LIBSWRESAMPLE_VERSION_MAJOR} - 1")
532 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libswresample${LIBSWRESAMPLE_VERSION_DEBIAN}|libswresample-ffmpeg${LIBSWRESAMPLE_VERSION_DEBIAN}")
533 else()
534 string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
535 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavresample${LIBAVRESAMPLE_VERSION_MAJOR}|libavresample-ffmpeg${LIBAVRESAMPLE_VERSION_MAJOR}")
536 endif()
537 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavutil${LIBAVUTIL_VERSION_MAJOR}|libavutil-ffmpeg${LIBAVUTIL_VERSION_MAJOR}")
538 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libswscale${LIBSWSCALE_VERSION_MAJOR}|libswscale-ffmpeg${LIBSWSCALE_VERSION_MAJOR}")
539 set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
540 if(APPLE)
541 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
542 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
543 endif()
544endif()
545
546list(APPEND THIRD_PARTY_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
547
548if(USE_MAGICK)
549 list(APPEND FEATURES MAGICK)
550 include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
551 link_directories(${MAGICKWAND_LIBRARY_DIRS})
552 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/imagemagick/imagemagick-gif-encoder.c")
553 list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
554 string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
555 string(REGEX MATCH "^[0-9]+" MAGICKWAND_VERSION_MAJOR ${MagickWand_VERSION})
556 if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
557 set(MAGICKWAND_DEB_VERSION "5")
558 elseif(${MagickWand_VERSION} EQUAL "6.9.7")
559 set(MAGICKWAND_DEB_VERSION "-6.q16-3")
560 else()
561 set(MAGICKWAND_DEB_VERSION "-6.q16-2")
562 endif()
563 list(APPEND FEATURE_DEFINES MAGICKWAND_VERSION_MAJOR=${MAGICKWAND_VERSION_MAJOR})
564 list(APPEND FEATURE_FLAGS ${MAGICKWAND_CFLAGS_OTHER})
565
566 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
567endif()
568
569if(WANT_ZLIB AND NOT USE_ZLIB)
570 set(SKIP_INSTALL_ALL ON)
571 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib zlib)
572 set_property(TARGET zlibstatic PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/zlib;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib)
573 set_property(TARGET zlib PROPERTY EXCLUDE_FROM_ALL ON)
574 set_property(TARGET example PROPERTY EXCLUDE_FROM_ALL ON)
575 set_property(TARGET minigzip PROPERTY EXCLUDE_FROM_ALL ON)
576 set(ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
577 set(ZLIB_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
578 set(ZLIB_LIBRARY zlibstatic)
579 list(APPEND DEPENDENCY_LIB zlibstatic)
580 set(USE_ZLIB ON)
581endif()
582
583if(USE_ZLIB)
584 list(APPEND FEATURES ZLIB)
585 include_directories(AFTER ${ZLIB_INCLUDE_DIRS})
586 list(APPEND DEPENDENCY_LIB ${ZLIB_LIBRARIES})
587 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},zlib1g")
588 set(HAVE_CRC32 ON)
589 list(APPEND OS_LIB ${ZLIB_LIBRARIES})
590else()
591 # zlib pulls in crc32
592 check_function_exists(crc32 HAVE_CRC32)
593endif()
594
595if(HAVE_CRC32)
596 list(APPEND FUNCTION_DEFINES HAVE_CRC32)
597endif()
598
599if(WANT_PNG AND USE_ZLIB AND NOT USE_PNG)
600 set(PNG_STATIC ON CACHE BOOL "" FORCE)
601 set(PNG_SHARED OFF CACHE BOOL "" FORCE)
602 set(PNG_TESTS OFF CACHE BOOL "" FORCE)
603 set(SKIP_INSTALL_ALL ON)
604 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng libpng)
605 set_property(TARGET png16_static PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/libpng;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng;${ZLIB_INCLUDE_DIRS})
606 set(PNG_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng ${CMAKE_CURRENT_BINARY_DIR}/libpng)
607 list(APPEND DEPENDENCY_LIB png16_static)
608 set(USE_PNG ON)
609endif()
610
611if(USE_PNG)
612 list(APPEND FEATURES PNG)
613 include_directories(AFTER ${PNG_INCLUDE_DIRS})
614 list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
615 if(PNG_VERSION_STRING)
616 string(REGEX MATCH "^[0-9]+\\.[0-9]+" PNG_VERSION_PARTIAL ${PNG_VERSION_STRING})
617 if(${PNG_VERSION_PARTIAL} STREQUAL "1.6")
618 set(PNG_DEB_VERSION "16-16")
619 else()
620 set(PNG_DEB_VERSION "12-0")
621 endif()
622 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng${PNG_DEB_VERSION}")
623 endif()
624endif()
625
626if(WANT_SQLITE3 AND NOT USE_SQLITE3)
627 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/sqlite3.c)
628 include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/)
629 set(USE_SQLITE3 ON)
630endif()
631
632if(USE_LIBZIP)
633 include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
634 link_directories(${LIBZIP_LIBRARY_DIRS})
635 list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
636 list(APPEND FEATURES LIBZIP)
637 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
638 string(REGEX MATCH "^[0-9]+" LIBZIP_VERSION_MAJOR ${libzip_VERSION})
639 if (LIBZIP_VERSION_MAJOR LESS 1)
640 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
641 elseif(LIBZIP_VERSION_MAJOR EQUAL 1)
642 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip4")
643 else()
644 message(AUTHOR_WARNING Unknown version of libzip detected: ${libzip_VERSION})
645 endif()
646elseif(USE_MINIZIP)
647 include_directories(AFTER ${MINIZIP_INCLUDE_DIRS})
648 link_directories(${MINIZIP_LIBRARY_DIRS})
649 list(APPEND DEPENDENCY_LIB ${MINIZIP_LIBRARIES})
650 list(APPEND FEATURES MINIZIP)
651 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
652 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libminizip1")
653elseif(USE_ZLIB)
654 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c
655 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
656 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c)
657 if(NOT MSVC)
658 set_source_files_properties(
659 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
660 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c
661 PROPERTIES COMPILE_FLAGS "-Wno-unused-parameter -Wno-implicit-function-declaration")
662 endif()
663endif()
664
665if (USE_LZMA)
666 include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma)
667 add_definitions(-D_7ZIP_PPMD_SUPPPORT)
668 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-lzma.c)
669 set(LZMA_SRC
670 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
671 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
672 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
673 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
674 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
675 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
676 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zDec.c
677 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
678 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Delta.c
679 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
680 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
681 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra.c
682 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra86.c
683 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/BraIA64.c
684 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
685 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
686 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
687 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zFile.c
688 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
689 list(APPEND VFS_SRC ${LZMA_SRC})
690 list(APPEND FEATURES LZMA)
691endif()
692
693if(USE_EPOXY)
694 add_definitions(-DBUILD_GL -DBUILD_GLES2)
695 list(APPEND FEATURES EPOXY)
696 include_directories(AFTER ${EPOXY_INCLUDE_DIRS})
697 set(OPENGLES2_LIBRARY ${EPOXY_LIBRARIES})
698 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libepoxy0")
699endif()
700
701if(USE_SQLITE3)
702 list(APPEND FEATURES SQLITE3)
703 include_directories(AFTER ${SQLITE3_INCLUDE_DIRS})
704 list(APPEND DEPENDENCY_LIB ${SQLITE3_LIBRARIES})
705 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libsqlite3-0")
706 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/sqlite3/no-intro.c")
707endif()
708
709if(USE_ELF)
710 list(APPEND FEATURES ELF)
711 include_directories(AFTER ${LIBELF_INCLUDE_DIRS})
712 list(APPEND DEPENDENCY_LIB ${LIBELF_LIBRARIES})
713 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libelf1")
714endif()
715
716if(ENABLE_SCRIPTING)
717 list(APPEND ENABLES SCRIPTING)
718
719 if(BUILD_PYTHON)
720 find_package(PythonLibs ${USE_PYTHON_VERSION})
721 list(APPEND DEPENDENCY_LIB ${PYTHON_LIBRARIES})
722 include_directories(AFTER ${PYTHON_INCLUDE_DIRS})
723 list(APPEND ENABLES PYTHON)
724 endif()
725endif()
726
727set(TEST_SRC ${CORE_TEST_SRC})
728if(M_CORE_GB)
729 add_definitions(-DM_CORE_GB)
730 list(APPEND CORE_SRC
731 ${LR35902_SRC}
732 ${GB_SRC}
733 ${GB_RENDERER_SRC})
734 list(APPEND DEBUGGER_SRC
735 ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/cli-debugger.c
736 ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/debugger.c
737 ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/memory-debugger.c
738 ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/debugger/cli.c
739 ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/debugger/symbols.c)
740 list(APPEND TEST_SRC
741 ${LR35902_TEST_SRC}
742 ${GB_TEST_SRC})
743endif()
744
745if(M_CORE_GBA)
746 add_definitions(-DM_CORE_GBA)
747 list(APPEND CORE_SRC
748 ${ARM_SRC}
749 ${GBA_SRC}
750 ${GBA_CHEATS_SRC}
751 ${GBA_RENDERER_SRC})
752 list(APPEND DEBUGGER_SRC
753 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c
754 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/debugger.c
755 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/memory-debugger.c
756 ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/debugger/cli.c)
757 list(APPEND TEST_SRC
758 ${ARM_TEST_SRC}
759 ${GBA_TEST_SRC})
760 if(NOT M_CORE_GB)
761 list(APPEND CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/audio.c)
762 endif()
763endif()
764
765if(M_CORE_DS)
766 add_definitions(-DM_CORE_DS)
767 list(APPEND CORE_SRC
768 ${ARM_SRC}
769 ${DS_SRC}
770 ${DS_RENDERER_SRC})
771 list(APPEND DEBUGGER_SRC
772 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c
773 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/debugger.c
774 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/memory-debugger.c
775 ${CMAKE_CURRENT_SOURCE_DIR}/src/ds/extra/cli.c)
776endif()
777
778if(USE_DEBUGGERS)
779 list(APPEND FEATURE_SRC ${DEBUGGER_SRC})
780 list(APPEND TEST_SRC ${DEBUGGER_TEST_SRC})
781 list(APPEND FEATURES DEBUGGERS)
782endif()
783
784foreach(FEATURE IN LISTS FEATURES)
785 list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
786endforeach()
787
788foreach(ENABLE IN LISTS ENABLES)
789 list(APPEND FEATURE_DEFINES "ENABLE_${ENABLE}")
790endforeach()
791
792source_group("Virtual files" FILES ${CORE_VFS_SRC} ${VFS_SRC})
793source_group("Extra features" FILES ${FEATURE_SRC})
794source_group("Third-party code" FILES ${THIRD_PARTY_SRC})
795
796# Platform binaries
797if(DEFINED 3DS)
798 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/3ds ${CMAKE_CURRENT_BINARY_DIR}/3ds)
799endif()
800
801if(DEFINED WII)
802 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/wii ${CMAKE_CURRENT_BINARY_DIR}/wii)
803endif()
804
805if(DEFINED PSP2)
806 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/psp2 ${CMAKE_CURRENT_BINARY_DIR}/psp2)
807endif()
808
809# Binaries
810list(APPEND CORE_SRC
811 ${UTIL_SRC}
812 ${CORE_VFS_SRC}
813 ${OS_SRC}
814 ${THIRD_PARTY_SRC})
815list(APPEND TEST_SRC ${UTIL_TEST_SRC})
816
817set(SRC ${CORE_SRC} ${VFS_SRC})
818if(NOT MINIMAL_CORE)
819 set(ENABLE_EXTRA ON)
820 if(M_CORE_GBA)
821 list(APPEND SRC
822 ${GBA_SIO_SRC})
823 endif()
824 if(M_CORE_GB)
825 list(APPEND SRC
826 ${GB_SIO_SRC})
827 endif()
828 list(APPEND SRC
829 ${FEATURE_SRC})
830endif()
831
832if(ENABLE_EXTRA)
833 if(M_CORE_GBA)
834 list(APPEND SRC
835 ${GBA_RR_SRC}
836 ${GBA_EXTRA_SRC})
837 endif()
838 if(M_CORE_GB)
839 list(APPEND SRC
840 ${GB_EXTRA_SRC})
841 endif()
842 list(APPEND SRC
843 ${EXTRA_SRC})
844endif()
845
846if(NOT SKIP_LIBRARY)
847 if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
848 set(BUILD_SHARED ON)
849 endif()
850
851 if(BUILD_SHARED)
852 add_library(${BINARY_NAME} SHARED ${SRC} ${VFS_SRC})
853 if(BUILD_STATIC)
854 add_library(${BINARY_NAME}-static STATIC ${SRC})
855 set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}" COMPILE_OPTIONS "${FEATURE_FLAGS}")
856 install(TARGETS ${BINARY_NAME}-static DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
857 add_dependencies(${BINARY_NAME}-static version-info)
858 endif()
859 else()
860 add_library(${BINARY_NAME} STATIC ${SRC})
861 endif()
862
863 add_dependencies(${BINARY_NAME} version-info)
864 set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}" COMPILE_OPTIONS "${FEATURE_FLAGS}")
865
866 target_link_libraries(${BINARY_NAME} ${DEBUGGER_LIB} ${DEPENDENCY_LIB} ${OS_LIB})
867 install(TARGETS ${BINARY_NAME} LIBRARY DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME} NAMELINK_SKIP ARCHIVE DESTINATION ${LIBDIR} RUNTIME DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
868 if(UNIX AND NOT APPLE AND NOT HAIKU)
869 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-16.png DESTINATION share/icons/hicolor/16x16/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
870 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-24.png DESTINATION share/icons/hicolor/24x24/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
871 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-32.png DESTINATION share/icons/hicolor/32x32/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
872 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-48.png DESTINATION share/icons/hicolor/48x48/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
873 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-64.png DESTINATION share/icons/hicolor/64x64/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
874 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-96.png DESTINATION share/icons/hicolor/96x96/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
875 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-128.png DESTINATION share/icons/hicolor/128x128/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
876 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-256.png DESTINATION share/icons/hicolor/256x256/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
877 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-512.png DESTINATION share/icons/hicolor/512x512/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
878 endif()
879else()
880 set(BUILD_SHARED OFF)
881 set(BUILD_STATIC OFF)
882 find_library(${BINARY_NAME} ${BINARY_NAME})
883 if(NOT ${BINARY_NAME}_FOUND)
884 set(DISABLE_FRONTENDS ON)
885 set(BUILD_PERF OFF)
886 set(BUILD_TEST OFF)
887 set(BUILD_SUITE OFF)
888 endif()
889endif()
890
891if(BUILD_GL)
892 add_definitions(-DBUILD_GL)
893endif()
894
895if(BUILD_GLES2)
896 add_definitions(-DBUILD_GLES2)
897endif()
898
899if(DISABLE_FRONTENDS)
900 set(BUILD_SDL OFF)
901 set(BUILD_QT OFF)
902endif()
903
904if(BUILD_PYTHON)
905 enable_testing()
906 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/python ${CMAKE_CURRENT_BINARY_DIR}/python)
907endif()
908
909if(BUILD_LIBRETRO)
910 file(GLOB RETRO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/libretro/*.c)
911 add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
912 set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5;DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=2")
913 target_link_libraries(${BINARY_NAME}_libretro ${OS_LIB})
914 install(TARGETS ${BINARY_NAME}_libretro LIBRARY DESTINATION ${LIBRETRO_LIBDIR} COMPONENT ${BINARY_NAME}_libretro NAMELINK_SKIP)
915endif()
916
917if(BUILD_OPENEMU)
918 find_library(FOUNDATION Foundation)
919 find_library(OPENEMUBASE OpenEmuBase)
920 file(GLOB OE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/*.m)
921 add_library(${BINARY_NAME}-openemu MODULE ${CORE_SRC} ${OS_SRC})
922 set_target_properties(${BINARY_NAME}-openemu PROPERTIES
923 MACOSX_BUNDLE_INFO_PLIST ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/Info.plist.in
924 BUNDLE TRUE
925 BUNDLE_EXTENSION oecoreplugin
926 OUTPUT_NAME ${PROJECT_NAME}
927 COMPILE_DEFINITIONS "DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=1")
928 target_link_libraries(${BINARY_NAME}-openemu ${OS_LIB} ${FOUNDATION} ${OPENEMUBASE})
929 install(TARGETS ${BINARY_NAME}-openemu LIBRARY DESTINATION ${OE_LIBDIR} COMPONENT ${BINARY_NAME}.oecoreplugin NAMELINK_SKIP)
930endif()
931
932if(BUILD_SDL)
933 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/sdl ${CMAKE_CURRENT_BINARY_DIR}/sdl)
934endif()
935
936if(BUILD_QT)
937 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/qt ${CMAKE_CURRENT_BINARY_DIR}/qt)
938endif()
939
940if(BUILD_PERF)
941 set(PERF_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/perf-main.c)
942 if(UNIX AND NOT APPLE)
943 list(APPEND PERF_LIB rt)
944 endif()
945
946 add_executable(${BINARY_NAME}-perf ${PERF_SRC})
947 target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB} ${OS_LIB})
948 set_target_properties(${BINARY_NAME}-perf PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
949 install(TARGETS ${BINARY_NAME}-perf DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT ${BINARY_NAME}-perf)
950 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/tools/perf.py DESTINATION "${LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
951endif()
952
953if(BUILD_TEST)
954 add_executable(${BINARY_NAME}-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/fuzz-main.c)
955 target_link_libraries(${BINARY_NAME}-fuzz ${BINARY_NAME})
956 set_target_properties(${BINARY_NAME}-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
957 add_executable(tbl-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/tbl-fuzz-main.c)
958 target_link_libraries(tbl-fuzz ${BINARY_NAME})
959 set_target_properties(tbl-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
960 install(TARGETS ${BINARY_NAME}-fuzz tbl-fuzz DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT ${BINARY_NAME}-test)
961endif()
962
963if(NOT USE_CMOCKA)
964 set(BUILD_SUITE OFF)
965endif()
966if(BUILD_SUITE)
967 enable_testing()
968 include_directories(AFTER ${CMOCKA_INCLUDE_DIRS})
969 link_directories(${CMOCKA_LIBRARY_DIRS})
970
971 foreach(TEST IN LISTS TEST_SRC)
972 string(REPLACE "${CMAKE_SOURCE_DIR}/src/" "" TEST_NAME "${TEST}")
973 string(REPLACE "/" "-" TEST_NAME "${TEST_NAME}")
974 string(REPLACE "-test" "" TEST_NAME "${TEST_NAME}")
975 string(REPLACE ".c" "" TEST_NAME "${TEST_NAME}")
976 add_executable(test-${TEST_NAME} ${TEST})
977 target_link_libraries(test-${TEST_NAME} ${BINARY_NAME} ${PLATFORM_LIBRARY} cmocka)
978 set_target_properties(test-${TEST_NAME} PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
979 add_test(${TEST_NAME} test-${TEST_NAME})
980 endforeach()
981endif()
982
983if(BUILD_EXAMPLE)
984 add_executable(${BINARY_NAME}-example-server ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/server.c)
985 target_link_libraries(${BINARY_NAME}-example-server ${BINARY_NAME})
986 set_target_properties(${BINARY_NAME}-example-server PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
987
988 if(FOUND_SDL)
989 add_executable(${BINARY_NAME}-example-client ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/client.c)
990 target_link_libraries(${BINARY_NAME}-example-client ${BINARY_NAME} ${SDL_LIBRARY} ${SDLMAIN_LIBRARY} ${OPENGL_LIBRARY} ${OPENGLES2_LIBRARY})
991 set_target_properties(${BINARY_NAME}-example-client PROPERTIES
992 COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}"
993 INCLUDE_DIRECTORIES "${SDL_INCLUDE_DIR};${CMAKE_CURRENT_SOURCE_DIR}/src;${CMAKE_CURRENT_SOURCE_DIR}/include")
994 endif()
995endif()
996
997configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/flags.h.in ${CMAKE_CURRENT_BINARY_DIR}/flags.h)
998install(FILES ${CMAKE_CURRENT_BINARY_DIR}/flags.h DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/mgba COMPONENT lib${BINARY_NAME})
999
1000# Packaging
1001install(DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/res/licenses DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT ${BINARY_NAME})
1002if(EXTRA_LICENSES)
1003 install(FILES ${EXTRA_LICENSES} DESTINATION ${CMAKE_INSTALL_DOCDIR}/licenses COMPONENT ${BINARY_NAME})
1004endif()
1005
1006file(GLOB READMES ${CMAKE_CURRENT_SOURCE_DIR}/README*.md)
1007
1008find_program(DOS2UNIX NAMES dos2unix)
1009find_program(MARKDOWN NAMES markdown kramdown pandoc)
1010
1011if(UNIX OR NOT DOS2UNIX)
1012 if(UNIX OR NOT MARKDOWN)
1013 install(FILES ${READMES} DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT ${BINARY_NAME})
1014 endif()
1015 install(FILES "${CMAKE_CURRENT_SOURCE_DIR}/CHANGES" "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE" DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT ${BINARY_NAME})
1016else()
1017 add_custom_command(OUTPUT CHANGES.txt COMMAND ${DOS2UNIX} -n "${CMAKE_CURRENT_SOURCE_DIR}/CHANGES" "${CMAKE_CURRENT_BINARY_DIR}/CHANGES.txt" MAIN_DEPENDENCY "${CMAKE_CURRENT_SOURCE_DIR}/CHANGES")
1018 add_custom_command(OUTPUT LICENSE.txt COMMAND ${DOS2UNIX} -n "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE" "${CMAKE_CURRENT_BINARY_DIR}/LICENSE.txt" MAIN_DEPENDENCY "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE")
1019 add_custom_target(CHANGES ALL DEPENDS CHANGES.txt)
1020 add_custom_target(LICENSE ALL DEPENDS LICENSE.txt)
1021 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/CHANGES.txt ${CMAKE_CURRENT_BINARY_DIR}/LICENSE.txt DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT ${BINARY_NAME})
1022endif()
1023
1024if(MARKDOWN)
1025 foreach(README ${READMES})
1026 get_filename_component(README_BASE "${README}" NAME_WE)
1027 add_custom_command(OUTPUT ${README_BASE}.html COMMAND ${MARKDOWN} "${README}" > ${README_BASE}.html MAIN_DEPENDENCY "${README}")
1028 add_custom_target(${README_BASE} ALL DEPENDS ${README_BASE}.html)
1029 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${README_BASE}.html DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT ${BINARY_NAME})
1030 endforeach()
1031endif()
1032
1033set(CPACK_PACKAGE_VERSION ${VERSION_STRING})
1034set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
1035set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
1036set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
1037set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
1038set(CPACK_RESOURCE_FILE_README ${CMAKE_CURRENT_SOURCE_DIR}/README.md)
1039
1040set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
1041set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
1042set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
1043set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README.md")
1044set(CPACK_DEBIAN_PACKAGE_SECTION "games")
1045
1046SET(CPACK_DEB_COMPONENT_INSTALL ON)
1047
1048set(CPACK_STRIP_FILES ON)
1049
1050if(DISTBUILD)
1051 set(CPACK_ARCHIVE_COMPONENT_INSTALL ON)
1052 if(WIN32 OR APPLE)
1053 set(CPACK_COMPONENTS_ALL ${BINARY_NAME} ${BINARY_NAME}-qt ${BINARY_NAME}-sdl ${BINARY_NAME}-perf)
1054 set(CPACK_COMPONENTS_GROUPING ALL_COMPONENTS_IN_ONE)
1055 elseif(3DS)
1056 set(CPACK_COMPONENTS_ALL ${BINARY_NAME} ${BINARY_NAME}-3ds ${BINARY_NAME}-perf)
1057 elseif(WII)
1058 set(CPACK_COMPONENTS_ALL ${BINARY_NAME} ${BINARY_NAME}-wii)
1059 elseif(PSP2)
1060 set(CPACK_COMPONENTS_ALL ${BINARY_NAME} ${BINARY_NAME}-psp2)
1061 endif()
1062endif()
1063
1064include(CPack)
1065
1066cpack_add_component_group(base)
1067cpack_add_component(${BINARY_NAME} GROUP base)
1068
1069cpack_add_component_group(dev PARENT_GROUP base)
1070if(BUILD_SHARED)
1071 cpack_add_component(lib${BINARY_NAME} GROUP base)
1072 if(BUILD_STATIC)
1073 cpack_add_component(lib${BINARY_NAME}-static GROUP dev)
1074 endif()
1075elseif(BUILD_STATIC)
1076 cpack_add_component(lib${BINARY_NAME} GROUP dev)
1077endif()
1078
1079if(3DS)
1080 cpack_add_component(${BINARY_NAME}-3ds GROUP base)
1081elseif(PSP2)
1082 cpack_add_component(${BINARY_NAME}-psp2 GROUP base)
1083elseif(WII)
1084 cpack_add_component(${BINARY_NAME}-wii GROUP base)
1085endif()
1086
1087if(BUILD_QT)
1088 cpack_add_component_group(qt PARENT_GROUP base)
1089 cpack_add_component(${BINARY_NAME}-qt GROUP qt DEPENDS base)
1090endif()
1091
1092if(FOUND_SDL)
1093 cpack_add_component_group(sdl PARENT_GROUP base)
1094 cpack_add_component(${BINARY_NAME}-sdl GROUP sdl DEPENDS base)
1095endif()
1096
1097cpack_add_component_group(test PARENT_GROUP dev)
1098cpack_add_component(${BINARY_NAME}-perf GROUP test DEPENDS dev)
1099cpack_add_component(${BINARY_NAME}-fuzz GROUP test DEPENDS dev)
1100cpack_add_component(tbl-fuzz GROUP test DEPENDS dev)
1101
1102# Summaries
1103set(SUMMARY_GL_LIST)
1104if(USE_EPOXY)
1105 set(SUMMARY_GL_LIST "libepoxy")
1106else()
1107 if(BUILD_GL)
1108 list(APPEND SUMMARY_GL_LIST "OpenGL")
1109 endif()
1110 if(BUILD_GLES2)
1111 list(APPEND SUMMARY_GL_LIST "OpenGL|ES 2")
1112 endif()
1113endif()
1114if(NOT SUMMARY_GL_LIST)
1115 set(SUMMARY_GL OFF)
1116else()
1117 string(REPLACE ";" ", " SUMMARY_GL "${SUMMARY_GL_LIST}")
1118endif()
1119if(USE_LIBZIP)
1120 set(SUMMARY_ZIP libzip)
1121elseif(USE_MINIZIP)
1122 set(SUMMARY_ZIP "minizip (external)")
1123elseif(USE_ZLIB)
1124 set(SUMMARY_ZIP "minizip (included)")
1125else()
1126 set(SUMMARY_ZIP OFF)
1127endif()
1128
1129if(NOT QUIET)
1130 message(STATUS "Build type: ${CMAKE_BUILD_TYPE}")
1131 message(STATUS "Platforms:")
1132 message(STATUS " Game Boy Advance: ${M_CORE_GBA}")
1133 message(STATUS " Game Boy: ${M_CORE_GB}")
1134 message(STATUS " DS: ${M_CORE_DS}")
1135 message(STATUS "Features:")
1136 message(STATUS " Debuggers: ${USE_DEBUGGERS}")
1137 if(NOT WIN32)
1138 message(STATUS " CLI debugger: ${USE_EDITLINE}")
1139 endif()
1140 message(STATUS " GDB stub: ${USE_GDB_STUB}")
1141 message(STATUS " Video recording: ${USE_FFMPEG}")
1142 message(STATUS " GIF recording: ${USE_MAGICK}")
1143 message(STATUS " Screenshot/advanced savestate support: ${USE_PNG}")
1144 message(STATUS " ZIP support: ${SUMMARY_ZIP}")
1145 message(STATUS " 7-Zip support: ${USE_LZMA}")
1146 message(STATUS " SQLite3 game database: ${USE_SQLITE3}")
1147 message(STATUS " ELF loading support: ${USE_ELF}")
1148 message(STATUS " OpenGL support: ${SUMMARY_GL}")
1149 message(STATUS "Frontends:")
1150 message(STATUS " Qt: ${BUILD_QT}")
1151 message(STATUS " SDL (${SDL_VERSION}): ${BUILD_SDL}")
1152 message(STATUS " Profiling: ${BUILD_PERF}")
1153 message(STATUS " Test harness: ${BUILD_TEST}")
1154 message(STATUS " Test suite: ${BUILD_SUITE}")
1155 message(STATUS " Python bindings: ${BUILD_PYTHON}")
1156 message(STATUS " Examples: ${BUILD_EXAMPLE}")
1157 message(STATUS "Cores:")
1158 message(STATUS " Libretro core: ${BUILD_LIBRETRO}")
1159 if(APPLE)
1160 message(STATUS " OpenEmu core: ${BUILD_OPENEMU}")
1161 endif()
1162 message(STATUS "Libraries:")
1163 message(STATUS " Static: ${BUILD_STATIC}")
1164 message(STATUS " Shared: ${BUILD_SHARED}")
1165endif()