1cmake_minimum_required(VERSION 2.8.11)
  2enable_language(CXX)
  3
  4set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++11")
  5
  6if(APPLE)
  7	set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mmacosx-version-min=10.7 -stdlib=libc++")
  8endif()
  9
 10set(PLATFORM_SRC)
 11
 12if(BUILD_SDL)
 13	if(NOT SDL_FOUND AND NOT SDL2_FOUND)
 14		find_package(SDL 1.2 REQUIRED)
 15	endif()
 16	if(SDL2_FOUND)
 17		link_directories(${SDL2_LIBDIR})
 18	endif()
 19	list(APPEND PLATFORM_LIBRARY ${SDL_LIBRARY} ${SDLMAIN_LIBRARY})
 20	list(APPEND PLATFORM_SRC ${PLATFORM_SRC} ${CMAKE_SOURCE_DIR}/src/platform/sdl/sdl-events.c ${CMAKE_SOURCE_DIR}/src/platform/sdl/sdl-audio.c)
 21	include_directories(${SDL_INCLUDE_DIR} ${CMAKE_SOURCE_DIR}/src/platform/sdl)
 22endif()
 23
 24set(CMAKE_AUTOMOC ON)
 25set(CMAKE_INCLUDE_CURRENT_DIR ON)
 26
 27find_package(Qt5Multimedia)
 28find_package(Qt5OpenGL)
 29find_package(Qt5Widgets)
 30find_package(OpenGL)
 31
 32if(NOT Qt5OpenGL_FOUND OR NOT Qt5Widgets_FOUND OR NOT OPENGL_FOUND)
 33	message(WARNING "Cannot find Qt modules")
 34	set(BUILD_QT OFF PARENT_SCOPE)
 35	return()
 36endif()
 37
 38set(SOURCE_FILES
 39	AudioProcessor.cpp
 40	ConfigController.cpp
 41	Display.cpp
 42	GBAApp.cpp
 43	GBAKeyEditor.cpp
 44	GIFView.cpp
 45	GameController.cpp
 46	GamePakView.cpp
 47	InputController.cpp
 48	KeyEditor.cpp
 49	LoadSaveState.cpp
 50	LogView.cpp
 51	SavestateButton.cpp
 52	SettingsView.cpp
 53	ShortcutController.cpp
 54	ShortcutView.cpp
 55	Window.cpp
 56	VFileDevice.cpp
 57	VideoView.cpp)
 58
 59qt5_wrap_ui(UI_FILES
 60	GIFView.ui
 61	GamePakView.ui
 62	LoadSaveState.ui
 63	LogView.ui
 64	SettingsView.ui
 65	ShortcutView.ui
 66	VideoView.ui)
 67
 68set(QT_LIBRARIES)
 69set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libqt5widgets5,libqt5opengl5" PARENT_SCOPE)
 70if(BUILD_SDL)
 71	list(APPEND SOURCE_FILES AudioProcessorSDL.cpp)
 72elseif(Qt5Multimedia_FOUND)
 73	list(APPEND SOURCE_FILES
 74		AudioProcessorQt.cpp
 75		AudioDevice.cpp)
 76	list(APPEND QT_LIBRARIES Qt5::Multimedia)
 77	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libqt5multimedia5" PARENT_SCOPE)
 78else()
 79	message(WARNING "No supported audio modules found")
 80	set(BUILD_QT OFF PARENT_SCOPE)
 81	return()
 82endif()
 83
 84if(USE_GDB_STUB)
 85	list(APPEND PLATFORM_SRC GDBController.cpp GDBWindow.cpp)
 86endif()
 87set(MACOSX_BUNDLE_ICON_FILE mgba.icns)
 88set(MACOSX_BUNDLE_BUNDLE_VERSION ${LIB_VERSION_STRING})
 89set(MACOSX_BUNDLE_BUNDLE_NAME ${PROJECT_NAME})
 90set(MACOSX_BUNDLE_GUI_IDENTIFIER com.endrift.${BINARY_NAME}-qt)
 91set_source_files_properties(${CMAKE_SOURCE_DIR}/res/mgba.icns PROPERTIES MACOSX_PACKAGE_LOCATION Resources)
 92
 93qt5_add_resources(RESOURCES resources.qrc)
 94if(WIN32)
 95	list(APPEND RESOURCES ${CMAKE_SOURCE_DIR}/res/mgba.rc)
 96endif()
 97add_executable(${BINARY_NAME}-qt WIN32 MACOSX_BUNDLE main.cpp ${CMAKE_SOURCE_DIR}/res/mgba.icns ${SOURCE_FILES} ${PLATFORM_SRC} ${UI_FILES} ${RESOURCES})
 98set_target_properties(${BINARY_NAME}-qt PROPERTIES MACOSX_BUNDLE_INFO_PLIST ${CMAKE_SOURCE_DIR}/res/info.plist.in)
 99
100list(APPEND QT_LIBRARIES Qt5::Widgets Qt5::OpenGL)
101target_link_libraries(${BINARY_NAME}-qt ${PLATFORM_LIBRARY} ${OPENGL_LIBRARY} ${BINARY_NAME} ${QT_LIBRARIES})
102
103install(TARGETS ${BINARY_NAME}-qt
104	RUNTIME DESTINATION bin COMPONENT ${BINARY_NAME}-qt
105	BUNDLE DESTINATION Applications COMPONENT ${BINARY_NAME}-qt)
106if(APPLE OR WIN32)
107	set_target_properties(${BINARY_NAME}-qt PROPERTIES OUTPUT_NAME ${PROJECT_NAME})
108endif()
109if(APPLE)
110	set(DEPLOY_OPTIONS -p platforms/libqcocoa.dylib,audio/libqtaudio_coreaudio.dylib)
111	if(NOT CMAKE_INSTALL_NAME_TOOL EQUAL "install_name_tool")
112		set(DEPLOY_OPTIONS ${DEPLOY_OPTIONS} -I ${CMAKE_INSTALL_NAME_TOOL})
113	endif()
114	if(DEFINED CMAKE_OTOOL AND NOT CMAKE_OTOOL EQUAL "otool")
115		set(DEPLOY_OPTIONS ${DEPLOY_OPTIONS} -O ${CMAKE_OTOOL})
116	endif()
117	if(DEFINED CROSS_ROOT)
118		set(DEPLOY_OPTIONS ${DEPLOY_OPTIONS} -R ${CROSS_ROOT})
119	endif()
120	add_custom_command(TARGET ${BINARY_NAME}-qt POST_BUILD COMMAND ${CMAKE_SOURCE_DIR}/tools/deploy-mac.py ${DEPLOY_OPTIONS} ${PROJECT_NAME}.app)
121endif()