1cmake_minimum_required(VERSION 2.6)
  2project(mGBA C)
  3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
  4if(NOT MSVC)
  5	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wno-missing-field-initializers -std=c99")
  6else()
  7	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_CRT_SECURE_NO_WARNINGS /wd4003 /wd4244 /wd4146")
  8endif()
  9set(USE_DEBUGGERS ON CACHE BOOL "Whether or not to enable the debugging infrastructure")
 10set(USE_EDITLINE ON CACHE BOOL "Whether or not to enable the CLI-mode debugger")
 11set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
 12set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
 13set(USE_ZLIB ON CACHE BOOL "Whether or not to enable zlib support")
 14set(USE_MINIZIP ON CACHE BOOL "Whether or not to enable external minizip support")
 15set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
 16set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable LIBZIP support")
 17set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
 18set(USE_SQLITE3 ON CACHE BOOL "Whether or not to enable SQLite3 support")
 19set(M_CORE_GBA ON CACHE BOOL "Build Game Boy Advance core")
 20set(M_CORE_GB ON CACHE BOOL "Build Game Boy core")
 21set(M_CORE_DS ON CACHE BOOL "Build DS core")
 22set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
 23set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
 24set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
 25set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
 26if(APPLE)
 27	set(BUILD_OPENEMU OFF CACHE BOOL "Build OpenEmu core")
 28endif()
 29set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
 30set(BUILD_TEST OFF CACHE BOOL "Build testing harness")
 31set(BUILD_SUITE OFF CACHE BOOL "Build test suite")
 32set(BUILD_EXAMPLE OFF CACHE BOOL "Build example frontends")
 33set(BUILD_PYTHON OFF CACHE BOOL "Build Python bindings")
 34set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
 35set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
 36set(SKIP_LIBRARY OFF CACHE BOOL "Skip building the library (useful for only building libretro or OpenEmu cores)")
 37set(BUILD_GL ON CACHE STRING "Build with OpenGL")
 38set(BUILD_GLES2 OFF CACHE STRING "Build with OpenGL|ES 2")
 39set(USE_EPOXY ON CACHE STRING "Build with libepoxy")
 40set(DISABLE_DEPS OFF CACHE BOOL "Build without dependencies")
 41file(GLOB ARM_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/*.c)
 42file(GLOB ARM_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/test/*.c)
 43file(GLOB LR35902_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/*.c)
 44file(GLOB LR35902_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/test/*.c)
 45file(GLOB GBA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/*.c)
 46file(GLOB GBA_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/test/*.c)
 47file(GLOB GB_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/*.c)
 48file(GLOB GB_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/test/*.c)
 49file(GLOB DS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/ds/*.c)
 50file(GLOB GBA_CHEATS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/cheats/*.c)
 51file(GLOB GBA_RR_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/rr/*.c)
 52file(GLOB CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/*.c)
 53file(GLOB CORE_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/test/*.c)
 54file(GLOB UTIL_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/*.[cSs])
 55file(GLOB UTIL_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/test/*.c)
 56file(GLOB GUI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/gui/*.c ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/gui/*.c)
 57file(GLOB GBA_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/renderers/*.c)
 58file(GLOB GBA_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/sio/lockstep.c)
 59file(GLOB GB_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/sio/lockstep.c)
 60file(GLOB GB_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/renderers/*.c)
 61file(GLOB DS_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/ds/renderers/*.c ${CMAKE_CURRENT_SOURCE_DIR}/src/ds/gx/*.c)
 62file(GLOB THIRD_PARTY_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/inih/*.c)
 63set(CLI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/commandline.c)
 64set(CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-mem.c)
 65set(VFS_SRC)
 66source_group("ARM core" FILES ${ARM_SRC})
 67source_group("LR35902 core" FILES ${LR35902_SRC})
 68source_group("GBA board" FILES ${GBA_SRC} ${GBA_RENDERER_SRC} ${GBA_SIO_SRC})
 69source_group("GBA extra" FILES ${GBA_CHEATS_SRC} ${GBA_RR_SRC})
 70source_group("GB board" FILES ${GB_SRC} ${GB_SIO_SRC})
 71source_group("DS board" FILES ${DS_SRC})
 72source_group("Utilities" FILES ${UTIL_SRC})
 73include_directories(BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/include ${CMAKE_CURRENT_SOURCE_DIR}/src)
 74
 75if(NOT CMAKE_BUILD_TYPE)
 76	set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
 77endif()
 78
 79include(GNUInstallDirs)
 80
 81set(LIBDIR "${CMAKE_INSTALL_LIBDIR}" CACHE PATH "Installed library directory")
 82mark_as_advanced(LIBDIR)
 83
 84if (BUILD_LIBRETRO)
 85	set(LIBRETRO_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (Libretro)")
 86	mark_as_advanced(LIBRETRO_LIBDIR)
 87endif()
 88
 89if (BUILD_OPENEMU)
 90	set(OE_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (OpenEmu)")
 91	mark_as_advanced(OE_LIBDIR)
 92endif()
 93
 94
 95set(CMAKE_INSTALL_RPATH "${LIBDIR}")
 96
 97if (NOT DEFINED MANDIR)
 98	set(MANDIR ${CMAKE_INSTALL_MANDIR})
 99endif()
100
101# Function definitions
102include(FindPkgConfig)
103function(find_feature FEATURE_NAME FEATURE_REQUIRES)
104	if (NOT ${FEATURE_NAME})
105		return()
106	endif()
107	if (DISABLE_DEPS)
108		set(${FEATURE_NAME} OFF PARENT_SCOPE)
109		return()
110	endif()
111	foreach(REQUIRE ${FEATURE_REQUIRES})
112		if(NOT ${REQUIRE}_FOUND)
113			find_package(${REQUIRE} QUIET)
114			if(NOT ${REQUIRE}_FOUND)
115				pkg_search_module(${REQUIRE} ${REQUIRE})
116				if (NOT ${REQUIRE}_FOUND)
117					message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
118					set(${FEATURE_NAME} OFF PARENT_SCOPE)
119					return()
120				endif()
121			endif()
122		endif()
123		string(TOUPPER ${REQUIRE} UREQUIRE)
124		set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
125		set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
126		set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
127		if (APPLE)
128			set(IS_FRAMEWORK OFF)
129			set(LIBS)
130			foreach(LIB IN LISTS ${REQUIRE}_LIBRARIES)
131				if(LIB STREQUAL "-framework")
132					set(IS_FRAMEWORK ON)
133				elseif(IS_FRAMEWORK)
134					list(APPEND LIBS "-framework ${LIB}")
135					set(IS_FRAMEWORK OFF)
136				else()
137					list(APPEND LIBS ${LIB})
138				endif()
139			endforeach()
140			set(${UREQUIRE}_LIBRARIES ${LIBS} PARENT_SCOPE)
141		else()
142			set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
143		endif()
144		set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
145		set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
146	endforeach()
147endfunction()
148
149# Version information
150add_custom_target(version-info ALL
151	COMMAND ${CMAKE_COMMAND}
152	-DBINARY_NAME=${BINARY_NAME}
153	-DCONFIG_FILE=${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in
154	-DOUT_FILE=${CMAKE_CURRENT_BINARY_DIR}/version.c
155	-P ${CMAKE_CURRENT_SOURCE_DIR}/version.cmake
156	WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
157
158include(${CMAKE_CURRENT_SOURCE_DIR}/version.cmake)
159configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in ${CMAKE_CURRENT_BINARY_DIR}/version.c)
160configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/flags.h.in ${CMAKE_CURRENT_BINARY_DIR}/flags.h)
161install(FILES ${CMAKE_CURRENT_BINARY_DIR}/flags.h DESTINATION include/mgba COMPONENT lib${BINARY_NAME})
162
163list(APPEND UTIL_SRC ${CMAKE_CURRENT_BINARY_DIR}/version.c)
164source_group("Generated sources" FILES ${CMAKE_CURRENT_BINARY_DIR}/version.c)
165
166# Advanced settings
167if(NOT DEFINED 3DS)
168	# LTO appears to make 3DS binary slower
169	set(DEFAULT_LTO ON)
170else()
171	set(DEFAULT_LTO OFF)
172endif()
173
174set(BUILD_LTO ${DEFAULT_LTO} CACHE BOOL "Build with link-time optimization")
175set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
176set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
177set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
178mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
179set(PGO_PRE_FLAGS "-fprofile-generate=${PGO_DIR} -fprofile-arcs")
180set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
181
182if(BUILD_PGO AND NOT PGO_STAGE_2)
183	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
184	set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
185	set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
186elseif(BUILD_PGO AND PGO_STAGE_2)
187	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
188	set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
189	set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
190endif()
191
192# Platform support
193if(WIN32)
194	set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
195	add_definitions(-D_WIN32_WINNT=0x0600)
196	list(APPEND OS_LIB ws2_32 shlwapi)
197	list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/vfs-w32.c)
198	file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/*.c)
199	source_group("Windows-specific code" FILES ${OS_SRC})
200	if(MSVC)
201		add_definitions(-DNOMINMAX -DWIN32_LEAN_AND_MEAN)
202		set(CMAKE_WINDOWS_EXPORT_ALL_SYMBOLS TRUE)
203	endif()
204elseif(UNIX)
205	add_definitions(-DUSE_PTHREADS)
206
207	if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
208		add_definitions(-D_GNU_SOURCE)
209	endif()
210	if(NOT APPLE AND NOT HAIKU)
211		set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
212	endif()
213
214	list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
215	file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/posix/*.c)
216	source_group("POSIX-specific code" FILES ${OS_SRC})
217endif()
218
219if(APPLE)
220	add_definitions(-D_DARWIN_C_SOURCE)
221	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
222endif()
223
224if(NOT HAIKU AND NOT MSVC AND NOT PSP2)
225	set(M_LIBRARY m)
226endif()
227list(APPEND OS_LIB ${M_LIBRARY})
228
229if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
230	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
231	set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
232endif()
233
234if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
235	if(NOT BUILD_EGL)
236		add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
237	endif()
238endif()
239
240if(BUILD_RASPI)
241	set(BUILD_GL OFF CACHE BOOL "OpenGL not supported" FORCE)
242endif()
243
244if(BUILD_PANDORA)
245	add_definitions(-DBUILD_PANDORA)
246endif()
247
248if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
249	enable_language(ASM)
250endif()
251
252if(PSP2 OR WII)
253	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-format")
254endif()
255
256if(DEFINED 3DS OR DEFINED PSP2 OR DEFINED WII)
257	set(USE_DEBUGGERS OFF)
258	set(USE_SQLITE3 OFF)
259endif()
260
261if(NOT M_CORE_GBA)
262	set(USE_GDB_STUB OFF)
263endif()
264
265if(NOT USE_DEBUGGERS)
266	set(USE_EDITLINE OFF)
267	set(USE_GDB_STUB OFF)
268endif()
269
270if(WII)
271	add_definitions(-U__STRICT_ANSI__)
272endif()
273
274if(DEFINED 3DS)
275	add_definitions(-D_GNU_SOURCE)
276endif()
277
278include(CheckFunctionExists)
279check_function_exists(strdup HAVE_STRDUP)
280check_function_exists(strndup HAVE_STRNDUP)
281check_function_exists(localtime_r HAVE_LOCALTIME_R)
282if(NOT CMAKE_SYSTEM_NAME STREQUAL "Generic")
283	check_function_exists(snprintf_l HAVE_SNPRINTF_L)
284	if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
285		# The strtof_l on Linux not actually exposed nor actually strtof_l
286		set(HAVE_STRTOF_L OFF)
287	else()
288		check_function_exists(strtof_l HAVE_STRTOF_L)
289	endif()
290	check_function_exists(newlocale HAVE_NEWLOCALE)
291	check_function_exists(freelocale HAVE_FREELOCALE)
292	check_function_exists(uselocale HAVE_USELOCALE)
293	check_function_exists(setlocale HAVE_SETLOCALE)
294else()
295	if(DEFINED 3DS)
296		check_function_exists(snprintf_l HAVE_SNPRINTF_L)
297		check_function_exists(newlocale HAVE_NEWLOCALE)
298		check_function_exists(freelocale HAVE_FREELOCALE)
299		check_function_exists(uselocale HAVE_USELOCALE)
300		check_function_exists(setlocale HAVE_SETLOCALE)
301	endif()
302	if(NOT DEFINED 3DS AND NOT DEFINED PSP2 AND NOT DEFINED WII)
303		set(DISABLE_DEPS ON CACHE BOOL "This platform cannot build with dependencies" FORCE)
304	endif()
305	set(DISABLE_FRONTENDS ON)
306	set(MINIMAL_CORE ON)
307endif()
308
309check_function_exists(chmod HAVE_CHMOD)
310check_function_exists(umask HAVE_UMASK)
311
312set(FUNCTION_DEFINES)
313
314if(HAVE_STRDUP)
315	list(APPEND FUNCTION_DEFINES HAVE_STRDUP)
316endif()
317
318if(HAVE_STRNDUP)
319	list(APPEND FUNCTION_DEFINES HAVE_STRNDUP)
320endif()
321
322if(HAVE_LOCALTIME_R)
323	list(APPEND FUNCTION_DEFINES HAVE_LOCALTIME_R)
324endif()
325
326if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE OR APPLE OR DEFINED 3DS)
327	list(APPEND FUNCTION_DEFINES HAVE_LOCALE)
328	if (HAVE_STRTOF_L)
329		list(APPEND FUNCTION_DEFINES HAVE_STRTOF_L)
330	endif()
331	if (HAVE_SNPRINTF_L)
332		list(APPEND FUNCTION_DEFINES HAVE_SNPRINTF_L)
333	endif()
334endif()
335
336if(HAVE_SETLOCALE)
337	list(APPEND FUNCTION_DEFINES HAVE_SETLOCALE)
338endif()
339
340if(HAVE_CHMOD)
341	list(APPEND FUNCTION_DEFINES HAVE_CHMOD)
342endif()
343
344if(HAVE_UMASK)
345	list(APPEND FUNCTION_DEFINES HAVE_UMASK)
346endif()
347
348# Feature dependencies
349set(FEATURE_DEFINES)
350set(FEATURES)
351if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
352	set(LIBEDIT_LIBRARIES -ledit)
353	if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
354		list(APPEND LIBEDIT_LIBRARIES -ltermcap)
355	endif()
356else()
357	find_feature(USE_EDITLINE "libedit")
358endif()
359if(BUILD_GL)
360	find_package(OpenGL QUIET)
361	if(NOT OPENGL_FOUND)
362		set(BUILD_GL OFF CACHE BOOL "OpenGL not found" FORCE)
363	endif()
364endif()
365if(NOT BUILD_GL)
366	set(OPENGLE_LIBRARY "" CACHE PATH "" FORCE)
367endif()
368if(BUILD_GLES2 AND NOT BUILD_RASPI)
369	find_path(OPENGLES2_INCLUDE_DIR NAMES GLES2/gl2.h)
370	find_library(OPENGLES2_LIBRARY NAMES GLESv2 GLESv2_CM)
371	if(NOT OPENGLES2_INCLUDE_DIR OR NOT OPENGLES2_LIBRARY)
372		set(BUILD_GLES2 OFF CACHE BOOL "OpenGL|ES 2 not found" FORCE)
373	endif()
374endif()
375if(NOT BUILD_GLES2)
376	set(OPENGLES2_LIBRARY "" CACHE PATH "" FORCE)
377endif()
378set(WANT_ZLIB ${USE_ZLIB})
379set(WANT_PNG ${USE_PNG})
380set(WANT_LIBZIP ${USE_LIBZIP})
381set(WANT_SQLITE3 ${USE_SQLITE3})
382set(USE_CMOCKA ${BUILD_SUITE})
383
384find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
385find_feature(USE_ZLIB "ZLIB")
386find_feature(USE_MINIZIP "minizip")
387find_feature(USE_PNG "PNG")
388find_feature(USE_LIBZIP "libzip")
389find_feature(USE_MAGICK "MagickWand")
390find_feature(USE_EPOXY "epoxy")
391find_feature(USE_CMOCKA "cmocka")
392find_feature(USE_SQLITE3 "sqlite3")
393
394# Features
395set(DEBUGGER_SRC
396	${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/debugger.c
397	${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/parser.c
398	${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/cli-debugger.c)
399
400set(FEATURE_SRC)
401set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
402
403if(DISABLE_DEPS)
404	set(USE_GDB_STUB OFF)
405endif()
406
407if(USE_EDITLINE)
408	list(APPEND FEATURES EDITLINE)
409	list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/cli-debugger.c)
410	list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/parser.c)
411	if(M_CORE_GBA)
412		list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c)
413		list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/extra/cli.c)
414	endif()
415	if(M_CORE_GB)
416		list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/cli-debugger.c)
417	endif()
418	if(M_CORE_DS)
419		list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c)
420		list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/ds/extra/cli.c)
421	endif()
422	include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
423	link_directories(${LIBEDIT_LIBRARY_DIRS})
424	set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
425	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
426	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/editline/cli-el-backend.c")
427else()
428	set(DEBUGGER_LIB "")
429endif()
430
431if(USE_GDB_STUB)
432	list(APPEND FEATURES GDB_STUB)
433	list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/gdb-stub.c)
434endif()
435source_group("Debugger" FILES ${DEBUGGER_SRC})
436
437if(USE_FFMPEG)
438	list(APPEND FEATURES FFMPEG)
439	pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
440	if(NOT LIBSWRESAMPLE_FOUND)
441		list(APPEND FEATURES LIBAV)
442	endif()
443	include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
444	link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
445	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/ffmpeg/ffmpeg-encoder.c")
446	string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
447	string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
448	string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
449	string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
450	string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
451	list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
452	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR}|libavcodec-extra-${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
453	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavformat${LIBAVFORMAT_VERSION_MAJOR}|libavformat-ffmpeg${LIBAVFORMAT_VERSION_MAJOR}")
454	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavresample${LIBAVRESAMPLE_VERSION_MAJOR}|libavresample-ffmpeg${LIBAVRESAMPLE_VERSION_MAJOR}")
455	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavutil${LIBAVUTIL_VERSION_MAJOR}|libavutil-ffmpeg${LIBAVUTIL_VERSION_MAJOR}")
456	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libswscale${LIBSWSCALE_VERSION_MAJOR}|libswscale-ffmpeg${LIBSWSCALE_VERSION_MAJOR}")
457	set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
458	if(APPLE)
459		set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
460		set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
461	endif()
462endif()
463
464list(APPEND THIRD_PARTY_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
465
466if(USE_MAGICK)
467	list(APPEND FEATURES MAGICK)
468	include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
469	link_directories(${MAGICKWAND_LIBRARY_DIRS})
470	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/imagemagick/imagemagick-gif-encoder.c")
471	list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
472	string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
473	string(REGEX MATCH "^[0-9]+" MAGICKWAND_VERSION_MAJOR ${MagickWand_VERSION})
474	if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
475		set(MAGICKWAND_DEB_VERSION "5")
476	elseif(${MagickWand_VERSION} EQUAL "6.9.7")
477		set(MAGICKWAND_DEB_VERSION "-6.q16-3")
478	else()
479		set(MAGICKWAND_DEB_VERSION "-6.q16-2")
480	endif()
481	list(APPEND FEATURE_DEFINES MAGICKWAND_VERSION_MAJOR=${MAGICKWAND_VERSION_MAJOR})
482
483	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
484endif()
485
486if(WANT_ZLIB AND NOT USE_ZLIB)
487	set(SKIP_INSTALL_ALL ON)
488	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib zlib)
489	set_property(TARGET zlibstatic PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/zlib;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib)
490	set_property(TARGET zlib PROPERTY EXCLUDE_FROM_ALL ON)
491	set_property(TARGET example PROPERTY EXCLUDE_FROM_ALL ON)
492	set_property(TARGET minigzip PROPERTY EXCLUDE_FROM_ALL ON)
493	set(ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
494	set(ZLIB_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
495	set(ZLIB_LIBRARY zlibstatic)
496	list(APPEND DEPENDENCY_LIB zlibstatic)
497	set(USE_ZLIB ON)
498endif()
499
500if(USE_ZLIB)
501	list(APPEND FEATURES ZLIB)
502	include_directories(AFTER ${ZLIB_INCLUDE_DIRS})
503	list(APPEND DEPENDENCY_LIB ${ZLIB_LIBRARIES})
504	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},zlib1g")
505endif()
506
507if(WANT_PNG AND USE_ZLIB AND NOT USE_PNG)
508	set(PNG_STATIC ON CACHE BOOL "" FORCE)
509	set(PNG_SHARED OFF CACHE BOOL "" FORCE)
510	set(PNG_TESTS OFF CACHE BOOL "" FORCE)
511	set(SKIP_INSTALL_ALL ON)
512	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng libpng)
513	set_property(TARGET png16_static PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/libpng;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng;${ZLIB_INCLUDE_DIRS})
514	set(PNG_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng ${CMAKE_CURRENT_BINARY_DIR}/libpng)
515	list(APPEND DEPENDENCY_LIB png16_static)
516	set(USE_PNG ON)
517endif()
518
519if(USE_PNG)
520	list(APPEND FEATURES PNG)
521	include_directories(AFTER ${PNG_INCLUDE_DIRS})
522	list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
523	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng12-0")
524endif()
525
526if(WANT_SQLITE3 AND NOT USE_SQLITE3)
527	list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/sqlite3.c)
528	include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/)
529	set(USE_SQLITE3 ON)
530endif()
531
532if(USE_LIBZIP)
533	include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
534	link_directories(${LIBZIP_LIBRARY_DIRS})
535	list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
536	list(APPEND FEATURES LIBZIP)
537	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
538	string(REGEX MATCH "^[0-9]+" LIBZIP_VERSION_MAJOR ${libzip_VERSION})
539	if (LIBZIP_VERSION_MAJOR LESS 1)
540		set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
541	elseif(LIBZIP_VERSION_MAJOR EQUAL 1)
542		set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip4")
543	else()
544		message(AUTHOR_WARNING Unknown version of libzip detected: ${libzip_VERSION})
545	endif()
546elseif(USE_MINIZIP)
547	include_directories(AFTER ${MINIZIP_INCLUDE_DIRS})
548	link_directories(${MINIZIP_LIBRARY_DIRS})
549	list(APPEND DEPENDENCY_LIB ${MINIZIP_LIBRARIES})
550	list(APPEND FEATURES MINIZIP)
551	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
552	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libminizip1")
553elseif(USE_ZLIB)
554	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c
555		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
556		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c)
557	if(NOT MSVC)
558		set_source_files_properties(
559			${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
560			${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c
561			PROPERTIES COMPILE_FLAGS "-Wno-unused-parameter -Wno-implicit-function-declaration")
562	endif()
563endif()
564
565if (USE_LZMA)
566	include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/third-party/lzma)
567	add_definitions(-D_7ZIP_PPMD_SUPPPORT)
568	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-lzma.c)
569	set(LZMA_SRC
570		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
571		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
572		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
573		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
574		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
575		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
576		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zDec.c
577		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
578		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Delta.c
579		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
580		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
581		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra.c
582		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra86.c
583		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/BraIA64.c
584		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
585		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
586		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
587		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zFile.c
588		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
589	list(APPEND VFS_SRC ${LZMA_SRC})
590	list(APPEND FEATURES LZMA)
591endif()
592
593if(USE_EPOXY)
594	add_definitions(-DBUILD_GL -DBUILD_GLES2)
595	list(APPEND FEATURES EPOXY)
596	include_directories(AFTER ${EPOXY_INCLUDE_DIRS})
597	set(OPENGLES2_LIBRARY ${EPOXY_LIBRARIES})
598	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libepoxy0")
599endif()
600
601if(USE_SQLITE3)
602	list(APPEND FEATURES SQLITE3)
603	include_directories(AFTER ${SQLITE3_INCLUDE_DIRS})
604	list(APPEND DEPENDENCY_LIB ${SQLITE3_LIBRARIES})
605	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libsqlite3-0")
606	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/sqlite3/no-intro.c")
607endif()
608
609set(TEST_SRC ${CORE_TEST_SRC})
610if(M_CORE_GB)
611	add_definitions(-DM_CORE_GB)
612	list(APPEND CORE_SRC
613		${LR35902_SRC}
614		${GB_SRC}
615		${GB_RENDERER_SRC})
616	list(APPEND DEBUGGER_SRC
617		${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/cli-debugger.c
618		${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/debugger.c
619		${CMAKE_CURRENT_SOURCE_DIR}/src/gb/extra/cli.c)
620	list(APPEND TEST_SRC
621		${LR35902_TEST_SRC}
622		${GB_TEST_SRC})
623endif()
624
625if(M_CORE_GBA)
626	add_definitions(-DM_CORE_GBA)
627	list(APPEND CORE_SRC
628		${ARM_SRC}
629		${GBA_SRC}
630		${GBA_CHEATS_SRC}
631		${GBA_RENDERER_SRC})
632	list(APPEND DEBUGGER_SRC
633		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c
634		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/debugger.c
635		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/memory-debugger.c
636		${CMAKE_CURRENT_SOURCE_DIR}/src/gba/extra/cli.c)
637	list(APPEND TEST_SRC
638		${ARM_TEST_SRC}
639		${GBA_TEST_SRC})
640	if(NOT M_CORE_GB)
641		list(APPEND CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/audio.c)
642	endif()
643endif()
644
645if(M_CORE_DS)
646	add_definitions(-DM_CORE_DS)
647	list(APPEND CORE_SRC 
648		${ARM_SRC}
649		${DS_SRC}
650		${DS_RENDERER_SRC})
651	list(APPEND DEBUGGER_SRC
652		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c
653		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/debugger.c
654		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/memory-debugger.c
655		${CMAKE_CURRENT_SOURCE_DIR}/src/ds/extra/cli.c)
656endif()
657
658if(USE_DEBUGGERS)
659	list(APPEND FEATURE_SRC ${DEBUGGER_SRC})
660	list(APPEND FEATURES DEBUGGERS)
661endif()
662
663foreach(FEATURE IN LISTS FEATURES)
664	list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
665endforeach()
666
667source_group("Virtual files" FILES ${CORE_VFS_SRC} ${VFS_SRC})
668source_group("Extra features" FILES ${FEATURE_SRC})
669source_group("Third-party code" FILES ${THIRD_PARTY_SRC})
670
671# Platform binaries
672if(DEFINED 3DS)
673	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/3ds ${CMAKE_CURRENT_BINARY_DIR}/3ds)
674endif()
675
676if(DEFINED WII)
677	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/wii ${CMAKE_CURRENT_BINARY_DIR}/wii)
678endif()
679
680if(DEFINED PSP2)
681	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/psp2 ${CMAKE_CURRENT_BINARY_DIR}/psp2)
682endif()
683
684# Binaries
685list(APPEND CORE_SRC
686	${UTIL_SRC}
687	${CORE_VFS_SRC}
688	${OS_SRC}
689	${THIRD_PARTY_SRC})
690list(APPEND TEST_SRC ${UTIL_TEST_SRC})
691
692set(SRC ${CORE_SRC} ${VFS_SRC})
693if(NOT MINIMAL_CORE)
694	if(M_CORE_GBA)
695		list(APPEND SRC
696			${GBA_RR_SRC}
697			${GBA_EXTRA_SRC}
698			${GBA_SIO_SRC})
699	endif()
700	if(M_CORE_GB)
701		list(APPEND SRC
702			${GB_SIO_SRC})
703	endif()
704	list(APPEND SRC
705		${FEATURE_SRC}
706		${CLI_SRC})
707endif()
708
709if(NOT SKIP_LIBRARY)
710	if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
711		set(BUILD_SHARED ON)
712	endif()
713
714	if(BUILD_SHARED)
715		add_library(${BINARY_NAME} SHARED ${SRC} ${VFS_SRC})
716		if(BUILD_STATIC)
717			add_library(${BINARY_NAME}-static STATIC ${SRC})
718			set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
719			install(TARGETS ${BINARY_NAME}-static DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
720			add_dependencies(${BINARY_NAME}-static version-info)
721		endif()
722	else()
723		add_library(${BINARY_NAME} STATIC ${SRC})
724	endif()
725
726	add_dependencies(${BINARY_NAME} version-info)
727	set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
728
729	target_link_libraries(${BINARY_NAME} ${DEBUGGER_LIB} ${DEPENDENCY_LIB} ${OS_LIB})
730	install(TARGETS ${BINARY_NAME} LIBRARY DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME} NAMELINK_SKIP ARCHIVE DESTINATION ${LIBDIR} RUNTIME DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
731	if(UNIX AND NOT APPLE)
732		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-16.png DESTINATION share/icons/hicolor/16x16/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
733		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-24.png DESTINATION share/icons/hicolor/24x24/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
734		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-32.png DESTINATION share/icons/hicolor/32x32/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
735		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-48.png DESTINATION share/icons/hicolor/48x48/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
736		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-64.png DESTINATION share/icons/hicolor/64x64/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
737		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-96.png DESTINATION share/icons/hicolor/96x96/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
738		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-128.png DESTINATION share/icons/hicolor/128x128/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
739		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-256.png DESTINATION share/icons/hicolor/256x256/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
740		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-512.png DESTINATION share/icons/hicolor/512x512/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
741	endif()
742else()
743	set(BUILD_SHARED OFF)
744	set(BUILD_STATIC OFF)
745	find_library(${BINARY_NAME} ${BINARY_NAME})
746	if(NOT ${BINARY_NAME}_FOUND)
747		set(DISABLE_FRONTENDS ON)
748		set(BUILD_PERF OFF)
749		set(BUILD_TEST OFF)
750		set(BUILD_SUITE OFF)
751	endif()
752endif()
753
754if(BUILD_GL)
755	add_definitions(-DBUILD_GL)
756endif()
757
758if(BUILD_GLES2)
759	add_definitions(-DBUILD_GLES2)
760endif()
761
762if(DISABLE_FRONTENDS)
763	set(BUILD_SDL OFF)
764	set(BUILD_QT OFF)
765endif()
766
767if(BUILD_LIBRETRO)
768	file(GLOB RETRO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/libretro/*.c)
769	add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
770	set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5;DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=2")
771	target_link_libraries(${BINARY_NAME}_libretro ${OS_LIB})
772	install(TARGETS ${BINARY_NAME}_libretro LIBRARY DESTINATION ${LIBRETRO_LIBDIR} COMPONENT ${BINARY_NAME}_libretro NAMELINK_SKIP)
773endif()
774
775if(BUILD_OPENEMU)
776	find_library(FOUNDATION Foundation)
777	find_library(OPENEMUBASE OpenEmuBase)
778	file(GLOB OE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/*.m)
779	add_library(${BINARY_NAME}-openemu MODULE ${CORE_SRC} ${OE_SRC})
780	set_target_properties(${BINARY_NAME}-openemu PROPERTIES
781		MACOSX_BUNDLE_INFO_PLIST ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/Info.plist.in
782		BUNDLE TRUE
783		BUNDLE_EXTENSION oecoreplugin
784		OUTPUT_NAME ${PROJECT_NAME}
785		COMPILE_DEFINITIONS "DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=1")
786	target_link_libraries(${BINARY_NAME}-openemu ${OS_LIB} ${FOUNDATION} ${OPENEMUBASE})
787	install(TARGETS ${BINARY_NAME}-openemu LIBRARY DESTINATION ${OE_LIBDIR} COMPONENT ${BINARY_NAME}.oecoreplugin NAMELINK_SKIP)
788endif()
789
790if(BUILD_SDL)
791	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/sdl ${CMAKE_CURRENT_BINARY_DIR}/sdl)
792	# The SDL platform CMakeLists could decide to disable SDL, so check again before adding the define.
793	if(BUILD_SDL)
794		add_definitions(-DBUILD_SDL)
795	endif()
796endif()
797
798if(BUILD_QT)
799	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/qt ${CMAKE_CURRENT_BINARY_DIR}/qt)
800endif()
801
802if(BUILD_PERF)
803	set(PERF_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/perf-main.c ${CLI_SRC})
804	if(UNIX AND NOT APPLE)
805		list(APPEND PERF_LIB rt)
806	endif()
807
808	add_executable(${BINARY_NAME}-perf ${PERF_SRC})
809	target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB} ${OS_LIB})
810	set_target_properties(${BINARY_NAME}-perf PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
811	install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
812	install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
813endif()
814
815if(BUILD_TEST)
816	add_executable(${BINARY_NAME}-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/fuzz-main.c)
817	target_link_libraries(${BINARY_NAME}-fuzz ${BINARY_NAME})
818	set_target_properties(${BINARY_NAME}-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
819	add_executable(tbl-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/tbl-fuzz-main.c)
820	target_link_libraries(tbl-fuzz ${BINARY_NAME})
821	set_target_properties(tbl-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
822	install(TARGETS ${BINARY_NAME}-fuzz tbl-fuzz DESTINATION bin COMPONENT ${BINARY_NAME}-test)
823endif()
824
825if(NOT USE_CMOCKA)
826	set(BUILD_SUITE OFF)
827endif()
828if(BUILD_SUITE)
829	enable_testing()
830	include_directories(AFTER ${CMOCKA_INCLUDE_DIRS})
831	link_directories(${CMOCKA_LIBRARY_DIRS})
832
833	add_executable(${BINARY_NAME}-suite ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/suite-main.c ${TEST_SRC})
834	target_link_libraries(${BINARY_NAME}-suite ${BINARY_NAME} ${PLATFORM_LIBRARY} cmocka)
835	set_target_properties(${BINARY_NAME}-suite PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
836	add_test(${BINARY_NAME}-suite ${BINARY_NAME}-suite)
837endif()
838
839if(BUILD_PYTHON)
840	enable_testing()
841	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/python ${CMAKE_CURRENT_BINARY_DIR}/python)
842endif()
843
844if(BUILD_EXAMPLE)
845	add_executable(${BINARY_NAME}-example-server ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/server.c)
846	target_link_libraries(${BINARY_NAME}-example-server ${BINARY_NAME})
847	set_target_properties(${BINARY_NAME}-example-server PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
848
849	if(BUILD_SDL)
850		add_executable(${BINARY_NAME}-example-client ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/client.c)
851		target_link_libraries(${BINARY_NAME}-example-client ${BINARY_NAME} ${SDL_LIBRARY} ${SDLMAIN_LIBRARY} ${OPENGL_LIBRARY} ${OPENGLES2_LIBRARY})
852		set_target_properties(${BINARY_NAME}-example-client PROPERTIES
853		                      COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}"
854		                      INCLUDE_DIRECTORIES "${SDL_INCLUDE_DIR};${CMAKE_CURRENT_SOURCE_DIR}/src;${CMAKE_CURRENT_SOURCE_DIR}/include")
855	endif()
856endif()
857
858# Packaging
859set(CPACK_PACKAGE_VERSION ${VERSION_STRING})
860set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
861set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
862set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
863set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
864set(CPACK_RESOURCE_FILE_README ${CMAKE_CURRENT_SOURCE_DIR}/README.md)
865
866set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
867set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
868set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
869set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README.md")
870set(CPACK_DEBIAN_PACKAGE_SECTION "games")
871
872SET(CPACK_DEB_COMPONENT_INSTALL ON)
873
874set(CPACK_STRIP_FILES ${BINARY_NAME})
875
876install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/README.md ${CMAKE_CURRENT_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
877
878include(CPack)
879
880# Summaries
881set(SUMMARY_GL_LIST)
882if(USE_EPOXY)
883	set(SUMMARY_GL_LIST "libepoxy")
884else()
885	if(BUILD_GL)
886		list(APPEND SUMMARY_GL_LIST "OpenGL")
887	endif()
888	if(BUILD_GLES2)
889		list(APPEND SUMMARY_GL_LIST "OpenGL|ES 2")
890	endif()
891endif()
892if(NOT SUMMARY_GL_LIST)
893	set(SUMMARY_GL OFF)
894else()
895	string(REPLACE ";" ", " SUMMARY_GL "${SUMMARY_GL_LIST}")
896endif()
897if(USE_LIBZIP)
898	set(SUMMARY_ZIP libzip)
899elseif(USE_MINIZIP)
900	set(SUMMARY_ZIP "minizip (external)")
901elseif(USE_ZLIB)
902	set(SUMMARY_ZIP "minizip (included)")
903else()
904	set(SUMMARY_ZIP OFF)
905endif()
906
907if(NOT QUIET)
908	message(STATUS "Platforms:")
909	message(STATUS "	Game Boy Advance: ${M_CORE_GBA}")
910	message(STATUS "	Game Boy: ${M_CORE_GB}")
911	message(STATUS "	DS: ${M_CORE_DS}")
912	message(STATUS "Features:")
913	message(STATUS "	Debuggers: ${USE_DEBUGGERS}")
914	message(STATUS "	CLI debugger: ${USE_EDITLINE}")
915	message(STATUS "	GDB stub: ${USE_GDB_STUB}")
916	message(STATUS "	Video recording: ${USE_FFMPEG}")
917	message(STATUS "	GIF recording: ${USE_MAGICK}")
918	message(STATUS "	Screenshot/advanced savestate support: ${USE_PNG}")
919	message(STATUS "	ZIP support: ${SUMMARY_ZIP}")
920	message(STATUS "	7-Zip support: ${USE_LZMA}")
921	message(STATUS "	SQLite3 game database: ${USE_SQLITE3}")
922	message(STATUS "	OpenGL support: ${SUMMARY_GL}")
923	message(STATUS "Frontends:")
924	message(STATUS "	Qt: ${BUILD_QT}")
925	message(STATUS "	SDL (${SDL_VERSION}): ${BUILD_SDL}")
926	message(STATUS "	Profiling: ${BUILD_PERF}")
927	message(STATUS "	Test harness: ${BUILD_TEST}")
928	message(STATUS "	Test suite: ${BUILD_SUITE}")
929	message(STATUS "	Python bindings: ${BUILD_PYTHON}")
930	message(STATUS "	Examples: ${BUILD_EXAMPLE}")
931	message(STATUS "Cores:")
932	message(STATUS "	Libretro core: ${BUILD_LIBRETRO}")
933	if(APPLE)
934		message(STATUS "	OpenEmu core: ${BUILD_OPENEMU}")
935	endif()
936	message(STATUS "Libraries:")
937	message(STATUS "	Static: ${BUILD_STATIC}")
938	message(STATUS "	Shared: ${BUILD_SHARED}")
939endif()