CMakeLists.txt (view raw)
1cmake_minimum_required(VERSION 2.6)
2project(mGBA C)
3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
4if(NOT MSVC)
5 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -std=c99")
6else()
7 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_CRT_SECURE_NO_WARNINGS /wd4003 /wd4244 /wd4146")
8endif()
9set(USE_CLI_DEBUGGER ON CACHE BOOL "Whether or not to enable the CLI-mode ARM debugger")
10set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
11set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
12set(USE_ZLIB ON CACHE BOOL "Whether or not to enable zlib support")
13set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
14set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable ZIP support")
15set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
16set(USE_BLIP ON CACHE BOOL "Whether or not to enable blip_buf support")
17set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
18set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
19set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
20set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
21set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
22set(BUILD_TEST OFF CACHE BOOL "Build testing harness")
23set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
24set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
25set(BUILD_GL ON CACHE STRING "Build with OpenGL")
26set(BUILD_GLES2 OFF CACHE STRING "Build with OpenGL|ES 2")
27set(DISABLE_DEPS OFF CACHE BOOL "Build without dependencies")
28file(GLOB ARM_SRC ${CMAKE_SOURCE_DIR}/src/arm/*.c)
29file(GLOB GBA_SRC ${CMAKE_SOURCE_DIR}/src/gba/*.c)
30file(GLOB GBA_CHEATS_SRC ${CMAKE_SOURCE_DIR}/src/gba/cheats/*.c)
31file(GLOB GBA_RR_SRC ${CMAKE_SOURCE_DIR}/src/gba/rr/*.c)
32file(GLOB GBA_SV_SRC ${CMAKE_SOURCE_DIR}/src/gba/supervisor/*.c)
33file(GLOB GBA_CTX_SRC ${CMAKE_SOURCE_DIR}/src/gba/context/*.c)
34file(GLOB UTIL_SRC ${CMAKE_SOURCE_DIR}/src/util/*.[cSs])
35file(GLOB GUI_SRC ${CMAKE_SOURCE_DIR}/src/util/gui/*.c ${CMAKE_SOURCE_DIR}/src/gba/gui/*.c)
36file(GLOB RENDERER_SRC ${CMAKE_SOURCE_DIR}/src/gba/renderers/*.c)
37file(GLOB SIO_SRC ${CMAKE_SOURCE_DIR}/src/gba/sio/lockstep.c)
38file(GLOB THIRD_PARTY_SRC ${CMAKE_SOURCE_DIR}/src/third-party/inih/*.c)
39list(APPEND UTIL_SRC ${CMAKE_SOURCE_DIR}/src/platform/commandline.c)
40set(VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-mem.c)
41source_group("ARM core" FILES ${ARM_SRC})
42source_group("GBA board" FILES ${GBA_SRC} ${RENDERER_SRC} ${SIO_SRC})
43source_group("GBA extra" FILES ${GBA_CHEATS_SRC} ${GBA_CTX_SRC} ${GBA_SV_SRC} ${GBA_RR_SRC})
44source_group("Utilities" FILES ${UTIL_SRC})
45include_directories(${CMAKE_SOURCE_DIR}/src/arm)
46include_directories(${CMAKE_SOURCE_DIR}/src)
47
48if(NOT CMAKE_BUILD_TYPE)
49 set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
50endif()
51
52set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${LIBDIR}")
53
54include(GNUInstallDirs)
55
56if (NOT DEFINED LIBDIR)
57 set(LIBDIR "lib")
58endif()
59
60if (NOT DEFINED MANDIR)
61 set(MANDIR ${CMAKE_INSTALL_MANDIR})
62endif()
63
64# Function definitions
65include(FindPkgConfig)
66function(find_feature FEATURE_NAME FEATURE_REQUIRES)
67 if (NOT ${FEATURE_NAME})
68 return()
69 endif()
70 if (DISABLE_DEPS)
71 set(${FEATURE_NAME} OFF PARENT_SCOPE)
72 return()
73 endif()
74 foreach(REQUIRE ${FEATURE_REQUIRES})
75 if(NOT ${REQUIRE}_FOUND)
76 find_package(${REQUIRE} QUIET)
77 if(NOT ${REQUIRE}_FOUND)
78 pkg_search_module(${REQUIRE} ${REQUIRE})
79 if (NOT ${REQUIRE}_FOUND)
80 message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
81 set(${FEATURE_NAME} OFF PARENT_SCOPE)
82 return()
83 endif()
84 endif()
85 endif()
86 string(TOUPPER ${REQUIRE} UREQUIRE)
87 set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
88 set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
89 set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
90 set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
91 set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
92 set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
93 endforeach()
94endfunction()
95
96# Version information
97add_custom_target(version-info ALL ${CMAKE_COMMAND} -E touch ${CMAKE_SOURCE_DIR}/src/util/version.c.in
98 COMMAND ${CMAKE_COMMAND}
99 -DBINARY_NAME=${BINARY_NAME}
100 -DCONFIG_FILE=${CMAKE_SOURCE_DIR}/src/util/version.c.in
101 -DOUT_FILE=${CMAKE_CURRENT_BINARY_DIR}/version.c
102 -P ${CMAKE_SOURCE_DIR}/version.cmake
103 WORKING_DIRECTORY ${CMAKE_BINARY_DIR})
104
105include(${CMAKE_SOURCE_DIR}/version.cmake)
106configure_file(${CMAKE_SOURCE_DIR}/src/util/version.c.in ${CMAKE_CURRENT_BINARY_DIR}/version.c)
107list(APPEND UTIL_SRC ${CMAKE_BINARY_DIR}/version.c)
108source_group("Generated sources" FILES ${CMAKE_BINARY_DIR}/version.c)
109
110# Advanced settings
111set(BUILD_LTO ON CACHE BOOL "Build with link-time optimization")
112set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
113set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
114set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
115mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
116set(PGO_PRE_FLAGS "-pg -fprofile-generate=${PGO_DIR} -fprofile-arcs")
117set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
118
119if(BUILD_PGO AND NOT PGO_STAGE_2)
120 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
121 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
122 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
123elseif(BUILD_PGO AND PGO_STAGE_2)
124 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
125 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
126 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
127endif()
128
129# Platform support
130if(WIN32)
131 set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
132 add_definitions(-D_WIN32_WINNT=0x0600)
133 list(APPEND OS_LIB ws2_32 shlwapi)
134 list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
135 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/windows/*.c)
136 source_group("Windows-specific code" FILES ${OS_SRC})
137elseif(UNIX)
138 add_definitions(-DUSE_PTHREADS)
139
140 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
141 add_definitions(-D_GNU_SOURCE)
142 endif()
143 if(NOT APPLE AND NOT HAIKU)
144 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
145 endif()
146
147 list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
148 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/posix/*.c)
149 source_group("POSIX-specific code" FILES ${OS_SRC})
150endif()
151
152if(APPLE)
153 add_definitions(-D_DARWIN_C_SOURCE)
154 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
155endif()
156
157if(NOT HAIKU AND NOT MSVC AND NOT PSP2)
158 set(M_LIBRARY m)
159endif()
160list(APPEND OS_LIB ${M_LIBRARY})
161
162if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
163 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
164 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
165 set_source_files_properties(${CMAKE_SOURCE_DIR}/src/arm/isa-arm.c ${CMAKE_SOURCE_DIR}/src/arm/isa-thumb.c PROPERTIES COMPILE_FLAGS -fno-lto)
166endif()
167
168if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
169 if(NOT BUILD_EGL)
170 add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
171 endif()
172endif()
173
174if(BUILD_RASPI)
175 set(BUILD_GL OFF CACHE BOOL "OpenGL not supported" FORCE)
176endif()
177
178if(BUILD_PANDORA)
179 add_definitions(-DBUILD_PANDORA)
180endif()
181
182if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
183 enable_language(ASM)
184endif()
185
186if(PSP2)
187 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-format")
188endif()
189
190include(CheckFunctionExists)
191check_function_exists(strdup HAVE_STRDUP)
192check_function_exists(strndup HAVE_STRNDUP)
193if(NOT CMAKE_SYSTEM_NAME STREQUAL "Generic")
194 check_function_exists(snprintf_l HAVE_SNPRINTF_L)
195 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
196 # The strtof_l on Linux not actually exposed nor actually strtof_l
197 set(HAVE_STRTOF_L OFF)
198 else()
199 check_function_exists(strtof_l HAVE_STRTOF_L)
200 endif()
201 check_function_exists(newlocale HAVE_NEWLOCALE)
202 check_function_exists(freelocale HAVE_FREELOCALE)
203 check_function_exists(uselocale HAVE_USELOCALE)
204 check_function_exists(setlocale HAVE_SETLOCALE)
205else()
206 set(DISABLE_DEPS ON CACHE BOOL "This platform cannot build with dependencies" FORCE)
207 set(DISABLE_FRONTENDS ON)
208 set(MINIMAL_CORE ON)
209endif()
210
211if(HAVE_STRDUP)
212 add_definitions(-DHAVE_STRDUP)
213endif()
214
215if(HAVE_STRNDUP)
216 add_definitions(-DHAVE_STRNDUP)
217endif()
218
219if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE)
220 add_definitions(-DHAVE_LOCALE)
221 if (HAVE_STRTOF_L)
222 add_definitions(-DHAVE_STRTOF_L)
223 endif()
224 if (HAVE_SNPRINTF_L)
225 add_definitions(-DHAVE_SNPRINTF_L)
226 endif()
227endif()
228
229if(HAVE_SETLOCALE)
230 add_definitions(-DHAVE_SETLOCALE)
231endif()
232
233# Feature dependencies
234set(FEATURES)
235if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
236 set(LIBEDIT_LIBRARIES -ledit)
237 if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
238 list(APPEND LIBEDIT_LIBRARIES -ltermcap)
239 endif()
240else()
241 find_feature(USE_CLI_DEBUGGER "libedit")
242endif()
243if(BUILD_GL)
244 find_package(OpenGL QUIET)
245 if(NOT OPENGL_FOUND)
246 set(BUILD_GL OFF CACHE BOOL "OpenGL not found" FORCE)
247 endif()
248endif()
249if(BUILD_GLES2 AND NOT BUILD_RASPI)
250 find_path(OPENGLES2_INCLUDE_DIR NAMES GLES2/gl2.h)
251 find_library(OPENGLES2_LIBRARY NAMES GLESv2 GLESv2_CM)
252 if(NOT OPENGLES2_INCLUDE_DIR OR NOT OPENGLES2_LIBRARY)
253 set(BUILD_GLES2 OFF CACHE BOOL "OpenGL|ES 2 not found" FORCE)
254 endif()
255endif()
256set(WANT_ZLIB ${USE_ZLIB})
257set(WANT_PNG ${USE_PNG})
258find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
259if(NOT PSP2)
260 find_feature(USE_ZLIB "ZLIB")
261 find_feature(USE_PNG "PNG")
262endif()
263find_feature(USE_LIBZIP "libzip")
264find_feature(USE_MAGICK "MagickWand")
265
266# Features
267set(DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/debugger.c ${CMAKE_SOURCE_DIR}/src/debugger/memory-debugger.c)
268set(FEATURE_SRC)
269set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
270
271if(DISABLE_DEPS)
272 set(USE_LZMA OFF)
273 set(USE_GDB_STUB OFF)
274endif()
275
276if(USE_CLI_DEBUGGER)
277 list(APPEND FEATURES CLI_DEBUGGER)
278 list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/debugger/cli-debugger.c)
279 list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/debugger/parser.c)
280 list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/gba/supervisor/cli.c)
281 include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
282 link_directories(${LIBEDIT_LIBRARY_DIRS})
283 set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
284 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
285else()
286 set(DEBUGGER_LIB "")
287endif()
288
289if(USE_GDB_STUB)
290 list(APPEND FEATURES GDB_STUB)
291 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/gdb-stub.c)
292endif()
293source_group("ARM debugger" FILES ${DEBUGGER_SRC})
294
295if(USE_FFMPEG)
296 list(APPEND FEATURES FFMPEG)
297 pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
298 if(NOT LIBSWRESAMPLE_FOUND)
299 list(APPEND FEATURES LIBAV)
300 endif()
301 include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
302 link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
303 list(APPEND FEATURE_SRC "${CMAKE_SOURCE_DIR}/src/platform/ffmpeg/ffmpeg-encoder.c")
304 string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
305 string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
306 string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
307 string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
308 string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
309 list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
310 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR}|libavcodec-extra-${LIBAVCODEC_VERSION_MAJOR},libavformat${LIBAVFORMAT_VERSION_MAJOR},libavresample${LIBAVRESAMPLE_VERSION_MAJOR},libavutil${LIBAVUTIL_VERSION_MAJOR},libswscale${LIBSWSCALE_VERSION_MAJOR}")
311 set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra")
312 if(APPLE)
313 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
314 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
315 endif()
316endif()
317
318if(USE_BLIP)
319 list(APPEND THIRD_PARTY_SRC "${CMAKE_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
320 add_definitions(-DRESAMPLE_LIBRARY=RESAMPLE_BLIP_BUF)
321else()
322 add_definitions(-DRESAMPLE_LIBRARY=RESAMPLE_NN)
323endif()
324
325if(USE_MAGICK)
326 list(APPEND FEATURES MAGICK)
327 include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
328 link_directories(${MAGICKWAND_LIBRARY_DIRS})
329 list(APPEND FEATURE_SRC "${CMAKE_SOURCE_DIR}/src/platform/imagemagick/imagemagick-gif-encoder.c")
330 list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
331 string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
332 if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
333 set(MAGICKWAND_DEB_VERSION "5")
334 else()
335 set(MAGICKWAND_DEB_VERSION "-6.q16-2")
336 endif()
337 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
338endif()
339
340if(WANT_ZLIB AND NOT USE_ZLIB)
341 set(SKIP_INSTALL_ALL ON)
342 add_subdirectory(${CMAKE_SOURCE_DIR}/src/third-party/zlib zlib)
343 set_property(TARGET zlibstatic PROPERTY INCLUDE_DIRECTORIES ${CMAKE_BINARY_DIR}/zlib;${CMAKE_SOURCE_DIR}/src/third-party/zlib)
344 set_property(TARGET zlib PROPERTY EXCLUDE_FROM_ALL ON)
345 set_property(TARGET example PROPERTY EXCLUDE_FROM_ALL ON)
346 set_property(TARGET minigzip PROPERTY EXCLUDE_FROM_ALL ON)
347 set(ZLIB_INCLUDE_DIRS ${CMAKE_SOURCE_DIR}/src/third-party/zlib ${CMAKE_BINARY_DIR}/zlib)
348 set(ZLIB_INCLUDE_DIR ${CMAKE_SOURCE_DIR}/src/third-party/zlib ${CMAKE_BINARY_DIR}/zlib)
349 set(ZLIB_LIBRARY zlibstatic)
350 list(APPEND DEPENDENCY_LIB zlibstatic)
351 set(USE_ZLIB ON)
352endif()
353
354if(USE_ZLIB)
355 list(APPEND FEATURES ZLIB)
356 include_directories(AFTER ${ZLIB_INCLUDE_DIRS})
357 list(APPEND DEPENDENCY_LIB ${ZLIB_LIBRARIES})
358 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},zlib1g")
359endif()
360
361if(WANT_PNG AND USE_ZLIB AND NOT USE_PNG)
362 set(PNG_STATIC ON CACHE BOOL "" FORCE)
363 set(PNG_SHARED OFF CACHE BOOL "" FORCE)
364 set(PNG_TESTS OFF CACHE BOOL "" FORCE)
365 set(SKIP_INSTALL_ALL ON)
366 add_subdirectory(${CMAKE_SOURCE_DIR}/src/third-party/libpng libpng)
367 set_property(TARGET png16_static PROPERTY INCLUDE_DIRECTORIES ${CMAKE_BINARY_DIR}/libpng;${CMAKE_SOURCE_DIR}/src/third-party/libpng;${ZLIB_INCLUDE_DIRS})
368 set(PNG_INCLUDE_DIRS ${CMAKE_SOURCE_DIR}/src/third-party/libpng ${CMAKE_BINARY_DIR}/libpng)
369 list(APPEND DEPENDENCY_LIB png16_static)
370 set(USE_PNG ON)
371endif()
372
373if(USE_PNG)
374 list(APPEND FEATURES PNG)
375 if(NOT PSP2)
376 include_directories(AFTER ${PNG_INCLUDE_DIRS})
377 list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
378 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng12-0")
379 endif()
380endif()
381
382if(USE_LIBZIP)
383 include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
384 link_directories(${LIBZIP_LIBRARY_DIRS})
385 list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
386 list(APPEND FEATURES LIBZIP)
387 list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
388 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
389endif()
390
391if (USE_LZMA)
392 include_directories(AFTER ${CMAKE_SOURCE_DIR}/third-party/lzma)
393 add_definitions(-D_7ZIP_PPMD_SUPPPORT)
394 list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-lzma.c)
395 set(LZMA_SRC
396 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
397 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
398 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
399 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
400 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
401 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
402 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zDec.c
403 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
404 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
405 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
406 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bra.c
407 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bra86.c
408 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
409 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
410 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
411 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zFile.c
412 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
413 list(APPEND FEATURE_SRC ${LZMA_SRC})
414 list(APPEND FEATURES LZMA)
415endif()
416
417set(FEATURE_DEFINES)
418foreach(FEATURE IN LISTS FEATURES)
419 list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
420endforeach()
421
422source_group("Virtual files" FILES ${VFS_SRC})
423source_group("Extra features" FILES ${FEATURE_SRC})
424source_group("Third-party code" FILES ${THIRD_PARTY_SRC})
425
426# Platform binaries
427if(3DS)
428 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/3ds ${CMAKE_BINARY_DIR}/3ds)
429endif()
430
431if(WII)
432 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/wii ${CMAKE_BINARY_DIR}/wii)
433endif()
434
435if(PSP2)
436 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/psp2 ${CMAKE_BINARY_DIR}/psp2)
437endif()
438
439# Binaries
440set(CORE_SRC
441 ${ARM_SRC}
442 ${GBA_SRC}
443 ${GBA_CHEATS_SRC}
444 ${GBA_CTX_SRC}
445 ${DEBUGGER_SRC}
446 ${RENDERER_SRC}
447 ${UTIL_SRC}
448 ${VFS_SRC}
449 ${OS_SRC}
450 ${THIRD_PARTY_SRC})
451
452if(NOT MINIMAL_CORE)
453 set(SRC
454 ${CORE_SRC}
455 ${GBA_RR_SRC}
456 ${GBA_SV_SRC}
457 ${SIO_SRC}
458 ${FEATURE_SRC})
459else()
460 set(SRC ${CORE_SRC})
461endif()
462
463if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
464 set(BUILD_SHARED ON)
465endif()
466
467if(BUILD_SHARED)
468 add_library(${BINARY_NAME} SHARED ${SRC})
469 if(BUILD_STATIC)
470 add_library(${BINARY_NAME}-static STATIC ${SRC})
471 set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES}")
472 install(TARGETS ${BINARY_NAME}-static DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
473 add_dependencies(${BINARY_NAME}-static version-info)
474 endif()
475else()
476 add_library(${BINARY_NAME} STATIC ${SRC})
477endif()
478
479add_dependencies(${BINARY_NAME} version-info)
480set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES}")
481
482target_link_libraries(${BINARY_NAME} ${DEBUGGER_LIB} ${DEPENDENCY_LIB} ${OS_LIB})
483install(TARGETS ${BINARY_NAME} LIBRARY DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME} NAMELINK_SKIP ARCHIVE DESTINATION ${LIBDIR} RUNTIME DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
484if(UNIX AND NOT APPLE)
485 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-16.png DESTINATION share/icons/hicolor/16x16/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
486 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-24.png DESTINATION share/icons/hicolor/24x24/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
487 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-32.png DESTINATION share/icons/hicolor/32x32/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
488 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-48.png DESTINATION share/icons/hicolor/48x48/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
489 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-64.png DESTINATION share/icons/hicolor/64x64/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
490 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-96.png DESTINATION share/icons/hicolor/96x96/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
491 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-128.png DESTINATION share/icons/hicolor/128x128/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
492 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-256.png DESTINATION share/icons/hicolor/256x256/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
493 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-512.png DESTINATION share/icons/hicolor/512x512/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
494endif()
495
496if(BUILD_GL)
497 add_definitions(-DBUILD_GL)
498endif()
499
500if(BUILD_GLES2)
501 add_definitions(-DBUILD_GLES2)
502endif()
503
504if(DISABLE_FRONTENDS)
505 set(BUILD_SDL OFF)
506 set(BUILD_QT OFF)
507endif()
508
509if(BUILD_LIBRETRO)
510 file(GLOB RETRO_SRC ${CMAKE_SOURCE_DIR}/src/platform/libretro/*.c)
511 add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
512 set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5;DISABLE_THREADING")
513 target_link_libraries(${BINARY_NAME}_libretro ${OS_LIB})
514endif()
515
516if(BUILD_SDL)
517 add_definitions(-DBUILD_SDL)
518 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/sdl ${CMAKE_BINARY_DIR}/sdl)
519endif()
520
521if(BUILD_QT)
522 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/qt ${CMAKE_BINARY_DIR}/qt)
523endif()
524
525if(BUILD_PERF)
526 set(PERF_SRC ${CMAKE_SOURCE_DIR}/src/platform/test/perf-main.c)
527 if(UNIX AND NOT APPLE)
528 list(APPEND PERF_LIB rt)
529 endif()
530
531 add_executable(${BINARY_NAME}-perf ${PERF_SRC})
532 target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB})
533 install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
534 install(FILES ${CMAKE_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
535endif()
536
537if(BUILD_TEST)
538 add_executable(${BINARY_NAME}-fuzz ${CMAKE_SOURCE_DIR}/src/platform/test/fuzz-main.c)
539 target_link_libraries(${BINARY_NAME}-fuzz ${BINARY_NAME})
540 install(TARGETS ${BINARY_NAME}-fuzz DESTINATION bin COMPONENT ${BINARY_NAME}-test)
541endif()
542
543# Packaging
544set(CPACK_PACKAGE_VERSION ${VERSION_STRING})
545set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
546set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
547set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
548set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_SOURCE_DIR}/LICENSE)
549set(CPACK_RESOURCE_FILE_README ${CMAKE_SOURCE_DIR}/README.md)
550
551set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
552set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
553set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
554set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_SOURCE_DIR}/README.md")
555set(CPACK_DEBIAN_PACKAGE_SECTION "games")
556
557SET(CPACK_DEB_COMPONENT_INSTALL ON)
558
559set(CPACK_STRIP_FILES ${BINARY_NAME})
560
561install(FILES ${CMAKE_SOURCE_DIR}/README.md ${CMAKE_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
562
563include(CPack)
564
565# Summaries
566message(STATUS "Feature summary:")
567message(STATUS " CLI debugger: ${USE_CLI_DEBUGGER}")
568message(STATUS " GDB stub: ${USE_GDB_STUB}")
569message(STATUS " Video recording: ${USE_FFMPEG}")
570message(STATUS " GIF recording: ${USE_MAGICK}")
571message(STATUS " Screenshot/advanced savestate support: ${USE_PNG}")
572message(STATUS " ZIP support: ${USE_LIBZIP}")
573message(STATUS " 7-Zip support: ${USE_LZMA}")
574message(STATUS " Better audio resampling: ${USE_BLIP}")
575message(STATUS "Frontend summary:")
576message(STATUS " Qt: ${BUILD_QT}")
577message(STATUS " SDL (${SDL_VERSION}): ${BUILD_SDL}")
578message(STATUS " Libretro core: ${BUILD_LIBRETRO}")
579message(STATUS " Profiling: ${BUILD_PERF}")
580message(STATUS " Test harness: ${BUILD_TEST}")
581message(STATUS "Library summary:")
582message(STATUS " Static: ${BUILD_STATIC}")
583message(STATUS " Shared: ${BUILD_SHARED}")