1set(USE_VFS_3DS ON CACNE BOOL "Use 3DS-specific file support")
 2mark_as_advanced(USE_VFS_3DS)
 3
 4set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-format" PARENT_SCOPE)
 5set(OS_DEFINES COLOR_16_BIT COLOR_5_6_5)
 6
 7include_directories(${CMAKE_CURRENT_BINARY_DIR})
 8list(APPEND OS_LIB sf2d ctru)
 9file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/3ds-*.c)
10set(OS_SRC ${OS_SRC} PARENT_SCOPE)
11source_group("3DS-specific code" FILES ${OS_SRC})
12
13if(USE_VFS_3DS)
14	list(APPEND OS_DEFINES USE_VFS_3DS)
15else()
16	list(APPEND OS_DEFINES USE_VFS_FILE)
17	list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-file.c ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
18endif()
19set(VFS_SRC ${VFS_SRC} PARENT_SCOPE)
20set(OS_DEFINES ${OS_DEFINES} PARENT_SCOPE)
21
22list(APPEND GUI_SRC ${CMAKE_CURRENT_BINARY_DIR}/font.c ${CMAKE_CURRENT_SOURCE_DIR}/gui-font.c)
23
24set_source_files_properties(${CMAKE_CURRENT_BINARY_DIR}/font.c PROPERTIES GENERATED ON)
25add_executable(${BINARY_NAME}.elf ${GUI_SRC} main.c ctru-heap.c)
26set_target_properties(${BINARY_NAME}.elf PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES}")
27target_link_libraries(${BINARY_NAME}.elf ${BINARY_NAME} ${M_LIBRARY} ${OS_LIB})
28
29add_custom_command(OUTPUT ${BINARY_NAME}.smdh
30                   COMMAND ${BANNERTOOL} makesmdh -s "${PROJECT_NAME}" -l "${SUMMARY}" -p "endrift" -i ${CMAKE_SOURCE_DIR}/res/mgba-48.png -o ${BINARY_NAME}.smdh
31                   DEPENDS ${CMAKE_SOURCE_DIR}/res/mgba-48.png)
32
33add_custom_command(OUTPUT ${BINARY_NAME}.bnr
34                   COMMAND ${BANNERTOOL} makebanner -i ${CMAKE_CURRENT_SOURCE_DIR}/logo.png -a ${CMAKE_CURRENT_SOURCE_DIR}/bios.wav -o ${BINARY_NAME}.bnr
35                   DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/logo.png ${CMAKE_CURRENT_SOURCE_DIR}/bios.wav)
36
37add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/font.c
38                   COMMAND ${RAW2C} ${CMAKE_SOURCE_DIR}/src/platform/3ds/font.raw
39                   DEPENDS ${CMAKE_SOURCE_DIR}/src/platform/3ds/font.raw)
40
41add_custom_target(${BINARY_NAME}.3dsx ALL
42                  ${3DSXTOOL} ${BINARY_NAME}.elf ${BINARY_NAME}.3dsx --smdh=${BINARY_NAME}.smdh
43                  DEPENDS ${BINARY_NAME}.elf ${BINARY_NAME}.smdh)
44
45add_custom_target(${BINARY_NAME}.cia ALL
46                  ${STRIP} -o ${BINARY_NAME}-stripped.elf ${BINARY_NAME}.elf
47                  COMMAND ${MAKEROM} -f cia -o ${BINARY_NAME}.cia -rsf cia.rsf -target t -exefslogo -elf ${BINARY_NAME}-stripped.elf -icon ${BINARY_NAME}.smdh -banner ${BINARY_NAME}.bnr
48                  DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/cia.rsf ${BINARY_NAME}.elf ${BINARY_NAME}.smdh ${BINARY_NAME}.bnr)
49
50add_custom_target(run ${3DSLINK} ${CMAKE_CURRENT_BINARY_DIR}/${BINARY_NAME}.3dsx
51                  DEPENDS ${BINARY_NAME}.3dsx)
52
53configure_file(${CMAKE_CURRENT_SOURCE_DIR}/cia.rsf.in ${CMAKE_CURRENT_BINARY_DIR}/cia.rsf)
54install(FILES
55	    ${CMAKE_CURRENT_BINARY_DIR}/${BINARY_NAME}.3dsx
56	    ${CMAKE_CURRENT_BINARY_DIR}/${BINARY_NAME}.smdh
57	    ${CMAKE_CURRENT_BINARY_DIR}/${BINARY_NAME}.cia
58	    DESTINATION . COMPONENT ${BINARY_NAME}-3ds)