CMakeLists.txt (view raw)
1cmake_minimum_required(VERSION 2.6)
2project(mGBA C)
3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
4if(NOT MSVC)
5 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wno-missing-field-initializers -std=c99")
6else()
7 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_CRT_SECURE_NO_WARNINGS /wd4003 /wd4244 /wd4146")
8endif()
9set(USE_EDITLINE ON CACHE BOOL "Whether or not to enable the CLI-mode debugger")
10set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
11set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
12set(USE_ZLIB ON CACHE BOOL "Whether or not to enable zlib support")
13set(USE_MINIZIP ON CACHE BOOL "Whether or not to enable external minizip support")
14set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
15set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable LIBZIP support")
16set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
17set(M_CORE_GBA ON CACHE BOOL "Build Game Boy Advance core")
18set(M_CORE_GB ON CACHE BOOL "Build Game Boy core")
19set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
20set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
21set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
22set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
23if(APPLE)
24 set(BUILD_OPENEMU OFF CACHE BOOL "Build OpenEmu core")
25endif()
26set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
27set(BUILD_TEST OFF CACHE BOOL "Build testing harness")
28set(BUILD_SUITE OFF CACHE BOOL "Build test suite")
29set(BUILD_EXAMPLE OFF CACHE BOOL "Build example frontends")
30set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
31set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
32set(SKIP_LIBRARY OFF CACHE BOOL "Skip building the library (useful for only building libretro or OpenEmu cores)")
33set(BUILD_GL ON CACHE STRING "Build with OpenGL")
34set(BUILD_GLES2 OFF CACHE STRING "Build with OpenGL|ES 2")
35set(USE_EPOXY ON CACHE STRING "Build with libepoxy")
36set(DISABLE_DEPS OFF CACHE BOOL "Build without dependencies")
37file(GLOB ARM_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/*.c)
38file(GLOB ARM_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/test/*.c)
39file(GLOB LR35902_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/*.c)
40file(GLOB LR35902_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/test/*.c)
41file(GLOB GBA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/*.c)
42file(GLOB GBA_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/test/*.c)
43file(GLOB GB_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/*.c)
44file(GLOB GB_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/test/*.c)
45file(GLOB GBA_CHEATS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/cheats/*.c)
46file(GLOB GBA_RR_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/rr/*.c)
47file(GLOB GBA_EXTRA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/extra/*.c)
48file(GLOB CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/*.c)
49file(GLOB CORE_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/test/*.c)
50file(GLOB UTIL_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/*.[cSs])
51file(GLOB UTIL_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/test/*.c)
52file(GLOB GUI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/gui/*.c ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/gui/*.c)
53file(GLOB GBA_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/renderers/*.c)
54file(GLOB SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/sio/lockstep.c)
55file(GLOB GB_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/renderers/*.c)
56file(GLOB THIRD_PARTY_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/inih/*.c)
57set(CLI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/commandline.c)
58set(CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-mem.c)
59set(VFS_SRC)
60source_group("ARM core" FILES ${ARM_SRC})
61source_group("LR35902 core" FILES ${LR35902_SRC})
62source_group("GBA board" FILES ${GBA_SRC} ${GBA_RENDERER_SRC} ${SIO_SRC})
63source_group("GBA extra" FILES ${GBA_CHEATS_SRC} ${GBA_EXTRA_SRC} ${GBA_RR_SRC})
64source_group("GB board" FILES ${GB_SRC})
65source_group("Utilities" FILES ${UTIL_SRC})
66include_directories(BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/src)
67
68if(NOT CMAKE_BUILD_TYPE)
69 set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
70endif()
71
72include(GNUInstallDirs)
73
74set(LIBDIR "${CMAKE_INSTALL_LIBDIR}" CACHE PATH "Installed library directory")
75mark_as_advanced(LIBDIR)
76
77if (BUILD_LIBRETRO)
78 set(LIBRETRO_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (Libretro)")
79 mark_as_advanced(LIBRETRO_LIBDIR)
80endif()
81
82if (BUILD_OPENEMU)
83 set(OE_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (OpenEmu)")
84 mark_as_advanced(OE_LIBDIR)
85endif()
86
87
88set(CMAKE_INSTALL_RPATH "${LIBDIR}")
89
90if (NOT DEFINED MANDIR)
91 set(MANDIR ${CMAKE_INSTALL_MANDIR})
92endif()
93
94# Function definitions
95include(FindPkgConfig)
96function(find_feature FEATURE_NAME FEATURE_REQUIRES)
97 if (NOT ${FEATURE_NAME})
98 return()
99 endif()
100 if (DISABLE_DEPS)
101 set(${FEATURE_NAME} OFF PARENT_SCOPE)
102 return()
103 endif()
104 foreach(REQUIRE ${FEATURE_REQUIRES})
105 if(NOT ${REQUIRE}_FOUND)
106 find_package(${REQUIRE} QUIET)
107 if(NOT ${REQUIRE}_FOUND)
108 pkg_search_module(${REQUIRE} ${REQUIRE})
109 if (NOT ${REQUIRE}_FOUND)
110 message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
111 set(${FEATURE_NAME} OFF PARENT_SCOPE)
112 return()
113 endif()
114 endif()
115 endif()
116 string(TOUPPER ${REQUIRE} UREQUIRE)
117 set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
118 set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
119 set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
120 if (APPLE)
121 set(IS_FRAMEWORK OFF)
122 set(LIBS)
123 foreach(LIB IN LISTS ${REQUIRE}_LIBRARIES)
124 if(LIB STREQUAL "-framework")
125 set(IS_FRAMEWORK ON)
126 elseif(IS_FRAMEWORK)
127 list(APPEND LIBS "-framework ${LIB}")
128 set(IS_FRAMEWORK OFF)
129 else()
130 list(APPEND LIBS ${LIB})
131 endif()
132 endforeach()
133 set(${UREQUIRE}_LIBRARIES ${LIBS} PARENT_SCOPE)
134 else()
135 set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
136 endif()
137 set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
138 set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
139 endforeach()
140endfunction()
141
142# Version information
143add_custom_target(version-info ALL
144 COMMAND ${CMAKE_COMMAND}
145 -DBINARY_NAME=${BINARY_NAME}
146 -DCONFIG_FILE=${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in
147 -DOUT_FILE=${CMAKE_CURRENT_BINARY_DIR}/version.c
148 -P ${CMAKE_CURRENT_SOURCE_DIR}/version.cmake
149 WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
150
151include(${CMAKE_CURRENT_SOURCE_DIR}/version.cmake)
152configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in ${CMAKE_CURRENT_BINARY_DIR}/version.c)
153list(APPEND UTIL_SRC ${CMAKE_CURRENT_BINARY_DIR}/version.c)
154source_group("Generated sources" FILES ${CMAKE_CURRENT_BINARY_DIR}/version.c)
155
156# Advanced settings
157set(BUILD_LTO ON CACHE BOOL "Build with link-time optimization")
158set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
159set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
160set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
161mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
162set(PGO_PRE_FLAGS "-fprofile-generate=${PGO_DIR} -fprofile-arcs")
163set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
164
165if(BUILD_PGO AND NOT PGO_STAGE_2)
166 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
167 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
168 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
169elseif(BUILD_PGO AND PGO_STAGE_2)
170 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
171 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
172 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
173endif()
174
175# Platform support
176if(WIN32)
177 set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
178 add_definitions(-D_WIN32_WINNT=0x0600)
179 list(APPEND OS_LIB ws2_32 shlwapi)
180 list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/vfs-w32.c)
181 file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/*.c)
182 source_group("Windows-specific code" FILES ${OS_SRC})
183 if(MSVC)
184 add_definitions(-DNOMINMAX -DWIN32_LEAN_AND_MEAN)
185 endif()
186elseif(UNIX)
187 add_definitions(-DUSE_PTHREADS)
188
189 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
190 add_definitions(-D_GNU_SOURCE)
191 endif()
192 if(NOT APPLE AND NOT HAIKU)
193 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
194 endif()
195
196 list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
197 file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/posix/*.c)
198 source_group("POSIX-specific code" FILES ${OS_SRC})
199endif()
200
201if(APPLE)
202 add_definitions(-D_DARWIN_C_SOURCE)
203 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
204endif()
205
206if(NOT HAIKU AND NOT MSVC AND NOT PSP2)
207 set(M_LIBRARY m)
208endif()
209list(APPEND OS_LIB ${M_LIBRARY})
210
211if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
212 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
213 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
214endif()
215
216if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
217 if(NOT BUILD_EGL)
218 add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
219 endif()
220endif()
221
222if(BUILD_RASPI)
223 set(BUILD_GL OFF CACHE BOOL "OpenGL not supported" FORCE)
224endif()
225
226if(BUILD_PANDORA)
227 add_definitions(-DBUILD_PANDORA)
228endif()
229
230if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
231 enable_language(ASM)
232endif()
233
234if(PSP2 OR WII)
235 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-format")
236endif()
237
238if(DEFINED 3DS OR DEFINED PSP2 OR DEFINED WII OR NOT M_CORE_GBA)
239 set(USE_GDB_STUB OFF)
240endif()
241
242if(WII)
243 add_definitions(-U__STRICT_ANSI__)
244endif()
245
246include(CheckFunctionExists)
247check_function_exists(strdup HAVE_STRDUP)
248check_function_exists(strndup HAVE_STRNDUP)
249check_function_exists(localtime_r HAVE_LOCALTIME_R)
250if(NOT CMAKE_SYSTEM_NAME STREQUAL "Generic")
251 check_function_exists(snprintf_l HAVE_SNPRINTF_L)
252 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
253 # The strtof_l on Linux not actually exposed nor actually strtof_l
254 set(HAVE_STRTOF_L OFF)
255 else()
256 check_function_exists(strtof_l HAVE_STRTOF_L)
257 endif()
258 check_function_exists(newlocale HAVE_NEWLOCALE)
259 check_function_exists(freelocale HAVE_FREELOCALE)
260 check_function_exists(uselocale HAVE_USELOCALE)
261 check_function_exists(setlocale HAVE_SETLOCALE)
262else()
263 if(NOT DEFINED 3DS AND NOT DEFINED PSP2 AND NOT DEFINED WII)
264 set(DISABLE_DEPS ON CACHE BOOL "This platform cannot build with dependencies" FORCE)
265 endif()
266 set(DISABLE_FRONTENDS ON)
267 set(MINIMAL_CORE ON)
268endif()
269
270check_function_exists(chmod HAVE_CHMOD)
271check_function_exists(umask HAVE_UMASK)
272
273set(FUNCTION_DEFINES)
274
275if(HAVE_STRDUP)
276 list(APPEND FUNCTION_DEFINES HAVE_STRDUP)
277endif()
278
279if(HAVE_STRNDUP)
280 list(APPEND FUNCTION_DEFINES HAVE_STRNDUP)
281endif()
282
283if(HAVE_LOCALTIME_R)
284 list(APPEND FUNCTION_DEFINES HAVE_LOCALTIME_R)
285endif()
286
287if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE OR APPLE)
288 list(APPEND FUNCTION_DEFINES HAVE_LOCALE)
289 if (HAVE_STRTOF_L)
290 list(APPEND FUNCTION_DEFINES HAVE_STRTOF_L)
291 endif()
292 if (HAVE_SNPRINTF_L)
293 list(APPEND FUNCTION_DEFINES HAVE_SNPRINTF_L)
294 endif()
295endif()
296
297if(HAVE_SETLOCALE)
298 list(APPEND FUNCTION_DEFINES HAVE_SETLOCALE)
299endif()
300
301if(HAVE_CHMOD)
302 list(APPEND FUNCTION_DEFINES HAVE_CHMOD)
303endif()
304
305if(HAVE_UMASK)
306 list(APPEND FUNCTION_DEFINES HAVE_UMASK)
307endif()
308
309# Feature dependencies
310set(FEATURES)
311if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
312 set(LIBEDIT_LIBRARIES -ledit)
313 if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
314 list(APPEND LIBEDIT_LIBRARIES -ltermcap)
315 endif()
316else()
317 find_feature(USE_EDITLINE "libedit")
318endif()
319if(BUILD_GL)
320 find_package(OpenGL QUIET)
321 if(NOT OPENGL_FOUND)
322 set(BUILD_GL OFF CACHE BOOL "OpenGL not found" FORCE)
323 endif()
324endif()
325if(NOT BUILD_GL)
326 set(OPENGLE_LIBRARY "" CACHE PATH "" FORCE)
327endif()
328if(BUILD_GLES2 AND NOT BUILD_RASPI)
329 find_path(OPENGLES2_INCLUDE_DIR NAMES GLES2/gl2.h)
330 find_library(OPENGLES2_LIBRARY NAMES GLESv2 GLESv2_CM)
331 if(NOT OPENGLES2_INCLUDE_DIR OR NOT OPENGLES2_LIBRARY)
332 set(BUILD_GLES2 OFF CACHE BOOL "OpenGL|ES 2 not found" FORCE)
333 endif()
334endif()
335if(NOT BUILD_GLES2)
336 set(OPENGLES2_LIBRARY "" CACHE PATH "" FORCE)
337endif()
338set(WANT_ZLIB ${USE_ZLIB})
339set(WANT_PNG ${USE_PNG})
340set(WANT_LIBZIP ${USE_LIBZIP})
341set(USE_CMOCKA ${BUILD_SUITE})
342
343find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
344find_feature(USE_ZLIB "ZLIB")
345find_feature(USE_MINIZIP "minizip")
346find_feature(USE_PNG "PNG")
347find_feature(USE_LIBZIP "libzip")
348find_feature(USE_MAGICK "MagickWand")
349find_feature(USE_EPOXY "epoxy")
350find_feature(USE_CMOCKA "cmocka")
351
352# Features
353set(DEBUGGER_SRC
354 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/debugger.c
355 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/parser.c
356 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/cli-debugger.c)
357
358set(FEATURE_SRC)
359set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
360
361if(DISABLE_DEPS)
362 set(USE_GDB_STUB OFF)
363endif()
364
365if(USE_EDITLINE)
366 list(APPEND FEATURES EDITLINE)
367 include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
368 link_directories(${LIBEDIT_LIBRARY_DIRS})
369 set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
370 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
371 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/editline/cli-el-backend.c")
372else()
373 set(DEBUGGER_LIB "")
374endif()
375
376if(USE_GDB_STUB)
377 list(APPEND FEATURES GDB_STUB)
378 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/gdb-stub.c)
379endif()
380source_group("Debugger" FILES ${DEBUGGER_SRC})
381
382if(USE_FFMPEG)
383 list(APPEND FEATURES FFMPEG)
384 pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
385 if(NOT LIBSWRESAMPLE_FOUND)
386 list(APPEND FEATURES LIBAV)
387 endif()
388 include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
389 link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
390 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/ffmpeg/ffmpeg-encoder.c")
391 string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
392 string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
393 string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
394 string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
395 string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
396 list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
397 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR}|libavcodec-extra-${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
398 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavformat${LIBAVFORMAT_VERSION_MAJOR}|libavformat-ffmpeg${LIBAVFORMAT_VERSION_MAJOR}")
399 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavresample${LIBAVRESAMPLE_VERSION_MAJOR}|libavresample-ffmpeg${LIBAVRESAMPLE_VERSION_MAJOR}")
400 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavutil${LIBAVUTIL_VERSION_MAJOR}|libavutil-ffmpeg${LIBAVUTIL_VERSION_MAJOR}")
401 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libswscale${LIBSWSCALE_VERSION_MAJOR}|libswscale-ffmpeg${LIBSWSCALE_VERSION_MAJOR}")
402 set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
403 if(APPLE)
404 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
405 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
406 endif()
407endif()
408
409list(APPEND THIRD_PARTY_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
410
411if(USE_MAGICK)
412 list(APPEND FEATURES MAGICK)
413 include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
414 link_directories(${MAGICKWAND_LIBRARY_DIRS})
415 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/imagemagick/imagemagick-gif-encoder.c")
416 list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
417 string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
418 if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
419 set(MAGICKWAND_DEB_VERSION "5")
420 else()
421 set(MAGICKWAND_DEB_VERSION "-6.q16-2")
422 endif()
423 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
424endif()
425
426if(WANT_ZLIB AND NOT USE_ZLIB)
427 set(SKIP_INSTALL_ALL ON)
428 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib zlib)
429 set_property(TARGET zlibstatic PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/zlib;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib)
430 set_property(TARGET zlib PROPERTY EXCLUDE_FROM_ALL ON)
431 set_property(TARGET example PROPERTY EXCLUDE_FROM_ALL ON)
432 set_property(TARGET minigzip PROPERTY EXCLUDE_FROM_ALL ON)
433 set(ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
434 set(ZLIB_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
435 set(ZLIB_LIBRARY zlibstatic)
436 list(APPEND DEPENDENCY_LIB zlibstatic)
437 set(USE_ZLIB ON)
438endif()
439
440if(USE_ZLIB)
441 list(APPEND FEATURES ZLIB)
442 include_directories(AFTER ${ZLIB_INCLUDE_DIRS})
443 list(APPEND DEPENDENCY_LIB ${ZLIB_LIBRARIES})
444 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},zlib1g")
445endif()
446
447if(WANT_PNG AND USE_ZLIB AND NOT USE_PNG)
448 set(PNG_STATIC ON CACHE BOOL "" FORCE)
449 set(PNG_SHARED OFF CACHE BOOL "" FORCE)
450 set(PNG_TESTS OFF CACHE BOOL "" FORCE)
451 set(SKIP_INSTALL_ALL ON)
452 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng libpng)
453 set_property(TARGET png16_static PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/libpng;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng;${ZLIB_INCLUDE_DIRS})
454 set(PNG_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng ${CMAKE_CURRENT_BINARY_DIR}/libpng)
455 list(APPEND DEPENDENCY_LIB png16_static)
456 set(USE_PNG ON)
457endif()
458
459if(USE_PNG)
460 list(APPEND FEATURES PNG)
461 include_directories(AFTER ${PNG_INCLUDE_DIRS})
462 list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
463 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng12-0")
464endif()
465
466if(USE_LIBZIP)
467 include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
468 link_directories(${LIBZIP_LIBRARY_DIRS})
469 list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
470 list(APPEND FEATURES LIBZIP)
471 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
472 string(REGEX MATCH "^[0-9]+" LIBZIP_VERSION_MAJOR ${libzip_VERSION})
473 if (LIBZIP_VERSION_MAJOR LESS 1)
474 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
475 elseif(LIBZIP_VERSION_MAJOR EQUAL 1)
476 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip4")
477 else()
478 message(AUTHOR_WARNING Unknown version of libzip detected: ${libzip_VERSION})
479 endif()
480elseif(USE_MINIZIP)
481 include_directories(AFTER ${MINIZIP_INCLUDE_DIRS})
482 link_directories(${MINIZIP_LIBRARY_DIRS})
483 list(APPEND DEPENDENCY_LIB ${MINIZIP_LIBRARIES})
484 list(APPEND FEATURES MINIZIP)
485 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
486 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libminizip1")
487elseif(USE_ZLIB)
488 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c
489 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
490 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c)
491 set_source_files_properties(
492 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
493 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c
494 PROPERTIES COMPILE_FLAGS "-Wno-unused-parameter -Wno-implicit-function-declaration")
495endif()
496
497if (USE_LZMA)
498 include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/third-party/lzma)
499 add_definitions(-D_7ZIP_PPMD_SUPPPORT)
500 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-lzma.c)
501 set(LZMA_SRC
502 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
503 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
504 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
505 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
506 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
507 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
508 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zDec.c
509 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
510 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Delta.c
511 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
512 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
513 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra.c
514 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra86.c
515 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/BraIA64.c
516 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
517 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
518 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
519 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zFile.c
520 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
521 list(APPEND VFS_SRC ${LZMA_SRC})
522 list(APPEND FEATURES LZMA)
523endif()
524
525if(USE_EPOXY)
526 add_definitions(-DBUILD_GL -DBUILD_GLES2)
527 list(APPEND FEATURES EPOXY)
528 include_directories(AFTER ${EPOXY_INCLUDE_DIRS})
529 set(OPENGLES2_LIBRARY ${EPOXY_LIBRARIES})
530 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libepoxy0")
531endif()
532
533
534set(FEATURE_DEFINES)
535foreach(FEATURE IN LISTS FEATURES)
536 list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
537endforeach()
538
539set(TEST_SRC ${CORE_TEST_SRC})
540if(M_CORE_GB)
541 add_definitions(-DM_CORE_GB)
542 list(APPEND CORE_SRC
543 ${LR35902_SRC}
544 ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/debugger.c
545 ${GB_SRC}
546 ${GB_RENDERER_SRC})
547 list(APPEND CLI_SRC
548 ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/cli-debugger.c)
549 list(APPEND TEST_SRC
550 ${LR35902_TEST_SRC}
551 ${GB_TEST_SRC})
552endif()
553
554if(M_CORE_GBA)
555 add_definitions(-DM_CORE_GBA)
556 list(APPEND CORE_SRC
557 ${ARM_SRC}
558 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/debugger.c
559 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/memory-debugger.c
560 ${GBA_SRC}
561 ${GBA_CHEATS_SRC}
562 ${GBA_RENDERER_SRC})
563 list(APPEND CLI_SRC
564 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c
565 ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/extra/cli.c)
566 list(APPEND TEST_SRC
567 ${ARM_TEST_SRC}
568 ${GBA_TEST_SRC})
569 if(NOT M_CORE_GB)
570 list(APPEND CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/audio.c)
571 endif()
572endif()
573
574source_group("Virtual files" FILES ${CORE_VFS_SRC} ${VFS_SRC})
575source_group("Extra features" FILES ${FEATURE_SRC})
576source_group("Third-party code" FILES ${THIRD_PARTY_SRC})
577
578# Platform binaries
579if(3DS)
580 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/3ds ${CMAKE_CURRENT_BINARY_DIR}/3ds)
581endif()
582
583if(WII)
584 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/wii ${CMAKE_CURRENT_BINARY_DIR}/wii)
585endif()
586
587if(PSP2)
588 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/psp2 ${CMAKE_CURRENT_BINARY_DIR}/psp2)
589endif()
590
591# Binaries
592list(APPEND CORE_SRC
593 ${UTIL_SRC}
594 ${CORE_VFS_SRC}
595 ${DEBUGGER_SRC}
596 ${OS_SRC}
597 ${THIRD_PARTY_SRC})
598list(APPEND TEST_SRC ${UTIL_TEST_SRC})
599
600set(SRC ${CORE_SRC} ${VFS_SRC})
601if(NOT MINIMAL_CORE)
602 if(M_CORE_GBA)
603 list(APPEND SRC
604 ${GBA_RR_SRC}
605 ${GBA_EXTRA_SRC}
606 ${SIO_SRC})
607 endif()
608 list(APPEND SRC
609 ${FEATURE_SRC}
610 ${CLI_SRC})
611endif()
612
613if(NOT SKIP_LIBRARY)
614 if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
615 set(BUILD_SHARED ON)
616 endif()
617
618 if(BUILD_SHARED)
619 add_library(${BINARY_NAME} SHARED ${SRC} ${VFS_SRC})
620 if(BUILD_STATIC)
621 add_library(${BINARY_NAME}-static STATIC ${SRC})
622 set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
623 install(TARGETS ${BINARY_NAME}-static DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
624 add_dependencies(${BINARY_NAME}-static version-info)
625 endif()
626 else()
627 add_library(${BINARY_NAME} STATIC ${SRC})
628 endif()
629
630 add_dependencies(${BINARY_NAME} version-info)
631 set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
632
633 target_link_libraries(${BINARY_NAME} ${DEBUGGER_LIB} ${DEPENDENCY_LIB} ${OS_LIB})
634 install(TARGETS ${BINARY_NAME} LIBRARY DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME} NAMELINK_SKIP ARCHIVE DESTINATION ${LIBDIR} RUNTIME DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
635 if(UNIX AND NOT APPLE)
636 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-16.png DESTINATION share/icons/hicolor/16x16/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
637 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-24.png DESTINATION share/icons/hicolor/24x24/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
638 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-32.png DESTINATION share/icons/hicolor/32x32/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
639 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-48.png DESTINATION share/icons/hicolor/48x48/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
640 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-64.png DESTINATION share/icons/hicolor/64x64/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
641 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-96.png DESTINATION share/icons/hicolor/96x96/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
642 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-128.png DESTINATION share/icons/hicolor/128x128/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
643 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-256.png DESTINATION share/icons/hicolor/256x256/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
644 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-512.png DESTINATION share/icons/hicolor/512x512/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
645 endif()
646else()
647 set(BUILD_SHARED OFF)
648 set(BUILD_STATIC OFF)
649 find_library(${BINARY_NAME} ${BINARY_NAME})
650 if(NOT ${BINARY_NAME}_FOUND)
651 set(DISABLE_FRONTENDS ON)
652 set(BUILD_PERF OFF)
653 set(BUILD_TEST OFF)
654 set(BUILD_SUITE OFF)
655 endif()
656endif()
657
658if(BUILD_GL)
659 add_definitions(-DBUILD_GL)
660endif()
661
662if(BUILD_GLES2)
663 add_definitions(-DBUILD_GLES2)
664endif()
665
666if(DISABLE_FRONTENDS)
667 set(BUILD_SDL OFF)
668 set(BUILD_QT OFF)
669endif()
670
671if(BUILD_LIBRETRO)
672 file(GLOB RETRO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/libretro/*.c)
673 add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
674 set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5;DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=2")
675 target_link_libraries(${BINARY_NAME}_libretro ${OS_LIB})
676 install(TARGETS ${BINARY_NAME}_libretro LIBRARY DESTINATION ${LIBRETRO_LIBDIR} COMPONENT ${BINARY_NAME}_libretro NAMELINK_SKIP)
677endif()
678
679if(BUILD_OPENEMU)
680 find_library(FOUNDATION Foundation)
681 find_library(OPENEMUBASE OpenEmuBase)
682 file(GLOB OE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/*.m)
683 add_library(${BINARY_NAME}-openemu MODULE ${CORE_SRC} ${OE_SRC})
684 set_target_properties(${BINARY_NAME}-openemu PROPERTIES
685 MACOSX_BUNDLE_INFO_PLIST ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/Info.plist.in
686 BUNDLE TRUE
687 BUNDLE_EXTENSION oecoreplugin
688 OUTPUT_NAME ${PROJECT_NAME}
689 COMPILE_DEFINITIONS "DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=1")
690 target_link_libraries(${BINARY_NAME}-openemu ${OS_LIB} ${FOUNDATION} ${OPENEMUBASE})
691 install(TARGETS ${BINARY_NAME}-openemu LIBRARY DESTINATION ${OE_LIBDIR} COMPONENT ${BINARY_NAME}.oecoreplugin NAMELINK_SKIP)
692endif()
693
694if(BUILD_SDL)
695 add_definitions(-DBUILD_SDL)
696 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/sdl ${CMAKE_CURRENT_BINARY_DIR}/sdl)
697endif()
698
699if(BUILD_QT)
700 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/qt ${CMAKE_CURRENT_BINARY_DIR}/qt)
701endif()
702
703if(BUILD_PERF)
704 set(PERF_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/perf-main.c ${CLI_SRC})
705 if(UNIX AND NOT APPLE)
706 list(APPEND PERF_LIB rt)
707 endif()
708
709 add_executable(${BINARY_NAME}-perf ${PERF_SRC})
710 target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB} ${OS_LIB})
711 set_target_properties(${BINARY_NAME}-perf PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
712 install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
713 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
714endif()
715
716if(BUILD_TEST)
717 add_executable(${BINARY_NAME}-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/fuzz-main.c)
718 target_link_libraries(${BINARY_NAME}-fuzz ${BINARY_NAME})
719 set_target_properties(${BINARY_NAME}-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
720 install(TARGETS ${BINARY_NAME}-fuzz DESTINATION bin COMPONENT ${BINARY_NAME}-test)
721endif()
722
723if(NOT USE_CMOCKA)
724 set(BUILD_SUITE OFF)
725endif()
726if(BUILD_SUITE)
727 enable_testing()
728 include_directories(AFTER ${CMOCKA_INCLUDE_DIRS})
729 link_directories(${CMOCKA_LIBRARY_DIRS})
730
731 add_executable(${BINARY_NAME}-suite ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/suite-main.c ${TEST_SRC})
732 target_link_libraries(${BINARY_NAME}-suite ${BINARY_NAME} ${PLATFORM_LIBRARY} cmocka)
733 set_target_properties(${BINARY_NAME}-suite PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
734 add_test(${BINARY_NAME}-suite ${BINARY_NAME}-suite)
735endif()
736
737if(BUILD_EXAMPLE)
738 add_executable(${BINARY_NAME}-example-server ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/server.c)
739 target_link_libraries(${BINARY_NAME}-example-server ${BINARY_NAME})
740 set_target_properties(${BINARY_NAME}-example-server PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
741
742 if(BUILD_SDL)
743 add_executable(${BINARY_NAME}-example-client ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/client.c)
744 target_link_libraries(${BINARY_NAME}-example-client ${BINARY_NAME} ${SDL_LIBRARY} ${SDLMAIN_LIBRARY} ${OPENGL_LIBRARY} ${OPENGLES2_LIBRARY})
745 set_target_properties(${BINARY_NAME}-example-client PROPERTIES
746 COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}"
747 INCLUDE_DIRECTORIES "${SDL_INCLUDE_DIR};${CMAKE_CURRENT_SOURCE_DIR}/src")
748 endif()
749endif()
750
751# Packaging
752set(CPACK_PACKAGE_VERSION ${VERSION_STRING})
753set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
754set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
755set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
756set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
757set(CPACK_RESOURCE_FILE_README ${CMAKE_CURRENT_SOURCE_DIR}/README.md)
758
759set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
760set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
761set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
762set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README.md")
763set(CPACK_DEBIAN_PACKAGE_SECTION "games")
764
765SET(CPACK_DEB_COMPONENT_INSTALL ON)
766
767set(CPACK_STRIP_FILES ${BINARY_NAME})
768
769install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/README.md ${CMAKE_CURRENT_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
770
771include(CPack)
772
773# Summaries
774set(SUMMARY_GL_LIST)
775if(USE_EPOXY)
776 set(SUMMARY_GL_LIST "libepoxy")
777else()
778 if(BUILD_GL)
779 list(APPEND SUMMARY_GL_LIST "OpenGL")
780 endif()
781 if(BUILD_GLES2)
782 list(APPEND SUMMARY_GL_LIST "OpenGL|ES 2")
783 endif()
784endif()
785if(NOT SUMMARY_GL_LIST)
786 set(SUMMARY_GL OFF)
787else()
788 string(REPLACE ";" ", " SUMMARY_GL "${SUMMARY_GL_LIST}")
789endif()
790if(USE_LIBZIP)
791 set(SUMMARY_ZIP libzip)
792elseif(USE_MINIZIP)
793 set(SUMMARY_ZIP "minizip (external)")
794elseif(USE_ZLIB)
795 set(SUMMARY_ZIP "minizip (included)")
796else()
797 set(SUMMARY_ZIP OFF)
798endif()
799
800if(NOT QUIET)
801 message(STATUS "Platforms:")
802 message(STATUS " Game Boy Advance: ${M_CORE_GBA}")
803 message(STATUS " Game Boy: ${M_CORE_GB}")
804 message(STATUS "Features:")
805 message(STATUS " CLI debugger: ${USE_EDITLINE}")
806 message(STATUS " GDB stub: ${USE_GDB_STUB}")
807 message(STATUS " Video recording: ${USE_FFMPEG}")
808 message(STATUS " GIF recording: ${USE_MAGICK}")
809 message(STATUS " Screenshot/advanced savestate support: ${USE_PNG}")
810 message(STATUS " ZIP support: ${SUMMARY_ZIP}")
811 message(STATUS " 7-Zip support: ${USE_LZMA}")
812 message(STATUS " OpenGL support: ${SUMMARY_GL}")
813 message(STATUS "Frontends:")
814 message(STATUS " Qt: ${BUILD_QT}")
815 message(STATUS " SDL (${SDL_VERSION}): ${BUILD_SDL}")
816 message(STATUS " Profiling: ${BUILD_PERF}")
817 message(STATUS " Test harness: ${BUILD_TEST}")
818 message(STATUS " Test suite: ${BUILD_SUITE}")
819 message(STATUS " Examples: ${BUILD_EXAMPLE}")
820 message(STATUS "Cores:")
821 message(STATUS " Libretro core: ${BUILD_LIBRETRO}")
822 if(APPLE)
823 message(STATUS " OpenEmu core: ${BUILD_OPENEMU}")
824 endif()
825 message(STATUS "Libraries:")
826 message(STATUS " Static: ${BUILD_STATIC}")
827 message(STATUS " Shared: ${BUILD_SHARED}")
828endif()