CMakeLists.txt (view raw)
1cmake_minimum_required(VERSION 2.6)
2project(medusa C)
3set(BINARY_NAME medusa-emu CACHE INTERNAL "Name of output binaries")
4if(NOT MSVC)
5 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wno-missing-field-initializers -std=c99")
6else()
7 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_CRT_SECURE_NO_WARNINGS /wd4003 /wd4244 /wd4146")
8endif()
9set(USE_DEBUGGERS ON CACHE BOOL "Whether or not to enable the debugging infrastructure")
10set(USE_EDITLINE ON CACHE BOOL "Whether or not to enable the CLI-mode debugger")
11set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
12set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
13set(USE_ZLIB ON CACHE BOOL "Whether or not to enable zlib support")
14set(USE_MINIZIP ON CACHE BOOL "Whether or not to enable external minizip support")
15set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
16set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable LIBZIP support")
17set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
18set(USE_SQLITE3 ON CACHE BOOL "Whether or not to enable SQLite3 support")
19set(M_CORE_GBA ON CACHE BOOL "Build Game Boy Advance core")
20set(M_CORE_GB ON CACHE BOOL "Build Game Boy core")
21set(M_CORE_DS ON CACHE BOOL "Build DS core")
22set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
23set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
24set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
25set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
26if(APPLE)
27 set(BUILD_OPENEMU OFF CACHE BOOL "Build OpenEmu core")
28endif()
29set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
30set(BUILD_TEST OFF CACHE BOOL "Build testing harness")
31set(BUILD_SUITE OFF CACHE BOOL "Build test suite")
32set(BUILD_EXAMPLE OFF CACHE BOOL "Build example frontends")
33set(BUILD_PYTHON OFF CACHE BOOL "Build Python bindings")
34set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
35set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
36set(SKIP_LIBRARY OFF CACHE BOOL "Skip building the library (useful for only building libretro or OpenEmu cores)")
37set(BUILD_GL ON CACHE STRING "Build with OpenGL")
38set(BUILD_GLES2 OFF CACHE STRING "Build with OpenGL|ES 2")
39set(USE_EPOXY ON CACHE STRING "Build with libepoxy")
40set(DISABLE_DEPS OFF CACHE BOOL "Build without dependencies")
41file(GLOB ARM_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/*.c)
42file(GLOB ARM_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/test/*.c)
43file(GLOB LR35902_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/*.c)
44file(GLOB LR35902_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/test/*.c)
45file(GLOB GBA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/*.c)
46file(GLOB GBA_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/test/*.c)
47file(GLOB GB_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/*.c)
48file(GLOB GB_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/test/*.c)
49file(GLOB DS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/ds/*.c)
50file(GLOB GBA_CHEATS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/cheats/*.c)
51file(GLOB GBA_RR_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/rr/*.c)
52file(GLOB CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/*.c)
53file(GLOB CORE_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/test/*.c)
54file(GLOB UTIL_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/*.[cSs])
55file(GLOB UTIL_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/test/*.c)
56file(GLOB GUI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/gui/*.c ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/gui/*.c)
57file(GLOB GBA_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/renderers/*.c)
58file(GLOB GBA_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/sio/lockstep.c)
59file(GLOB GB_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/sio/lockstep.c)
60file(GLOB GB_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/renderers/*.c)
61file(GLOB DS_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/ds/renderers/*.c ${CMAKE_CURRENT_SOURCE_DIR}/src/ds/gx/*.c)
62file(GLOB THIRD_PARTY_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/inih/*.c)
63set(CLI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/commandline.c)
64set(CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-mem.c)
65set(VFS_SRC)
66source_group("ARM core" FILES ${ARM_SRC})
67source_group("LR35902 core" FILES ${LR35902_SRC})
68source_group("GBA board" FILES ${GBA_SRC} ${GBA_RENDERER_SRC} ${GBA_SIO_SRC})
69source_group("GBA extra" FILES ${GBA_CHEATS_SRC} ${GBA_RR_SRC})
70source_group("GB board" FILES ${GB_SRC} ${GB_SIO_SRC})
71source_group("DS board" FILES ${DS_SRC})
72source_group("Utilities" FILES ${UTIL_SRC})
73include_directories(BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/include ${CMAKE_CURRENT_SOURCE_DIR}/src)
74
75if(NOT CMAKE_BUILD_TYPE)
76 set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
77endif()
78
79include(GNUInstallDirs)
80string(REPLACE "${PROJECT_NAME}" "${BINARY_NAME}" CMAKE_INSTALL_DOCDIR "${CMAKE_INSTALL_DOCDIR}")
81
82set(LIBDIR "${CMAKE_INSTALL_LIBDIR}" CACHE PATH "Installed library directory")
83mark_as_advanced(LIBDIR)
84
85if (BUILD_LIBRETRO)
86 set(LIBRETRO_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (Libretro)")
87 mark_as_advanced(LIBRETRO_LIBDIR)
88endif()
89
90if (BUILD_OPENEMU)
91 set(OE_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (OpenEmu)")
92 mark_as_advanced(OE_LIBDIR)
93endif()
94
95
96set(CMAKE_INSTALL_RPATH "${LIBDIR}")
97
98if (NOT DEFINED MANDIR)
99 set(MANDIR ${CMAKE_INSTALL_MANDIR})
100endif()
101
102# Function definitions
103include(FindPkgConfig)
104function(find_feature FEATURE_NAME FEATURE_REQUIRES)
105 if (NOT ${FEATURE_NAME})
106 return()
107 endif()
108 if (DISABLE_DEPS)
109 set(${FEATURE_NAME} OFF PARENT_SCOPE)
110 return()
111 endif()
112 foreach(REQUIRE ${FEATURE_REQUIRES})
113 if(NOT ${REQUIRE}_FOUND)
114 find_package(${REQUIRE} QUIET)
115 if(NOT ${REQUIRE}_FOUND)
116 pkg_search_module(${REQUIRE} ${REQUIRE})
117 if (NOT ${REQUIRE}_FOUND)
118 message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
119 set(${FEATURE_NAME} OFF PARENT_SCOPE)
120 return()
121 endif()
122 endif()
123 endif()
124 string(TOUPPER ${REQUIRE} UREQUIRE)
125 set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
126 set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
127 set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
128 if (APPLE)
129 set(IS_FRAMEWORK OFF)
130 set(LIBS)
131 foreach(LIB IN LISTS ${REQUIRE}_LIBRARIES)
132 if(LIB STREQUAL "-framework")
133 set(IS_FRAMEWORK ON)
134 elseif(IS_FRAMEWORK)
135 list(APPEND LIBS "-framework ${LIB}")
136 set(IS_FRAMEWORK OFF)
137 else()
138 list(APPEND LIBS ${LIB})
139 endif()
140 endforeach()
141 set(${UREQUIRE}_LIBRARIES ${LIBS} PARENT_SCOPE)
142 else()
143 set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
144 endif()
145 set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
146 set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
147 endforeach()
148endfunction()
149
150# Version information
151add_custom_target(version-info ALL
152 COMMAND ${CMAKE_COMMAND}
153 -DBINARY_NAME=${BINARY_NAME}
154 -DCONFIG_FILE=${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in
155 -DOUT_FILE=${CMAKE_CURRENT_BINARY_DIR}/version.c
156 -P ${CMAKE_CURRENT_SOURCE_DIR}/version.cmake
157 WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
158
159include(${CMAKE_CURRENT_SOURCE_DIR}/version.cmake)
160configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in ${CMAKE_CURRENT_BINARY_DIR}/version.c)
161configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/flags.h.in ${CMAKE_CURRENT_BINARY_DIR}/flags.h)
162install(FILES ${CMAKE_CURRENT_BINARY_DIR}/flags.h DESTINATION include/mgba COMPONENT lib${BINARY_NAME})
163
164list(APPEND UTIL_SRC ${CMAKE_CURRENT_BINARY_DIR}/version.c)
165source_group("Generated sources" FILES ${CMAKE_CURRENT_BINARY_DIR}/version.c)
166
167# Advanced settings
168if(NOT DEFINED 3DS)
169 # LTO appears to make 3DS binary slower
170 set(DEFAULT_LTO ON)
171else()
172 set(DEFAULT_LTO OFF)
173endif()
174
175set(BUILD_LTO ${DEFAULT_LTO} CACHE BOOL "Build with link-time optimization")
176set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
177set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
178set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
179mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
180set(PGO_PRE_FLAGS "-fprofile-generate=${PGO_DIR} -fprofile-arcs")
181set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
182
183if(BUILD_PGO AND NOT PGO_STAGE_2)
184 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
185 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
186 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
187elseif(BUILD_PGO AND PGO_STAGE_2)
188 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
189 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
190 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
191endif()
192
193# Platform support
194if(WIN32)
195 set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
196 add_definitions(-D_WIN32_WINNT=0x0600)
197 list(APPEND OS_LIB ws2_32 shlwapi)
198 list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/vfs-w32.c)
199 file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/*.c)
200 source_group("Windows-specific code" FILES ${OS_SRC})
201 if(MSVC)
202 add_definitions(-DNOMINMAX -DWIN32_LEAN_AND_MEAN)
203 set(CMAKE_WINDOWS_EXPORT_ALL_SYMBOLS TRUE)
204 endif()
205elseif(UNIX)
206 add_definitions(-DUSE_PTHREADS)
207
208 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
209 add_definitions(-D_GNU_SOURCE)
210 endif()
211 if(NOT APPLE AND NOT HAIKU)
212 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
213 endif()
214
215 list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
216 file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/posix/*.c)
217 source_group("POSIX-specific code" FILES ${OS_SRC})
218endif()
219
220if(APPLE)
221 add_definitions(-D_DARWIN_C_SOURCE)
222 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
223endif()
224
225if(NOT HAIKU AND NOT MSVC AND NOT PSP2)
226 set(M_LIBRARY m)
227endif()
228list(APPEND OS_LIB ${M_LIBRARY})
229
230if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
231 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
232 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
233endif()
234
235if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
236 if(NOT BUILD_EGL)
237 add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
238 endif()
239endif()
240
241if(BUILD_RASPI)
242 set(BUILD_GL OFF CACHE BOOL "OpenGL not supported" FORCE)
243endif()
244
245if(BUILD_PANDORA)
246 add_definitions(-DBUILD_PANDORA)
247endif()
248
249if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
250 enable_language(ASM)
251endif()
252
253if(PSP2 OR WII)
254 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-format")
255endif()
256
257if(DEFINED 3DS OR DEFINED PSP2 OR DEFINED WII)
258 set(USE_DEBUGGERS OFF)
259 set(USE_SQLITE3 OFF)
260endif()
261
262if(NOT M_CORE_GBA)
263 set(USE_GDB_STUB OFF)
264endif()
265
266if(NOT USE_DEBUGGERS)
267 set(USE_EDITLINE OFF)
268 set(USE_GDB_STUB OFF)
269endif()
270
271if(WII)
272 add_definitions(-U__STRICT_ANSI__)
273endif()
274
275if(DEFINED 3DS)
276 add_definitions(-D_GNU_SOURCE)
277endif()
278
279include(CheckFunctionExists)
280check_function_exists(strdup HAVE_STRDUP)
281check_function_exists(strndup HAVE_STRNDUP)
282check_function_exists(localtime_r HAVE_LOCALTIME_R)
283if(NOT CMAKE_SYSTEM_NAME STREQUAL "Generic")
284 check_function_exists(snprintf_l HAVE_SNPRINTF_L)
285 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
286 # The strtof_l on Linux not actually exposed nor actually strtof_l
287 set(HAVE_STRTOF_L OFF)
288 else()
289 check_function_exists(strtof_l HAVE_STRTOF_L)
290 endif()
291 check_function_exists(newlocale HAVE_NEWLOCALE)
292 check_function_exists(freelocale HAVE_FREELOCALE)
293 check_function_exists(uselocale HAVE_USELOCALE)
294 check_function_exists(setlocale HAVE_SETLOCALE)
295else()
296 if(DEFINED 3DS)
297 check_function_exists(snprintf_l HAVE_SNPRINTF_L)
298 check_function_exists(strtof_l HAVE_STRTOF_L)
299 check_function_exists(newlocale HAVE_NEWLOCALE)
300 check_function_exists(freelocale HAVE_FREELOCALE)
301 check_function_exists(uselocale HAVE_USELOCALE)
302 check_function_exists(setlocale HAVE_SETLOCALE)
303 endif()
304 if(NOT DEFINED 3DS AND NOT DEFINED PSP2 AND NOT DEFINED WII)
305 set(DISABLE_DEPS ON CACHE BOOL "This platform cannot build with dependencies" FORCE)
306 endif()
307 set(DISABLE_FRONTENDS ON)
308 set(MINIMAL_CORE ON)
309endif()
310
311check_function_exists(chmod HAVE_CHMOD)
312check_function_exists(umask HAVE_UMASK)
313
314set(FUNCTION_DEFINES)
315
316if(HAVE_STRDUP)
317 list(APPEND FUNCTION_DEFINES HAVE_STRDUP)
318endif()
319
320if(HAVE_STRNDUP)
321 list(APPEND FUNCTION_DEFINES HAVE_STRNDUP)
322endif()
323
324if(HAVE_LOCALTIME_R)
325 list(APPEND FUNCTION_DEFINES HAVE_LOCALTIME_R)
326endif()
327
328if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE OR APPLE OR DEFINED 3DS)
329 list(APPEND FUNCTION_DEFINES HAVE_LOCALE)
330 if (HAVE_STRTOF_L)
331 list(APPEND FUNCTION_DEFINES HAVE_STRTOF_L)
332 endif()
333 if (HAVE_SNPRINTF_L)
334 list(APPEND FUNCTION_DEFINES HAVE_SNPRINTF_L)
335 endif()
336endif()
337
338if(HAVE_SETLOCALE)
339 list(APPEND FUNCTION_DEFINES HAVE_SETLOCALE)
340endif()
341
342if(HAVE_CHMOD)
343 list(APPEND FUNCTION_DEFINES HAVE_CHMOD)
344endif()
345
346if(HAVE_UMASK)
347 list(APPEND FUNCTION_DEFINES HAVE_UMASK)
348endif()
349
350# Feature dependencies
351set(FEATURE_DEFINES)
352set(FEATURES)
353if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
354 set(LIBEDIT_LIBRARIES -ledit)
355 if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
356 list(APPEND LIBEDIT_LIBRARIES -ltermcap)
357 endif()
358else()
359 find_feature(USE_EDITLINE "libedit")
360endif()
361if(BUILD_GL)
362 find_package(OpenGL QUIET)
363 if(NOT OPENGL_FOUND)
364 set(BUILD_GL OFF CACHE BOOL "OpenGL not found" FORCE)
365 endif()
366endif()
367if(NOT BUILD_GL)
368 set(OPENGLE_LIBRARY "" CACHE PATH "" FORCE)
369endif()
370if(BUILD_GLES2 AND NOT BUILD_RASPI)
371 find_path(OPENGLES2_INCLUDE_DIR NAMES GLES2/gl2.h)
372 find_library(OPENGLES2_LIBRARY NAMES GLESv2 GLESv2_CM)
373 if(NOT OPENGLES2_INCLUDE_DIR OR NOT OPENGLES2_LIBRARY)
374 set(BUILD_GLES2 OFF CACHE BOOL "OpenGL|ES 2 not found" FORCE)
375 endif()
376endif()
377if(NOT BUILD_GLES2)
378 set(OPENGLES2_LIBRARY "" CACHE PATH "" FORCE)
379endif()
380set(WANT_ZLIB ${USE_ZLIB})
381set(WANT_PNG ${USE_PNG})
382set(WANT_LIBZIP ${USE_LIBZIP})
383set(WANT_SQLITE3 ${USE_SQLITE3})
384set(USE_CMOCKA ${BUILD_SUITE})
385
386find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
387find_feature(USE_ZLIB "ZLIB")
388find_feature(USE_MINIZIP "minizip")
389find_feature(USE_PNG "PNG")
390find_feature(USE_LIBZIP "libzip")
391find_feature(USE_MAGICK "MagickWand")
392find_feature(USE_EPOXY "epoxy")
393find_feature(USE_CMOCKA "cmocka")
394find_feature(USE_SQLITE3 "sqlite3")
395
396# Features
397set(DEBUGGER_SRC
398 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/debugger.c
399 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/parser.c
400 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/cli-debugger.c)
401
402set(FEATURE_SRC)
403set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
404
405if(DISABLE_DEPS)
406 set(USE_GDB_STUB OFF)
407endif()
408
409if(USE_EDITLINE)
410 list(APPEND FEATURES EDITLINE)
411 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/cli-debugger.c)
412 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/parser.c)
413 if(M_CORE_GBA)
414 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c)
415 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/extra/cli.c)
416 endif()
417 if(M_CORE_GB)
418 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/cli-debugger.c)
419 endif()
420 if(M_CORE_DS)
421 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c)
422 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/ds/extra/cli.c)
423 endif()
424 include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
425 link_directories(${LIBEDIT_LIBRARY_DIRS})
426 set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
427 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
428 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/editline/cli-el-backend.c")
429else()
430 set(DEBUGGER_LIB "")
431endif()
432
433if(USE_GDB_STUB)
434 list(APPEND FEATURES GDB_STUB)
435 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/gdb-stub.c)
436endif()
437source_group("Debugger" FILES ${DEBUGGER_SRC})
438
439if(USE_FFMPEG)
440 list(APPEND FEATURES FFMPEG)
441 pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
442 if(NOT LIBSWRESAMPLE_FOUND)
443 list(APPEND FEATURES LIBAV)
444 endif()
445 include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
446 link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
447 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/ffmpeg/ffmpeg-encoder.c")
448 string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
449 string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
450 string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
451 string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
452 string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
453 list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
454 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR}|libavcodec-extra-${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
455 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavformat${LIBAVFORMAT_VERSION_MAJOR}|libavformat-ffmpeg${LIBAVFORMAT_VERSION_MAJOR}")
456 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavresample${LIBAVRESAMPLE_VERSION_MAJOR}|libavresample-ffmpeg${LIBAVRESAMPLE_VERSION_MAJOR}")
457 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavutil${LIBAVUTIL_VERSION_MAJOR}|libavutil-ffmpeg${LIBAVUTIL_VERSION_MAJOR}")
458 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libswscale${LIBSWSCALE_VERSION_MAJOR}|libswscale-ffmpeg${LIBSWSCALE_VERSION_MAJOR}")
459 set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
460 if(APPLE)
461 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
462 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
463 endif()
464endif()
465
466list(APPEND THIRD_PARTY_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
467
468if(USE_MAGICK)
469 list(APPEND FEATURES MAGICK)
470 include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
471 link_directories(${MAGICKWAND_LIBRARY_DIRS})
472 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/imagemagick/imagemagick-gif-encoder.c")
473 list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
474 string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
475 string(REGEX MATCH "^[0-9]+" MAGICKWAND_VERSION_MAJOR ${MagickWand_VERSION})
476 if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
477 set(MAGICKWAND_DEB_VERSION "5")
478 elseif(${MagickWand_VERSION} EQUAL "6.9.7")
479 set(MAGICKWAND_DEB_VERSION "-6.q16-3")
480 else()
481 set(MAGICKWAND_DEB_VERSION "-6.q16-2")
482 endif()
483 list(APPEND FEATURE_DEFINES MAGICKWAND_VERSION_MAJOR=${MAGICKWAND_VERSION_MAJOR})
484
485 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
486endif()
487
488if(WANT_ZLIB AND NOT USE_ZLIB)
489 set(SKIP_INSTALL_ALL ON)
490 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib zlib)
491 set_property(TARGET zlibstatic PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/zlib;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib)
492 set_property(TARGET zlib PROPERTY EXCLUDE_FROM_ALL ON)
493 set_property(TARGET example PROPERTY EXCLUDE_FROM_ALL ON)
494 set_property(TARGET minigzip PROPERTY EXCLUDE_FROM_ALL ON)
495 set(ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
496 set(ZLIB_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
497 set(ZLIB_LIBRARY zlibstatic)
498 list(APPEND DEPENDENCY_LIB zlibstatic)
499 set(USE_ZLIB ON)
500endif()
501
502if(USE_ZLIB)
503 list(APPEND FEATURES ZLIB)
504 include_directories(AFTER ${ZLIB_INCLUDE_DIRS})
505 list(APPEND DEPENDENCY_LIB ${ZLIB_LIBRARIES})
506 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},zlib1g")
507endif()
508
509if(WANT_PNG AND USE_ZLIB AND NOT USE_PNG)
510 set(PNG_STATIC ON CACHE BOOL "" FORCE)
511 set(PNG_SHARED OFF CACHE BOOL "" FORCE)
512 set(PNG_TESTS OFF CACHE BOOL "" FORCE)
513 set(SKIP_INSTALL_ALL ON)
514 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng libpng)
515 set_property(TARGET png16_static PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/libpng;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng;${ZLIB_INCLUDE_DIRS})
516 set(PNG_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng ${CMAKE_CURRENT_BINARY_DIR}/libpng)
517 list(APPEND DEPENDENCY_LIB png16_static)
518 set(USE_PNG ON)
519endif()
520
521if(USE_PNG)
522 list(APPEND FEATURES PNG)
523 include_directories(AFTER ${PNG_INCLUDE_DIRS})
524 list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
525 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng12-0")
526endif()
527
528if(WANT_SQLITE3 AND NOT USE_SQLITE3)
529 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/sqlite3.c)
530 include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/)
531 set(USE_SQLITE3 ON)
532endif()
533
534if(USE_LIBZIP)
535 include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
536 link_directories(${LIBZIP_LIBRARY_DIRS})
537 list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
538 list(APPEND FEATURES LIBZIP)
539 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
540 string(REGEX MATCH "^[0-9]+" LIBZIP_VERSION_MAJOR ${libzip_VERSION})
541 if (LIBZIP_VERSION_MAJOR LESS 1)
542 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
543 elseif(LIBZIP_VERSION_MAJOR EQUAL 1)
544 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip4")
545 else()
546 message(AUTHOR_WARNING Unknown version of libzip detected: ${libzip_VERSION})
547 endif()
548elseif(USE_MINIZIP)
549 include_directories(AFTER ${MINIZIP_INCLUDE_DIRS})
550 link_directories(${MINIZIP_LIBRARY_DIRS})
551 list(APPEND DEPENDENCY_LIB ${MINIZIP_LIBRARIES})
552 list(APPEND FEATURES MINIZIP)
553 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
554 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libminizip1")
555elseif(USE_ZLIB)
556 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c
557 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
558 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c)
559 if(NOT MSVC)
560 set_source_files_properties(
561 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
562 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c
563 PROPERTIES COMPILE_FLAGS "-Wno-unused-parameter -Wno-implicit-function-declaration")
564 endif()
565endif()
566
567if (USE_LZMA)
568 include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/third-party/lzma)
569 add_definitions(-D_7ZIP_PPMD_SUPPPORT)
570 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-lzma.c)
571 set(LZMA_SRC
572 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
573 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
574 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
575 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
576 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
577 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
578 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zDec.c
579 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
580 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Delta.c
581 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
582 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
583 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra.c
584 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra86.c
585 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/BraIA64.c
586 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
587 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
588 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
589 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zFile.c
590 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
591 list(APPEND VFS_SRC ${LZMA_SRC})
592 list(APPEND FEATURES LZMA)
593endif()
594
595if(USE_EPOXY)
596 add_definitions(-DBUILD_GL -DBUILD_GLES2)
597 list(APPEND FEATURES EPOXY)
598 include_directories(AFTER ${EPOXY_INCLUDE_DIRS})
599 set(OPENGLES2_LIBRARY ${EPOXY_LIBRARIES})
600 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libepoxy0")
601endif()
602
603if(USE_SQLITE3)
604 list(APPEND FEATURES SQLITE3)
605 include_directories(AFTER ${SQLITE3_INCLUDE_DIRS})
606 list(APPEND DEPENDENCY_LIB ${SQLITE3_LIBRARIES})
607 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libsqlite3-0")
608 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/sqlite3/no-intro.c")
609endif()
610
611set(TEST_SRC ${CORE_TEST_SRC})
612if(M_CORE_GB)
613 add_definitions(-DM_CORE_GB)
614 list(APPEND CORE_SRC
615 ${LR35902_SRC}
616 ${GB_SRC}
617 ${GB_RENDERER_SRC})
618 list(APPEND DEBUGGER_SRC
619 ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/cli-debugger.c
620 ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/debugger.c
621 ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/extra/cli.c)
622 list(APPEND TEST_SRC
623 ${LR35902_TEST_SRC}
624 ${GB_TEST_SRC})
625endif()
626
627if(M_CORE_GBA)
628 add_definitions(-DM_CORE_GBA)
629 list(APPEND CORE_SRC
630 ${ARM_SRC}
631 ${GBA_SRC}
632 ${GBA_CHEATS_SRC}
633 ${GBA_RENDERER_SRC})
634 list(APPEND DEBUGGER_SRC
635 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c
636 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/debugger.c
637 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/memory-debugger.c
638 ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/extra/cli.c)
639 list(APPEND TEST_SRC
640 ${ARM_TEST_SRC}
641 ${GBA_TEST_SRC})
642 if(NOT M_CORE_GB)
643 list(APPEND CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/audio.c)
644 endif()
645endif()
646
647if(M_CORE_DS)
648 add_definitions(-DM_CORE_DS)
649 list(APPEND CORE_SRC
650 ${ARM_SRC}
651 ${DS_SRC}
652 ${DS_RENDERER_SRC})
653 list(APPEND DEBUGGER_SRC
654 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c
655 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/debugger.c
656 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/memory-debugger.c
657 ${CMAKE_CURRENT_SOURCE_DIR}/src/ds/extra/cli.c)
658endif()
659
660if(USE_DEBUGGERS)
661 list(APPEND FEATURE_SRC ${DEBUGGER_SRC})
662 list(APPEND FEATURES DEBUGGERS)
663endif()
664
665foreach(FEATURE IN LISTS FEATURES)
666 list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
667endforeach()
668
669source_group("Virtual files" FILES ${CORE_VFS_SRC} ${VFS_SRC})
670source_group("Extra features" FILES ${FEATURE_SRC})
671source_group("Third-party code" FILES ${THIRD_PARTY_SRC})
672
673# Platform binaries
674if(DEFINED 3DS)
675 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/3ds ${CMAKE_CURRENT_BINARY_DIR}/3ds)
676endif()
677
678if(DEFINED WII)
679 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/wii ${CMAKE_CURRENT_BINARY_DIR}/wii)
680endif()
681
682if(DEFINED PSP2)
683 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/psp2 ${CMAKE_CURRENT_BINARY_DIR}/psp2)
684endif()
685
686# Binaries
687list(APPEND CORE_SRC
688 ${UTIL_SRC}
689 ${CORE_VFS_SRC}
690 ${OS_SRC}
691 ${THIRD_PARTY_SRC})
692list(APPEND TEST_SRC ${UTIL_TEST_SRC})
693
694set(SRC ${CORE_SRC} ${VFS_SRC})
695if(NOT MINIMAL_CORE)
696 if(M_CORE_GBA)
697 list(APPEND SRC
698 ${GBA_RR_SRC}
699 ${GBA_EXTRA_SRC}
700 ${GBA_SIO_SRC})
701 endif()
702 if(M_CORE_GB)
703 list(APPEND SRC
704 ${GB_SIO_SRC})
705 endif()
706 list(APPEND SRC
707 ${FEATURE_SRC}
708 ${CLI_SRC})
709endif()
710
711if(NOT SKIP_LIBRARY)
712 if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
713 set(BUILD_SHARED ON)
714 endif()
715
716 if(BUILD_SHARED)
717 add_library(${BINARY_NAME} SHARED ${SRC} ${VFS_SRC})
718 if(BUILD_STATIC)
719 add_library(${BINARY_NAME}-static STATIC ${SRC})
720 set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
721 install(TARGETS ${BINARY_NAME}-static DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
722 add_dependencies(${BINARY_NAME}-static version-info)
723 endif()
724 else()
725 add_library(${BINARY_NAME} STATIC ${SRC})
726 endif()
727
728 add_dependencies(${BINARY_NAME} version-info)
729 set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
730
731 target_link_libraries(${BINARY_NAME} ${DEBUGGER_LIB} ${DEPENDENCY_LIB} ${OS_LIB})
732 install(TARGETS ${BINARY_NAME} LIBRARY DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME} NAMELINK_SKIP ARCHIVE DESTINATION ${LIBDIR} RUNTIME DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
733 if(UNIX AND NOT APPLE)
734 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/${BINARY_NAME}-16.png DESTINATION share/icons/hicolor/16x16/apps RENAME ${BINARY_NAME}.png COMPONENT lib${BINARY_NAME})
735 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/${BINARY_NAME}-24.png DESTINATION share/icons/hicolor/24x24/apps RENAME ${BINARY_NAME}.png COMPONENT lib${BINARY_NAME})
736 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/${BINARY_NAME}-32.png DESTINATION share/icons/hicolor/32x32/apps RENAME ${BINARY_NAME}.png COMPONENT lib${BINARY_NAME})
737 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/${BINARY_NAME}-48.png DESTINATION share/icons/hicolor/48x48/apps RENAME ${BINARY_NAME}.png COMPONENT lib${BINARY_NAME})
738 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/${BINARY_NAME}-64.png DESTINATION share/icons/hicolor/64x64/apps RENAME ${BINARY_NAME}.png COMPONENT lib${BINARY_NAME})
739 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/${BINARY_NAME}-96.png DESTINATION share/icons/hicolor/96x96/apps RENAME ${BINARY_NAME}.png COMPONENT lib${BINARY_NAME})
740 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/${BINARY_NAME}-128.png DESTINATION share/icons/hicolor/128x128/apps RENAME ${BINARY_NAME}.png COMPONENT lib${BINARY_NAME})
741 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/${BINARY_NAME}-256.png DESTINATION share/icons/hicolor/256x256/apps RENAME ${BINARY_NAME}.png COMPONENT lib${BINARY_NAME})
742 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/${BINARY_NAME}-512.png DESTINATION share/icons/hicolor/512x512/apps RENAME ${BINARY_NAME}.png COMPONENT lib${BINARY_NAME})
743 endif()
744else()
745 set(BUILD_SHARED OFF)
746 set(BUILD_STATIC OFF)
747 find_library(${BINARY_NAME} ${BINARY_NAME})
748 if(NOT ${BINARY_NAME}_FOUND)
749 set(DISABLE_FRONTENDS ON)
750 set(BUILD_PERF OFF)
751 set(BUILD_TEST OFF)
752 set(BUILD_SUITE OFF)
753 endif()
754endif()
755
756if(BUILD_GL)
757 add_definitions(-DBUILD_GL)
758endif()
759
760if(BUILD_GLES2)
761 add_definitions(-DBUILD_GLES2)
762endif()
763
764if(DISABLE_FRONTENDS)
765 set(BUILD_SDL OFF)
766 set(BUILD_QT OFF)
767endif()
768
769if(BUILD_LIBRETRO)
770 file(GLOB RETRO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/libretro/*.c)
771 add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
772 set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5;DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=2")
773 target_link_libraries(${BINARY_NAME}_libretro ${OS_LIB})
774 install(TARGETS ${BINARY_NAME}_libretro LIBRARY DESTINATION ${LIBRETRO_LIBDIR} COMPONENT ${BINARY_NAME}_libretro NAMELINK_SKIP)
775endif()
776
777if(BUILD_OPENEMU)
778 find_library(FOUNDATION Foundation)
779 find_library(OPENEMUBASE OpenEmuBase)
780 file(GLOB OE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/*.m)
781 add_library(${BINARY_NAME}-openemu MODULE ${CORE_SRC} ${OE_SRC})
782 set_target_properties(${BINARY_NAME}-openemu PROPERTIES
783 MACOSX_BUNDLE_INFO_PLIST ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/Info.plist.in
784 BUNDLE TRUE
785 BUNDLE_EXTENSION oecoreplugin
786 OUTPUT_NAME ${PROJECT_NAME}
787 COMPILE_DEFINITIONS "DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=1")
788 target_link_libraries(${BINARY_NAME}-openemu ${OS_LIB} ${FOUNDATION} ${OPENEMUBASE})
789 install(TARGETS ${BINARY_NAME}-openemu LIBRARY DESTINATION ${OE_LIBDIR} COMPONENT ${BINARY_NAME}.oecoreplugin NAMELINK_SKIP)
790endif()
791
792if(BUILD_SDL)
793 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/sdl ${CMAKE_CURRENT_BINARY_DIR}/sdl)
794 # The SDL platform CMakeLists could decide to disable SDL, so check again before adding the define.
795 if(BUILD_SDL)
796 add_definitions(-DBUILD_SDL)
797 endif()
798endif()
799
800if(BUILD_QT)
801 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/qt ${CMAKE_CURRENT_BINARY_DIR}/qt)
802endif()
803
804if(BUILD_PERF)
805 set(PERF_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/perf-main.c ${CLI_SRC})
806 if(UNIX AND NOT APPLE)
807 list(APPEND PERF_LIB rt)
808 endif()
809
810 add_executable(${BINARY_NAME}-perf ${PERF_SRC})
811 target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB} ${OS_LIB})
812 set_target_properties(${BINARY_NAME}-perf PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
813 install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
814 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
815endif()
816
817if(BUILD_TEST)
818 add_executable(${BINARY_NAME}-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/fuzz-main.c)
819 target_link_libraries(${BINARY_NAME}-fuzz ${BINARY_NAME})
820 set_target_properties(${BINARY_NAME}-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
821 add_executable(tbl-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/tbl-fuzz-main.c)
822 target_link_libraries(tbl-fuzz ${BINARY_NAME})
823 set_target_properties(tbl-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
824 install(TARGETS ${BINARY_NAME}-fuzz tbl-fuzz DESTINATION bin COMPONENT ${BINARY_NAME}-test)
825endif()
826
827if(NOT USE_CMOCKA)
828 set(BUILD_SUITE OFF)
829endif()
830if(BUILD_SUITE)
831 enable_testing()
832 include_directories(AFTER ${CMOCKA_INCLUDE_DIRS})
833 link_directories(${CMOCKA_LIBRARY_DIRS})
834
835 add_executable(${BINARY_NAME}-suite ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/suite-main.c ${TEST_SRC})
836 target_link_libraries(${BINARY_NAME}-suite ${BINARY_NAME} ${PLATFORM_LIBRARY} cmocka)
837 set_target_properties(${BINARY_NAME}-suite PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
838 add_test(${BINARY_NAME}-suite ${BINARY_NAME}-suite)
839endif()
840
841if(BUILD_PYTHON)
842 enable_testing()
843 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/python ${CMAKE_CURRENT_BINARY_DIR}/python)
844endif()
845
846if(BUILD_EXAMPLE)
847 add_executable(${BINARY_NAME}-example-server ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/server.c)
848 target_link_libraries(${BINARY_NAME}-example-server ${BINARY_NAME})
849 set_target_properties(${BINARY_NAME}-example-server PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
850
851 if(BUILD_SDL)
852 add_executable(${BINARY_NAME}-example-client ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/client.c)
853 target_link_libraries(${BINARY_NAME}-example-client ${BINARY_NAME} ${SDL_LIBRARY} ${SDLMAIN_LIBRARY} ${OPENGL_LIBRARY} ${OPENGLES2_LIBRARY})
854 set_target_properties(${BINARY_NAME}-example-client PROPERTIES
855 COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}"
856 INCLUDE_DIRECTORIES "${SDL_INCLUDE_DIR};${CMAKE_CURRENT_SOURCE_DIR}/src;${CMAKE_CURRENT_SOURCE_DIR}/include")
857 endif()
858endif()
859
860# Packaging
861set(CPACK_PACKAGE_VERSION ${VERSION_STRING})
862set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
863set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
864set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
865set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
866set(CPACK_RESOURCE_FILE_README ${CMAKE_CURRENT_SOURCE_DIR}/README.md)
867
868set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
869set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
870set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
871set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README.md")
872set(CPACK_DEBIAN_PACKAGE_SECTION "games")
873
874SET(CPACK_DEB_COMPONENT_INSTALL ON)
875
876set(CPACK_STRIP_FILES ${BINARY_NAME})
877
878install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/README.md ${CMAKE_CURRENT_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
879
880include(CPack)
881
882# Summaries
883set(SUMMARY_GL_LIST)
884if(USE_EPOXY)
885 set(SUMMARY_GL_LIST "libepoxy")
886else()
887 if(BUILD_GL)
888 list(APPEND SUMMARY_GL_LIST "OpenGL")
889 endif()
890 if(BUILD_GLES2)
891 list(APPEND SUMMARY_GL_LIST "OpenGL|ES 2")
892 endif()
893endif()
894if(NOT SUMMARY_GL_LIST)
895 set(SUMMARY_GL OFF)
896else()
897 string(REPLACE ";" ", " SUMMARY_GL "${SUMMARY_GL_LIST}")
898endif()
899if(USE_LIBZIP)
900 set(SUMMARY_ZIP libzip)
901elseif(USE_MINIZIP)
902 set(SUMMARY_ZIP "minizip (external)")
903elseif(USE_ZLIB)
904 set(SUMMARY_ZIP "minizip (included)")
905else()
906 set(SUMMARY_ZIP OFF)
907endif()
908
909if(NOT QUIET)
910 message(STATUS "Platforms:")
911 message(STATUS " Game Boy Advance: ${M_CORE_GBA}")
912 message(STATUS " Game Boy: ${M_CORE_GB}")
913 message(STATUS " DS: ${M_CORE_DS}")
914 message(STATUS "Features:")
915 message(STATUS " Debuggers: ${USE_DEBUGGERS}")
916 message(STATUS " CLI debugger: ${USE_EDITLINE}")
917 message(STATUS " GDB stub: ${USE_GDB_STUB}")
918 message(STATUS " Video recording: ${USE_FFMPEG}")
919 message(STATUS " GIF recording: ${USE_MAGICK}")
920 message(STATUS " Screenshot/advanced savestate support: ${USE_PNG}")
921 message(STATUS " ZIP support: ${SUMMARY_ZIP}")
922 message(STATUS " 7-Zip support: ${USE_LZMA}")
923 message(STATUS " SQLite3 game database: ${USE_SQLITE3}")
924 message(STATUS " OpenGL support: ${SUMMARY_GL}")
925 message(STATUS "Frontends:")
926 message(STATUS " Qt: ${BUILD_QT}")
927 message(STATUS " SDL (${SDL_VERSION}): ${BUILD_SDL}")
928 message(STATUS " Profiling: ${BUILD_PERF}")
929 message(STATUS " Test harness: ${BUILD_TEST}")
930 message(STATUS " Test suite: ${BUILD_SUITE}")
931 message(STATUS " Python bindings: ${BUILD_PYTHON}")
932 message(STATUS " Examples: ${BUILD_EXAMPLE}")
933 message(STATUS "Cores:")
934 message(STATUS " Libretro core: ${BUILD_LIBRETRO}")
935 if(APPLE)
936 message(STATUS " OpenEmu core: ${BUILD_OPENEMU}")
937 endif()
938 message(STATUS "Libraries:")
939 message(STATUS " Static: ${BUILD_STATIC}")
940 message(STATUS " Shared: ${BUILD_SHARED}")
941endif()