1cmake_minimum_required(VERSION 2.6)
  2project(mGBA C)
  3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
  4set(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -g -Wall -Wextra -std=gnu99")
  5set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -O3 -Wall -Wextra -std=gnu99")
  6set(USE_CLI_DEBUGGER ON CACHE BOOL "Whether or not to enable the CLI-mode ARM debugger")
  7set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
  8set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
  9set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
 10set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable ZIP support")
 11set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
 12set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
 13file(GLOB ARM_SRC ${CMAKE_SOURCE_DIR}/src/arm/*.c)
 14file(GLOB GBA_SRC ${CMAKE_SOURCE_DIR}/src/gba/*.c)
 15file(GLOB UTIL_SRC ${CMAKE_SOURCE_DIR}/src/util/*.[cS])
 16file(GLOB VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/*.c)
 17file(GLOB RENDERER_SRC ${CMAKE_SOURCE_DIR}/src/gba/renderers/video-software.c)
 18list(APPEND UTIL_SRC ${CMAKE_SOURCE_DIR}/src/platform/commandline.c)
 19source_group("ARM core" FILES ${ARM_SRC})
 20source_group("GBA board" FILES ${GBA_SRC} ${RENDERER_SRC})
 21source_group("Utilities" FILES ${UTIL_SRC} ${VFS_SRC}})
 22include_directories(${CMAKE_SOURCE_DIR}/src/arm)
 23include_directories(${CMAKE_SOURCE_DIR}/src/gba)
 24include_directories(${CMAKE_SOURCE_DIR}/src)
 25
 26include(GNUInstallDirs)
 27
 28# Function definitions
 29include(FindPkgConfig)
 30function(find_feature FEATURE_NAME FEATURE_REQUIRES)
 31	if (NOT ${FEATURE_NAME})
 32		return()
 33	endif()
 34	foreach(REQUIRE ${FEATURE_REQUIRES})
 35		find_package(${REQUIRE} QUIET)
 36		pkg_search_module(${REQUIRE} ${REQUIRE})
 37		if (NOT ${REQUIRE}_FOUND)
 38			message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
 39			set(${FEATURE_NAME} OFF PARENT_SCOPE)
 40			return()
 41		endif()
 42		string(TOUPPER ${REQUIRE} UREQUIRE)
 43		set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
 44		set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
 45		set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
 46		set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
 47		set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
 48		set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
 49	endforeach()
 50endfunction()
 51
 52# Version information
 53set(LIB_VERSION_MAJOR 0)
 54set(LIB_VERSION_MINOR 1)
 55set(LIB_VERSION_PATCH 0)
 56set(LIB_VERSION_ABI 0.1)
 57set(LIB_VERSION_STRING ${LIB_VERSION_MAJOR}.${LIB_VERSION_MINOR}.${LIB_VERSION_PATCH})
 58
 59# Advanced settings
 60set(BUILD_PGO CACHE BOOL "Build with profiling-guided optimization")
 61set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
 62set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
 63mark_as_advanced(BUILD_PGO PGO_STAGE_2 PGO_DIR)
 64set(PGO_PRE_FLAGS "-pg -fprofile-generate=${PGO_DIR}")
 65set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR}")
 66
 67if(BUILD_PGO AND NOT PGO_STAGE_2)
 68	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
 69	set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
 70	set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
 71elseif(BUILD_PGO AND PGO_STAGE_2)
 72	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
 73	set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
 74	set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
 75endif()
 76
 77add_definitions(-DBINARY_NAME="${BINARY_NAME}" -DPROJECT_NAME="${PROJECT_NAME}")
 78
 79# Feature dependencies
 80find_feature(USE_CLI_DEBUGGER "libedit")
 81find_feature(USE_FFMPEG "libavcodec;libavformat;libavutil")
 82find_feature(USE_PNG "PNG;ZLIB")
 83find_feature(USE_LIBZIP "libzip")
 84
 85# Platform support
 86if(WIN32)
 87	add_definitions(-D_WIN32_WINNT=0x0600)
 88	list(APPEND OS_LIB Ws2_32)
 89	file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/windows/*.c)
 90	source_group("Windows-specific code" FILES ${OS_SRC})
 91else()
 92	add_definitions(-DUSE_PTHREADS)
 93	list(APPEND OS_LIB pthread)
 94	file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/posix/*.c)
 95	source_group("POSIX-specific code" FILES ${OS_SRC})
 96endif()
 97
 98if(BUILD_BBB OR BUILD_RASPI)
 99	enable_language(ASM)
100	if(NOT BUILD_EGL)
101		add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
102	endif()
103endif()
104
105# Features
106set(DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/debugger.c ${CMAKE_SOURCE_DIR}/src/debugger/memory-debugger.c)
107
108if(USE_CLI_DEBUGGER)
109	add_definitions(-DUSE_CLI_DEBUGGER)
110	list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/cli-debugger.c)
111	list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/parser.c)
112	include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
113	link_directories(${LIBEDIT_LIBRARY_DIRS})
114	set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
115else()
116	set(DEBUGGER_LIB "")
117endif()
118
119if(USE_GDB_STUB)
120	add_definitions(-DUSE_GDB_STUB)
121	list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/gdb-stub.c)
122endif()
123source_group("ARM debugger" FILES ${DEBUGGER_SRC})
124
125if(USE_FFMPEG)
126	add_definitions(-DUSE_FFMPEG)
127	include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS})
128	link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS})
129	list(APPEND UTIL_SRC "${CMAKE_SOURCE_DIR}/src/platform/ffmpeg/ffmpeg-encoder.c")
130	list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVUTIL_LIBRARIES})
131endif()
132
133if(USE_PNG)
134	add_definitions(-DUSE_PNG)
135	include_directories(AFTER ${PNG_INCLUDE_DIRS})
136	list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
137endif()
138
139if(USE_LIBZIP)
140	include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
141	link_directories(${LIBZIP_LIBRARY_DIRS})
142	list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
143	add_definitions(-DENABLE_LIBZIP)
144endif()
145
146# Binaries
147add_library(${BINARY_NAME} SHARED ${ARM_SRC} ${GBA_SRC} ${DEBUGGER_SRC} ${RENDERER_SRC} ${UTIL_SRC} ${VFS_SRC} ${OS_SRC})
148target_link_libraries(${BINARY_NAME} m ${DEBUGGER_LIB} ${OS_LIB} ${DEPENDENCY_LIB})
149install(TARGETS ${BINARY_NAME} DESTINATION lib)
150set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI})
151
152if(BUILD_SDL)
153	add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/sdl ${CMAKE_BINARY_DIR}/sdl)
154endif()
155
156if(BUILD_PERF)
157	set(PERF_SRC ${CMAKE_SOURCE_DIR}/src/platform/perf-main.c)
158	if(UNIX AND NOT APPLE)
159		list(APPEND PERF_LIB rt)
160	endif()
161
162	add_executable(${BINARY_NAME}-perf ${PERF_SRC})
163	target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB})
164	install(TARGETS ${BINARY_NAME}-perf DESTINATION bin)
165	install(FILES ${CMAKE_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}")
166endif()
167
168# Summaries
169message(STATUS "Feature summary:")
170message(STATUS "	CLI debugger: ${USE_CLI_DEBUGGER}")
171message(STATUS "	GDB stub: ${USE_GDB_STUB}")
172message(STATUS "	Video recording: ${USE_FFMPEG}")
173message(STATUS "	Screenshot/advanced savestate support: ${USE_PNG}")
174message(STATUS "	ZIP support: ${USE_LIBZIP}")
175message(STATUS "Frontend summary:")
176message(STATUS "	SDL (${SDL_VERSION}): ${BUILD_SDL}")
177message(STATUS "	Profiling: ${BUILD_PERF}")