CMakeLists.txt (view raw)
1cmake_minimum_required(VERSION 2.6)
2project(mGBA C)
3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
4if(NOT MSVC)
5 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wno-missing-field-initializers -std=c99")
6else()
7 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_CRT_SECURE_NO_WARNINGS /wd4003 /wd4244 /wd4146")
8endif()
9set(USE_CLI_DEBUGGER ON CACHE BOOL "Whether or not to enable the CLI-mode ARM debugger")
10set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
11set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
12set(USE_ZLIB ON CACHE BOOL "Whether or not to enable zlib support")
13set(USE_MINIZIP ON CACHE BOOL "Whether or not to enable external minizip support")
14set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
15set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable LIBZIP support")
16set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
17set(M_CORE_GBA ON CACHE BOOL "Build Game Boy Advance core")
18set(M_CORE_GB ON CACHE BOOL "Build Game Boy core")
19set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
20set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
21set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
22set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
23if(APPLE)
24 set(BUILD_OPENEMU OFF CACHE BOOL "Build OpenEmu core")
25endif()
26set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
27set(BUILD_TEST OFF CACHE BOOL "Build testing harness")
28set(BUILD_SUITE OFF CACHE BOOL "Build test suite")
29set(BUILD_EXAMPLE OFF CACHE BOOL "Build example frontends")
30set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
31set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
32set(SKIP_LIBRARY OFF CACHE BOOL "Skip building the library (useful for only building libretro or OpenEmu cores)")
33set(BUILD_GL ON CACHE STRING "Build with OpenGL")
34set(BUILD_GLES2 OFF CACHE STRING "Build with OpenGL|ES 2")
35set(USE_EPOXY ON CACHE STRING "Build with libepoxy")
36set(DISABLE_DEPS OFF CACHE BOOL "Build without dependencies")
37file(GLOB ARM_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/*.c)
38file(GLOB LR35902_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/*.c)
39file(GLOB GBA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/*.c)
40file(GLOB GB_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/*.c)
41file(GLOB GBA_CHEATS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/cheats/*.c)
42file(GLOB GBA_RR_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/rr/*.c)
43file(GLOB GBA_EXTRA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/extra/*.c)
44file(GLOB UTIL_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/*.[cSs] ${CMAKE_CURRENT_SOURCE_DIR}/src/core/*.c)
45file(GLOB GUI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/gui/*.c ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/gui/*.c)
46file(GLOB GBA_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/renderers/*.c)
47file(GLOB SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/sio/lockstep.c)
48file(GLOB GB_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/renderers/*.c)
49file(GLOB THIRD_PARTY_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/inih/*.c)
50set(CLI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/commandline.c)
51set(CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-mem.c)
52set(VFS_SRC)
53source_group("ARM core" FILES ${ARM_SRC})
54source_group("LR35902 core" FILES ${LR35902_SRC})
55source_group("GBA board" FILES ${GBA_SRC} ${GBA_RENDERER_SRC} ${SIO_SRC})
56source_group("GBA extra" FILES ${GBA_CHEATS_SRC} ${GBA_EXTRA_SRC} ${GBA_RR_SRC})
57source_group("GB board" FILES ${GB_SRC})
58source_group("Utilities" FILES ${UTIL_SRC})
59include_directories(BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/src)
60
61if(NOT CMAKE_BUILD_TYPE)
62 set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
63endif()
64
65include(GNUInstallDirs)
66
67set(LIBDIR "${CMAKE_INSTALL_LIBDIR}" CACHE PATH "Installed library directory")
68mark_as_advanced(LIBDIR)
69
70if (BUILD_LIBRETRO)
71 set(LIBRETRO_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (Libretro)")
72 mark_as_advanced(LIBRETRO_LIBDIR)
73endif()
74
75if (BUILD_OPENEMU)
76 set(OE_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (OpenEmu)")
77 mark_as_advanced(OE_LIBDIR)
78endif()
79
80
81set(CMAKE_INSTALL_RPATH "${LIBDIR}")
82
83if (NOT DEFINED MANDIR)
84 set(MANDIR ${CMAKE_INSTALL_MANDIR})
85endif()
86
87# Function definitions
88include(FindPkgConfig)
89function(find_feature FEATURE_NAME FEATURE_REQUIRES)
90 if (NOT ${FEATURE_NAME})
91 return()
92 endif()
93 if (DISABLE_DEPS)
94 set(${FEATURE_NAME} OFF PARENT_SCOPE)
95 return()
96 endif()
97 foreach(REQUIRE ${FEATURE_REQUIRES})
98 if(NOT ${REQUIRE}_FOUND)
99 find_package(${REQUIRE} QUIET)
100 if(NOT ${REQUIRE}_FOUND)
101 pkg_search_module(${REQUIRE} ${REQUIRE})
102 if (NOT ${REQUIRE}_FOUND)
103 message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
104 set(${FEATURE_NAME} OFF PARENT_SCOPE)
105 return()
106 endif()
107 endif()
108 endif()
109 string(TOUPPER ${REQUIRE} UREQUIRE)
110 set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
111 set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
112 set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
113 if (APPLE)
114 set(IS_FRAMEWORK OFF)
115 set(LIBS)
116 foreach(LIB IN LISTS ${REQUIRE}_LIBRARIES)
117 if(LIB STREQUAL "-framework")
118 set(IS_FRAMEWORK ON)
119 elseif(IS_FRAMEWORK)
120 list(APPEND LIBS "-framework ${LIB}")
121 set(IS_FRAMEWORK OFF)
122 else()
123 list(APPEND LIBS ${LIB})
124 endif()
125 endforeach()
126 set(${UREQUIRE}_LIBRARIES ${LIBS} PARENT_SCOPE)
127 else()
128 set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
129 endif()
130 set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
131 set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
132 endforeach()
133endfunction()
134
135# Version information
136add_custom_target(version-info ALL
137 COMMAND ${CMAKE_COMMAND}
138 -DBINARY_NAME=${BINARY_NAME}
139 -DCONFIG_FILE=${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in
140 -DOUT_FILE=${CMAKE_CURRENT_BINARY_DIR}/version.c
141 -P ${CMAKE_CURRENT_SOURCE_DIR}/version.cmake
142 WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
143
144include(${CMAKE_CURRENT_SOURCE_DIR}/version.cmake)
145configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in ${CMAKE_CURRENT_BINARY_DIR}/version.c)
146list(APPEND UTIL_SRC ${CMAKE_CURRENT_BINARY_DIR}/version.c)
147source_group("Generated sources" FILES ${CMAKE_CURRENT_BINARY_DIR}/version.c)
148
149# Advanced settings
150set(BUILD_LTO ON CACHE BOOL "Build with link-time optimization")
151set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
152set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
153set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
154mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
155set(PGO_PRE_FLAGS "-fprofile-generate=${PGO_DIR} -fprofile-arcs")
156set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
157
158if(BUILD_PGO AND NOT PGO_STAGE_2)
159 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
160 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
161 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
162elseif(BUILD_PGO AND PGO_STAGE_2)
163 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
164 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
165 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
166endif()
167
168# Platform support
169if(WIN32)
170 set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
171 add_definitions(-D_WIN32_WINNT=0x0600)
172 list(APPEND OS_LIB ws2_32 shlwapi)
173 list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/vfs-w32.c)
174 file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/*.c)
175 source_group("Windows-specific code" FILES ${OS_SRC})
176 if(MSVC)
177 add_definitions(-DNOMINMAX -DWIN32_LEAN_AND_MEAN)
178 endif()
179elseif(UNIX)
180 add_definitions(-DUSE_PTHREADS)
181
182 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
183 add_definitions(-D_GNU_SOURCE)
184 endif()
185 if(NOT APPLE AND NOT HAIKU)
186 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
187 endif()
188
189 list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
190 file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/posix/*.c)
191 source_group("POSIX-specific code" FILES ${OS_SRC})
192endif()
193
194if(APPLE)
195 add_definitions(-D_DARWIN_C_SOURCE)
196 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
197endif()
198
199if(NOT HAIKU AND NOT MSVC AND NOT PSP2)
200 set(M_LIBRARY m)
201endif()
202list(APPEND OS_LIB ${M_LIBRARY})
203
204if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
205 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
206 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
207endif()
208
209if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
210 if(NOT BUILD_EGL)
211 add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
212 endif()
213endif()
214
215if(BUILD_RASPI)
216 set(BUILD_GL OFF CACHE BOOL "OpenGL not supported" FORCE)
217endif()
218
219if(BUILD_PANDORA)
220 add_definitions(-DBUILD_PANDORA)
221endif()
222
223if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
224 enable_language(ASM)
225endif()
226
227if(PSP2 OR WII)
228 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-format")
229endif()
230
231if(DEFINED 3DS OR DEFINED PSP2 OR DEFINED WII OR NOT M_CORE_GBA)
232 set(USE_GDB_STUB OFF)
233endif()
234
235if(WII)
236 add_definitions(-U__STRICT_ANSI__)
237endif()
238
239include(CheckFunctionExists)
240check_function_exists(strdup HAVE_STRDUP)
241check_function_exists(strndup HAVE_STRNDUP)
242check_function_exists(localtime_r HAVE_LOCALTIME_R)
243if(NOT CMAKE_SYSTEM_NAME STREQUAL "Generic")
244 check_function_exists(snprintf_l HAVE_SNPRINTF_L)
245 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
246 # The strtof_l on Linux not actually exposed nor actually strtof_l
247 set(HAVE_STRTOF_L OFF)
248 else()
249 check_function_exists(strtof_l HAVE_STRTOF_L)
250 endif()
251 check_function_exists(newlocale HAVE_NEWLOCALE)
252 check_function_exists(freelocale HAVE_FREELOCALE)
253 check_function_exists(uselocale HAVE_USELOCALE)
254 check_function_exists(setlocale HAVE_SETLOCALE)
255else()
256 if(NOT DEFINED 3DS AND NOT DEFINED PSP2 AND NOT DEFINED WII)
257 set(DISABLE_DEPS ON CACHE BOOL "This platform cannot build with dependencies" FORCE)
258 endif()
259 set(DISABLE_FRONTENDS ON)
260 set(MINIMAL_CORE ON)
261endif()
262
263check_function_exists(chmod HAVE_CHMOD)
264check_function_exists(umask HAVE_UMASK)
265
266set(FUNCTION_DEFINES)
267
268if(HAVE_STRDUP)
269 list(APPEND FUNCTION_DEFINES HAVE_STRDUP)
270endif()
271
272if(HAVE_STRNDUP)
273 list(APPEND FUNCTION_DEFINES HAVE_STRNDUP)
274endif()
275
276if(HAVE_LOCALTIME_R)
277 list(APPEND FUNCTION_DEFINES HAVE_LOCALTIME_R)
278endif()
279
280if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE OR APPLE)
281 list(APPEND FUNCTION_DEFINES HAVE_LOCALE)
282 if (HAVE_STRTOF_L)
283 list(APPEND FUNCTION_DEFINES HAVE_STRTOF_L)
284 endif()
285 if (HAVE_SNPRINTF_L)
286 list(APPEND FUNCTION_DEFINES HAVE_SNPRINTF_L)
287 endif()
288endif()
289
290if(HAVE_SETLOCALE)
291 list(APPEND FUNCTION_DEFINES HAVE_SETLOCALE)
292endif()
293
294if(HAVE_CHMOD)
295 list(APPEND FUNCTION_DEFINES HAVE_CHMOD)
296endif()
297
298if(HAVE_UMASK)
299 list(APPEND FUNCTION_DEFINES HAVE_UMASK)
300endif()
301
302# Feature dependencies
303set(FEATURES)
304if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
305 set(LIBEDIT_LIBRARIES -ledit)
306 if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
307 list(APPEND LIBEDIT_LIBRARIES -ltermcap)
308 endif()
309else()
310 find_feature(USE_CLI_DEBUGGER "libedit")
311endif()
312if(BUILD_GL)
313 find_package(OpenGL QUIET)
314 if(NOT OPENGL_FOUND)
315 set(BUILD_GL OFF CACHE BOOL "OpenGL not found" FORCE)
316 endif()
317endif()
318if(NOT BUILD_GL)
319 set(OPENGLE_LIBRARY "" CACHE PATH "" FORCE)
320endif()
321if(BUILD_GLES2 AND NOT BUILD_RASPI)
322 find_path(OPENGLES2_INCLUDE_DIR NAMES GLES2/gl2.h)
323 find_library(OPENGLES2_LIBRARY NAMES GLESv2 GLESv2_CM)
324 if(NOT OPENGLES2_INCLUDE_DIR OR NOT OPENGLES2_LIBRARY)
325 set(BUILD_GLES2 OFF CACHE BOOL "OpenGL|ES 2 not found" FORCE)
326 endif()
327endif()
328if(NOT BUILD_GLES2)
329 set(OPENGLES2_LIBRARY "" CACHE PATH "" FORCE)
330endif()
331set(WANT_ZLIB ${USE_ZLIB})
332set(WANT_PNG ${USE_PNG})
333set(WANT_LIBZIP ${USE_LIBZIP})
334set(USE_CMOCKA ${BUILD_SUITE})
335
336find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
337find_feature(USE_ZLIB "ZLIB")
338find_feature(USE_MINIZIP "minizip")
339find_feature(USE_PNG "PNG")
340find_feature(USE_LIBZIP "libzip")
341find_feature(USE_MAGICK "MagickWand")
342find_feature(USE_EPOXY "epoxy")
343find_feature(USE_CMOCKA "cmocka")
344
345# Features
346set(DEBUGGER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/debugger.c)
347set(FEATURE_SRC)
348set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
349
350if(DISABLE_DEPS)
351 set(USE_GDB_STUB OFF)
352endif()
353
354if(USE_CLI_DEBUGGER)
355 list(APPEND FEATURES CLI_DEBUGGER)
356 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/cli-debugger.c)
357 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/parser.c)
358 if(M_CORE_GBA)
359 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c)
360 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/extra/cli.c)
361 endif()
362 if(M_CORE_GB)
363 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/cli-debugger.c)
364 endif()
365 include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
366 link_directories(${LIBEDIT_LIBRARY_DIRS})
367 set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
368 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
369else()
370 set(DEBUGGER_LIB "")
371endif()
372
373if(USE_GDB_STUB)
374 list(APPEND FEATURES GDB_STUB)
375 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/gdb-stub.c)
376endif()
377source_group("Debugger" FILES ${DEBUGGER_SRC})
378
379if(USE_FFMPEG)
380 list(APPEND FEATURES FFMPEG)
381 pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
382 if(NOT LIBSWRESAMPLE_FOUND)
383 list(APPEND FEATURES LIBAV)
384 endif()
385 include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
386 link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
387 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/ffmpeg/ffmpeg-encoder.c")
388 string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
389 string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
390 string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
391 string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
392 string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
393 list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
394 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR}|libavcodec-extra-${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
395 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavformat${LIBAVFORMAT_VERSION_MAJOR}|libavformat-ffmpeg${LIBAVFORMAT_VERSION_MAJOR}")
396 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavresample${LIBAVRESAMPLE_VERSION_MAJOR}|libavresample-ffmpeg${LIBAVRESAMPLE_VERSION_MAJOR}")
397 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavutil${LIBAVUTIL_VERSION_MAJOR}|libavutil-ffmpeg${LIBAVUTIL_VERSION_MAJOR}")
398 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libswscale${LIBSWSCALE_VERSION_MAJOR}|libswscale-ffmpeg${LIBSWSCALE_VERSION_MAJOR}")
399 set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
400 if(APPLE)
401 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
402 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
403 endif()
404endif()
405
406list(APPEND THIRD_PARTY_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
407
408if(USE_MAGICK)
409 list(APPEND FEATURES MAGICK)
410 include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
411 link_directories(${MAGICKWAND_LIBRARY_DIRS})
412 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/imagemagick/imagemagick-gif-encoder.c")
413 list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
414 string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
415 if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
416 set(MAGICKWAND_DEB_VERSION "5")
417 else()
418 set(MAGICKWAND_DEB_VERSION "-6.q16-2")
419 endif()
420 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
421endif()
422
423if(WANT_ZLIB AND NOT USE_ZLIB)
424 set(SKIP_INSTALL_ALL ON)
425 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib zlib)
426 set_property(TARGET zlibstatic PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/zlib;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib)
427 set_property(TARGET zlib PROPERTY EXCLUDE_FROM_ALL ON)
428 set_property(TARGET example PROPERTY EXCLUDE_FROM_ALL ON)
429 set_property(TARGET minigzip PROPERTY EXCLUDE_FROM_ALL ON)
430 set(ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
431 set(ZLIB_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
432 set(ZLIB_LIBRARY zlibstatic)
433 list(APPEND DEPENDENCY_LIB zlibstatic)
434 set(USE_ZLIB ON)
435endif()
436
437if(USE_ZLIB)
438 list(APPEND FEATURES ZLIB)
439 include_directories(AFTER ${ZLIB_INCLUDE_DIRS})
440 list(APPEND DEPENDENCY_LIB ${ZLIB_LIBRARIES})
441 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},zlib1g")
442endif()
443
444if(WANT_PNG AND USE_ZLIB AND NOT USE_PNG)
445 set(PNG_STATIC ON CACHE BOOL "" FORCE)
446 set(PNG_SHARED OFF CACHE BOOL "" FORCE)
447 set(PNG_TESTS OFF CACHE BOOL "" FORCE)
448 set(SKIP_INSTALL_ALL ON)
449 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng libpng)
450 set_property(TARGET png16_static PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/libpng;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng;${ZLIB_INCLUDE_DIRS})
451 set(PNG_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng ${CMAKE_CURRENT_BINARY_DIR}/libpng)
452 list(APPEND DEPENDENCY_LIB png16_static)
453 set(USE_PNG ON)
454endif()
455
456if(USE_PNG)
457 list(APPEND FEATURES PNG)
458 include_directories(AFTER ${PNG_INCLUDE_DIRS})
459 list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
460 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng12-0")
461endif()
462
463if(USE_LIBZIP)
464 include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
465 link_directories(${LIBZIP_LIBRARY_DIRS})
466 list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
467 list(APPEND FEATURES LIBZIP)
468 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
469 string(REGEX MATCH "^[0-9]+" LIBZIP_VERSION_MAJOR ${libzip_VERSION})
470 if (LIBZIP_VERSION_MAJOR LESS 1)
471 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
472 elseif(LIBZIP_VERSION_MAJOR EQUAL 1)
473 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip4")
474 else()
475 message(AUTHOR_WARNING Unknown version of libzip detected: ${libzip_VERSION})
476 endif()
477elseif(USE_MINIZIP)
478 include_directories(AFTER ${MINIZIP_INCLUDE_DIRS})
479 link_directories(${MINIZIP_LIBRARY_DIRS})
480 list(APPEND DEPENDENCY_LIB ${MINIZIP_LIBRARIES})
481 list(APPEND FEATURES MINIZIP)
482 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
483 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libminizip1")
484elseif(USE_ZLIB)
485 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c
486 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
487 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c)
488 set_source_files_properties(
489 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
490 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c
491 PROPERTIES COMPILE_FLAGS "-Wno-unused-parameter -Wno-implicit-function-declaration")
492endif()
493
494if (USE_LZMA)
495 include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/third-party/lzma)
496 add_definitions(-D_7ZIP_PPMD_SUPPPORT)
497 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-lzma.c)
498 set(LZMA_SRC
499 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
500 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
501 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
502 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
503 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
504 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
505 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zDec.c
506 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
507 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Delta.c
508 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
509 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
510 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra.c
511 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra86.c
512 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/BraIA64.c
513 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
514 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
515 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
516 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zFile.c
517 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
518 list(APPEND VFS_SRC ${LZMA_SRC})
519 list(APPEND FEATURES LZMA)
520endif()
521
522if(USE_EPOXY)
523 add_definitions(-DBUILD_GL -DBUILD_GLES2)
524 list(APPEND FEATURES EPOXY)
525 include_directories(AFTER ${EPOXY_INCLUDE_DIRS})
526 set(OPENGLES2_LIBRARY ${EPOXY_LIBRARIES})
527 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libepoxy0")
528endif()
529
530
531set(FEATURE_DEFINES)
532foreach(FEATURE IN LISTS FEATURES)
533 list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
534endforeach()
535
536set(CORE_SRC)
537if(M_CORE_GB)
538 add_definitions(-DM_CORE_GB)
539 list(APPEND CORE_SRC
540 ${LR35902_SRC}
541 ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/debugger.c
542 ${GB_SRC}
543 ${GB_RENDERER_SRC})
544endif()
545
546if(M_CORE_GBA)
547 add_definitions(-DM_CORE_GBA)
548 list(APPEND CORE_SRC
549 ${ARM_SRC}
550 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/debugger.c
551 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/memory-debugger.c
552 ${GBA_SRC}
553 ${GBA_CHEATS_SRC}
554 ${GBA_RENDERER_SRC})
555 if(NOT M_CORE_GB)
556 list(APPEND CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/audio.c)
557 endif()
558endif()
559
560source_group("Virtual files" FILES ${CORE_VFS_SRC} ${VFS_SRC})
561source_group("Extra features" FILES ${FEATURE_SRC})
562source_group("Third-party code" FILES ${THIRD_PARTY_SRC})
563
564# Platform binaries
565if(3DS)
566 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/3ds ${CMAKE_CURRENT_BINARY_DIR}/3ds)
567endif()
568
569if(WII)
570 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/wii ${CMAKE_CURRENT_BINARY_DIR}/wii)
571endif()
572
573if(PSP2)
574 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/psp2 ${CMAKE_CURRENT_BINARY_DIR}/psp2)
575endif()
576
577# Binaries
578list(APPEND CORE_SRC
579 ${UTIL_SRC}
580 ${CORE_VFS_SRC}
581 ${DEBUGGER_SRC}
582 ${OS_SRC}
583 ${THIRD_PARTY_SRC})
584
585set(SRC ${CORE_SRC} ${VFS_SRC})
586if(NOT MINIMAL_CORE)
587 if(M_CORE_GBA)
588 list(APPEND SRC
589 ${GBA_RR_SRC}
590 ${GBA_EXTRA_SRC}
591 ${SIO_SRC})
592 endif()
593 list(APPEND SRC
594 ${FEATURE_SRC}
595 ${CLI_SRC})
596endif()
597
598if(NOT SKIP_LIBRARY)
599 if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
600 set(BUILD_SHARED ON)
601 endif()
602
603 if(BUILD_SHARED)
604 add_library(${BINARY_NAME} SHARED ${SRC} ${VFS_SRC})
605 if(BUILD_STATIC)
606 add_library(${BINARY_NAME}-static STATIC ${SRC})
607 set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
608 install(TARGETS ${BINARY_NAME}-static DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
609 add_dependencies(${BINARY_NAME}-static version-info)
610 endif()
611 else()
612 add_library(${BINARY_NAME} STATIC ${SRC})
613 endif()
614
615 add_dependencies(${BINARY_NAME} version-info)
616 set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
617
618 target_link_libraries(${BINARY_NAME} ${DEBUGGER_LIB} ${DEPENDENCY_LIB} ${OS_LIB})
619 install(TARGETS ${BINARY_NAME} LIBRARY DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME} NAMELINK_SKIP ARCHIVE DESTINATION ${LIBDIR} RUNTIME DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
620 if(UNIX AND NOT APPLE)
621 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-16.png DESTINATION share/icons/hicolor/16x16/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
622 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-24.png DESTINATION share/icons/hicolor/24x24/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
623 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-32.png DESTINATION share/icons/hicolor/32x32/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
624 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-48.png DESTINATION share/icons/hicolor/48x48/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
625 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-64.png DESTINATION share/icons/hicolor/64x64/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
626 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-96.png DESTINATION share/icons/hicolor/96x96/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
627 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-128.png DESTINATION share/icons/hicolor/128x128/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
628 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-256.png DESTINATION share/icons/hicolor/256x256/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
629 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-512.png DESTINATION share/icons/hicolor/512x512/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
630 endif()
631else()
632 set(BUILD_SHARED OFF)
633 set(BUILD_STATIC OFF)
634 find_library(${BINARY_NAME} ${BINARY_NAME})
635 if(NOT ${BINARY_NAME}_FOUND)
636 set(DISABLE_FRONTENDS ON)
637 set(BUILD_PERF OFF)
638 set(BUILD_TEST OFF)
639 set(BUILD_SUITE OFF)
640 endif()
641endif()
642
643if(BUILD_GL)
644 add_definitions(-DBUILD_GL)
645endif()
646
647if(BUILD_GLES2)
648 add_definitions(-DBUILD_GLES2)
649endif()
650
651if(DISABLE_FRONTENDS)
652 set(BUILD_SDL OFF)
653 set(BUILD_QT OFF)
654endif()
655
656if(BUILD_LIBRETRO)
657 file(GLOB RETRO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/libretro/*.c)
658 add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
659 set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5;DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=2")
660 target_link_libraries(${BINARY_NAME}_libretro ${OS_LIB})
661 install(TARGETS ${BINARY_NAME}_libretro LIBRARY DESTINATION ${LIBRETRO_LIBDIR} COMPONENT ${BINARY_NAME}_libretro NAMELINK_SKIP)
662endif()
663
664if(BUILD_OPENEMU)
665 find_library(FOUNDATION Foundation)
666 find_library(OPENEMUBASE OpenEmuBase)
667 file(GLOB OE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/*.m)
668 add_library(${BINARY_NAME}-openemu MODULE ${CORE_SRC} ${OE_SRC})
669 set_target_properties(${BINARY_NAME}-openemu PROPERTIES
670 MACOSX_BUNDLE_INFO_PLIST ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/Info.plist.in
671 BUNDLE TRUE
672 BUNDLE_EXTENSION oecoreplugin
673 OUTPUT_NAME ${PROJECT_NAME}
674 COMPILE_DEFINITIONS "DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=1")
675 target_link_libraries(${BINARY_NAME}-openemu ${OS_LIB} ${FOUNDATION} ${OPENEMUBASE})
676 install(TARGETS ${BINARY_NAME}-openemu LIBRARY DESTINATION ${OE_LIBDIR} COMPONENT ${BINARY_NAME}.oecoreplugin NAMELINK_SKIP)
677endif()
678
679if(BUILD_SDL)
680 add_definitions(-DBUILD_SDL)
681 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/sdl ${CMAKE_CURRENT_BINARY_DIR}/sdl)
682endif()
683
684if(BUILD_QT)
685 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/qt ${CMAKE_CURRENT_BINARY_DIR}/qt)
686endif()
687
688if(BUILD_PERF)
689 set(PERF_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/perf-main.c ${CLI_SRC})
690 if(UNIX AND NOT APPLE)
691 list(APPEND PERF_LIB rt)
692 endif()
693
694 add_executable(${BINARY_NAME}-perf ${PERF_SRC})
695 target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB} ${OS_LIB})
696 set_target_properties(${BINARY_NAME}-perf PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
697 install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
698 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
699endif()
700
701if(BUILD_TEST)
702 add_executable(${BINARY_NAME}-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/fuzz-main.c)
703 target_link_libraries(${BINARY_NAME}-fuzz ${BINARY_NAME})
704 set_target_properties(${BINARY_NAME}-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
705 install(TARGETS ${BINARY_NAME}-fuzz DESTINATION bin COMPONENT ${BINARY_NAME}-test)
706endif()
707
708if(NOT USE_CMOCKA)
709 set(BUILD_SUITE OFF)
710endif()
711if(USE_CMOCKA)
712 enable_testing()
713 include_directories(AFTER ${CMOCKA_INCLUDE_DIRS})
714 link_directories(${CMOCKA_LIBRARY_DIRS})
715 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/suite ${CMAKE_CURRENT_BINARY_DIR}/suite)
716endif()
717
718if(BUILD_EXAMPLE)
719 add_executable(${BINARY_NAME}-example-server ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/server.c)
720 target_link_libraries(${BINARY_NAME}-example-server ${BINARY_NAME})
721 set_target_properties(${BINARY_NAME}-example-server PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
722
723 if(BUILD_SDL)
724 add_executable(${BINARY_NAME}-example-client ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/client.c)
725 target_link_libraries(${BINARY_NAME}-example-client ${BINARY_NAME} ${SDL_LIBRARY} ${SDLMAIN_LIBRARY} ${OPENGL_LIBRARY} ${OPENGLES2_LIBRARY})
726 set_target_properties(${BINARY_NAME}-example-client PROPERTIES
727 COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}"
728 INCLUDE_DIRECTORIES "${SDL_INCLUDE_DIR};${CMAKE_CURRENT_SOURCE_DIR}/src")
729 endif()
730endif()
731
732# Packaging
733set(CPACK_PACKAGE_VERSION ${VERSION_STRING})
734set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
735set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
736set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
737set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
738set(CPACK_RESOURCE_FILE_README ${CMAKE_CURRENT_SOURCE_DIR}/README.md)
739
740set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
741set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
742set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
743set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README.md")
744set(CPACK_DEBIAN_PACKAGE_SECTION "games")
745
746SET(CPACK_DEB_COMPONENT_INSTALL ON)
747
748set(CPACK_STRIP_FILES ${BINARY_NAME})
749
750install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/README.md ${CMAKE_CURRENT_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
751
752include(CPack)
753
754# Summaries
755set(SUMMARY_GL_LIST)
756if(USE_EPOXY)
757 set(SUMMARY_GL_LIST "libepoxy")
758else()
759 if(BUILD_GL)
760 list(APPEND SUMMARY_GL_LIST "OpenGL")
761 endif()
762 if(BUILD_GLES2)
763 list(APPEND SUMMARY_GL_LIST "OpenGL|ES 2")
764 endif()
765endif()
766if(NOT SUMMARY_GL_LIST)
767 set(SUMMARY_GL OFF)
768else()
769 string(REPLACE ";" ", " SUMMARY_GL "${SUMMARY_GL_LIST}")
770endif()
771if(USE_LIBZIP)
772 set(SUMMARY_ZIP libzip)
773elseif(USE_MINIZIP)
774 set(SUMMARY_ZIP "minizip (external)")
775elseif(USE_ZLIB)
776 set(SUMMARY_ZIP "minizip (included)")
777else()
778 set(SUMMARY_ZIP OFF)
779endif()
780
781if(NOT QUIET)
782 message(STATUS "Platforms:")
783 message(STATUS " Game Boy Advance: ${M_CORE_GBA}")
784 message(STATUS " Game Boy: ${M_CORE_GB}")
785 message(STATUS "Features:")
786 message(STATUS " CLI debugger: ${USE_CLI_DEBUGGER}")
787 message(STATUS " GDB stub: ${USE_GDB_STUB}")
788 message(STATUS " Video recording: ${USE_FFMPEG}")
789 message(STATUS " GIF recording: ${USE_MAGICK}")
790 message(STATUS " Screenshot/advanced savestate support: ${USE_PNG}")
791 message(STATUS " ZIP support: ${SUMMARY_ZIP}")
792 message(STATUS " 7-Zip support: ${USE_LZMA}")
793 message(STATUS " OpenGL support: ${SUMMARY_GL}")
794 message(STATUS "Frontends:")
795 message(STATUS " Qt: ${BUILD_QT}")
796 message(STATUS " SDL (${SDL_VERSION}): ${BUILD_SDL}")
797 message(STATUS " Profiling: ${BUILD_PERF}")
798 message(STATUS " Test harness: ${BUILD_TEST}")
799 message(STATUS " Test suite: ${BUILD_SUITE}")
800 message(STATUS " Examples: ${BUILD_EXAMPLE}")
801 message(STATUS "Cores:")
802 message(STATUS " Libretro core: ${BUILD_LIBRETRO}")
803 if(APPLE)
804 message(STATUS " OpenEmu core: ${BUILD_OPENEMU}")
805 endif()
806 message(STATUS "Libraries:")
807 message(STATUS " Static: ${BUILD_STATIC}")
808 message(STATUS " Shared: ${BUILD_SHARED}")
809endif()