1cmake_minimum_required(VERSION 2.6)
  2project(mGBA C)
  3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
  4if(NOT MSVC)
  5	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -std=c99")
  6else()
  7	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_CRT_SECURE_NO_WARNINGS /wd4003 /wd4244 /wd4146")
  8endif()
  9set(USE_CLI_DEBUGGER ON CACHE BOOL "Whether or not to enable the CLI-mode ARM debugger")
 10set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
 11set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
 12set(USE_ZLIB ON CACHE BOOL "Whether or not to enable zlib support")
 13set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
 14set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable ZIP support")
 15set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
 16set(USE_BLIP ON CACHE BOOL "Whether or not to enable blip_buf support")
 17set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
 18set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
 19set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
 20set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
 21set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
 22set(BUILD_TEST OFF CACHE BOOL "Build testing harness")
 23set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
 24set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
 25set(BUILD_GL ON CACHE STRING "Build with OpenGL")
 26set(BUILD_GLES2 OFF CACHE STRING "Build with OpenGL|ES 2")
 27set(USE_EPOXY ON CACHE STRING "Build with libepoxy")
 28set(DISABLE_DEPS OFF CACHE BOOL "Build without dependencies")
 29file(GLOB ARM_SRC ${CMAKE_SOURCE_DIR}/src/arm/*.c)
 30file(GLOB GBA_SRC ${CMAKE_SOURCE_DIR}/src/gba/*.c)
 31file(GLOB GBA_CHEATS_SRC ${CMAKE_SOURCE_DIR}/src/gba/cheats/*.c)
 32file(GLOB GBA_RR_SRC ${CMAKE_SOURCE_DIR}/src/gba/rr/*.c)
 33file(GLOB GBA_SV_SRC ${CMAKE_SOURCE_DIR}/src/gba/supervisor/*.c)
 34file(GLOB GBA_CTX_SRC ${CMAKE_SOURCE_DIR}/src/gba/context/*.c)
 35file(GLOB UTIL_SRC ${CMAKE_SOURCE_DIR}/src/util/*.[cSs])
 36file(GLOB GUI_SRC ${CMAKE_SOURCE_DIR}/src/util/gui/*.c ${CMAKE_SOURCE_DIR}/src/gba/gui/*.c)
 37file(GLOB RENDERER_SRC ${CMAKE_SOURCE_DIR}/src/gba/renderers/*.c)
 38file(GLOB SIO_SRC ${CMAKE_SOURCE_DIR}/src/gba/sio/lockstep.c)
 39file(GLOB THIRD_PARTY_SRC ${CMAKE_SOURCE_DIR}/src/third-party/inih/*.c)
 40list(APPEND UTIL_SRC ${CMAKE_SOURCE_DIR}/src/platform/commandline.c)
 41set(VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-mem.c)
 42source_group("ARM core" FILES ${ARM_SRC})
 43source_group("GBA board" FILES ${GBA_SRC} ${RENDERER_SRC} ${SIO_SRC})
 44source_group("GBA extra" FILES ${GBA_CHEATS_SRC} ${GBA_CTX_SRC} ${GBA_SV_SRC} ${GBA_RR_SRC})
 45source_group("Utilities" FILES ${UTIL_SRC})
 46include_directories(${CMAKE_SOURCE_DIR}/src/arm)
 47include_directories(${CMAKE_SOURCE_DIR}/src)
 48
 49if(NOT CMAKE_BUILD_TYPE)
 50	set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
 51endif()
 52
 53set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${LIBDIR}")
 54
 55include(GNUInstallDirs)
 56
 57if (NOT DEFINED LIBDIR)
 58	set(LIBDIR "lib")
 59endif()
 60
 61if (NOT DEFINED MANDIR)
 62	set(MANDIR ${CMAKE_INSTALL_MANDIR})
 63endif()
 64
 65# Function definitions
 66include(FindPkgConfig)
 67function(find_feature FEATURE_NAME FEATURE_REQUIRES)
 68	if (NOT ${FEATURE_NAME})
 69		return()
 70	endif()
 71	if (DISABLE_DEPS)
 72		set(${FEATURE_NAME} OFF PARENT_SCOPE)
 73		return()
 74	endif()
 75	foreach(REQUIRE ${FEATURE_REQUIRES})
 76		if(NOT ${REQUIRE}_FOUND)
 77			find_package(${REQUIRE} QUIET)
 78			if(NOT ${REQUIRE}_FOUND)
 79				pkg_search_module(${REQUIRE} ${REQUIRE})
 80				if (NOT ${REQUIRE}_FOUND)
 81					message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
 82					set(${FEATURE_NAME} OFF PARENT_SCOPE)
 83					return()
 84				endif()
 85			endif()
 86		endif()
 87		string(TOUPPER ${REQUIRE} UREQUIRE)
 88		set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
 89		set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
 90		set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
 91		set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
 92		set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
 93		set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
 94	endforeach()
 95endfunction()
 96
 97# Version information
 98add_custom_target(version-info ALL ${CMAKE_COMMAND} -E touch ${CMAKE_SOURCE_DIR}/src/util/version.c.in
 99	COMMAND ${CMAKE_COMMAND}
100	-DBINARY_NAME=${BINARY_NAME}
101	-DCONFIG_FILE=${CMAKE_SOURCE_DIR}/src/util/version.c.in
102	-DOUT_FILE=${CMAKE_CURRENT_BINARY_DIR}/version.c
103	-P ${CMAKE_SOURCE_DIR}/version.cmake
104	WORKING_DIRECTORY ${CMAKE_BINARY_DIR})
105
106include(${CMAKE_SOURCE_DIR}/version.cmake)
107configure_file(${CMAKE_SOURCE_DIR}/src/util/version.c.in ${CMAKE_CURRENT_BINARY_DIR}/version.c)
108list(APPEND UTIL_SRC ${CMAKE_BINARY_DIR}/version.c)
109source_group("Generated sources" FILES ${CMAKE_BINARY_DIR}/version.c)
110
111# Advanced settings
112set(BUILD_LTO ON CACHE BOOL "Build with link-time optimization")
113set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
114set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
115set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
116mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
117set(PGO_PRE_FLAGS "-pg -fprofile-generate=${PGO_DIR} -fprofile-arcs")
118set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
119
120if(BUILD_PGO AND NOT PGO_STAGE_2)
121	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
122	set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
123	set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
124elseif(BUILD_PGO AND PGO_STAGE_2)
125	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
126	set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
127	set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
128endif()
129
130# Platform support
131if(WIN32)
132	set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
133	add_definitions(-D_WIN32_WINNT=0x0600)
134	list(APPEND OS_LIB ws2_32 shlwapi)
135	list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
136	file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/windows/*.c)
137	source_group("Windows-specific code" FILES ${OS_SRC})
138elseif(UNIX)
139	add_definitions(-DUSE_PTHREADS)
140
141	if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
142		add_definitions(-D_GNU_SOURCE)
143	endif()
144	if(NOT APPLE AND NOT HAIKU)
145		set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
146	endif()
147
148	list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
149	file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/posix/*.c)
150	source_group("POSIX-specific code" FILES ${OS_SRC})
151endif()
152
153if(APPLE)
154	add_definitions(-D_DARWIN_C_SOURCE)
155	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
156endif()
157
158if(NOT HAIKU AND NOT MSVC AND NOT PSP2)
159	set(M_LIBRARY m)
160endif()
161list(APPEND OS_LIB ${M_LIBRARY})
162
163if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
164	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
165	set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
166	set_source_files_properties(${CMAKE_SOURCE_DIR}/src/arm/isa-arm.c ${CMAKE_SOURCE_DIR}/src/arm/isa-thumb.c PROPERTIES COMPILE_FLAGS -fno-lto)
167endif()
168
169if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
170	if(NOT BUILD_EGL)
171		add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
172	endif()
173endif()
174
175if(BUILD_RASPI)
176	set(BUILD_GL OFF CACHE BOOL "OpenGL not supported" FORCE)
177endif()
178
179if(BUILD_PANDORA)
180	add_definitions(-DBUILD_PANDORA)
181endif()
182
183if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
184	enable_language(ASM)
185endif()
186
187if(PSP2 OR WII)
188	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-format")
189endif()
190
191if(WII)
192	add_definitions(-U__STRICT_ANSI__)
193endif()
194
195include(CheckFunctionExists)
196check_function_exists(strdup HAVE_STRDUP)
197check_function_exists(strndup HAVE_STRNDUP)
198check_function_exists(localtime_r HAVE_LOCALTIME_R)
199if(NOT CMAKE_SYSTEM_NAME STREQUAL "Generic")
200	check_function_exists(snprintf_l HAVE_SNPRINTF_L)
201	if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
202		# The strtof_l on Linux not actually exposed nor actually strtof_l
203		set(HAVE_STRTOF_L OFF)
204	else()
205		check_function_exists(strtof_l HAVE_STRTOF_L)
206	endif()
207	check_function_exists(newlocale HAVE_NEWLOCALE)
208	check_function_exists(freelocale HAVE_FREELOCALE)
209	check_function_exists(uselocale HAVE_USELOCALE)
210	check_function_exists(setlocale HAVE_SETLOCALE)
211else()
212	set(DISABLE_DEPS ON CACHE BOOL "This platform cannot build with dependencies" FORCE)
213	set(DISABLE_FRONTENDS ON)
214	set(MINIMAL_CORE ON)
215endif()
216
217check_function_exists(chmod HAVE_CHMOD)
218check_function_exists(umask HAVE_UMASK)
219
220set(FUNCTION_DEFINES)
221
222if(HAVE_STRDUP)
223	list(APPEND FUNCTION_DEFINES HAVE_STRDUP)
224endif()
225
226if(HAVE_STRNDUP)
227	list(APPEND FUNCTION_DEFINES HAVE_STRNDUP)
228endif()
229
230if(HAVE_LOCALTIME_R)
231	list(APPEND FUNCTION_DEFINES HAVE_LOCALTIME_R)
232endif()
233
234if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE)
235	list(APPEND FUNCTION_DEFINES HAVE_LOCALE)
236	if (HAVE_STRTOF_L)
237		list(APPEND FUNCTION_DEFINES HAVE_STRTOF_L)
238	endif()
239	if (HAVE_SNPRINTF_L)
240		list(APPEND FUNCTION_DEFINES HAVE_SNPRINTF_L)
241	endif()
242endif()
243
244if(HAVE_SETLOCALE)
245	list(APPEND FUNCTION_DEFINES HAVE_SETLOCALE)
246endif()
247
248if(HAVE_CHMOD)
249	list(APPEND FUNCTION_DEFINES HAVE_CHMOD)
250endif()
251
252if(HAVE_UMASK)
253	list(APPEND FUNCTION_DEFINES HAVE_UMASK)
254endif()
255
256# Feature dependencies
257set(FEATURES)
258if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
259	set(LIBEDIT_LIBRARIES -ledit)
260	if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
261		list(APPEND LIBEDIT_LIBRARIES -ltermcap)
262	endif()
263else()
264	find_feature(USE_CLI_DEBUGGER "libedit")
265endif()
266if(BUILD_GL)
267	find_package(OpenGL QUIET)
268	if(NOT OPENGL_FOUND)
269		set(BUILD_GL OFF CACHE BOOL "OpenGL not found" FORCE)
270	endif()
271endif()
272if(BUILD_GLES2 AND NOT BUILD_RASPI)
273	find_path(OPENGLES2_INCLUDE_DIR NAMES GLES2/gl2.h)
274	find_library(OPENGLES2_LIBRARY NAMES GLESv2 GLESv2_CM)
275	if(NOT OPENGLES2_INCLUDE_DIR OR NOT OPENGLES2_LIBRARY)
276		set(BUILD_GLES2 OFF CACHE BOOL "OpenGL|ES 2 not found" FORCE)
277	endif()
278endif()
279set(WANT_ZLIB ${USE_ZLIB})
280set(WANT_PNG ${USE_PNG})
281set(WANT_LIBZIP ${USE_LIBZIP})
282
283find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
284find_feature(USE_ZLIB "ZLIB")
285find_feature(USE_PNG "PNG")
286find_feature(USE_LIBZIP "libzip")
287find_feature(USE_MAGICK "MagickWand")
288find_feature(USE_EPOXY "epoxy")
289
290# Features
291set(DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/debugger.c ${CMAKE_SOURCE_DIR}/src/debugger/memory-debugger.c)
292set(FEATURE_SRC)
293set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
294
295if(DISABLE_DEPS)
296	set(USE_LZMA OFF)
297	set(USE_GDB_STUB OFF)
298endif()
299
300if(USE_CLI_DEBUGGER)
301	list(APPEND FEATURES CLI_DEBUGGER)
302	list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/debugger/cli-debugger.c)
303	list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/debugger/parser.c)
304	list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/gba/supervisor/cli.c)
305	include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
306	link_directories(${LIBEDIT_LIBRARY_DIRS})
307	set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
308	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
309else()
310	set(DEBUGGER_LIB "")
311endif()
312
313if(USE_GDB_STUB)
314	list(APPEND FEATURES GDB_STUB)
315	list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/gdb-stub.c)
316endif()
317source_group("ARM debugger" FILES ${DEBUGGER_SRC})
318
319if(USE_FFMPEG)
320	list(APPEND FEATURES FFMPEG)
321	pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
322	if(NOT LIBSWRESAMPLE_FOUND)
323		list(APPEND FEATURES LIBAV)
324	endif()
325	include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
326	link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
327	list(APPEND FEATURE_SRC "${CMAKE_SOURCE_DIR}/src/platform/ffmpeg/ffmpeg-encoder.c")
328	string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
329	string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
330	string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
331	string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
332	string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
333	list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
334	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR}|libavcodec-extra-${LIBAVCODEC_VERSION_MAJOR},libavformat${LIBAVFORMAT_VERSION_MAJOR},libavresample${LIBAVRESAMPLE_VERSION_MAJOR},libavutil${LIBAVUTIL_VERSION_MAJOR},libswscale${LIBSWSCALE_VERSION_MAJOR}")
335	set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra")
336	if(APPLE)
337		set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
338		set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
339	endif()
340endif()
341
342if(USE_BLIP)
343	list(APPEND THIRD_PARTY_SRC "${CMAKE_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
344	add_definitions(-DRESAMPLE_LIBRARY=RESAMPLE_BLIP_BUF)
345else()
346	add_definitions(-DRESAMPLE_LIBRARY=RESAMPLE_NN)
347endif()
348
349if(USE_MAGICK)
350	list(APPEND FEATURES MAGICK)
351	include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
352	link_directories(${MAGICKWAND_LIBRARY_DIRS})
353	list(APPEND FEATURE_SRC "${CMAKE_SOURCE_DIR}/src/platform/imagemagick/imagemagick-gif-encoder.c")
354	list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
355	string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
356	if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
357		set(MAGICKWAND_DEB_VERSION "5")
358	else()
359		set(MAGICKWAND_DEB_VERSION "-6.q16-2")
360	endif()
361	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
362endif()
363
364if(WANT_ZLIB AND NOT USE_ZLIB)
365	set(SKIP_INSTALL_ALL ON)
366	add_subdirectory(${CMAKE_SOURCE_DIR}/src/third-party/zlib zlib)
367	set_property(TARGET zlibstatic PROPERTY INCLUDE_DIRECTORIES ${CMAKE_BINARY_DIR}/zlib;${CMAKE_SOURCE_DIR}/src/third-party/zlib)
368	set_property(TARGET zlib PROPERTY EXCLUDE_FROM_ALL ON)
369	set_property(TARGET example PROPERTY EXCLUDE_FROM_ALL ON)
370	set_property(TARGET minigzip PROPERTY EXCLUDE_FROM_ALL ON)
371	set(ZLIB_INCLUDE_DIRS ${CMAKE_SOURCE_DIR}/src/third-party/zlib ${CMAKE_BINARY_DIR}/zlib)
372	set(ZLIB_INCLUDE_DIR ${CMAKE_SOURCE_DIR}/src/third-party/zlib ${CMAKE_BINARY_DIR}/zlib)
373	set(ZLIB_LIBRARY zlibstatic)
374	list(APPEND DEPENDENCY_LIB zlibstatic)
375	set(USE_ZLIB ON)
376endif()
377
378if(USE_ZLIB)
379	list(APPEND FEATURES ZLIB)
380	include_directories(AFTER ${ZLIB_INCLUDE_DIRS})
381	list(APPEND DEPENDENCY_LIB ${ZLIB_LIBRARIES})
382	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},zlib1g")
383endif()
384
385if(WANT_PNG AND USE_ZLIB AND NOT USE_PNG)
386	set(PNG_STATIC ON CACHE BOOL "" FORCE)
387	set(PNG_SHARED OFF CACHE BOOL "" FORCE)
388	set(PNG_TESTS OFF CACHE BOOL "" FORCE)
389	set(SKIP_INSTALL_ALL ON)
390	add_subdirectory(${CMAKE_SOURCE_DIR}/src/third-party/libpng libpng)
391	set_property(TARGET png16_static PROPERTY INCLUDE_DIRECTORIES ${CMAKE_BINARY_DIR}/libpng;${CMAKE_SOURCE_DIR}/src/third-party/libpng;${ZLIB_INCLUDE_DIRS})
392	set(PNG_INCLUDE_DIRS ${CMAKE_SOURCE_DIR}/src/third-party/libpng ${CMAKE_BINARY_DIR}/libpng)
393	list(APPEND DEPENDENCY_LIB png16_static)
394	set(USE_PNG ON)
395endif()
396
397if(USE_PNG)
398	list(APPEND FEATURES PNG)
399	include_directories(AFTER ${PNG_INCLUDE_DIRS})
400	list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
401	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng12-0")
402endif()
403
404if(USE_LIBZIP)
405	include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
406	link_directories(${LIBZIP_LIBRARY_DIRS})
407	list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
408	list(APPEND FEATURES LIBZIP)
409	list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
410	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
411endif()
412
413if (USE_LZMA)
414	include_directories(AFTER ${CMAKE_SOURCE_DIR}/third-party/lzma)
415	add_definitions(-D_7ZIP_PPMD_SUPPPORT)
416	list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-lzma.c)
417	set(LZMA_SRC
418		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
419		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
420		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
421		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
422		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
423		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
424		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zDec.c
425		${CMAKE_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
426		${CMAKE_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
427		${CMAKE_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
428		${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bra.c
429		${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bra86.c
430		${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
431		${CMAKE_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
432		${CMAKE_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
433		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zFile.c
434		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
435	list(APPEND FEATURE_SRC ${LZMA_SRC})
436	list(APPEND FEATURES LZMA)
437endif()
438
439if(USE_EPOXY)
440	add_definitions(-DBUILD_GL -DBUILD_GLES2)
441	list(APPEND FEATURES EPOXY)
442	include_directories(AFTER ${EPOXY_INCLUDE_DIRS})
443	set(OPENGLES2_LIBRARY ${EPOXY_LIBRARIES})
444	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libepoxy0")
445endif()
446
447
448set(FEATURE_DEFINES)
449foreach(FEATURE IN LISTS FEATURES)
450	list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
451endforeach()
452
453source_group("Virtual files" FILES ${VFS_SRC})
454source_group("Extra features" FILES ${FEATURE_SRC})
455source_group("Third-party code" FILES ${THIRD_PARTY_SRC})
456
457# Platform binaries
458if(3DS)
459	add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/3ds ${CMAKE_BINARY_DIR}/3ds)
460endif()
461
462if(WII)
463	add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/wii ${CMAKE_BINARY_DIR}/wii)
464endif()
465
466if(PSP2)
467	add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/psp2 ${CMAKE_BINARY_DIR}/psp2)
468endif()
469
470# Binaries
471set(CORE_SRC
472	${ARM_SRC}
473	${GBA_SRC}
474	${GBA_CHEATS_SRC}
475	${GBA_CTX_SRC}
476	${DEBUGGER_SRC}
477	${RENDERER_SRC}
478	${UTIL_SRC}
479	${VFS_SRC}
480	${OS_SRC}
481	${THIRD_PARTY_SRC})
482
483if(NOT MINIMAL_CORE)
484	set(SRC
485		${CORE_SRC}
486		${GBA_RR_SRC}
487		${GBA_SV_SRC}
488		${SIO_SRC}
489		${FEATURE_SRC})
490else()
491	set(SRC ${CORE_SRC})
492endif()
493
494if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
495	set(BUILD_SHARED ON)
496endif()
497
498if(BUILD_SHARED)
499	add_library(${BINARY_NAME} SHARED ${SRC})
500	if(BUILD_STATIC)
501		add_library(${BINARY_NAME}-static STATIC ${SRC})
502		set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
503		install(TARGETS ${BINARY_NAME}-static DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
504		add_dependencies(${BINARY_NAME}-static version-info)
505	endif()
506else()
507	add_library(${BINARY_NAME} STATIC ${SRC})
508endif()
509
510add_dependencies(${BINARY_NAME} version-info)
511set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
512
513target_link_libraries(${BINARY_NAME} ${DEBUGGER_LIB} ${DEPENDENCY_LIB} ${OS_LIB})
514install(TARGETS ${BINARY_NAME} LIBRARY DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME} NAMELINK_SKIP ARCHIVE DESTINATION ${LIBDIR} RUNTIME DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
515if(UNIX AND NOT APPLE)
516	install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-16.png DESTINATION share/icons/hicolor/16x16/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
517	install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-24.png DESTINATION share/icons/hicolor/24x24/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
518	install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-32.png DESTINATION share/icons/hicolor/32x32/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
519	install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-48.png DESTINATION share/icons/hicolor/48x48/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
520	install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-64.png DESTINATION share/icons/hicolor/64x64/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
521	install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-96.png DESTINATION share/icons/hicolor/96x96/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
522	install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-128.png DESTINATION share/icons/hicolor/128x128/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
523	install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-256.png DESTINATION share/icons/hicolor/256x256/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
524	install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-512.png DESTINATION share/icons/hicolor/512x512/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
525endif()
526
527if(BUILD_GL)
528	add_definitions(-DBUILD_GL)
529endif()
530
531if(BUILD_GLES2)
532	add_definitions(-DBUILD_GLES2)
533endif()
534
535if(DISABLE_FRONTENDS)
536	set(BUILD_SDL OFF)
537	set(BUILD_QT OFF)
538endif()
539
540if(BUILD_LIBRETRO)
541	file(GLOB RETRO_SRC ${CMAKE_SOURCE_DIR}/src/platform/libretro/*.c)
542	add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
543	set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5;DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES}")
544	target_link_libraries(${BINARY_NAME}_libretro ${OS_LIB})
545endif()
546
547if(BUILD_SDL)
548	add_definitions(-DBUILD_SDL)
549	add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/sdl ${CMAKE_BINARY_DIR}/sdl)
550endif()
551
552if(BUILD_QT)
553	add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/qt ${CMAKE_BINARY_DIR}/qt)
554endif()
555
556if(BUILD_PERF)
557	set(PERF_SRC ${CMAKE_SOURCE_DIR}/src/platform/test/perf-main.c)
558	if(UNIX AND NOT APPLE)
559		list(APPEND PERF_LIB rt)
560	endif()
561
562	add_executable(${BINARY_NAME}-perf ${PERF_SRC})
563	target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB})
564	set_target_properties(${BINARY_NAME}-perf PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
565	install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
566	install(FILES ${CMAKE_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
567endif()
568
569if(BUILD_TEST)
570	add_executable(${BINARY_NAME}-fuzz ${CMAKE_SOURCE_DIR}/src/platform/test/fuzz-main.c)
571	target_link_libraries(${BINARY_NAME}-fuzz ${BINARY_NAME})
572	set_target_properties(${BINARY_NAME}-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
573	install(TARGETS ${BINARY_NAME}-fuzz DESTINATION bin COMPONENT ${BINARY_NAME}-test)
574endif()
575
576# Packaging
577set(CPACK_PACKAGE_VERSION ${VERSION_STRING})
578set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
579set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
580set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
581set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_SOURCE_DIR}/LICENSE)
582set(CPACK_RESOURCE_FILE_README ${CMAKE_SOURCE_DIR}/README.md)
583
584set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
585set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
586set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
587set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_SOURCE_DIR}/README.md")
588set(CPACK_DEBIAN_PACKAGE_SECTION "games")
589
590SET(CPACK_DEB_COMPONENT_INSTALL ON)
591
592set(CPACK_STRIP_FILES ${BINARY_NAME})
593
594install(FILES ${CMAKE_SOURCE_DIR}/README.md ${CMAKE_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
595
596include(CPack)
597
598# Summaries
599message(STATUS "Feature summary:")
600message(STATUS "	CLI debugger: ${USE_CLI_DEBUGGER}")
601message(STATUS "	GDB stub: ${USE_GDB_STUB}")
602message(STATUS "	Video recording: ${USE_FFMPEG}")
603message(STATUS "	GIF recording: ${USE_MAGICK}")
604message(STATUS "	Screenshot/advanced savestate support: ${USE_PNG}")
605message(STATUS "	ZIP support: ${USE_LIBZIP}")
606message(STATUS "	7-Zip support: ${USE_LZMA}")
607message(STATUS "	Better audio resampling: ${USE_BLIP}")
608message(STATUS "Frontend summary:")
609message(STATUS "	Qt: ${BUILD_QT}")
610message(STATUS "	SDL (${SDL_VERSION}): ${BUILD_SDL}")
611message(STATUS "	Libretro core: ${BUILD_LIBRETRO}")
612message(STATUS "	Profiling: ${BUILD_PERF}")
613message(STATUS "	Test harness: ${BUILD_TEST}")
614message(STATUS "Library summary:")
615message(STATUS "	Static: ${BUILD_STATIC}")
616message(STATUS "	Shared: ${BUILD_SHARED}")