CMakeLists.txt (view raw)
1cmake_minimum_required(VERSION 2.6)
2project(mGBA C)
3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
4set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -std=gnu99")
5set(USE_CLI_DEBUGGER ON CACHE BOOL "Whether or not to enable the CLI-mode ARM debugger")
6set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
7set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
8set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
9set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable ZIP support")
10set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
11set(USE_BLIP ON CACHE BOOL "Whether or not to enable blip_buf support")
12set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
13set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
14set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
15set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
16set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
17set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
18set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
19file(GLOB ARM_SRC ${CMAKE_SOURCE_DIR}/src/arm/*.c)
20file(GLOB GBA_SRC ${CMAKE_SOURCE_DIR}/src/gba/*.c)
21file(GLOB GBA_RR_SRC ${CMAKE_SOURCE_DIR}/src/gba/rr/*.c)
22file(GLOB GBA_SV_SRC ${CMAKE_SOURCE_DIR}/src/gba/supervisor/*.c)
23file(GLOB UTIL_SRC ${CMAKE_SOURCE_DIR}/src/util/*.[cSs])
24file(GLOB VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/*.c)
25file(GLOB RENDERER_SRC ${CMAKE_SOURCE_DIR}/src/gba/renderers/video-software.c)
26file(GLOB THIRD_PARTY_SRC ${CMAKE_SOURCE_DIR}/src/third-party/inih/*.c)
27list(APPEND UTIL_SRC ${CMAKE_SOURCE_DIR}/src/platform/commandline.c)
28source_group("ARM core" FILES ${ARM_SRC})
29source_group("GBA board" FILES ${GBA_SRC} ${RENDERER_SRC})
30source_group("GBA supervisor" FILES ${GBA_SV_SRC} ${GBA_RR_SRC})
31source_group("Utilities" FILES ${UTIL_SRC} ${VFS_SRC}})
32include_directories(${CMAKE_SOURCE_DIR}/src/arm)
33include_directories(${CMAKE_SOURCE_DIR}/src)
34
35if(NOT CMAKE_BUILD_TYPE)
36 set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
37endif()
38
39set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
40
41include(GNUInstallDirs)
42
43# Function definitions
44include(FindPkgConfig)
45function(find_feature FEATURE_NAME FEATURE_REQUIRES)
46 if (NOT ${FEATURE_NAME})
47 return()
48 endif()
49 foreach(REQUIRE ${FEATURE_REQUIRES})
50 if(NOT ${REQUIRE}_FOUND)
51 find_package(${REQUIRE} QUIET)
52 if(NOT ${REQUIRE}_FOUND)
53 pkg_search_module(${REQUIRE} ${REQUIRE})
54 if (NOT ${REQUIRE}_FOUND)
55 message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
56 set(${FEATURE_NAME} OFF PARENT_SCOPE)
57 return()
58 endif()
59 endif()
60 endif()
61 string(TOUPPER ${REQUIRE} UREQUIRE)
62 set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
63 set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
64 set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
65 set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
66 set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
67 set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
68 endforeach()
69endfunction()
70
71# Version information
72set(LIB_VERSION_MAJOR 0)
73set(LIB_VERSION_MINOR 2)
74set(LIB_VERSION_PATCH 0)
75set(LIB_VERSION_ABI 0.2)
76set(LIB_VERSION_STRING ${LIB_VERSION_MAJOR}.${LIB_VERSION_MINOR}.${LIB_VERSION_PATCH})
77
78# Advanced settings
79set(BUILD_LTO ON CACHE BOOL "Build with link-time optimization")
80set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
81set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
82set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
83mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
84set(PGO_PRE_FLAGS "-pg -fprofile-generate=${PGO_DIR} -fprofile-arcs")
85set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
86
87if(BUILD_PGO AND NOT PGO_STAGE_2)
88 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
89 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
90 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
91elseif(BUILD_PGO AND PGO_STAGE_2)
92 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
93 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
94 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
95endif()
96
97add_definitions(-DBINARY_NAME="${BINARY_NAME}" -DPROJECT_NAME="${PROJECT_NAME}" -DPROJECT_VERSION="${LIB_VERSION_STRING}")
98
99# Feature dependencies
100set(FEATURES)
101if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
102 set(LIBEDIT_LIBRARIES -ledit)
103else()
104 find_feature(USE_CLI_DEBUGGER "libedit")
105endif()
106find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
107find_feature(USE_PNG "ZLIB;PNG")
108find_feature(USE_LIBZIP "libzip")
109find_feature(USE_MAGICK "MagickWand")
110
111# Platform support
112if(WIN32)
113 add_definitions(-D_WIN32_WINNT=0x0600)
114 list(APPEND OS_LIB ws2_32)
115 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/windows/*.c)
116 source_group("Windows-specific code" FILES ${OS_SRC})
117elseif(UNIX)
118 add_definitions(-DUSE_PTHREADS)
119 if(NOT APPLE)
120 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
121 endif()
122 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/posix/*.c)
123 source_group("POSIX-specific code" FILES ${OS_SRC})
124elseif(3DS)
125 add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
126 list(APPEND OS_LIB ctru)
127 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/3ds/3ds-*.c)
128 source_group("3DS-specific code" FILES ${OS_SRC})
129endif()
130
131if(APPLE)
132 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
133endif()
134
135if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
136 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
137 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
138endif()
139
140if(BUILD_BBB OR BUILD_RASPI)
141 if(NOT BUILD_EGL)
142 add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
143 endif()
144endif()
145
146if(CMAKE_SYSTEM_PROCESSOR STREQUAL "arm")
147 enable_language(ASM)
148endif()
149
150include(CheckFunctionExists)
151check_function_exists(strndup HAVE_STRNDUP)
152check_function_exists(snprintf_l HAVE_SNPRINTF_L)
153if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
154 # The strtof_l on Linux not actually exposed nor actually strtof_l
155 set(HAVE_STRTOF_L OFF)
156else()
157 check_function_exists(strtof_l HAVE_STRTOF_L)
158endif()
159check_function_exists(newlocale HAVE_NEWLOCALE)
160check_function_exists(freelocale HAVE_FREELOCALE)
161check_function_exists(uselocale HAVE_USELOCALE)
162
163if(HAVE_STRNDUP)
164 add_definitions(-DHAVE_STRNDUP)
165endif()
166
167if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE)
168 add_definitions(-DHAVE_LOCALE)
169 if (HAVE_STRTOF_L)
170 add_definitions(-DHAVE_STRTOF_L)
171 endif()
172 if (HAVE_SNPRINTF_L)
173 add_definitions(-DHAVE_SNPRINTF_L)
174 endif()
175endif()
176
177
178# Features
179set(DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/debugger.c ${CMAKE_SOURCE_DIR}/src/debugger/memory-debugger.c)
180set(FEATURE_SRC)
181set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
182
183if(USE_CLI_DEBUGGER)
184 list(APPEND FEATURES CLI_DEBUGGER)
185 list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/debugger/cli-debugger.c)
186 list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/debugger/parser.c)
187 list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/gba/supervisor/cli.c)
188 include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
189 link_directories(${LIBEDIT_LIBRARY_DIRS})
190 set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
191 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
192else()
193 set(DEBUGGER_LIB "")
194endif()
195
196if(USE_GDB_STUB)
197 list(APPEND FEATURES GDB_STUB)
198 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/gdb-stub.c)
199endif()
200source_group("ARM debugger" FILES ${DEBUGGER_SRC})
201
202if(USE_FFMPEG)
203 list(APPEND FEATURES FFMPEG)
204 pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
205 if(NOT LIBSWRESAMPLE_FOUND)
206 list(APPEND FEATURES LIBAV)
207 endif()
208 include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
209 link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
210 list(APPEND FEATURE_SRC "${CMAKE_SOURCE_DIR}/src/platform/ffmpeg/ffmpeg-encoder.c")
211 string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
212 string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
213 string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
214 string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
215 string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
216 list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
217 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR},libavformat${LIBAVFORMAT_VERSION_MAJOR},libavresample${LIBAVRESAMPLE_VERSION_MAJOR},libavutil${LIBAVUTIL_VERSION_MAJOR},libswscale${LIBSWSCALE_VERSION_MAJOR}")
218 set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra")
219endif()
220
221if(USE_BLIP)
222 list(APPEND FEATURE_SRC "${CMAKE_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
223 add_definitions(-DRESAMPLE_LIBRARY=RESAMPLE_BLIP_BUF)
224else()
225 add_definitions(-DRESAMPLE_LIBRARY=RESAMPLE_NN)
226endif()
227
228if(USE_MAGICK)
229 list(APPEND FEATURES MAGICK)
230 include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
231 link_directories(${MAGICKWAND_LIBRARY_DIRS})
232 list(APPEND FEATURE_SRC "${CMAKE_SOURCE_DIR}/src/platform/imagemagick/imagemagick-gif-encoder.c")
233 list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
234 string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
235 if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
236 set(MAGICKWAND_DEB_VERSION "5")
237 else()
238 set(MAGICKWAND_DEB_VERSION "-6.q16-2")
239 endif()
240 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
241endif()
242
243if(USE_PNG)
244 list(APPEND FEATURES PNG)
245 include_directories(AFTER ${PNG_INCLUDE_DIRS})
246 list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
247 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng12-0,zlib1g")
248endif()
249
250if(USE_LIBZIP)
251 include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
252 link_directories(${LIBZIP_LIBRARY_DIRS})
253 list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
254 list(APPEND FEATURES LIBZIP)
255 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
256endif()
257
258if (USE_LZMA)
259 include_directories(AFTER ${CMAKE_SOURCE_DIR}/third-party/lzma)
260 add_definitions(-D_7ZIP_PPMD_SUPPPORT)
261 set(LZMA_SRC
262 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
263 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
264 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
265 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
266 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
267 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
268 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zDec.c
269 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
270 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
271 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
272 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bra.c
273 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bra86.c
274 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
275 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
276 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
277 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zFile.c
278 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
279 list(APPEND FEATURE_SRC ${LZMA_SRC})
280 list(APPEND FEATURES LZMA)
281endif()
282
283set(FEATURE_DEFINES)
284foreach(FEATURE IN LISTS FEATURES)
285 list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
286endforeach()
287
288# Binaries
289set(CORE_SRC
290 ${ARM_SRC}
291 ${GBA_SRC}
292 ${GBA_RR_SRC}
293 ${GBA_SV_SRC}
294 ${DEBUGGER_SRC}
295 ${RENDERER_SRC}
296 ${UTIL_SRC}
297 ${VFS_SRC}
298 ${OS_SRC}
299 ${THIRD_PARTY_SRC})
300
301set(SRC
302 ${CORE_SRC}
303 ${FEATURE_SRC})
304
305if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
306 set(BUILD_SHARED ON)
307endif()
308
309if(BUILD_SHARED)
310 add_library(${BINARY_NAME} SHARED ${SRC})
311 if(BUILD_STATIC)
312 add_library(${BINARY_NAME}-static STATIC ${SRC})
313 target_compile_definitions(${BINARY_NAME}-static PRIVATE ${FEATURE_DEFINES})
314 install(TARGETS ${BINARY_NAME}-static DESTINATION lib COMPONENT lib${BINARY_NAME})
315 endif()
316else()
317 add_library(${BINARY_NAME} STATIC ${SRC})
318endif()
319
320target_link_libraries(${BINARY_NAME} m ${DEBUGGER_LIB} ${OS_LIB} ${DEPENDENCY_LIB})
321target_compile_definitions(${BINARY_NAME} PRIVATE ${FEATURE_DEFINES})
322install(TARGETS ${BINARY_NAME} DESTINATION lib COMPONENT lib${BINARY_NAME})
323set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI})
324
325if(BUILD_LIBRETRO)
326 file(GLOB RETRO_SRC ${CMAKE_SOURCE_DIR}/src/platform/libretro/*.c)
327 add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
328 set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "")
329 target_compile_definitions(${BINARY_NAME}_libretro PRIVATE COLOR_16_BIT;COLOR_5_6_5 PUBLIC "" INTERFACE "")
330 target_link_libraries(${BINARY_NAME}_libretro m ${OS_LIB})
331endif()
332
333if(BUILD_SDL)
334 add_definitions(-DBUILD_SDL)
335 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/sdl ${CMAKE_BINARY_DIR}/sdl)
336endif()
337
338if(BUILD_QT)
339 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/qt ${CMAKE_BINARY_DIR}/qt)
340endif()
341
342if(BUILD_PERF)
343 set(PERF_SRC ${CMAKE_SOURCE_DIR}/src/platform/perf-main.c)
344 if(UNIX AND NOT APPLE)
345 list(APPEND PERF_LIB rt)
346 endif()
347
348 add_executable(${BINARY_NAME}-perf ${PERF_SRC})
349 target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB})
350 install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
351 install(FILES ${CMAKE_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
352endif()
353
354if(3DS)
355 add_executable(${BINARY_NAME}.elf ${CMAKE_SOURCE_DIR}/src/platform/3ds/main.c)
356 target_link_libraries(${BINARY_NAME}.elf ${BINARY_NAME} m ${OS_LIB})
357 add_custom_command(TARGET ${BINARY_NAME}.elf POST_BUILD COMMAND ${3DSXTOOL} ${BINARY_NAME}.elf ${BINARY_NAME}.3dsx)
358endif()
359
360# Packaging
361set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
362set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
363set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
364set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_SOURCE_DIR}/LICENSE)
365set(CPACK_RESOURCE_FILE_README ${CMAKE_SOURCE_DIR}/README.md)
366
367set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
368set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
369set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
370set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_SOURCE_DIR}/README.md")
371set(CPACK_DEBIAN_PACKAGE_SECTION "games")
372
373SET(CPACK_DEB_COMPONENT_INSTALL ON)
374
375set(CPACK_STRIP_FILES ${BINARY_NAME})
376
377install(FILES ${CMAKE_SOURCE_DIR}/README.md ${CMAKE_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
378
379include(CPack)
380
381# Summaries
382message(STATUS "Feature summary:")
383message(STATUS " CLI debugger: ${USE_CLI_DEBUGGER}")
384message(STATUS " GDB stub: ${USE_GDB_STUB}")
385message(STATUS " Video recording: ${USE_FFMPEG}")
386message(STATUS " GIF recording: ${USE_MAGICK}")
387message(STATUS " Screenshot/advanced savestate support: ${USE_PNG}")
388message(STATUS " ZIP support: ${USE_LIBZIP}")
389message(STATUS " 7-Zip support: ${USE_LZMA}")
390message(STATUS " Better audio resampling: ${USE_BLIP}")
391message(STATUS "Frontend summary:")
392message(STATUS " Qt: ${BUILD_QT}")
393message(STATUS " SDL (${SDL_VERSION}): ${BUILD_SDL}")
394message(STATUS " Libretro core: ${BUILD_LIBRETRO}")
395message(STATUS " Profiling: ${BUILD_PERF}")
396message(STATUS "Library summary:")
397message(STATUS " Static: ${BUILD_STATIC}")
398message(STATUS " Shared: ${BUILD_SHARED}")