CMakeLists.txt (view raw)
1cmake_minimum_required(VERSION 2.8.11)
2project(mGBA)
3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
4if(NOT MSVC)
5 set(GCC_STD "c99")
6 if(CMAKE_C_COMPILER_ID STREQUAL "GNU" AND CMAKE_COMPILER_VERSION VERSION_LESS "4.3")
7 set(GCC_STD "gnu99")
8 endif()
9 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wno-missing-field-initializers -std=${GCC_STD}")
10else()
11 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_CRT_SECURE_NO_WARNINGS /wd4003 /wd4244 /wd4146")
12endif()
13set(USE_DEBUGGERS ON CACHE BOOL "Whether or not to enable the debugging infrastructure")
14set(USE_EDITLINE ON CACHE BOOL "Whether or not to enable the CLI-mode debugger")
15set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
16set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
17set(USE_ZLIB ON CACHE BOOL "Whether or not to enable zlib support")
18set(USE_MINIZIP ON CACHE BOOL "Whether or not to enable external minizip support")
19set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
20set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable LIBZIP support")
21set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
22set(USE_SQLITE3 ON CACHE BOOL "Whether or not to enable SQLite3 support")
23set(M_CORE_GBA ON CACHE BOOL "Build Game Boy Advance core")
24set(M_CORE_GB ON CACHE BOOL "Build Game Boy core")
25set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
26set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
27set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
28set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
29if(APPLE)
30 set(BUILD_OPENEMU OFF CACHE BOOL "Build OpenEmu core")
31endif()
32set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
33set(BUILD_TEST OFF CACHE BOOL "Build testing harness")
34set(BUILD_SUITE OFF CACHE BOOL "Build test suite")
35set(BUILD_EXAMPLE OFF CACHE BOOL "Build example frontends")
36set(BUILD_PYTHON OFF CACHE BOOL "Build Python bindings")
37set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
38set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
39set(SKIP_LIBRARY OFF CACHE BOOL "Skip building the library (useful for only building libretro or OpenEmu cores)")
40set(BUILD_GL ON CACHE STRING "Build with OpenGL")
41set(BUILD_GLES2 OFF CACHE STRING "Build with OpenGL|ES 2")
42set(USE_EPOXY ON CACHE STRING "Build with libepoxy")
43set(DISABLE_DEPS OFF CACHE BOOL "Build without dependencies")
44file(GLOB ARM_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/*.c)
45file(GLOB ARM_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/test/*.c)
46file(GLOB LR35902_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/*.c)
47file(GLOB LR35902_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/test/*.c)
48file(GLOB GBA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/*.c)
49file(GLOB GBA_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/test/*.c)
50file(GLOB GB_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/*.c)
51file(GLOB GB_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/test/*.c)
52file(GLOB GBA_CHEATS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/cheats/*.c)
53file(GLOB GBA_RR_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/rr/*.c)
54file(GLOB CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/*.c)
55file(GLOB CORE_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/test/*.c)
56file(GLOB UTIL_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/*.[cSs])
57file(GLOB UTIL_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/test/*.c)
58file(GLOB GUI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/gui/*.c ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/gui/*.c)
59file(GLOB GBA_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/renderers/*.c)
60file(GLOB GBA_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/sio/lockstep.c)
61file(GLOB GBA_EXTRA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/extra/*.c)
62file(GLOB GB_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/sio/lockstep.c)
63file(GLOB GB_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/renderers/*.c)
64file(GLOB GB_EXTRA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/extra/*.c)
65file(GLOB THIRD_PARTY_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/inih/*.c)
66file(GLOB EXTRA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/*.c)
67set(CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-mem.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fifo.c)
68set(VFS_SRC)
69source_group("ARM core" FILES ${ARM_SRC})
70source_group("LR35902 core" FILES ${LR35902_SRC})
71source_group("GBA board" FILES ${GBA_SRC} ${GBA_RENDERER_SRC} ${GBA_SIO_SRC})
72source_group("GBA extra" FILES ${GBA_CHEATS_SRC} ${GBA_RR_SRC})
73source_group("GB board" FILES ${GB_SRC} ${GB_SIO_SRC})
74source_group("Utilities" FILES ${UTIL_SRC})
75include_directories(BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/include ${CMAKE_CURRENT_SOURCE_DIR}/src)
76
77if(NOT CMAKE_BUILD_TYPE)
78 set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
79endif()
80
81include(GNUInstallDirs)
82
83set(LIBDIR "${CMAKE_INSTALL_LIBDIR}" CACHE PATH "Installed library directory")
84mark_as_advanced(LIBDIR)
85
86if (BUILD_LIBRETRO)
87 set(LIBRETRO_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (Libretro)")
88 mark_as_advanced(LIBRETRO_LIBDIR)
89endif()
90
91if (BUILD_OPENEMU)
92 set(OE_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (OpenEmu)")
93 mark_as_advanced(OE_LIBDIR)
94endif()
95
96
97set(CMAKE_INSTALL_RPATH "${LIBDIR}")
98
99if (NOT DEFINED MANDIR)
100 set(MANDIR ${CMAKE_INSTALL_MANDIR})
101endif()
102
103# Function definitions
104include(FindPkgConfig)
105function(find_feature FEATURE_NAME FEATURE_REQUIRES)
106 if (NOT ${FEATURE_NAME})
107 return()
108 endif()
109 if (DISABLE_DEPS)
110 set(${FEATURE_NAME} OFF PARENT_SCOPE)
111 return()
112 endif()
113 foreach(REQUIRE ${FEATURE_REQUIRES})
114 if(NOT ${REQUIRE}_FOUND)
115 find_package(${REQUIRE} QUIET)
116 if(NOT ${REQUIRE}_FOUND)
117 pkg_search_module(${REQUIRE} ${REQUIRE})
118 if (NOT ${REQUIRE}_FOUND)
119 message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
120 set(${FEATURE_NAME} OFF PARENT_SCOPE)
121 return()
122 endif()
123 endif()
124 endif()
125 string(TOUPPER ${REQUIRE} UREQUIRE)
126 set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
127 set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
128 set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
129 set(${UREQUIRE}_VERSION_STRING ${${REQUIRE}_VERSION_STRING} PARENT_SCOPE)
130 if (APPLE)
131 set(IS_FRAMEWORK OFF)
132 set(LIBS)
133 foreach(LIB IN LISTS ${REQUIRE}_LIBRARIES)
134 if(LIB STREQUAL "-framework")
135 set(IS_FRAMEWORK ON)
136 elseif(IS_FRAMEWORK)
137 list(APPEND LIBS "-framework ${LIB}")
138 set(IS_FRAMEWORK OFF)
139 else()
140 list(APPEND LIBS ${LIB})
141 endif()
142 endforeach()
143 set(${UREQUIRE}_LIBRARIES ${LIBS} PARENT_SCOPE)
144 else()
145 set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
146 endif()
147 set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
148 set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
149 endforeach()
150endfunction()
151
152# Version information
153add_custom_target(version-info ALL
154 COMMAND ${CMAKE_COMMAND}
155 -DBINARY_NAME=${BINARY_NAME}
156 -DCONFIG_FILE=${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in
157 -DOUT_FILE=${CMAKE_CURRENT_BINARY_DIR}/version.c
158 -P ${CMAKE_CURRENT_SOURCE_DIR}/version.cmake
159 WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
160
161include(${CMAKE_CURRENT_SOURCE_DIR}/version.cmake)
162configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in ${CMAKE_CURRENT_BINARY_DIR}/version.c)
163
164list(APPEND UTIL_SRC ${CMAKE_CURRENT_BINARY_DIR}/version.c)
165source_group("Generated sources" FILES ${CMAKE_CURRENT_BINARY_DIR}/version.c)
166
167# Advanced settings
168if(NOT DEFINED 3DS)
169 # LTO appears to make 3DS binary slower
170 set(DEFAULT_LTO ON)
171else()
172 set(DEFAULT_LTO OFF)
173endif()
174
175set(BUILD_LTO ${DEFAULT_LTO} CACHE BOOL "Build with link-time optimization")
176set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
177set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
178set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
179mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
180set(PGO_PRE_FLAGS "-fprofile-generate=${PGO_DIR} -fprofile-arcs")
181set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
182
183if(BUILD_PGO AND NOT PGO_STAGE_2)
184 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
185 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
186 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
187elseif(BUILD_PGO AND PGO_STAGE_2)
188 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
189 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
190 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
191endif()
192
193# Platform support
194if(WIN32)
195 set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
196 add_definitions(-D_WIN32_WINNT=0x0600)
197 list(APPEND OS_LIB ws2_32 shlwapi)
198 list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/vfs-w32.c)
199 file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/*.c)
200 source_group("Windows-specific code" FILES ${OS_SRC})
201 if(MSVC)
202 add_definitions(-DNOMINMAX -DWIN32_LEAN_AND_MEAN)
203 set(CMAKE_WINDOWS_EXPORT_ALL_SYMBOLS TRUE)
204 endif()
205elseif(UNIX)
206 set(USE_PTHREADS ON)
207 add_definitions(-DUSE_PTHREADS)
208
209 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
210 add_definitions(-D_GNU_SOURCE)
211 endif()
212 if(NOT APPLE AND NOT HAIKU)
213 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
214 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -pthread")
215 endif()
216
217 list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
218 file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/posix/*.c)
219 source_group("POSIX-specific code" FILES ${OS_SRC})
220endif()
221
222if(APPLE)
223 add_definitions(-D_DARWIN_C_SOURCE)
224 if(CMAKE_SYSTEM_VERSION VERSION_GREATER "10.5.8")
225 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
226 endif()
227endif()
228
229if(NOT HAIKU AND NOT MSVC AND NOT PSP2)
230 set(M_LIBRARY m)
231endif()
232list(APPEND OS_LIB ${M_LIBRARY})
233
234if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
235 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
236 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
237endif()
238
239if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
240 if(NOT BUILD_EGL)
241 add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
242 endif()
243endif()
244
245if(BUILD_RASPI)
246 set(BUILD_GL OFF CACHE BOOL "OpenGL not supported" FORCE)
247endif()
248
249if(BUILD_PANDORA)
250 add_definitions(-DBUILD_PANDORA)
251endif()
252
253if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
254 enable_language(ASM)
255endif()
256
257if(PSP2 OR WII)
258 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-format")
259endif()
260
261if(DEFINED 3DS OR DEFINED PSP2 OR DEFINED WII)
262 set(USE_DEBUGGERS OFF)
263 set(USE_SQLITE3 OFF)
264endif()
265
266if(NOT M_CORE_GBA)
267 set(USE_GDB_STUB OFF)
268endif()
269
270if(NOT USE_DEBUGGERS)
271 set(USE_EDITLINE OFF)
272 set(USE_GDB_STUB OFF)
273endif()
274
275if(WII)
276 add_definitions(-U__STRICT_ANSI__)
277endif()
278
279if(DEFINED 3DS)
280 add_definitions(-D_GNU_SOURCE)
281endif()
282
283include(CheckFunctionExists)
284check_function_exists(strdup HAVE_STRDUP)
285check_function_exists(strndup HAVE_STRNDUP)
286if(NOT DEFINED PSP2)
287 check_function_exists(localtime_r HAVE_LOCALTIME_R)
288endif()
289if(NOT CMAKE_SYSTEM_NAME STREQUAL "Generic")
290 check_function_exists(snprintf_l HAVE_SNPRINTF_L)
291 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
292 # The strtof_l on Linux not actually exposed nor actually strtof_l
293 set(HAVE_STRTOF_L OFF)
294 else()
295 check_function_exists(strtof_l HAVE_STRTOF_L)
296 endif()
297 check_function_exists(newlocale HAVE_NEWLOCALE)
298 check_function_exists(freelocale HAVE_FREELOCALE)
299 check_function_exists(uselocale HAVE_USELOCALE)
300 check_function_exists(setlocale HAVE_SETLOCALE)
301else()
302 if(DEFINED 3DS)
303 check_function_exists(snprintf_l HAVE_SNPRINTF_L)
304 check_function_exists(strtof_l HAVE_STRTOF_L)
305 check_function_exists(newlocale HAVE_NEWLOCALE)
306 check_function_exists(freelocale HAVE_FREELOCALE)
307 check_function_exists(uselocale HAVE_USELOCALE)
308 check_function_exists(setlocale HAVE_SETLOCALE)
309 endif()
310 if(NOT DEFINED 3DS AND NOT DEFINED PSP2 AND NOT DEFINED WII)
311 set(DISABLE_DEPS ON CACHE BOOL "This platform cannot build with dependencies" FORCE)
312 endif()
313 set(DISABLE_FRONTENDS ON)
314 set(MINIMAL_CORE ON)
315 set(ENABLE_EXTRA ON)
316endif()
317
318check_function_exists(chmod HAVE_CHMOD)
319check_function_exists(umask HAVE_UMASK)
320
321set(FUNCTION_DEFINES)
322
323if(HAVE_STRDUP)
324 list(APPEND FUNCTION_DEFINES HAVE_STRDUP)
325endif()
326
327if(HAVE_STRNDUP)
328 list(APPEND FUNCTION_DEFINES HAVE_STRNDUP)
329endif()
330
331if(HAVE_LOCALTIME_R)
332 list(APPEND FUNCTION_DEFINES HAVE_LOCALTIME_R)
333endif()
334
335if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE OR APPLE OR DEFINED 3DS)
336 list(APPEND FUNCTION_DEFINES HAVE_LOCALE)
337 if (HAVE_STRTOF_L)
338 list(APPEND FUNCTION_DEFINES HAVE_STRTOF_L)
339 endif()
340 if (HAVE_SNPRINTF_L)
341 list(APPEND FUNCTION_DEFINES HAVE_SNPRINTF_L)
342 endif()
343endif()
344
345if(HAVE_SETLOCALE)
346 list(APPEND FUNCTION_DEFINES HAVE_SETLOCALE)
347endif()
348
349if(HAVE_CHMOD)
350 list(APPEND FUNCTION_DEFINES HAVE_CHMOD)
351endif()
352
353if(HAVE_UMASK)
354 list(APPEND FUNCTION_DEFINES HAVE_UMASK)
355endif()
356
357# Feature dependencies
358set(FEATURE_DEFINES)
359set(FEATURES)
360if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
361 set(LIBEDIT_LIBRARIES -ledit)
362 if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
363 list(APPEND LIBEDIT_LIBRARIES -ltermcap)
364 endif()
365else()
366 find_feature(USE_EDITLINE "libedit")
367endif()
368if(BUILD_GL)
369 find_package(OpenGL QUIET)
370 if(NOT OPENGL_FOUND)
371 set(BUILD_GL OFF CACHE BOOL "OpenGL not found" FORCE)
372 endif()
373endif()
374if(NOT BUILD_GL)
375 set(OPENGLE_LIBRARY "" CACHE PATH "" FORCE)
376endif()
377if(BUILD_GLES2 AND NOT BUILD_RASPI)
378 find_path(OPENGLES2_INCLUDE_DIR NAMES GLES2/gl2.h)
379 find_library(OPENGLES2_LIBRARY NAMES GLESv2 GLESv2_CM)
380 if(NOT OPENGLES2_INCLUDE_DIR OR NOT OPENGLES2_LIBRARY)
381 set(BUILD_GLES2 OFF CACHE BOOL "OpenGL|ES 2 not found" FORCE)
382 endif()
383endif()
384if(NOT BUILD_GLES2)
385 set(OPENGLES2_LIBRARY "" CACHE PATH "" FORCE)
386endif()
387set(WANT_ZLIB ${USE_ZLIB})
388set(WANT_PNG ${USE_PNG})
389set(WANT_LIBZIP ${USE_LIBZIP})
390set(WANT_SQLITE3 ${USE_SQLITE3})
391set(USE_CMOCKA ${BUILD_SUITE})
392
393find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
394find_feature(USE_ZLIB "ZLIB")
395find_feature(USE_MINIZIP "minizip")
396find_feature(USE_PNG "PNG")
397find_feature(USE_LIBZIP "libzip")
398find_feature(USE_MAGICK "MagickWand")
399find_feature(USE_EPOXY "epoxy")
400find_feature(USE_CMOCKA "cmocka")
401find_feature(USE_SQLITE3 "sqlite3")
402
403# Features
404set(DEBUGGER_SRC
405 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/debugger.c
406 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/parser.c
407 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/symbols.c
408 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/cli-debugger.c)
409
410set(FEATURE_SRC)
411set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
412
413if(DISABLE_DEPS)
414 set(USE_GDB_STUB OFF)
415endif()
416
417if(USE_EDITLINE)
418 list(APPEND FEATURES EDITLINE)
419 include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
420 link_directories(${LIBEDIT_LIBRARY_DIRS})
421 set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
422 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
423 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/editline/cli-el-backend.c")
424else()
425 set(DEBUGGER_LIB "")
426endif()
427
428if(USE_GDB_STUB)
429 list(APPEND FEATURES GDB_STUB)
430 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/gdb-stub.c)
431endif()
432source_group("Debugger" FILES ${DEBUGGER_SRC})
433
434if(USE_FFMPEG)
435 list(APPEND FEATURES FFMPEG)
436 pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
437 if(NOT LIBSWRESAMPLE_FOUND)
438 list(APPEND FEATURES LIBAV)
439 endif()
440 include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
441 link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
442 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/ffmpeg/ffmpeg-encoder.c")
443 string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
444 string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
445 string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
446 string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
447 string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
448 list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
449 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR}|libavcodec-extra-${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
450 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavformat${LIBAVFORMAT_VERSION_MAJOR}|libavformat-ffmpeg${LIBAVFORMAT_VERSION_MAJOR}")
451 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavresample${LIBAVRESAMPLE_VERSION_MAJOR}|libavresample-ffmpeg${LIBAVRESAMPLE_VERSION_MAJOR}")
452 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavutil${LIBAVUTIL_VERSION_MAJOR}|libavutil-ffmpeg${LIBAVUTIL_VERSION_MAJOR}")
453 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libswscale${LIBSWSCALE_VERSION_MAJOR}|libswscale-ffmpeg${LIBSWSCALE_VERSION_MAJOR}")
454 set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
455 if(APPLE)
456 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
457 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
458 endif()
459endif()
460
461list(APPEND THIRD_PARTY_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
462
463if(USE_MAGICK)
464 list(APPEND FEATURES MAGICK)
465 include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
466 link_directories(${MAGICKWAND_LIBRARY_DIRS})
467 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/imagemagick/imagemagick-gif-encoder.c")
468 list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
469 string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
470 string(REGEX MATCH "^[0-9]+" MAGICKWAND_VERSION_MAJOR ${MagickWand_VERSION})
471 if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
472 set(MAGICKWAND_DEB_VERSION "5")
473 elseif(${MagickWand_VERSION} EQUAL "6.9.7")
474 set(MAGICKWAND_DEB_VERSION "-6.q16-3")
475 else()
476 set(MAGICKWAND_DEB_VERSION "-6.q16-2")
477 endif()
478 list(APPEND FEATURE_DEFINES MAGICKWAND_VERSION_MAJOR=${MAGICKWAND_VERSION_MAJOR})
479
480 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
481endif()
482
483if(WANT_ZLIB AND NOT USE_ZLIB)
484 set(SKIP_INSTALL_ALL ON)
485 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib zlib)
486 set_property(TARGET zlibstatic PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/zlib;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib)
487 set_property(TARGET zlib PROPERTY EXCLUDE_FROM_ALL ON)
488 set_property(TARGET example PROPERTY EXCLUDE_FROM_ALL ON)
489 set_property(TARGET minigzip PROPERTY EXCLUDE_FROM_ALL ON)
490 set(ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
491 set(ZLIB_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
492 set(ZLIB_LIBRARY zlibstatic)
493 list(APPEND DEPENDENCY_LIB zlibstatic)
494 set(USE_ZLIB ON)
495endif()
496
497if(USE_ZLIB)
498 list(APPEND FEATURES ZLIB)
499 include_directories(AFTER ${ZLIB_INCLUDE_DIRS})
500 list(APPEND DEPENDENCY_LIB ${ZLIB_LIBRARIES})
501 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},zlib1g")
502endif()
503
504if(WANT_PNG AND USE_ZLIB AND NOT USE_PNG)
505 set(PNG_STATIC ON CACHE BOOL "" FORCE)
506 set(PNG_SHARED OFF CACHE BOOL "" FORCE)
507 set(PNG_TESTS OFF CACHE BOOL "" FORCE)
508 set(SKIP_INSTALL_ALL ON)
509 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng libpng)
510 set_property(TARGET png16_static PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/libpng;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng;${ZLIB_INCLUDE_DIRS})
511 set(PNG_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng ${CMAKE_CURRENT_BINARY_DIR}/libpng)
512 list(APPEND DEPENDENCY_LIB png16_static)
513 set(USE_PNG ON)
514endif()
515
516if(USE_PNG)
517 list(APPEND FEATURES PNG)
518 include_directories(AFTER ${PNG_INCLUDE_DIRS})
519 list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
520 if(PNG_VERSION_STRING)
521 string(REGEX MATCH "^[0-9]+\\.[0-9]+" PNG_VERSION_PARTIAL ${PNG_VERSION_STRING})
522 if(${PNG_VERSION_PARTIAL} STREQUAL "1.6")
523 set(PNG_DEB_VERSION "16-16")
524 else()
525 set(PNG_DEB_VERSION "12-0")
526 endif()
527 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng${PNG_DEB_VERSION}")
528 endif()
529endif()
530
531if(WANT_SQLITE3 AND NOT USE_SQLITE3)
532 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/sqlite3.c)
533 include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/)
534 set(USE_SQLITE3 ON)
535endif()
536
537if(USE_LIBZIP)
538 include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
539 link_directories(${LIBZIP_LIBRARY_DIRS})
540 list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
541 list(APPEND FEATURES LIBZIP)
542 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
543 string(REGEX MATCH "^[0-9]+" LIBZIP_VERSION_MAJOR ${libzip_VERSION})
544 if (LIBZIP_VERSION_MAJOR LESS 1)
545 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
546 elseif(LIBZIP_VERSION_MAJOR EQUAL 1)
547 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip4")
548 else()
549 message(AUTHOR_WARNING Unknown version of libzip detected: ${libzip_VERSION})
550 endif()
551elseif(USE_MINIZIP)
552 include_directories(AFTER ${MINIZIP_INCLUDE_DIRS})
553 link_directories(${MINIZIP_LIBRARY_DIRS})
554 list(APPEND DEPENDENCY_LIB ${MINIZIP_LIBRARIES})
555 list(APPEND FEATURES MINIZIP)
556 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
557 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libminizip1")
558elseif(USE_ZLIB)
559 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c
560 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
561 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c)
562 if(NOT MSVC)
563 set_source_files_properties(
564 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
565 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c
566 PROPERTIES COMPILE_FLAGS "-Wno-unused-parameter -Wno-implicit-function-declaration")
567 endif()
568endif()
569
570if (USE_LZMA)
571 include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/third-party/lzma)
572 add_definitions(-D_7ZIP_PPMD_SUPPPORT)
573 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-lzma.c)
574 set(LZMA_SRC
575 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
576 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
577 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
578 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
579 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
580 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
581 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zDec.c
582 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
583 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Delta.c
584 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
585 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
586 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra.c
587 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra86.c
588 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/BraIA64.c
589 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
590 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
591 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
592 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zFile.c
593 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
594 list(APPEND VFS_SRC ${LZMA_SRC})
595 list(APPEND FEATURES LZMA)
596endif()
597
598if(USE_EPOXY)
599 add_definitions(-DBUILD_GL -DBUILD_GLES2)
600 list(APPEND FEATURES EPOXY)
601 include_directories(AFTER ${EPOXY_INCLUDE_DIRS})
602 set(OPENGLES2_LIBRARY ${EPOXY_LIBRARIES})
603 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libepoxy0")
604endif()
605
606if(USE_SQLITE3)
607 list(APPEND FEATURES SQLITE3)
608 include_directories(AFTER ${SQLITE3_INCLUDE_DIRS})
609 list(APPEND DEPENDENCY_LIB ${SQLITE3_LIBRARIES})
610 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libsqlite3-0")
611 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/sqlite3/no-intro.c")
612endif()
613
614set(TEST_SRC ${CORE_TEST_SRC})
615if(M_CORE_GB)
616 add_definitions(-DM_CORE_GB)
617 list(APPEND CORE_SRC
618 ${LR35902_SRC}
619 ${GB_SRC}
620 ${GB_RENDERER_SRC})
621 list(APPEND DEBUGGER_SRC
622 ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/cli-debugger.c
623 ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/debugger.c
624 ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/memory-debugger.c
625 ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/debugger/cli.c
626 ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/debugger/symbols.c)
627 list(APPEND TEST_SRC
628 ${LR35902_TEST_SRC}
629 ${GB_TEST_SRC})
630endif()
631
632if(M_CORE_GBA)
633 add_definitions(-DM_CORE_GBA)
634 list(APPEND CORE_SRC
635 ${ARM_SRC}
636 ${GBA_SRC}
637 ${GBA_CHEATS_SRC}
638 ${GBA_RENDERER_SRC})
639 list(APPEND DEBUGGER_SRC
640 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c
641 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/debugger.c
642 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/memory-debugger.c
643 ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/debugger/cli.c)
644 list(APPEND TEST_SRC
645 ${ARM_TEST_SRC}
646 ${GBA_TEST_SRC})
647 if(NOT M_CORE_GB)
648 list(APPEND CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/audio.c)
649 endif()
650endif()
651
652if(USE_DEBUGGERS)
653 list(APPEND FEATURE_SRC ${DEBUGGER_SRC})
654 list(APPEND FEATURES DEBUGGERS)
655endif()
656
657foreach(FEATURE IN LISTS FEATURES)
658 list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
659endforeach()
660
661source_group("Virtual files" FILES ${CORE_VFS_SRC} ${VFS_SRC})
662source_group("Extra features" FILES ${FEATURE_SRC})
663source_group("Third-party code" FILES ${THIRD_PARTY_SRC})
664
665# Platform binaries
666if(DEFINED 3DS)
667 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/3ds ${CMAKE_CURRENT_BINARY_DIR}/3ds)
668endif()
669
670if(DEFINED WII)
671 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/wii ${CMAKE_CURRENT_BINARY_DIR}/wii)
672endif()
673
674if(DEFINED PSP2)
675 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/psp2 ${CMAKE_CURRENT_BINARY_DIR}/psp2)
676endif()
677
678# Binaries
679list(APPEND CORE_SRC
680 ${UTIL_SRC}
681 ${CORE_VFS_SRC}
682 ${OS_SRC}
683 ${THIRD_PARTY_SRC})
684list(APPEND TEST_SRC ${UTIL_TEST_SRC})
685
686set(SRC ${CORE_SRC} ${VFS_SRC})
687if(NOT MINIMAL_CORE)
688 set(ENABLE_EXTRA ON)
689 if(M_CORE_GBA)
690 list(APPEND SRC
691 ${GBA_SIO_SRC})
692 endif()
693 if(M_CORE_GB)
694 list(APPEND SRC
695 ${GB_SIO_SRC})
696 endif()
697 list(APPEND SRC
698 ${FEATURE_SRC})
699endif()
700
701if(ENABLE_EXTRA)
702 if(M_CORE_GBA)
703 list(APPEND SRC
704 ${GBA_RR_SRC}
705 ${GBA_EXTRA_SRC})
706 endif()
707 if(M_CORE_GB)
708 list(APPEND SRC
709 ${GB_EXTRA_SRC})
710 endif()
711 list(APPEND SRC
712 ${EXTRA_SRC})
713endif()
714
715if(NOT SKIP_LIBRARY)
716 if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
717 set(BUILD_SHARED ON)
718 endif()
719
720 if(BUILD_SHARED)
721 add_library(${BINARY_NAME} SHARED ${SRC} ${VFS_SRC})
722 if(BUILD_STATIC)
723 add_library(${BINARY_NAME}-static STATIC ${SRC})
724 set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
725 install(TARGETS ${BINARY_NAME}-static DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
726 add_dependencies(${BINARY_NAME}-static version-info)
727 endif()
728 else()
729 add_library(${BINARY_NAME} STATIC ${SRC})
730 endif()
731
732 add_dependencies(${BINARY_NAME} version-info)
733 set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
734
735 target_link_libraries(${BINARY_NAME} ${DEBUGGER_LIB} ${DEPENDENCY_LIB} ${OS_LIB})
736 install(TARGETS ${BINARY_NAME} LIBRARY DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME} NAMELINK_SKIP ARCHIVE DESTINATION ${LIBDIR} RUNTIME DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
737 if(UNIX AND NOT APPLE AND NOT HAIKU)
738 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-16.png DESTINATION share/icons/hicolor/16x16/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
739 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-24.png DESTINATION share/icons/hicolor/24x24/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
740 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-32.png DESTINATION share/icons/hicolor/32x32/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
741 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-48.png DESTINATION share/icons/hicolor/48x48/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
742 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-64.png DESTINATION share/icons/hicolor/64x64/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
743 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-96.png DESTINATION share/icons/hicolor/96x96/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
744 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-128.png DESTINATION share/icons/hicolor/128x128/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
745 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-256.png DESTINATION share/icons/hicolor/256x256/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
746 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-512.png DESTINATION share/icons/hicolor/512x512/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
747 endif()
748else()
749 set(BUILD_SHARED OFF)
750 set(BUILD_STATIC OFF)
751 find_library(${BINARY_NAME} ${BINARY_NAME})
752 if(NOT ${BINARY_NAME}_FOUND)
753 set(DISABLE_FRONTENDS ON)
754 set(BUILD_PERF OFF)
755 set(BUILD_TEST OFF)
756 set(BUILD_SUITE OFF)
757 endif()
758endif()
759
760if(BUILD_GL)
761 add_definitions(-DBUILD_GL)
762endif()
763
764if(BUILD_GLES2)
765 add_definitions(-DBUILD_GLES2)
766endif()
767
768if(DISABLE_FRONTENDS)
769 set(BUILD_SDL OFF)
770 set(BUILD_QT OFF)
771endif()
772
773if(BUILD_LIBRETRO)
774 file(GLOB RETRO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/libretro/*.c)
775 add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
776 set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5;DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=2")
777 target_link_libraries(${BINARY_NAME}_libretro ${OS_LIB})
778 install(TARGETS ${BINARY_NAME}_libretro LIBRARY DESTINATION ${LIBRETRO_LIBDIR} COMPONENT ${BINARY_NAME}_libretro NAMELINK_SKIP)
779endif()
780
781if(BUILD_OPENEMU)
782 find_library(FOUNDATION Foundation)
783 find_library(OPENEMUBASE OpenEmuBase)
784 file(GLOB OE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/*.m)
785 add_library(${BINARY_NAME}-openemu MODULE ${CORE_SRC} ${OE_SRC})
786 set_target_properties(${BINARY_NAME}-openemu PROPERTIES
787 MACOSX_BUNDLE_INFO_PLIST ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/Info.plist.in
788 BUNDLE TRUE
789 BUNDLE_EXTENSION oecoreplugin
790 OUTPUT_NAME ${PROJECT_NAME}
791 COMPILE_DEFINITIONS "DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=1")
792 target_link_libraries(${BINARY_NAME}-openemu ${OS_LIB} ${FOUNDATION} ${OPENEMUBASE})
793 install(TARGETS ${BINARY_NAME}-openemu LIBRARY DESTINATION ${OE_LIBDIR} COMPONENT ${BINARY_NAME}.oecoreplugin NAMELINK_SKIP)
794endif()
795
796if(BUILD_SDL)
797 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/sdl ${CMAKE_CURRENT_BINARY_DIR}/sdl)
798 # The SDL platform CMakeLists could decide to disable SDL, so check again before adding the define.
799 if(BUILD_SDL)
800 add_definitions(-DBUILD_SDL)
801 endif()
802endif()
803
804if(BUILD_QT)
805 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/qt ${CMAKE_CURRENT_BINARY_DIR}/qt)
806endif()
807
808if(BUILD_PERF)
809 set(PERF_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/perf-main.c)
810 if(UNIX AND NOT APPLE)
811 list(APPEND PERF_LIB rt)
812 endif()
813
814 add_executable(${BINARY_NAME}-perf ${PERF_SRC})
815 target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB} ${OS_LIB})
816 set_target_properties(${BINARY_NAME}-perf PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
817 install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
818 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
819endif()
820
821if(BUILD_TEST)
822 add_executable(${BINARY_NAME}-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/fuzz-main.c)
823 target_link_libraries(${BINARY_NAME}-fuzz ${BINARY_NAME})
824 set_target_properties(${BINARY_NAME}-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
825 add_executable(tbl-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/tbl-fuzz-main.c)
826 target_link_libraries(tbl-fuzz ${BINARY_NAME})
827 set_target_properties(tbl-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
828 install(TARGETS ${BINARY_NAME}-fuzz tbl-fuzz DESTINATION bin COMPONENT ${BINARY_NAME}-test)
829endif()
830
831if(NOT USE_CMOCKA)
832 set(BUILD_SUITE OFF)
833endif()
834if(BUILD_SUITE)
835 enable_testing()
836 include_directories(AFTER ${CMOCKA_INCLUDE_DIRS})
837 link_directories(${CMOCKA_LIBRARY_DIRS})
838
839 add_executable(${BINARY_NAME}-suite ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/suite-main.c ${TEST_SRC})
840 target_link_libraries(${BINARY_NAME}-suite ${BINARY_NAME} ${PLATFORM_LIBRARY} cmocka)
841 set_target_properties(${BINARY_NAME}-suite PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
842 add_test(${BINARY_NAME}-suite ${BINARY_NAME}-suite)
843endif()
844
845if(BUILD_PYTHON)
846 enable_testing()
847 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/python ${CMAKE_CURRENT_BINARY_DIR}/python)
848endif()
849
850if(BUILD_EXAMPLE)
851 add_executable(${BINARY_NAME}-example-server ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/server.c)
852 target_link_libraries(${BINARY_NAME}-example-server ${BINARY_NAME})
853 set_target_properties(${BINARY_NAME}-example-server PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
854
855 if(BUILD_SDL)
856 add_executable(${BINARY_NAME}-example-client ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/client.c)
857 target_link_libraries(${BINARY_NAME}-example-client ${BINARY_NAME} ${SDL_LIBRARY} ${SDLMAIN_LIBRARY} ${OPENGL_LIBRARY} ${OPENGLES2_LIBRARY})
858 set_target_properties(${BINARY_NAME}-example-client PROPERTIES
859 COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}"
860 INCLUDE_DIRECTORIES "${SDL_INCLUDE_DIR};${CMAKE_CURRENT_SOURCE_DIR}/src;${CMAKE_CURRENT_SOURCE_DIR}/include")
861 endif()
862endif()
863
864configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/flags.h.in ${CMAKE_CURRENT_BINARY_DIR}/flags.h)
865install(FILES ${CMAKE_CURRENT_BINARY_DIR}/flags.h DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/mgba COMPONENT lib${BINARY_NAME})
866
867# Packaging
868set(CPACK_PACKAGE_VERSION ${VERSION_STRING})
869set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
870set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
871set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
872set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
873set(CPACK_RESOURCE_FILE_README ${CMAKE_CURRENT_SOURCE_DIR}/README.md)
874
875set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
876set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
877set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
878set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README.md")
879set(CPACK_DEBIAN_PACKAGE_SECTION "games")
880
881SET(CPACK_DEB_COMPONENT_INSTALL ON)
882
883set(CPACK_STRIP_FILES ${BINARY_NAME})
884
885install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/README.md ${CMAKE_CURRENT_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
886
887include(CPack)
888
889# Summaries
890set(SUMMARY_GL_LIST)
891if(USE_EPOXY)
892 set(SUMMARY_GL_LIST "libepoxy")
893else()
894 if(BUILD_GL)
895 list(APPEND SUMMARY_GL_LIST "OpenGL")
896 endif()
897 if(BUILD_GLES2)
898 list(APPEND SUMMARY_GL_LIST "OpenGL|ES 2")
899 endif()
900endif()
901if(NOT SUMMARY_GL_LIST)
902 set(SUMMARY_GL OFF)
903else()
904 string(REPLACE ";" ", " SUMMARY_GL "${SUMMARY_GL_LIST}")
905endif()
906if(USE_LIBZIP)
907 set(SUMMARY_ZIP libzip)
908elseif(USE_MINIZIP)
909 set(SUMMARY_ZIP "minizip (external)")
910elseif(USE_ZLIB)
911 set(SUMMARY_ZIP "minizip (included)")
912else()
913 set(SUMMARY_ZIP OFF)
914endif()
915
916if(NOT QUIET)
917 message(STATUS "Build type: ${CMAKE_BUILD_TYPE}")
918 message(STATUS "Platforms:")
919 message(STATUS " Game Boy Advance: ${M_CORE_GBA}")
920 message(STATUS " Game Boy: ${M_CORE_GB}")
921 message(STATUS "Features:")
922 message(STATUS " Debuggers: ${USE_DEBUGGERS}")
923 message(STATUS " CLI debugger: ${USE_EDITLINE}")
924 message(STATUS " GDB stub: ${USE_GDB_STUB}")
925 message(STATUS " Video recording: ${USE_FFMPEG}")
926 message(STATUS " GIF recording: ${USE_MAGICK}")
927 message(STATUS " Screenshot/advanced savestate support: ${USE_PNG}")
928 message(STATUS " ZIP support: ${SUMMARY_ZIP}")
929 message(STATUS " 7-Zip support: ${USE_LZMA}")
930 message(STATUS " SQLite3 game database: ${USE_SQLITE3}")
931 message(STATUS " OpenGL support: ${SUMMARY_GL}")
932 message(STATUS "Frontends:")
933 message(STATUS " Qt: ${BUILD_QT}")
934 message(STATUS " SDL (${SDL_VERSION}): ${BUILD_SDL}")
935 message(STATUS " Profiling: ${BUILD_PERF}")
936 message(STATUS " Test harness: ${BUILD_TEST}")
937 message(STATUS " Test suite: ${BUILD_SUITE}")
938 message(STATUS " Python bindings: ${BUILD_PYTHON}")
939 message(STATUS " Examples: ${BUILD_EXAMPLE}")
940 message(STATUS "Cores:")
941 message(STATUS " Libretro core: ${BUILD_LIBRETRO}")
942 if(APPLE)
943 message(STATUS " OpenEmu core: ${BUILD_OPENEMU}")
944 endif()
945 message(STATUS "Libraries:")
946 message(STATUS " Static: ${BUILD_STATIC}")
947 message(STATUS " Shared: ${BUILD_SHARED}")
948endif()