CMakeLists.txt (view raw)
1cmake_minimum_required(VERSION 2.6)
2project(mGBA C)
3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
4if(NOT MSVC)
5 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -std=c99")
6else()
7 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_CRT_SECURE_NO_WARNINGS /wd4003 /wd4244 /wd4146")
8endif()
9set(USE_CLI_DEBUGGER ON CACHE BOOL "Whether or not to enable the CLI-mode ARM debugger")
10set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
11set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
12set(USE_ZLIB ON CACHE BOOL "Whether or not to enable zlib support")
13set(USE_MINIZIP ON CACHE BOOL "Whether or not to enable external minizip support")
14set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
15set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable LIBZIP support")
16set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
17set(M_CORE_GBA ON CACHE BOOL "Build Game Boy Advance core")
18set(M_CORE_GB ON CACHE BOOL "Build Game Boy core")
19set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
20set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
21set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
22set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
23if(APPLE)
24 set(BUILD_OPENEMU OFF CACHE BOOL "Build OpenEmu core")
25endif()
26set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
27set(BUILD_TEST OFF CACHE BOOL "Build testing harness")
28set(BUILD_EXAMPLE OFF CACHE BOOL "Build example frontends")
29set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
30set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
31set(SKIP_LIBRARY OFF CACHE BOOL "Skip building the library (useful for only building libretro or OpenEmu cores)")
32set(BUILD_GL ON CACHE STRING "Build with OpenGL")
33set(BUILD_GLES2 OFF CACHE STRING "Build with OpenGL|ES 2")
34set(USE_EPOXY ON CACHE STRING "Build with libepoxy")
35set(DISABLE_DEPS OFF CACHE BOOL "Build without dependencies")
36file(GLOB ARM_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/*.c)
37file(GLOB LR35902_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/*.c)
38file(GLOB GBA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/*.c)
39file(GLOB GB_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/*.c)
40file(GLOB GBA_CHEATS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/cheats/*.c)
41file(GLOB GBA_RR_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/rr/*.c)
42file(GLOB GBA_EXTRA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/extra/*.c)
43file(GLOB UTIL_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/*.[cSs] ${CMAKE_CURRENT_SOURCE_DIR}/src/core/*.c)
44file(GLOB GUI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/gui/*.c ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/gui/*.c)
45file(GLOB GBA_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/renderers/*.c)
46file(GLOB SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/sio/lockstep.c)
47file(GLOB GB_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/renderers/*.c)
48file(GLOB THIRD_PARTY_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/inih/*.c)
49set(CLI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/commandline.c)
50set(CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-mem.c)
51set(VFS_SRC)
52source_group("ARM core" FILES ${ARM_SRC})
53source_group("LR35902 core" FILES ${LR35902_SRC})
54source_group("GBA board" FILES ${GBA_SRC} ${GBA_RENDERER_SRC} ${SIO_SRC})
55source_group("GBA extra" FILES ${GBA_CHEATS_SRC} ${GBA_EXTRA_SRC} ${GBA_RR_SRC})
56source_group("GB board" FILES ${GB_SRC})
57source_group("Utilities" FILES ${UTIL_SRC})
58include_directories(BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/src)
59
60if(NOT CMAKE_BUILD_TYPE)
61 set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
62endif()
63
64set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${LIBDIR}")
65
66include(GNUInstallDirs)
67
68if (NOT DEFINED LIBDIR)
69 set(LIBDIR "lib")
70endif()
71
72if (NOT DEFINED MANDIR)
73 set(MANDIR ${CMAKE_INSTALL_MANDIR})
74endif()
75
76# Function definitions
77include(FindPkgConfig)
78function(find_feature FEATURE_NAME FEATURE_REQUIRES)
79 if (NOT ${FEATURE_NAME})
80 return()
81 endif()
82 if (DISABLE_DEPS)
83 set(${FEATURE_NAME} OFF PARENT_SCOPE)
84 return()
85 endif()
86 foreach(REQUIRE ${FEATURE_REQUIRES})
87 if(NOT ${REQUIRE}_FOUND)
88 find_package(${REQUIRE} QUIET)
89 if(NOT ${REQUIRE}_FOUND)
90 pkg_search_module(${REQUIRE} ${REQUIRE})
91 if (NOT ${REQUIRE}_FOUND)
92 message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
93 set(${FEATURE_NAME} OFF PARENT_SCOPE)
94 return()
95 endif()
96 endif()
97 endif()
98 string(TOUPPER ${REQUIRE} UREQUIRE)
99 set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
100 set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
101 set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
102 set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
103 set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
104 set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
105 endforeach()
106endfunction()
107
108# Version information
109add_custom_target(version-info ALL ${CMAKE_COMMAND} -E touch ${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in
110 COMMAND ${CMAKE_COMMAND}
111 -DBINARY_NAME=${BINARY_NAME}
112 -DCONFIG_FILE=${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in
113 -DOUT_FILE=${CMAKE_CURRENT_BINARY_DIR}/version.c
114 -P ${CMAKE_CURRENT_SOURCE_DIR}/version.cmake
115 WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
116
117include(${CMAKE_CURRENT_SOURCE_DIR}/version.cmake)
118configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in ${CMAKE_CURRENT_BINARY_DIR}/version.c)
119list(APPEND UTIL_SRC ${CMAKE_CURRENT_BINARY_DIR}/version.c)
120source_group("Generated sources" FILES ${CMAKE_CURRENT_BINARY_DIR}/version.c)
121
122# Advanced settings
123set(BUILD_LTO ON CACHE BOOL "Build with link-time optimization")
124set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
125set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
126set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
127mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
128set(PGO_PRE_FLAGS "-fprofile-generate=${PGO_DIR} -fprofile-arcs")
129set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
130
131if(BUILD_PGO AND NOT PGO_STAGE_2)
132 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
133 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
134 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
135elseif(BUILD_PGO AND PGO_STAGE_2)
136 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
137 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
138 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
139endif()
140
141# Platform support
142if(WIN32)
143 set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
144 add_definitions(-D_WIN32_WINNT=0x0600)
145 list(APPEND OS_LIB ws2_32 shlwapi)
146 list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/vfs-w32.c)
147 file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/*.c)
148 source_group("Windows-specific code" FILES ${OS_SRC})
149 if(MSVC)
150 add_definitions(-DNOMINMAX -DWIN32_LEAN_AND_MEAN)
151 endif()
152elseif(UNIX)
153 add_definitions(-DUSE_PTHREADS)
154
155 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
156 add_definitions(-D_GNU_SOURCE)
157 endif()
158 if(NOT APPLE AND NOT HAIKU)
159 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
160 endif()
161
162 list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
163 file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/posix/*.c)
164 source_group("POSIX-specific code" FILES ${OS_SRC})
165endif()
166
167if(APPLE)
168 add_definitions(-D_DARWIN_C_SOURCE)
169 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
170endif()
171
172if(NOT HAIKU AND NOT MSVC AND NOT PSP2)
173 set(M_LIBRARY m)
174endif()
175list(APPEND OS_LIB ${M_LIBRARY})
176
177if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
178 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
179 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
180endif()
181
182if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
183 if(NOT BUILD_EGL)
184 add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
185 endif()
186endif()
187
188if(BUILD_RASPI)
189 set(BUILD_GL OFF CACHE BOOL "OpenGL not supported" FORCE)
190endif()
191
192if(BUILD_PANDORA)
193 add_definitions(-DBUILD_PANDORA)
194endif()
195
196if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
197 enable_language(ASM)
198endif()
199
200if(PSP2 OR WII)
201 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-format")
202endif()
203
204if(DEFINED 3DS OR DEFINED PSP2 OR DEFINED WII)
205 set(USE_GDB_STUB OFF)
206endif()
207
208if(WII)
209 add_definitions(-U__STRICT_ANSI__)
210endif()
211
212include(CheckFunctionExists)
213check_function_exists(strdup HAVE_STRDUP)
214check_function_exists(strndup HAVE_STRNDUP)
215check_function_exists(localtime_r HAVE_LOCALTIME_R)
216if(NOT CMAKE_SYSTEM_NAME STREQUAL "Generic")
217 check_function_exists(snprintf_l HAVE_SNPRINTF_L)
218 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
219 # The strtof_l on Linux not actually exposed nor actually strtof_l
220 set(HAVE_STRTOF_L OFF)
221 else()
222 check_function_exists(strtof_l HAVE_STRTOF_L)
223 endif()
224 check_function_exists(newlocale HAVE_NEWLOCALE)
225 check_function_exists(freelocale HAVE_FREELOCALE)
226 check_function_exists(uselocale HAVE_USELOCALE)
227 check_function_exists(setlocale HAVE_SETLOCALE)
228else()
229 if(NOT DEFINED 3DS AND NOT DEFINED PSP2 AND NOT DEFINED WII)
230 set(DISABLE_DEPS ON CACHE BOOL "This platform cannot build with dependencies" FORCE)
231 endif()
232 set(DISABLE_FRONTENDS ON)
233 set(MINIMAL_CORE ON)
234endif()
235
236check_function_exists(chmod HAVE_CHMOD)
237check_function_exists(umask HAVE_UMASK)
238
239set(FUNCTION_DEFINES)
240
241if(HAVE_STRDUP)
242 list(APPEND FUNCTION_DEFINES HAVE_STRDUP)
243endif()
244
245if(HAVE_STRNDUP)
246 list(APPEND FUNCTION_DEFINES HAVE_STRNDUP)
247endif()
248
249if(HAVE_LOCALTIME_R)
250 list(APPEND FUNCTION_DEFINES HAVE_LOCALTIME_R)
251endif()
252
253if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE)
254 list(APPEND FUNCTION_DEFINES HAVE_LOCALE)
255 if (HAVE_STRTOF_L)
256 list(APPEND FUNCTION_DEFINES HAVE_STRTOF_L)
257 endif()
258 if (HAVE_SNPRINTF_L)
259 list(APPEND FUNCTION_DEFINES HAVE_SNPRINTF_L)
260 endif()
261endif()
262
263if(HAVE_SETLOCALE)
264 list(APPEND FUNCTION_DEFINES HAVE_SETLOCALE)
265endif()
266
267if(HAVE_CHMOD)
268 list(APPEND FUNCTION_DEFINES HAVE_CHMOD)
269endif()
270
271if(HAVE_UMASK)
272 list(APPEND FUNCTION_DEFINES HAVE_UMASK)
273endif()
274
275# Feature dependencies
276set(FEATURES)
277if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
278 set(LIBEDIT_LIBRARIES -ledit)
279 if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
280 list(APPEND LIBEDIT_LIBRARIES -ltermcap)
281 endif()
282else()
283 find_feature(USE_CLI_DEBUGGER "libedit")
284endif()
285if(BUILD_GL)
286 find_package(OpenGL QUIET)
287 if(NOT OPENGL_FOUND)
288 set(BUILD_GL OFF CACHE BOOL "OpenGL not found" FORCE)
289 endif()
290endif()
291if(NOT BUILD_GL)
292 set(OPENGLE_LIBRARY "" CACHE PATH "" FORCE)
293endif()
294if(BUILD_GLES2 AND NOT BUILD_RASPI)
295 find_path(OPENGLES2_INCLUDE_DIR NAMES GLES2/gl2.h)
296 find_library(OPENGLES2_LIBRARY NAMES GLESv2 GLESv2_CM)
297 if(NOT OPENGLES2_INCLUDE_DIR OR NOT OPENGLES2_LIBRARY)
298 set(BUILD_GLES2 OFF CACHE BOOL "OpenGL|ES 2 not found" FORCE)
299 endif()
300endif()
301if(NOT BUILD_GLES2)
302 set(OPENGLES2_LIBRARY "" CACHE PATH "" FORCE)
303endif()
304set(WANT_ZLIB ${USE_ZLIB})
305set(WANT_PNG ${USE_PNG})
306set(WANT_LIBZIP ${USE_LIBZIP})
307
308find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
309find_feature(USE_ZLIB "ZLIB")
310find_feature(USE_MINIZIP "minizip")
311find_feature(USE_PNG "PNG")
312find_feature(USE_LIBZIP "libzip")
313find_feature(USE_MAGICK "MagickWand")
314find_feature(USE_EPOXY "epoxy")
315
316# Features
317set(DEBUGGER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/debugger.c)
318set(FEATURE_SRC)
319set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
320
321if(DISABLE_DEPS)
322 set(USE_GDB_STUB OFF)
323endif()
324
325if(USE_CLI_DEBUGGER)
326 list(APPEND FEATURES CLI_DEBUGGER)
327 list(APPEND DEBUGGER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/cli-debugger.c)
328 list(APPEND DEBUGGER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/parser.c)
329 list(APPEND DEBUGGER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/extra/cli.c)
330 include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
331 link_directories(${LIBEDIT_LIBRARY_DIRS})
332 set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
333 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
334else()
335 set(DEBUGGER_LIB "")
336endif()
337
338if(USE_GDB_STUB)
339 list(APPEND FEATURES GDB_STUB)
340 list(APPEND DEBUGGER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/gdb-stub.c)
341endif()
342source_group("ARM debugger" FILES ${DEBUGGER_SRC})
343
344if(USE_FFMPEG)
345 list(APPEND FEATURES FFMPEG)
346 pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
347 if(NOT LIBSWRESAMPLE_FOUND)
348 list(APPEND FEATURES LIBAV)
349 endif()
350 include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
351 link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
352 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/ffmpeg/ffmpeg-encoder.c")
353 string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
354 string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
355 string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
356 string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
357 string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
358 list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
359 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR}|libavcodec-extra-${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
360 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavformat${LIBAVFORMAT_VERSION_MAJOR}|libavformat-ffmpeg${LIBAVFORMAT_VERSION_MAJOR}")
361 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavresample${LIBAVRESAMPLE_VERSION_MAJOR}|libavresample-ffmpeg${LIBAVRESAMPLE_VERSION_MAJOR}")
362 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavutil${LIBAVUTIL_VERSION_MAJOR}|libavutil-ffmpeg${LIBAVUTIL_VERSION_MAJOR}")
363 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libswscale${LIBSWSCALE_VERSION_MAJOR}|libswscale-ffmpeg${LIBSWSCALE_VERSION_MAJOR}")
364 set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
365 if(APPLE)
366 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
367 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
368 endif()
369endif()
370
371list(APPEND THIRD_PARTY_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
372
373if(USE_MAGICK)
374 list(APPEND FEATURES MAGICK)
375 include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
376 link_directories(${MAGICKWAND_LIBRARY_DIRS})
377 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/imagemagick/imagemagick-gif-encoder.c")
378 list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
379 string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
380 if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
381 set(MAGICKWAND_DEB_VERSION "5")
382 else()
383 set(MAGICKWAND_DEB_VERSION "-6.q16-2")
384 endif()
385 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
386endif()
387
388if(WANT_ZLIB AND NOT USE_ZLIB)
389 set(SKIP_INSTALL_ALL ON)
390 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib zlib)
391 set_property(TARGET zlibstatic PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/zlib;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib)
392 set_property(TARGET zlib PROPERTY EXCLUDE_FROM_ALL ON)
393 set_property(TARGET example PROPERTY EXCLUDE_FROM_ALL ON)
394 set_property(TARGET minigzip PROPERTY EXCLUDE_FROM_ALL ON)
395 set(ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
396 set(ZLIB_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
397 set(ZLIB_LIBRARY zlibstatic)
398 list(APPEND DEPENDENCY_LIB zlibstatic)
399 set(USE_ZLIB ON)
400endif()
401
402if(USE_ZLIB)
403 list(APPEND FEATURES ZLIB)
404 include_directories(AFTER ${ZLIB_INCLUDE_DIRS})
405 list(APPEND DEPENDENCY_LIB ${ZLIB_LIBRARIES})
406 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},zlib1g")
407endif()
408
409if(WANT_PNG AND USE_ZLIB AND NOT USE_PNG)
410 set(PNG_STATIC ON CACHE BOOL "" FORCE)
411 set(PNG_SHARED OFF CACHE BOOL "" FORCE)
412 set(PNG_TESTS OFF CACHE BOOL "" FORCE)
413 set(SKIP_INSTALL_ALL ON)
414 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng libpng)
415 set_property(TARGET png16_static PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/libpng;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng;${ZLIB_INCLUDE_DIRS})
416 set(PNG_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng ${CMAKE_CURRENT_BINARY_DIR}/libpng)
417 list(APPEND DEPENDENCY_LIB png16_static)
418 set(USE_PNG ON)
419endif()
420
421if(USE_PNG)
422 list(APPEND FEATURES PNG)
423 include_directories(AFTER ${PNG_INCLUDE_DIRS})
424 list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
425 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng12-0")
426endif()
427
428if(USE_LIBZIP)
429 include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
430 link_directories(${LIBZIP_LIBRARY_DIRS})
431 list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
432 list(APPEND FEATURES LIBZIP)
433 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
434 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
435elseif(USE_MINIZIP)
436 include_directories(AFTER ${MINIZIP_INCLUDE_DIRS})
437 link_directories(${MINIZIP_LIBRARY_DIRS})
438 list(APPEND DEPENDENCY_LIB ${MINIZIP_LIBRARIES})
439 list(APPEND FEATURES MINIZIP)
440 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
441 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libminizip1")
442elseif(USE_ZLIB)
443 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c
444 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
445 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c)
446endif()
447
448if (USE_LZMA)
449 include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/third-party/lzma)
450 add_definitions(-D_7ZIP_PPMD_SUPPPORT)
451 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-lzma.c)
452 set(LZMA_SRC
453 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
454 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
455 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
456 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
457 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
458 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
459 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zDec.c
460 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
461 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Delta.c
462 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
463 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
464 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra.c
465 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra86.c
466 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/BraIA64.c
467 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
468 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
469 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
470 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zFile.c
471 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
472 list(APPEND VFS_SRC ${LZMA_SRC})
473 list(APPEND FEATURES LZMA)
474endif()
475
476if(USE_EPOXY)
477 add_definitions(-DBUILD_GL -DBUILD_GLES2)
478 list(APPEND FEATURES EPOXY)
479 include_directories(AFTER ${EPOXY_INCLUDE_DIRS})
480 set(OPENGLES2_LIBRARY ${EPOXY_LIBRARIES})
481 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libepoxy0")
482endif()
483
484
485set(FEATURE_DEFINES)
486foreach(FEATURE IN LISTS FEATURES)
487 list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
488endforeach()
489
490set(CORE_SRC)
491if(M_CORE_GB)
492 add_definitions(-DM_CORE_GB)
493 list(APPEND CORE_SRC
494 ${LR35902_SRC}
495 ${GB_SRC}
496 ${GB_RENDERER_SRC})
497endif()
498
499if(M_CORE_GBA)
500 add_definitions(-DM_CORE_GBA)
501 list(APPEND CORE_SRC
502 ${ARM_SRC}
503 ${GBA_SRC}
504 ${GBA_CHEATS_SRC}
505 ${DEBUGGER_SRC}
506 ${GBA_RENDERER_SRC})
507 if(NOT M_CORE_GB)
508 list(APPEND CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/audio.c)
509 endif()
510endif()
511
512source_group("Virtual files" FILES ${CORE_VFS_SRC} ${VFS_SRC})
513source_group("Extra features" FILES ${FEATURE_SRC})
514source_group("Third-party code" FILES ${THIRD_PARTY_SRC})
515
516# Platform binaries
517if(3DS)
518 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/3ds ${CMAKE_CURRENT_BINARY_DIR}/3ds)
519endif()
520
521if(WII)
522 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/wii ${CMAKE_CURRENT_BINARY_DIR}/wii)
523endif()
524
525if(PSP2)
526 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/psp2 ${CMAKE_CURRENT_BINARY_DIR}/psp2)
527endif()
528
529# Binaries
530list(APPEND CORE_SRC
531 ${UTIL_SRC}
532 ${CORE_VFS_SRC}
533 ${OS_SRC}
534 ${THIRD_PARTY_SRC})
535
536set(SRC ${CORE_SRC} ${VFS_SRC})
537if(NOT MINIMAL_CORE)
538 if(M_CORE_GBA)
539 list(APPEND SRC
540 ${GBA_RR_SRC}
541 ${GBA_EXTRA_SRC}
542 ${SIO_SRC})
543 endif()
544 list(APPEND SRC
545 ${FEATURE_SRC}
546 ${CLI_SRC})
547endif()
548
549if(NOT SKIP_LIBRARY)
550 if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
551 set(BUILD_SHARED ON)
552 endif()
553
554 if(BUILD_SHARED)
555 add_library(${BINARY_NAME} SHARED ${SRC} ${VFS_SRC})
556 if(BUILD_STATIC)
557 add_library(${BINARY_NAME}-static STATIC ${SRC})
558 set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
559 install(TARGETS ${BINARY_NAME}-static DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
560 add_dependencies(${BINARY_NAME}-static version-info)
561 endif()
562 else()
563 add_library(${BINARY_NAME} STATIC ${SRC})
564 endif()
565
566 add_dependencies(${BINARY_NAME} version-info)
567 set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
568
569 target_link_libraries(${BINARY_NAME} ${DEBUGGER_LIB} ${DEPENDENCY_LIB} ${OS_LIB})
570 install(TARGETS ${BINARY_NAME} LIBRARY DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME} NAMELINK_SKIP ARCHIVE DESTINATION ${LIBDIR} RUNTIME DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
571 if(UNIX AND NOT APPLE)
572 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-16.png DESTINATION share/icons/hicolor/16x16/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
573 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-24.png DESTINATION share/icons/hicolor/24x24/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
574 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-32.png DESTINATION share/icons/hicolor/32x32/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
575 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-48.png DESTINATION share/icons/hicolor/48x48/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
576 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-64.png DESTINATION share/icons/hicolor/64x64/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
577 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-96.png DESTINATION share/icons/hicolor/96x96/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
578 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-128.png DESTINATION share/icons/hicolor/128x128/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
579 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-256.png DESTINATION share/icons/hicolor/256x256/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
580 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-512.png DESTINATION share/icons/hicolor/512x512/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
581 endif()
582else()
583 set(BUILD_SHARED OFF)
584 set(BUILD_STATIC OFF)
585 find_library(${BINARY_NAME} ${BINARY_NAME})
586 if(NOT ${BINARY_NAME}_FOUND)
587 set(DISABLE_FRONTENDS ON)
588 set(BUILD_PERF OFF)
589 set(BUILD_TEST OFF)
590 endif()
591endif()
592
593if(BUILD_GL)
594 add_definitions(-DBUILD_GL)
595endif()
596
597if(BUILD_GLES2)
598 add_definitions(-DBUILD_GLES2)
599endif()
600
601if(DISABLE_FRONTENDS)
602 set(BUILD_SDL OFF)
603 set(BUILD_QT OFF)
604endif()
605
606if(BUILD_LIBRETRO)
607 file(GLOB RETRO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/libretro/*.c)
608 add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
609 set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5;DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=2")
610 target_link_libraries(${BINARY_NAME}_libretro ${OS_LIB})
611 install(TARGETS ${BINARY_NAME}_libretro LIBRARY DESTINATION ${LIBDIR} COMPONENT ${BINARY_NAME}_libretro NAMELINK_SKIP)
612endif()
613
614if(BUILD_OPENEMU)
615 find_library(FOUNDATION Foundation)
616 find_library(OPENEMUBASE OpenEmuBase)
617 file(GLOB OE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/*.m)
618 add_library(${BINARY_NAME}-openemu MODULE ${CORE_SRC} ${OE_SRC})
619 set_target_properties(${BINARY_NAME}-openemu PROPERTIES
620 MACOSX_BUNDLE_INFO_PLIST ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/Info.plist.in
621 BUNDLE TRUE
622 BUNDLE_EXTENSION oecoreplugin
623 OUTPUT_NAME ${PROJECT_NAME}
624 COMPILE_DEFINITIONS "DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=1")
625 target_link_libraries(${BINARY_NAME}-openemu ${OS_LIB} ${FOUNDATION} ${OPENEMUBASE})
626 install(TARGETS ${BINARY_NAME}-openemu LIBRARY DESTINATION ${LIBDIR} COMPONENT ${BINARY_NAME}.oecoreplugin NAMELINK_SKIP)
627endif()
628
629if(BUILD_SDL)
630 add_definitions(-DBUILD_SDL)
631 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/sdl ${CMAKE_CURRENT_BINARY_DIR}/sdl)
632endif()
633
634if(BUILD_QT)
635 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/qt ${CMAKE_CURRENT_BINARY_DIR}/qt)
636endif()
637
638if(BUILD_PERF)
639 set(PERF_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/perf-main.c ${CLI_SRC})
640 if(UNIX AND NOT APPLE)
641 list(APPEND PERF_LIB rt)
642 endif()
643
644 add_executable(${BINARY_NAME}-perf ${PERF_SRC})
645 target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB} ${OS_LIB})
646 set_target_properties(${BINARY_NAME}-perf PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
647 install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
648 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
649endif()
650
651if(BUILD_TEST)
652 add_executable(${BINARY_NAME}-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/fuzz-main.c)
653 target_link_libraries(${BINARY_NAME}-fuzz ${BINARY_NAME})
654 set_target_properties(${BINARY_NAME}-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
655 install(TARGETS ${BINARY_NAME}-fuzz DESTINATION bin COMPONENT ${BINARY_NAME}-test)
656endif()
657
658if(BUILD_EXAMPLE)
659 add_executable(${BINARY_NAME}-example-server ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/server.c)
660 target_link_libraries(${BINARY_NAME}-example-server ${BINARY_NAME})
661 set_target_properties(${BINARY_NAME}-example-server PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
662
663 if(BUILD_SDL)
664 add_executable(${BINARY_NAME}-example-client ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/client.c)
665 target_link_libraries(${BINARY_NAME}-example-client ${BINARY_NAME} ${SDL_LIBRARY} ${SDLMAIN_LIBRARY} ${OPENGL_LIBRARY} ${OPENGLES2_LIBRARY})
666 set_target_properties(${BINARY_NAME}-example-client PROPERTIES
667 COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}"
668 INCLUDE_DIRECTORIES "${SDL_INCLUDE_DIR};${CMAKE_CURRENT_SOURCE_DIR}/src")
669 endif()
670endif()
671
672# Packaging
673set(CPACK_PACKAGE_VERSION ${VERSION_STRING})
674set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
675set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
676set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
677set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
678set(CPACK_RESOURCE_FILE_README ${CMAKE_CURRENT_SOURCE_DIR}/README.md)
679
680set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
681set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
682set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
683set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README.md")
684set(CPACK_DEBIAN_PACKAGE_SECTION "games")
685
686SET(CPACK_DEB_COMPONENT_INSTALL ON)
687
688set(CPACK_STRIP_FILES ${BINARY_NAME})
689
690install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/README.md ${CMAKE_CURRENT_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
691
692include(CPack)
693
694# Summaries
695set(SUMMARY_GL_LIST)
696if(USE_EPOXY)
697 set(SUMMARY_GL_LIST "libepoxy")
698else()
699 if(BUILD_GL)
700 list(APPEND SUMMARY_GL_LIST "OpenGL")
701 endif()
702 if(BUILD_GLES2)
703 list(APPEND SUMMARY_GL_LIST "OpenGL|ES 2")
704 endif()
705endif()
706if(NOT SUMMARY_GL_LIST)
707 set(SUMMARY_GL OFF)
708else()
709 string(REPLACE ";" ", " SUMMARY_GL "${SUMMARY_GL_LIST}")
710endif()
711if(USE_LIBZIP)
712 set(SUMMARY_ZIP libzip)
713elseif(USE_MINIZIP)
714 set(SUMMARY_ZIP "minizip (external)")
715elseif(USE_ZLIB)
716 set(SUMMARY_ZIP "minizip (included)")
717else()
718 set(SUMMARY_ZIP OFF)
719endif()
720
721if(NOT QUIET)
722 message(STATUS "Platforms:")
723 message(STATUS " Game Boy Advance: ${M_CORE_GBA}")
724 message(STATUS " Game Boy: ${M_CORE_GB}")
725 message(STATUS "Features:")
726 message(STATUS " CLI debugger: ${USE_CLI_DEBUGGER}")
727 message(STATUS " GDB stub: ${USE_GDB_STUB}")
728 message(STATUS " Video recording: ${USE_FFMPEG}")
729 message(STATUS " GIF recording: ${USE_MAGICK}")
730 message(STATUS " Screenshot/advanced savestate support: ${USE_PNG}")
731 message(STATUS " ZIP support: ${SUMMARY_ZIP}")
732 message(STATUS " 7-Zip support: ${USE_LZMA}")
733 message(STATUS " OpenGL support: ${SUMMARY_GL}")
734 message(STATUS "Frontends:")
735 message(STATUS " Qt: ${BUILD_QT}")
736 message(STATUS " SDL (${SDL_VERSION}): ${BUILD_SDL}")
737 message(STATUS " Profiling: ${BUILD_PERF}")
738 message(STATUS " Test harness: ${BUILD_TEST}")
739 message(STATUS " Examples: ${BUILD_EXAMPLE}")
740 message(STATUS "Cores:")
741 message(STATUS " Libretro core: ${BUILD_LIBRETRO}")
742 if(APPLE)
743 message(STATUS " OpenEmu core: ${BUILD_OPENEMU}")
744 endif()
745 message(STATUS "Libraries:")
746 message(STATUS " Static: ${BUILD_STATIC}")
747 message(STATUS " Shared: ${BUILD_SHARED}")
748endif()