1set(USE_VFS_3DS ON CACHE BOOL "Use 3DS-specific file support")
  2mark_as_advanced(USE_VFS_3DS)
  3
  4find_program(3DSLINK 3dslink)
  5find_program(3DSXTOOL 3dsxtool)
  6find_program(BANNERTOOL bannertool)
  7find_program(MAKEROM makerom)
  8find_program(PICASSO picasso)
  9find_program(RAW2C raw2c)
 10find_program(STRIP ${cross_prefix}strip)
 11
 12set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-format" PARENT_SCOPE)
 13set(OS_DEFINES COLOR_16_BIT COLOR_5_6_5 IOAPI_NO_64)
 14
 15include_directories(${CMAKE_CURRENT_BINARY_DIR})
 16if(${CMAKE_BUILD_TYPE} STREQUAL Debug OR ${CMAKE_BUILD_TYPE} STREQUAL RelWithDebInfo)
 17	list(APPEND OS_LIB citro3dd ctrud)
 18else()
 19	list(APPEND OS_LIB citro3d ctru)
 20endif()
 21file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/3ds-*.c ${CMAKE_CURRENT_SOURCE_DIR}/ctru-heap.c ${CMAKE_CURRENT_SOURCE_DIR}/socket.c)
 22set(OS_SRC ${OS_SRC} PARENT_SCOPE)
 23set(OS_LIB ${OS_LIB} PARENT_SCOPE)
 24source_group("3DS-specific code" FILES ${OS_SRC})
 25
 26if(USE_VFS_3DS)
 27	list(APPEND OS_DEFINES USE_VFS_3DS)
 28else()
 29	list(APPEND OS_DEFINES USE_VFS_FILE)
 30	list(APPEND CORE_VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-file.c ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
 31endif()
 32set(CORE_VFS_SRC ${CORE_VFS_SRC} PARENT_SCOPE)
 33set(OS_DEFINES ${OS_DEFINES} PARENT_SCOPE)
 34
 35list(APPEND GUI_SRC
 36	${CMAKE_CURRENT_BINARY_DIR}/icons.c
 37	${CMAKE_CURRENT_BINARY_DIR}/uishader.c
 38	${CMAKE_CURRENT_BINARY_DIR}/uishader.h
 39	${CMAKE_CURRENT_BINARY_DIR}/uishader.shbin.h
 40
 41	${CMAKE_CURRENT_SOURCE_DIR}/gui-font.c
 42	${CMAKE_CURRENT_SOURCE_DIR}/ctr-gpu.c
 43	${CMAKE_CURRENT_SOURCE_DIR}/ctr-gpu.h)
 44
 45set_source_files_properties(
 46	${CMAKE_CURRENT_BINARY_DIR}/icons.c
 47	${CMAKE_CURRENT_BINARY_DIR}/uishader.c
 48	${CMAKE_CURRENT_BINARY_DIR}/uishader.h
 49	${CMAKE_CURRENT_BINARY_DIR}/uishader.shbin.h
 50	PROPERTIES GENERATED ON)
 51
 52add_executable(${BINARY_NAME}.elf ${GUI_SRC} main.c)
 53set_target_properties(${BINARY_NAME}.elf PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
 54target_link_libraries(${BINARY_NAME}.elf ${BINARY_NAME} ${M_LIBRARY} ${OS_LIB})
 55
 56add_custom_command(OUTPUT ${BINARY_NAME}.smdh
 57                   COMMAND ${BANNERTOOL} makesmdh -s "${PROJECT_NAME}" -l "${SUMMARY}" -p "endrift" -i ${CMAKE_SOURCE_DIR}/res/mgba-48.png -o ${BINARY_NAME}.smdh
 58                   DEPENDS ${CMAKE_SOURCE_DIR}/res/mgba-48.png)
 59
 60add_custom_command(OUTPUT ${BINARY_NAME}.bnr
 61                   COMMAND ${BANNERTOOL} makebanner -ci ${CMAKE_CURRENT_SOURCE_DIR}/banner.cgfx -a ${CMAKE_CURRENT_SOURCE_DIR}/bios.wav -o ${BINARY_NAME}.bnr
 62                   DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/banner.cgfx ${CMAKE_CURRENT_SOURCE_DIR}/bios.wav)
 63
 64add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/icons.c
 65                   COMMAND ${RAW2C} ${CMAKE_SOURCE_DIR}/src/platform/3ds/icons.raw
 66                   DEPENDS ${CMAKE_SOURCE_DIR}/src/platform/3ds/icons.raw)
 67
 68add_custom_command(
 69	OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/uishader.shbin ${CMAKE_CURRENT_BINARY_DIR}/uishader.shbin.h
 70	DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/uishader.v.pica ${CMAKE_CURRENT_SOURCE_DIR}/uishader.g.pica
 71	COMMAND ${PICASSO}
 72		-o ${CMAKE_CURRENT_BINARY_DIR}/uishader.shbin
 73		-h ${CMAKE_CURRENT_BINARY_DIR}/uishader.shbin.h
 74		${CMAKE_CURRENT_SOURCE_DIR}/uishader.v.pica
 75		${CMAKE_CURRENT_SOURCE_DIR}/uishader.g.pica
 76	COMMENT "picasso uishader.shbin")
 77
 78add_custom_command(
 79	OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/uishader.c ${CMAKE_CURRENT_BINARY_DIR}/uishader.h
 80	MAIN_DEPENDENCY ${CMAKE_CURRENT_BINARY_DIR}/uishader.shbin
 81	COMMAND ${RAW2C} ${CMAKE_CURRENT_BINARY_DIR}/uishader.shbin
 82	WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
 83	COMMENT "raw2c uishader.shbin")
 84
 85add_custom_command(OUTPUT ${BINARY_NAME}.3dsx
 86                   COMMAND ${3DSXTOOL} ${BINARY_NAME}.elf ${BINARY_NAME}.3dsx --smdh=${BINARY_NAME}.smdh
 87                   DEPENDS ${BINARY_NAME}.elf ${BINARY_NAME}.smdh)
 88add_custom_target(${BINARY_NAME}.3dsx ALL DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${BINARY_NAME}.3dsx)
 89
 90add_custom_command(OUTPUT ${BINARY_NAME}.cia
 91                   COMMAND ${STRIP} -o ${BINARY_NAME}-stripped.elf ${BINARY_NAME}.elf
 92                   COMMAND ${MAKEROM} -f cia -o ${BINARY_NAME}.cia -rsf cia.rsf -target t -exefslogo -elf ${BINARY_NAME}-stripped.elf -icon ${BINARY_NAME}.smdh -banner ${BINARY_NAME}.bnr -major ${LIB_VERSION_MAJOR} -minor ${LIB_VERSION_MINOR} -micro ${LIB_VERSION_PATCH}
 93                   DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/cia.rsf ${BINARY_NAME}.elf ${BINARY_NAME}.smdh ${BINARY_NAME}.bnr)
 94add_custom_target(${BINARY_NAME}.cia ALL DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${BINARY_NAME}.cia)
 95
 96add_custom_target(run ${3DSLINK} ${CMAKE_CURRENT_BINARY_DIR}/${BINARY_NAME}.3dsx
 97                  DEPENDS ${BINARY_NAME}.3dsx)
 98
 99add_custom_target(install-cia stat -f '0 00000001 %016Xz' '${CMAKE_CURRENT_BINARY_DIR}/${BINARY_NAME}.cia' | xxd -r | cat -- - '${CMAKE_CURRENT_BINARY_DIR}/${BINARY_NAME}.cia' | nc $ENV{N3DS_IP} 5000
100                  DEPENDS ${BINARY_NAME}.cia)
101
102if(BUILD_PERF)
103	add_custom_target(${BINARY_NAME}-perf.3dsx ALL
104	                  ${3DSXTOOL} ../${BINARY_NAME}-perf ${BINARY_NAME}-perf.3dsx --smdh=${BINARY_NAME}.smdh
105	                  DEPENDS ${BINARY_NAME}-perf ${BINARY_NAME}.smdh)
106	install(FILES
107		    ${CMAKE_CURRENT_BINARY_DIR}/${BINARY_NAME}-perf.3dsx
108		    DESTINATION . COMPONENT ${BINARY_NAME}-3ds)
109endif()
110
111configure_file(${CMAKE_CURRENT_SOURCE_DIR}/cia.rsf.in ${CMAKE_CURRENT_BINARY_DIR}/cia.rsf)
112install(FILES
113	    ${CMAKE_CURRENT_BINARY_DIR}/${BINARY_NAME}.3dsx
114	    ${CMAKE_CURRENT_BINARY_DIR}/${BINARY_NAME}.smdh
115	    ${CMAKE_CURRENT_BINARY_DIR}/${BINARY_NAME}.cia
116	    DESTINATION . COMPONENT ${BINARY_NAME}-3ds)