CMakeLists.txt (view raw)
1cmake_minimum_required(VERSION 2.6)
2project(mGBA C)
3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
4set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -std=gnu99")
5set(USE_CLI_DEBUGGER ON CACHE BOOL "Whether or not to enable the CLI-mode ARM debugger")
6set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
7set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
8set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
9set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable ZIP support")
10set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
11set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
12set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
13set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
14file(GLOB ARM_SRC ${CMAKE_SOURCE_DIR}/src/arm/*.c)
15file(GLOB GBA_SRC ${CMAKE_SOURCE_DIR}/src/gba/*.c)
16file(GLOB UTIL_SRC ${CMAKE_SOURCE_DIR}/src/util/*.[cSs])
17file(GLOB VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/*.c)
18file(GLOB RENDERER_SRC ${CMAKE_SOURCE_DIR}/src/gba/renderers/video-software.c)
19file(GLOB THIRD_PARTY_SRC ${CMAKE_SOURCE_DIR}/src/third-party/inih/*.c)
20list(APPEND UTIL_SRC ${CMAKE_SOURCE_DIR}/src/platform/commandline.c)
21source_group("ARM core" FILES ${ARM_SRC})
22source_group("GBA board" FILES ${GBA_SRC} ${RENDERER_SRC})
23source_group("Utilities" FILES ${UTIL_SRC} ${VFS_SRC}})
24include_directories(${CMAKE_SOURCE_DIR}/src/arm)
25include_directories(${CMAKE_SOURCE_DIR}/src/gba)
26include_directories(${CMAKE_SOURCE_DIR}/src)
27
28if(NOT CMAKE_BUILD_TYPE)
29 set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)")
30endif()
31
32include(GNUInstallDirs)
33
34# Function definitions
35include(FindPkgConfig)
36function(find_feature FEATURE_NAME FEATURE_REQUIRES)
37 if (NOT ${FEATURE_NAME})
38 return()
39 endif()
40 foreach(REQUIRE ${FEATURE_REQUIRES})
41 if(NOT ${REQUIRE}_FOUND)
42 find_package(${REQUIRE} QUIET)
43 if(NOT ${REQUIRE}_FOUND)
44 pkg_search_module(${REQUIRE} ${REQUIRE})
45 if (NOT ${REQUIRE}_FOUND)
46 message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
47 set(${FEATURE_NAME} OFF PARENT_SCOPE)
48 return()
49 endif()
50 endif()
51 endif()
52 string(TOUPPER ${REQUIRE} UREQUIRE)
53 set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
54 set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
55 set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
56 set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
57 set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
58 set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
59 endforeach()
60endfunction()
61
62# Version information
63set(LIB_VERSION_MAJOR 0)
64set(LIB_VERSION_MINOR 1)
65set(LIB_VERSION_PATCH 0)
66set(LIB_VERSION_ABI 0.1)
67set(LIB_VERSION_STRING ${LIB_VERSION_MAJOR}.${LIB_VERSION_MINOR}.${LIB_VERSION_PATCH})
68
69# Advanced settings
70set(BUILD_PGO CACHE BOOL "Build with profiling-guided optimization")
71set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
72set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
73mark_as_advanced(BUILD_PGO PGO_STAGE_2 PGO_DIR)
74set(PGO_PRE_FLAGS "-pg -fprofile-generate=${PGO_DIR} -fprofile-arcs")
75set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
76
77if(BUILD_PGO AND NOT PGO_STAGE_2)
78 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
79 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
80 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
81elseif(BUILD_PGO AND PGO_STAGE_2)
82 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
83 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
84 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
85endif()
86
87add_definitions(-DBINARY_NAME="${BINARY_NAME}" -DPROJECT_NAME="${PROJECT_NAME}" -DPROJECT_VERSION="${LIB_VERSION_STRING}")
88
89# Feature dependencies
90find_feature(USE_CLI_DEBUGGER "libedit")
91find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
92find_feature(USE_PNG "ZLIB;PNG")
93find_feature(USE_LIBZIP "libzip")
94find_feature(USE_MAGICK "MagickWand")
95
96include(CheckFunctionExists)
97check_function_exists(strndup HAVE_STRNDUP)
98
99if(HAVE_STRNDUP)
100 add_definitions(-DHAVE_STRNDUP)
101endif()
102
103# Platform support
104set(BINARY_TYPE SHARED)
105if(WIN32)
106 add_definitions(-D_WIN32_WINNT=0x0600)
107 list(APPEND OS_LIB ws2_32)
108 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/windows/*.c)
109 source_group("Windows-specific code" FILES ${OS_SRC})
110elseif(UNIX)
111 add_definitions(-DUSE_PTHREADS)
112 list(APPEND OS_LIB pthread)
113 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/posix/*.c)
114 source_group("POSIX-specific code" FILES ${OS_SRC})
115elseif(3DS)
116 list(APPEND OS_LIB ctru)
117 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/3ds/3ds-*.c)
118 source_group("3DS-specific code" FILES ${OS_SRC})
119 set(BINARY_TYPE STATIC)
120endif()
121
122if(APPLE)
123 set(CMAKE_OSX_DEPLOYMENT_TARGET "10.7")
124 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -stdlib=libc++")
125endif()
126
127if(BUILD_BBB OR BUILD_RASPI)
128 enable_language(ASM)
129 if(NOT BUILD_EGL)
130 add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
131 endif()
132endif()
133
134# Features
135set(DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/debugger.c ${CMAKE_SOURCE_DIR}/src/debugger/memory-debugger.c)
136
137if(USE_CLI_DEBUGGER)
138 add_definitions(-DUSE_CLI_DEBUGGER)
139 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/cli-debugger.c)
140 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/parser.c)
141 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/gba/gba-cli.c)
142 include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
143 link_directories(${LIBEDIT_LIBRARY_DIRS})
144 set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
145else()
146 set(DEBUGGER_LIB "")
147endif()
148
149if(USE_GDB_STUB)
150 add_definitions(-DUSE_GDB_STUB)
151 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/gdb-stub.c)
152endif()
153source_group("ARM debugger" FILES ${DEBUGGER_SRC})
154
155if(USE_FFMPEG)
156 add_definitions(-DUSE_FFMPEG)
157 include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
158 link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
159 list(APPEND UTIL_SRC "${CMAKE_SOURCE_DIR}/src/platform/ffmpeg/ffmpeg-encoder.c")
160 list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
161endif()
162
163if(USE_MAGICK)
164 add_definitions(-DUSE_MAGICK)
165 include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
166 link_directories(${MAGICKWAND_LIBRARY_DIRS})
167 list(APPEND UTIL_SRC "${CMAKE_SOURCE_DIR}/src/platform/imagemagick/imagemagick-gif-encoder.c")
168 list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
169endif()
170
171if(USE_PNG)
172 add_definitions(-DUSE_PNG)
173 include_directories(AFTER ${PNG_INCLUDE_DIRS})
174 list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
175endif()
176
177if(USE_LIBZIP)
178 include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
179 link_directories(${LIBZIP_LIBRARY_DIRS})
180 list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
181 add_definitions(-DENABLE_LIBZIP)
182endif()
183
184# Binaries
185add_library(${BINARY_NAME} ${BINARY_TYPE}
186 ${ARM_SRC}
187 ${GBA_SRC}
188 ${DEBUGGER_SRC}
189 ${RENDERER_SRC}
190 ${UTIL_SRC}
191 ${VFS_SRC}
192 ${OS_SRC}
193 ${THIRD_PARTY_SRC})
194target_link_libraries(${BINARY_NAME} m ${DEBUGGER_LIB} ${OS_LIB} ${DEPENDENCY_LIB})
195install(TARGETS ${BINARY_NAME} DESTINATION lib)
196set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI})
197
198if(BUILD_SDL)
199 add_definitions(-DBUILD_SDL)
200 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/sdl ${CMAKE_BINARY_DIR}/sdl)
201endif()
202
203if(BUILD_QT)
204 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/qt ${CMAKE_BINARY_DIR}/qt)
205endif()
206
207if(BUILD_PERF)
208 set(PERF_SRC ${CMAKE_SOURCE_DIR}/src/platform/perf-main.c)
209 if(UNIX AND NOT APPLE)
210 list(APPEND PERF_LIB rt)
211 endif()
212
213 add_executable(${BINARY_NAME}-perf ${PERF_SRC})
214 target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB})
215 install(TARGETS ${BINARY_NAME}-perf DESTINATION bin)
216 install(FILES ${CMAKE_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}")
217endif()
218
219if(3DS)
220 add_executable(${BINARY_NAME}.elf ${CMAKE_SOURCE_DIR}/src/platform/3ds/main.c)
221 target_link_libraries(${BINARY_NAME}.elf ${BINARY_NAME} m ${OS_LIB})
222 add_custom_command(TARGET ${BINARY_NAME}.elf POST_BUILD COMMAND ${3DSXTOOL} ${BINARY_NAME}.elf ${BINARY_NAME}.3dsx)
223endif()
224
225# Packaging
226set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
227set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
228set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
229set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_SOURCE_DIR}/LICENSE)
230
231set(CPACK_STRIP_FILES ${BINARY_NAME})
232
233include(CPack)
234
235# Summaries
236message(STATUS "Feature summary:")
237message(STATUS " CLI debugger: ${USE_CLI_DEBUGGER}")
238message(STATUS " GDB stub: ${USE_GDB_STUB}")
239message(STATUS " Video recording: ${USE_FFMPEG}")
240message(STATUS " GIF recording: ${USE_MAGICK}")
241message(STATUS " Screenshot/advanced savestate support: ${USE_PNG}")
242message(STATUS " ZIP support: ${USE_LIBZIP}")
243message(STATUS "Frontend summary:")
244message(STATUS " Qt: ${BUILD_QT}")
245message(STATUS " SDL (${SDL_VERSION}): ${BUILD_SDL}")
246message(STATUS " Profiling: ${BUILD_PERF}")