1cmake_minimum_required(VERSION 2.8.11)
  2project(mGBA)
  3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
  4if(NOT MSVC)
  5	set(GCC_STD "c99")
  6        if(CMAKE_C_COMPILER_ID STREQUAL "GNU" AND CMAKE_COMPILER_VERSION VERSION_LESS "4.3")
  7		set(GCC_STD "gnu99")
  8	endif()
  9	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wno-missing-field-initializers -std=${GCC_STD}")
 10else()
 11	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_CRT_SECURE_NO_WARNINGS /wd4003 /wd4244 /wd4146")
 12endif()
 13set(USE_DEBUGGERS ON CACHE BOOL "Whether or not to enable the debugging infrastructure")
 14if (NOT WIN32)
 15	set(USE_EDITLINE ON CACHE BOOL "Whether or not to enable the CLI-mode debugger")
 16endif()
 17set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
 18set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
 19set(USE_ZLIB ON CACHE BOOL "Whether or not to enable zlib support")
 20set(USE_MINIZIP ON CACHE BOOL "Whether or not to enable external minizip support")
 21set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
 22set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable LIBZIP support")
 23set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
 24set(USE_SQLITE3 ON CACHE BOOL "Whether or not to enable SQLite3 support")
 25set(M_CORE_GBA ON CACHE BOOL "Build Game Boy Advance core")
 26set(M_CORE_GB ON CACHE BOOL "Build Game Boy core")
 27set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
 28set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
 29set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
 30set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
 31if(APPLE)
 32	set(BUILD_OPENEMU OFF CACHE BOOL "Build OpenEmu core")
 33endif()
 34set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
 35set(BUILD_TEST OFF CACHE BOOL "Build testing harness")
 36set(BUILD_SUITE OFF CACHE BOOL "Build test suite")
 37set(BUILD_EXAMPLE OFF CACHE BOOL "Build example frontends")
 38set(BUILD_PYTHON OFF CACHE BOOL "Build Python bindings")
 39set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
 40set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
 41set(SKIP_LIBRARY OFF CACHE BOOL "Skip building the library (useful for only building libretro or OpenEmu cores)")
 42set(BUILD_GL ON CACHE STRING "Build with OpenGL")
 43set(BUILD_GLES2 OFF CACHE STRING "Build with OpenGL|ES 2")
 44set(USE_EPOXY ON CACHE STRING "Build with libepoxy")
 45set(DISABLE_DEPS OFF CACHE BOOL "Build without dependencies")
 46if(WIN32)
 47	set(WIN32_UNIX_PATHS OFF CACHE BOOL "Use Unix-like paths")
 48	mark_as_advanced(WIN32_UNIX_PATHS)
 49endif()
 50file(GLOB ARM_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/*.c)
 51file(GLOB ARM_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/test/*.c)
 52file(GLOB LR35902_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/*.c)
 53file(GLOB LR35902_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/test/*.c)
 54file(GLOB GBA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/*.c)
 55file(GLOB GBA_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/test/*.c)
 56file(GLOB GB_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/*.c)
 57file(GLOB GB_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/test/*.c)
 58file(GLOB GBA_CHEATS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/cheats/*.c)
 59file(GLOB GBA_RR_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/rr/*.c)
 60file(GLOB CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/*.c)
 61file(GLOB CORE_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/test/*.c)
 62file(GLOB UTIL_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/*.[cSs])
 63file(GLOB UTIL_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/test/*.c)
 64file(GLOB GUI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/gui/*.c ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/gui/*.c)
 65file(GLOB GBA_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/renderers/*.c)
 66file(GLOB GBA_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/sio/lockstep.c)
 67file(GLOB GBA_EXTRA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/extra/*.c)
 68file(GLOB GB_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/sio/lockstep.c)
 69file(GLOB GB_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/renderers/*.c)
 70file(GLOB GB_EXTRA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/extra/*.c)
 71file(GLOB THIRD_PARTY_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/inih/*.c)
 72file(GLOB EXTRA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/*.c)
 73set(CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-mem.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fifo.c)
 74set(VFS_SRC)
 75source_group("ARM core" FILES ${ARM_SRC})
 76source_group("LR35902 core" FILES ${LR35902_SRC})
 77source_group("GBA board" FILES ${GBA_SRC} ${GBA_RENDERER_SRC} ${GBA_SIO_SRC})
 78source_group("GBA extra" FILES ${GBA_CHEATS_SRC} ${GBA_RR_SRC})
 79source_group("GB board" FILES ${GB_SRC} ${GB_SIO_SRC})
 80source_group("Utilities" FILES ${UTIL_SRC})
 81include_directories(BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/include ${CMAKE_CURRENT_SOURCE_DIR}/src)
 82
 83if(NOT CMAKE_BUILD_TYPE)
 84	set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
 85endif()
 86
 87if(NOT WIN32 OR WIN32_UNIX_PATHS)
 88	include(GNUInstallDirs)
 89else()
 90	set(CMAKE_INSTALL_LIBDIR ".")
 91	set(CMAKE_INSTALL_BINDIR ".")
 92	set(CMAKE_INSTALL_DATADIR ".")
 93	set(CMAKE_INSTALL_DOCDIR ".")
 94	set(CMAKE_INSTALL_INCLUDEDIR "include")
 95endif()
 96
 97set(LIBDIR "${CMAKE_INSTALL_LIBDIR}" CACHE PATH "Installed library directory")
 98mark_as_advanced(LIBDIR)
 99
100if (BUILD_LIBRETRO)
101	set(LIBRETRO_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (Libretro)")
102	mark_as_advanced(LIBRETRO_LIBDIR)
103endif()
104
105if (BUILD_OPENEMU)
106	set(OE_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (OpenEmu)")
107	mark_as_advanced(OE_LIBDIR)
108endif()
109
110
111set(CMAKE_INSTALL_RPATH "${LIBDIR}")
112
113if (NOT DEFINED MANDIR)
114	set(MANDIR ${CMAKE_INSTALL_MANDIR})
115endif()
116
117# Function definitions
118include(FindPkgConfig)
119function(find_feature FEATURE_NAME FEATURE_REQUIRES)
120	if (NOT ${FEATURE_NAME})
121		return()
122	endif()
123	if (DISABLE_DEPS)
124		set(${FEATURE_NAME} OFF PARENT_SCOPE)
125		return()
126	endif()
127	foreach(REQUIRE ${FEATURE_REQUIRES})
128		if(NOT ${REQUIRE}_FOUND)
129			find_package(${REQUIRE} QUIET)
130			if(NOT ${REQUIRE}_FOUND)
131				pkg_search_module(${REQUIRE} ${REQUIRE})
132				if (NOT ${REQUIRE}_FOUND)
133					message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
134					set(${FEATURE_NAME} OFF PARENT_SCOPE)
135					return()
136				endif()
137			endif()
138		endif()
139		string(TOUPPER ${REQUIRE} UREQUIRE)
140		set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
141		set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
142		set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
143		set(${UREQUIRE}_VERSION_STRING ${${REQUIRE}_VERSION_STRING} PARENT_SCOPE)
144		if (APPLE)
145			set(IS_FRAMEWORK OFF)
146			set(LIBS)
147			foreach(LIB IN LISTS ${REQUIRE}_LIBRARIES)
148				if(LIB STREQUAL "-framework")
149					set(IS_FRAMEWORK ON)
150				elseif(IS_FRAMEWORK)
151					list(APPEND LIBS "-framework ${LIB}")
152					set(IS_FRAMEWORK OFF)
153				else()
154					list(APPEND LIBS ${LIB})
155				endif()
156			endforeach()
157			set(${UREQUIRE}_LIBRARIES ${LIBS} PARENT_SCOPE)
158		else()
159			set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
160		endif()
161		set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
162		set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
163	endforeach()
164endfunction()
165
166# Version information
167add_custom_target(version-info ALL
168	COMMAND ${CMAKE_COMMAND}
169	-DBINARY_NAME=${BINARY_NAME}
170	-DCONFIG_FILE=${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in
171	-DOUT_FILE=${CMAKE_CURRENT_BINARY_DIR}/version.c
172	-P ${CMAKE_CURRENT_SOURCE_DIR}/version.cmake
173	WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
174
175include(${CMAKE_CURRENT_SOURCE_DIR}/version.cmake)
176configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in ${CMAKE_CURRENT_BINARY_DIR}/version.c)
177
178list(APPEND UTIL_SRC ${CMAKE_CURRENT_BINARY_DIR}/version.c)
179source_group("Generated sources" FILES ${CMAKE_CURRENT_BINARY_DIR}/version.c)
180
181# Advanced settings
182if(NOT DEFINED 3DS)
183	# LTO appears to make 3DS binary slower
184	set(DEFAULT_LTO ON)
185else()
186	set(DEFAULT_LTO OFF)
187endif()
188
189set(BUILD_LTO ${DEFAULT_LTO} CACHE BOOL "Build with link-time optimization")
190set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
191set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
192set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
193mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
194set(PGO_PRE_FLAGS "-fprofile-generate=${PGO_DIR} -fprofile-arcs")
195set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
196
197if(BUILD_PGO AND NOT PGO_STAGE_2)
198	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
199	set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
200	set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
201elseif(BUILD_PGO AND PGO_STAGE_2)
202	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
203	set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
204	set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
205endif()
206
207# Platform support
208if(WIN32)
209	set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
210	add_definitions(-D_WIN32_WINNT=0x0600)
211	list(APPEND OS_LIB ws2_32 shlwapi)
212	list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/vfs-w32.c)
213	file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/*.c)
214	source_group("Windows-specific code" FILES ${OS_SRC})
215	if(MSVC)
216		add_definitions(-DNOMINMAX -DWIN32_LEAN_AND_MEAN)
217		set(CMAKE_WINDOWS_EXPORT_ALL_SYMBOLS TRUE)
218	endif()
219elseif(UNIX)
220	set(USE_PTHREADS ON)
221	add_definitions(-DUSE_PTHREADS)
222
223	if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
224		add_definitions(-D_GNU_SOURCE)
225	endif()
226	if(NOT APPLE AND NOT HAIKU)
227		set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
228		set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -pthread")
229	endif()
230
231	list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
232	file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/posix/*.c)
233	source_group("POSIX-specific code" FILES ${OS_SRC})
234endif()
235
236if(APPLE)
237	add_definitions(-D_DARWIN_C_SOURCE)
238	if(CMAKE_SYSTEM_VERSION VERSION_GREATER "10.5.8")
239		set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
240	endif()
241endif()
242
243if(NOT HAIKU AND NOT MSVC AND NOT PSP2)
244	set(M_LIBRARY m)
245endif()
246list(APPEND OS_LIB ${M_LIBRARY})
247
248if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
249	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
250	set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
251endif()
252
253if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
254	if(NOT BUILD_EGL)
255		add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
256	endif()
257endif()
258
259if(BUILD_RASPI)
260	set(BUILD_GL OFF CACHE BOOL "OpenGL not supported" FORCE)
261endif()
262
263if(BUILD_PANDORA)
264	add_definitions(-DBUILD_PANDORA)
265endif()
266
267if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
268	enable_language(ASM)
269endif()
270
271if(PSP2 OR WII)
272	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-format")
273endif()
274
275if(DEFINED 3DS OR DEFINED PSP2 OR DEFINED WII)
276	set(USE_DEBUGGERS OFF)
277	set(USE_SQLITE3 OFF)
278endif()
279
280if(NOT M_CORE_GBA)
281	set(USE_GDB_STUB OFF)
282endif()
283
284if(NOT USE_DEBUGGERS)
285	set(USE_EDITLINE OFF)
286	set(USE_GDB_STUB OFF)
287endif()
288
289if(WII)
290	add_definitions(-U__STRICT_ANSI__)
291endif()
292
293if(DEFINED 3DS)
294	add_definitions(-D_GNU_SOURCE)
295endif()
296
297include(CheckFunctionExists)
298check_function_exists(strdup HAVE_STRDUP)
299check_function_exists(strndup HAVE_STRNDUP)
300if(NOT DEFINED PSP2)
301	check_function_exists(localtime_r HAVE_LOCALTIME_R)
302endif()
303if(NOT CMAKE_SYSTEM_NAME STREQUAL "Generic")
304	check_function_exists(snprintf_l HAVE_SNPRINTF_L)
305	if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
306		# The strtof_l on Linux not actually exposed nor actually strtof_l
307		set(HAVE_STRTOF_L OFF)
308	else()
309		check_function_exists(strtof_l HAVE_STRTOF_L)
310	endif()
311	check_function_exists(newlocale HAVE_NEWLOCALE)
312	check_function_exists(freelocale HAVE_FREELOCALE)
313	check_function_exists(uselocale HAVE_USELOCALE)
314	check_function_exists(setlocale HAVE_SETLOCALE)
315else()
316	if(DEFINED 3DS OR DEFINED WII)
317		set(CMAKE_REQUIRED_FLAGS -Wl,--require-defined,snprintf_l)
318		check_function_exists(snprintf_l HAVE_SNPRINTF_L)
319		set(CMAKE_REQUIRED_FLAGS -Wl,--require-defined,strtof_l)
320		check_function_exists(strtof_l HAVE_STRTOF_L)
321		set(CMAKE_REQUIRED_FLAGS -Wl,--require-defined,newlocale)
322		check_function_exists(newlocale HAVE_NEWLOCALE)
323		set(CMAKE_REQUIRED_FLAGS -Wl,--require-defined,freelocale)
324		check_function_exists(freelocale HAVE_FREELOCALE)
325		set(CMAKE_REQUIRED_FLAGS -Wl,--require-defined,uselocale)
326		check_function_exists(uselocale HAVE_USELOCALE)
327		set(CMAKE_REQUIRED_FLAGS -Wl,--require-defined,setlocale)
328		check_function_exists(setlocale HAVE_SETLOCALE)
329		unset(CMAKE_REQUIRED_FLAGS)
330	endif()
331	if(NOT DEFINED 3DS AND NOT DEFINED PSP2 AND NOT DEFINED WII)
332		set(DISABLE_DEPS ON CACHE BOOL "This platform cannot build with dependencies" FORCE)
333	endif()
334	set(DISABLE_FRONTENDS ON)
335	set(MINIMAL_CORE ON)
336	set(ENABLE_EXTRA ON)
337endif()
338
339check_function_exists(chmod HAVE_CHMOD)
340check_function_exists(umask HAVE_UMASK)
341
342set(FUNCTION_DEFINES)
343
344if(HAVE_STRDUP)
345	list(APPEND FUNCTION_DEFINES HAVE_STRDUP)
346endif()
347
348if(HAVE_STRNDUP)
349	list(APPEND FUNCTION_DEFINES HAVE_STRNDUP)
350endif()
351
352if(HAVE_LOCALTIME_R)
353	list(APPEND FUNCTION_DEFINES HAVE_LOCALTIME_R)
354endif()
355
356if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE OR APPLE)
357	list(APPEND FUNCTION_DEFINES HAVE_LOCALE)
358	if (HAVE_STRTOF_L)
359		list(APPEND FUNCTION_DEFINES HAVE_STRTOF_L)
360	endif()
361	if (HAVE_SNPRINTF_L)
362		list(APPEND FUNCTION_DEFINES HAVE_SNPRINTF_L)
363	endif()
364endif()
365
366if(HAVE_SETLOCALE)
367	list(APPEND FUNCTION_DEFINES HAVE_SETLOCALE)
368endif()
369
370if(HAVE_CHMOD)
371	list(APPEND FUNCTION_DEFINES HAVE_CHMOD)
372endif()
373
374if(HAVE_UMASK)
375	list(APPEND FUNCTION_DEFINES HAVE_UMASK)
376endif()
377
378# Feature dependencies
379set(FEATURE_DEFINES)
380set(FEATURE_FLAGS)
381set(FEATURES)
382if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
383	set(LIBEDIT_LIBRARIES -ledit)
384	if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
385		list(APPEND LIBEDIT_LIBRARIES -ltermcap)
386	endif()
387else()
388	find_feature(USE_EDITLINE "libedit")
389endif()
390if(BUILD_GL)
391	find_package(OpenGL QUIET)
392	if(NOT OPENGL_FOUND)
393		set(BUILD_GL OFF CACHE BOOL "OpenGL not found" FORCE)
394	endif()
395endif()
396if(NOT BUILD_GL)
397	set(OPENGLE_LIBRARY "" CACHE PATH "" FORCE)
398endif()
399if(BUILD_GLES2 AND NOT BUILD_RASPI)
400	find_path(OPENGLES2_INCLUDE_DIR NAMES GLES2/gl2.h)
401	find_library(OPENGLES2_LIBRARY NAMES GLESv2 GLESv2_CM)
402	if(NOT OPENGLES2_INCLUDE_DIR OR NOT OPENGLES2_LIBRARY)
403		set(BUILD_GLES2 OFF CACHE BOOL "OpenGL|ES 2 not found" FORCE)
404	endif()
405endif()
406if(NOT BUILD_GLES2)
407	set(OPENGLES2_LIBRARY "" CACHE PATH "" FORCE)
408endif()
409set(WANT_ZLIB ${USE_ZLIB})
410set(WANT_PNG ${USE_PNG})
411set(WANT_LIBZIP ${USE_LIBZIP})
412set(WANT_SQLITE3 ${USE_SQLITE3})
413set(USE_CMOCKA ${BUILD_SUITE})
414
415find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
416find_feature(USE_ZLIB "ZLIB")
417find_feature(USE_MINIZIP "minizip")
418find_feature(USE_PNG "PNG")
419find_feature(USE_LIBZIP "libzip")
420find_feature(USE_MAGICK "MagickWand")
421find_feature(USE_EPOXY "epoxy")
422find_feature(USE_CMOCKA "cmocka")
423find_feature(USE_SQLITE3 "sqlite3")
424
425# Features
426set(DEBUGGER_SRC
427	${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/debugger.c
428	${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/parser.c
429	${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/symbols.c
430	${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/cli-debugger.c)
431
432set(FEATURE_SRC)
433set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
434
435if(DISABLE_DEPS)
436	set(USE_GDB_STUB OFF)
437endif()
438
439if(USE_EDITLINE)
440	list(APPEND FEATURES EDITLINE)
441	include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
442	link_directories(${LIBEDIT_LIBRARY_DIRS})
443	set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
444	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
445	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/editline/cli-el-backend.c")
446else()
447	set(DEBUGGER_LIB "")
448endif()
449
450if(USE_GDB_STUB)
451	list(APPEND FEATURES GDB_STUB)
452	list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/gdb-stub.c)
453endif()
454source_group("Debugger" FILES ${DEBUGGER_SRC})
455
456if(USE_FFMPEG)
457	list(APPEND FEATURES FFMPEG)
458	pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
459	if(NOT LIBSWRESAMPLE_FOUND)
460		list(APPEND FEATURES LIBAV)
461	endif()
462	include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
463	link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
464	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/ffmpeg/ffmpeg-encoder.c")
465	string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
466	string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
467	string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
468	string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
469	string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
470	list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
471	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR}|libavcodec-extra-${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
472	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavformat${LIBAVFORMAT_VERSION_MAJOR}|libavformat-ffmpeg${LIBAVFORMAT_VERSION_MAJOR}")
473	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavresample${LIBAVRESAMPLE_VERSION_MAJOR}|libavresample-ffmpeg${LIBAVRESAMPLE_VERSION_MAJOR}")
474	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavutil${LIBAVUTIL_VERSION_MAJOR}|libavutil-ffmpeg${LIBAVUTIL_VERSION_MAJOR}")
475	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libswscale${LIBSWSCALE_VERSION_MAJOR}|libswscale-ffmpeg${LIBSWSCALE_VERSION_MAJOR}")
476	set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
477	if(APPLE)
478		set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
479		set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
480	endif()
481endif()
482
483list(APPEND THIRD_PARTY_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
484
485if(USE_MAGICK)
486	list(APPEND FEATURES MAGICK)
487	include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
488	link_directories(${MAGICKWAND_LIBRARY_DIRS})
489	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/imagemagick/imagemagick-gif-encoder.c")
490	list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
491	string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
492	string(REGEX MATCH "^[0-9]+" MAGICKWAND_VERSION_MAJOR ${MagickWand_VERSION})
493	if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
494		set(MAGICKWAND_DEB_VERSION "5")
495	elseif(${MagickWand_VERSION} EQUAL "6.9.7")
496		set(MAGICKWAND_DEB_VERSION "-6.q16-3")
497	else()
498		set(MAGICKWAND_DEB_VERSION "-6.q16-2")
499	endif()
500	list(APPEND FEATURE_DEFINES MAGICKWAND_VERSION_MAJOR=${MAGICKWAND_VERSION_MAJOR})
501	list(APPEND FEATURE_FLAGS ${MAGICKWAND_CFLAGS_OTHER})
502
503	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
504endif()
505
506if(WANT_ZLIB AND NOT USE_ZLIB)
507	set(SKIP_INSTALL_ALL ON)
508	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib zlib)
509	set_property(TARGET zlibstatic PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/zlib;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib)
510	set_property(TARGET zlib PROPERTY EXCLUDE_FROM_ALL ON)
511	set_property(TARGET example PROPERTY EXCLUDE_FROM_ALL ON)
512	set_property(TARGET minigzip PROPERTY EXCLUDE_FROM_ALL ON)
513	set(ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
514	set(ZLIB_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
515	set(ZLIB_LIBRARY zlibstatic)
516	list(APPEND DEPENDENCY_LIB zlibstatic)
517	set(USE_ZLIB ON)
518endif()
519
520if(USE_ZLIB)
521	list(APPEND FEATURES ZLIB)
522	include_directories(AFTER ${ZLIB_INCLUDE_DIRS})
523	list(APPEND DEPENDENCY_LIB ${ZLIB_LIBRARIES})
524	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},zlib1g")
525endif()
526
527if(WANT_PNG AND USE_ZLIB AND NOT USE_PNG)
528	set(PNG_STATIC ON CACHE BOOL "" FORCE)
529	set(PNG_SHARED OFF CACHE BOOL "" FORCE)
530	set(PNG_TESTS OFF CACHE BOOL "" FORCE)
531	set(SKIP_INSTALL_ALL ON)
532	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng libpng)
533	set_property(TARGET png16_static PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/libpng;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng;${ZLIB_INCLUDE_DIRS})
534	set(PNG_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng ${CMAKE_CURRENT_BINARY_DIR}/libpng)
535	list(APPEND DEPENDENCY_LIB png16_static)
536	set(USE_PNG ON)
537endif()
538
539if(USE_PNG)
540	list(APPEND FEATURES PNG)
541	include_directories(AFTER ${PNG_INCLUDE_DIRS})
542	list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
543	if(PNG_VERSION_STRING)
544		string(REGEX MATCH "^[0-9]+\\.[0-9]+" PNG_VERSION_PARTIAL ${PNG_VERSION_STRING})
545		if(${PNG_VERSION_PARTIAL} STREQUAL "1.6")
546			set(PNG_DEB_VERSION "16-16")
547		else()
548			set(PNG_DEB_VERSION "12-0")
549		endif()
550		set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng${PNG_DEB_VERSION}")
551	endif()
552endif()
553
554if(WANT_SQLITE3 AND NOT USE_SQLITE3)
555	list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/sqlite3.c)
556	include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/)
557	set(USE_SQLITE3 ON)
558endif()
559
560if(USE_LIBZIP)
561	include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
562	link_directories(${LIBZIP_LIBRARY_DIRS})
563	list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
564	list(APPEND FEATURES LIBZIP)
565	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
566	string(REGEX MATCH "^[0-9]+" LIBZIP_VERSION_MAJOR ${libzip_VERSION})
567	if (LIBZIP_VERSION_MAJOR LESS 1)
568		set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
569	elseif(LIBZIP_VERSION_MAJOR EQUAL 1)
570		set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip4")
571	else()
572		message(AUTHOR_WARNING Unknown version of libzip detected: ${libzip_VERSION})
573	endif()
574elseif(USE_MINIZIP)
575	include_directories(AFTER ${MINIZIP_INCLUDE_DIRS})
576	link_directories(${MINIZIP_LIBRARY_DIRS})
577	list(APPEND DEPENDENCY_LIB ${MINIZIP_LIBRARIES})
578	list(APPEND FEATURES MINIZIP)
579	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
580	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libminizip1")
581elseif(USE_ZLIB)
582	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c
583		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
584		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c)
585	if(NOT MSVC)
586		set_source_files_properties(
587			${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
588			${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c
589			PROPERTIES COMPILE_FLAGS "-Wno-unused-parameter -Wno-implicit-function-declaration")
590	endif()
591endif()
592
593if (USE_LZMA)
594	include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma)
595	add_definitions(-D_7ZIP_PPMD_SUPPPORT)
596	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-lzma.c)
597	set(LZMA_SRC
598		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
599		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
600		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
601		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
602		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
603		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
604		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zDec.c
605		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
606		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Delta.c
607		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
608		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
609		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra.c
610		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra86.c
611		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/BraIA64.c
612		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
613		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
614		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
615		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zFile.c
616		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
617	list(APPEND VFS_SRC ${LZMA_SRC})
618	list(APPEND FEATURES LZMA)
619endif()
620
621if(USE_EPOXY)
622	add_definitions(-DBUILD_GL -DBUILD_GLES2)
623	list(APPEND FEATURES EPOXY)
624	include_directories(AFTER ${EPOXY_INCLUDE_DIRS})
625	set(OPENGLES2_LIBRARY ${EPOXY_LIBRARIES})
626	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libepoxy0")
627endif()
628
629if(USE_SQLITE3)
630	list(APPEND FEATURES SQLITE3)
631	include_directories(AFTER ${SQLITE3_INCLUDE_DIRS})
632	list(APPEND DEPENDENCY_LIB ${SQLITE3_LIBRARIES})
633	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libsqlite3-0")
634	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/sqlite3/no-intro.c")
635endif()
636
637set(TEST_SRC ${CORE_TEST_SRC})
638if(M_CORE_GB)
639	add_definitions(-DM_CORE_GB)
640	list(APPEND CORE_SRC
641		${LR35902_SRC}
642		${GB_SRC}
643		${GB_RENDERER_SRC})
644	list(APPEND DEBUGGER_SRC
645		${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/cli-debugger.c
646		${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/debugger.c
647		${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/memory-debugger.c
648		${CMAKE_CURRENT_SOURCE_DIR}/src/gb/debugger/cli.c
649		${CMAKE_CURRENT_SOURCE_DIR}/src/gb/debugger/symbols.c)
650	list(APPEND TEST_SRC
651		${LR35902_TEST_SRC}
652		${GB_TEST_SRC})
653endif()
654
655if(M_CORE_GBA)
656	add_definitions(-DM_CORE_GBA)
657	list(APPEND CORE_SRC
658		${ARM_SRC}
659		${GBA_SRC}
660		${GBA_CHEATS_SRC}
661		${GBA_RENDERER_SRC})
662	list(APPEND DEBUGGER_SRC
663		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c
664		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/debugger.c
665		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/memory-debugger.c
666		${CMAKE_CURRENT_SOURCE_DIR}/src/gba/debugger/cli.c)
667	list(APPEND TEST_SRC
668		${ARM_TEST_SRC}
669		${GBA_TEST_SRC})
670	if(NOT M_CORE_GB)
671		list(APPEND CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/audio.c)
672	endif()
673endif()
674
675if(USE_DEBUGGERS)
676	list(APPEND FEATURE_SRC ${DEBUGGER_SRC})
677	list(APPEND FEATURES DEBUGGERS)
678endif()
679
680foreach(FEATURE IN LISTS FEATURES)
681	list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
682endforeach()
683
684source_group("Virtual files" FILES ${CORE_VFS_SRC} ${VFS_SRC})
685source_group("Extra features" FILES ${FEATURE_SRC})
686source_group("Third-party code" FILES ${THIRD_PARTY_SRC})
687
688# Platform binaries
689if(DEFINED 3DS)
690	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/3ds ${CMAKE_CURRENT_BINARY_DIR}/3ds)
691endif()
692
693if(DEFINED WII)
694	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/wii ${CMAKE_CURRENT_BINARY_DIR}/wii)
695endif()
696
697if(DEFINED PSP2)
698	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/psp2 ${CMAKE_CURRENT_BINARY_DIR}/psp2)
699endif()
700
701# Binaries
702list(APPEND CORE_SRC
703	${UTIL_SRC}
704	${CORE_VFS_SRC}
705	${OS_SRC}
706	${THIRD_PARTY_SRC})
707list(APPEND TEST_SRC ${UTIL_TEST_SRC})
708
709set(SRC ${CORE_SRC} ${VFS_SRC})
710if(NOT MINIMAL_CORE)
711	set(ENABLE_EXTRA ON)
712	if(M_CORE_GBA)
713		list(APPEND SRC
714			${GBA_SIO_SRC})
715	endif()
716	if(M_CORE_GB)
717		list(APPEND SRC
718			${GB_SIO_SRC})
719	endif()
720	list(APPEND SRC
721		${FEATURE_SRC})
722endif()
723
724if(ENABLE_EXTRA)
725	if(M_CORE_GBA)
726		list(APPEND SRC
727			${GBA_RR_SRC}
728			${GBA_EXTRA_SRC})
729	endif()
730	if(M_CORE_GB)
731		list(APPEND SRC
732			${GB_EXTRA_SRC})
733	endif()
734	list(APPEND SRC
735		${EXTRA_SRC})
736endif()
737
738if(NOT SKIP_LIBRARY)
739	if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
740		set(BUILD_SHARED ON)
741	endif()
742
743	if(BUILD_SHARED)
744		add_library(${BINARY_NAME} SHARED ${SRC} ${VFS_SRC})
745		if(BUILD_STATIC)
746			add_library(${BINARY_NAME}-static STATIC ${SRC})
747			set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}" COMPILE_OPTIONS "${FEATURE_FLAGS}")
748			install(TARGETS ${BINARY_NAME}-static DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
749			add_dependencies(${BINARY_NAME}-static version-info)
750		endif()
751	else()
752		add_library(${BINARY_NAME} STATIC ${SRC})
753	endif()
754
755	add_dependencies(${BINARY_NAME} version-info)
756	set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}" COMPILE_OPTIONS "${FEATURE_FLAGS}")
757
758	target_link_libraries(${BINARY_NAME} ${DEBUGGER_LIB} ${DEPENDENCY_LIB} ${OS_LIB})
759	install(TARGETS ${BINARY_NAME} LIBRARY DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME} NAMELINK_SKIP ARCHIVE DESTINATION ${LIBDIR} RUNTIME DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
760	if(UNIX AND NOT APPLE AND NOT HAIKU)
761		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-16.png DESTINATION share/icons/hicolor/16x16/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
762		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-24.png DESTINATION share/icons/hicolor/24x24/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
763		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-32.png DESTINATION share/icons/hicolor/32x32/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
764		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-48.png DESTINATION share/icons/hicolor/48x48/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
765		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-64.png DESTINATION share/icons/hicolor/64x64/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
766		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-96.png DESTINATION share/icons/hicolor/96x96/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
767		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-128.png DESTINATION share/icons/hicolor/128x128/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
768		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-256.png DESTINATION share/icons/hicolor/256x256/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
769		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-512.png DESTINATION share/icons/hicolor/512x512/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
770	endif()
771else()
772	set(BUILD_SHARED OFF)
773	set(BUILD_STATIC OFF)
774	find_library(${BINARY_NAME} ${BINARY_NAME})
775	if(NOT ${BINARY_NAME}_FOUND)
776		set(DISABLE_FRONTENDS ON)
777		set(BUILD_PERF OFF)
778		set(BUILD_TEST OFF)
779		set(BUILD_SUITE OFF)
780	endif()
781endif()
782
783if(BUILD_GL)
784	add_definitions(-DBUILD_GL)
785endif()
786
787if(BUILD_GLES2)
788	add_definitions(-DBUILD_GLES2)
789endif()
790
791if(DISABLE_FRONTENDS)
792	set(BUILD_SDL OFF)
793	set(BUILD_QT OFF)
794endif()
795
796if(BUILD_LIBRETRO)
797	file(GLOB RETRO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/libretro/*.c)
798	add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
799	set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5;DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=2")
800	target_link_libraries(${BINARY_NAME}_libretro ${OS_LIB})
801	install(TARGETS ${BINARY_NAME}_libretro LIBRARY DESTINATION ${LIBRETRO_LIBDIR} COMPONENT ${BINARY_NAME}_libretro NAMELINK_SKIP)
802endif()
803
804if(BUILD_OPENEMU)
805	find_library(FOUNDATION Foundation)
806	find_library(OPENEMUBASE OpenEmuBase)
807	file(GLOB OE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/*.m)
808	add_library(${BINARY_NAME}-openemu MODULE ${CORE_SRC} ${OE_SRC})
809	set_target_properties(${BINARY_NAME}-openemu PROPERTIES
810		MACOSX_BUNDLE_INFO_PLIST ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/Info.plist.in
811		BUNDLE TRUE
812		BUNDLE_EXTENSION oecoreplugin
813		OUTPUT_NAME ${PROJECT_NAME}
814		COMPILE_DEFINITIONS "DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=1")
815	target_link_libraries(${BINARY_NAME}-openemu ${OS_LIB} ${FOUNDATION} ${OPENEMUBASE})
816	install(TARGETS ${BINARY_NAME}-openemu LIBRARY DESTINATION ${OE_LIBDIR} COMPONENT ${BINARY_NAME}.oecoreplugin NAMELINK_SKIP)
817endif()
818
819if(BUILD_SDL)
820	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/sdl ${CMAKE_CURRENT_BINARY_DIR}/sdl)
821	# The SDL platform CMakeLists could decide to disable SDL, so check again before adding the define.
822	if(BUILD_SDL)
823		add_definitions(-DBUILD_SDL)
824	endif()
825endif()
826
827if(BUILD_QT)
828	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/qt ${CMAKE_CURRENT_BINARY_DIR}/qt)
829endif()
830
831if(BUILD_PERF)
832	set(PERF_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/perf-main.c)
833	if(UNIX AND NOT APPLE)
834		list(APPEND PERF_LIB rt)
835	endif()
836
837	add_executable(${BINARY_NAME}-perf ${PERF_SRC})
838	target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB} ${OS_LIB})
839	set_target_properties(${BINARY_NAME}-perf PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
840	install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
841	install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
842endif()
843
844if(BUILD_TEST)
845	add_executable(${BINARY_NAME}-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/fuzz-main.c)
846	target_link_libraries(${BINARY_NAME}-fuzz ${BINARY_NAME})
847	set_target_properties(${BINARY_NAME}-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
848	add_executable(tbl-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/tbl-fuzz-main.c)
849	target_link_libraries(tbl-fuzz ${BINARY_NAME})
850	set_target_properties(tbl-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
851	install(TARGETS ${BINARY_NAME}-fuzz tbl-fuzz DESTINATION bin COMPONENT ${BINARY_NAME}-test)
852endif()
853
854if(NOT USE_CMOCKA)
855	set(BUILD_SUITE OFF)
856endif()
857if(BUILD_SUITE)
858	enable_testing()
859	include_directories(AFTER ${CMOCKA_INCLUDE_DIRS})
860	link_directories(${CMOCKA_LIBRARY_DIRS})
861
862	add_executable(${BINARY_NAME}-suite ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/suite-main.c ${TEST_SRC})
863	target_link_libraries(${BINARY_NAME}-suite ${BINARY_NAME} ${PLATFORM_LIBRARY} cmocka)
864	set_target_properties(${BINARY_NAME}-suite PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
865	add_test(${BINARY_NAME}-suite ${BINARY_NAME}-suite)
866endif()
867
868if(BUILD_PYTHON)
869	enable_testing()
870	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/python ${CMAKE_CURRENT_BINARY_DIR}/python)
871endif()
872
873if(BUILD_EXAMPLE)
874	add_executable(${BINARY_NAME}-example-server ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/server.c)
875	target_link_libraries(${BINARY_NAME}-example-server ${BINARY_NAME})
876	set_target_properties(${BINARY_NAME}-example-server PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
877
878	if(BUILD_SDL)
879		add_executable(${BINARY_NAME}-example-client ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/client.c)
880		target_link_libraries(${BINARY_NAME}-example-client ${BINARY_NAME} ${SDL_LIBRARY} ${SDLMAIN_LIBRARY} ${OPENGL_LIBRARY} ${OPENGLES2_LIBRARY})
881		set_target_properties(${BINARY_NAME}-example-client PROPERTIES
882		                      COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}"
883		                      INCLUDE_DIRECTORIES "${SDL_INCLUDE_DIR};${CMAKE_CURRENT_SOURCE_DIR}/src;${CMAKE_CURRENT_SOURCE_DIR}/include")
884	endif()
885endif()
886
887configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/flags.h.in ${CMAKE_CURRENT_BINARY_DIR}/flags.h)
888install(FILES ${CMAKE_CURRENT_BINARY_DIR}/flags.h DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/mgba COMPONENT lib${BINARY_NAME})
889
890# Packaging
891set(CPACK_PACKAGE_VERSION ${VERSION_STRING})
892set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
893set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
894set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
895set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
896set(CPACK_RESOURCE_FILE_README ${CMAKE_CURRENT_SOURCE_DIR}/README.md)
897
898set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
899set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
900set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
901set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README.md")
902set(CPACK_DEBIAN_PACKAGE_SECTION "games")
903
904SET(CPACK_DEB_COMPONENT_INSTALL ON)
905
906set(CPACK_STRIP_FILES ${BINARY_NAME})
907
908install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/README.md ${CMAKE_CURRENT_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
909
910include(CPack)
911
912# Summaries
913set(SUMMARY_GL_LIST)
914if(USE_EPOXY)
915	set(SUMMARY_GL_LIST "libepoxy")
916else()
917	if(BUILD_GL)
918		list(APPEND SUMMARY_GL_LIST "OpenGL")
919	endif()
920	if(BUILD_GLES2)
921		list(APPEND SUMMARY_GL_LIST "OpenGL|ES 2")
922	endif()
923endif()
924if(NOT SUMMARY_GL_LIST)
925	set(SUMMARY_GL OFF)
926else()
927	string(REPLACE ";" ", " SUMMARY_GL "${SUMMARY_GL_LIST}")
928endif()
929if(USE_LIBZIP)
930	set(SUMMARY_ZIP libzip)
931elseif(USE_MINIZIP)
932	set(SUMMARY_ZIP "minizip (external)")
933elseif(USE_ZLIB)
934	set(SUMMARY_ZIP "minizip (included)")
935else()
936	set(SUMMARY_ZIP OFF)
937endif()
938
939if(NOT QUIET)
940	message(STATUS "Build type: ${CMAKE_BUILD_TYPE}")
941	message(STATUS "Platforms:")
942	message(STATUS "	Game Boy Advance: ${M_CORE_GBA}")
943	message(STATUS "	Game Boy: ${M_CORE_GB}")
944	message(STATUS "Features:")
945	message(STATUS "	Debuggers: ${USE_DEBUGGERS}")
946	if(NOT WIN32)
947		message(STATUS "	CLI debugger: ${USE_EDITLINE}")
948	endif()
949	message(STATUS "	GDB stub: ${USE_GDB_STUB}")
950	message(STATUS "	Video recording: ${USE_FFMPEG}")
951	message(STATUS "	GIF recording: ${USE_MAGICK}")
952	message(STATUS "	Screenshot/advanced savestate support: ${USE_PNG}")
953	message(STATUS "	ZIP support: ${SUMMARY_ZIP}")
954	message(STATUS "	7-Zip support: ${USE_LZMA}")
955	message(STATUS "	SQLite3 game database: ${USE_SQLITE3}")
956	message(STATUS "	OpenGL support: ${SUMMARY_GL}")
957	message(STATUS "Frontends:")
958	message(STATUS "	Qt: ${BUILD_QT}")
959	message(STATUS "	SDL (${SDL_VERSION}): ${BUILD_SDL}")
960	message(STATUS "	Profiling: ${BUILD_PERF}")
961	message(STATUS "	Test harness: ${BUILD_TEST}")
962	message(STATUS "	Test suite: ${BUILD_SUITE}")
963	message(STATUS "	Python bindings: ${BUILD_PYTHON}")
964	message(STATUS "	Examples: ${BUILD_EXAMPLE}")
965	message(STATUS "Cores:")
966	message(STATUS "	Libretro core: ${BUILD_LIBRETRO}")
967	if(APPLE)
968		message(STATUS "	OpenEmu core: ${BUILD_OPENEMU}")
969	endif()
970	message(STATUS "Libraries:")
971	message(STATUS "	Static: ${BUILD_STATIC}")
972	message(STATUS "	Shared: ${BUILD_SHARED}")
973endif()