1cmake_minimum_required(VERSION 2.6)
  2project(mGBA C)
  3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
  4if(NOT MSVC)
  5	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wno-missing-field-initializers -std=c99")
  6else()
  7	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_CRT_SECURE_NO_WARNINGS /wd4003 /wd4244 /wd4146")
  8endif()
  9set(USE_DEBUGGERS ON CACHE BOOL "Whether or not to enable the debugging infrastructure")
 10set(USE_EDITLINE ON CACHE BOOL "Whether or not to enable the CLI-mode debugger")
 11set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
 12set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
 13set(USE_ZLIB ON CACHE BOOL "Whether or not to enable zlib support")
 14set(USE_MINIZIP ON CACHE BOOL "Whether or not to enable external minizip support")
 15set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
 16set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable LIBZIP support")
 17set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
 18set(M_CORE_GBA ON CACHE BOOL "Build Game Boy Advance core")
 19set(M_CORE_GB ON CACHE BOOL "Build Game Boy core")
 20set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
 21set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
 22set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
 23set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
 24if(APPLE)
 25	set(BUILD_OPENEMU OFF CACHE BOOL "Build OpenEmu core")
 26endif()
 27set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
 28set(BUILD_TEST OFF CACHE BOOL "Build testing harness")
 29set(BUILD_SUITE OFF CACHE BOOL "Build test suite")
 30set(BUILD_EXAMPLE OFF CACHE BOOL "Build example frontends")
 31set(BUILD_PYTHON OFF CACHE BOOL "Build Python bindings")
 32set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
 33set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
 34set(SKIP_LIBRARY OFF CACHE BOOL "Skip building the library (useful for only building libretro or OpenEmu cores)")
 35set(BUILD_GL ON CACHE STRING "Build with OpenGL")
 36set(BUILD_GLES2 OFF CACHE STRING "Build with OpenGL|ES 2")
 37set(USE_EPOXY ON CACHE STRING "Build with libepoxy")
 38set(DISABLE_DEPS OFF CACHE BOOL "Build without dependencies")
 39file(GLOB ARM_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/*.c)
 40file(GLOB ARM_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/test/*.c)
 41file(GLOB LR35902_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/*.c)
 42file(GLOB LR35902_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/test/*.c)
 43file(GLOB GBA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/*.c)
 44file(GLOB GBA_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/test/*.c)
 45file(GLOB GB_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/*.c)
 46file(GLOB GB_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/test/*.c)
 47file(GLOB GBA_CHEATS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/cheats/*.c)
 48file(GLOB GBA_RR_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/rr/*.c)
 49file(GLOB CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/*.c)
 50file(GLOB CORE_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/test/*.c)
 51file(GLOB UTIL_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/*.[cSs])
 52file(GLOB UTIL_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/test/*.c)
 53file(GLOB GUI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/gui/*.c ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/gui/*.c)
 54file(GLOB GBA_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/renderers/*.c)
 55file(GLOB SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/sio/lockstep.c)
 56file(GLOB GB_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/renderers/*.c)
 57file(GLOB THIRD_PARTY_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/inih/*.c)
 58set(CLI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/commandline.c)
 59set(CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-mem.c)
 60set(VFS_SRC)
 61source_group("ARM core" FILES ${ARM_SRC})
 62source_group("LR35902 core" FILES ${LR35902_SRC})
 63source_group("GBA board" FILES ${GBA_SRC} ${GBA_RENDERER_SRC} ${SIO_SRC})
 64source_group("GBA extra" FILES ${GBA_CHEATS_SRC} ${GBA_RR_SRC})
 65source_group("GB board" FILES ${GB_SRC})
 66source_group("Utilities" FILES ${UTIL_SRC})
 67include_directories(BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/src)
 68
 69if(NOT CMAKE_BUILD_TYPE)
 70	set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
 71endif()
 72
 73include(GNUInstallDirs)
 74
 75set(LIBDIR "${CMAKE_INSTALL_LIBDIR}" CACHE PATH "Installed library directory")
 76mark_as_advanced(LIBDIR)
 77
 78if (BUILD_LIBRETRO)
 79	set(LIBRETRO_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (Libretro)")
 80	mark_as_advanced(LIBRETRO_LIBDIR)
 81endif()
 82
 83if (BUILD_OPENEMU)
 84	set(OE_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (OpenEmu)")
 85	mark_as_advanced(OE_LIBDIR)
 86endif()
 87
 88
 89set(CMAKE_INSTALL_RPATH "${LIBDIR}")
 90
 91if (NOT DEFINED MANDIR)
 92	set(MANDIR ${CMAKE_INSTALL_MANDIR})
 93endif()
 94
 95# Function definitions
 96include(FindPkgConfig)
 97function(find_feature FEATURE_NAME FEATURE_REQUIRES)
 98	if (NOT ${FEATURE_NAME})
 99		return()
100	endif()
101	if (DISABLE_DEPS)
102		set(${FEATURE_NAME} OFF PARENT_SCOPE)
103		return()
104	endif()
105	foreach(REQUIRE ${FEATURE_REQUIRES})
106		if(NOT ${REQUIRE}_FOUND)
107			find_package(${REQUIRE} QUIET)
108			if(NOT ${REQUIRE}_FOUND)
109				pkg_search_module(${REQUIRE} ${REQUIRE})
110				if (NOT ${REQUIRE}_FOUND)
111					message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
112					set(${FEATURE_NAME} OFF PARENT_SCOPE)
113					return()
114				endif()
115			endif()
116		endif()
117		string(TOUPPER ${REQUIRE} UREQUIRE)
118		set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
119		set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
120		set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
121		if (APPLE)
122			set(IS_FRAMEWORK OFF)
123			set(LIBS)
124			foreach(LIB IN LISTS ${REQUIRE}_LIBRARIES)
125				if(LIB STREQUAL "-framework")
126					set(IS_FRAMEWORK ON)
127				elseif(IS_FRAMEWORK)
128					list(APPEND LIBS "-framework ${LIB}")
129					set(IS_FRAMEWORK OFF)
130				else()
131					list(APPEND LIBS ${LIB})
132				endif()
133			endforeach()
134			set(${UREQUIRE}_LIBRARIES ${LIBS} PARENT_SCOPE)
135		else()
136			set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
137		endif()
138		set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
139		set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
140	endforeach()
141endfunction()
142
143# Version information
144add_custom_target(version-info ALL
145	COMMAND ${CMAKE_COMMAND}
146	-DBINARY_NAME=${BINARY_NAME}
147	-DCONFIG_FILE=${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in
148	-DOUT_FILE=${CMAKE_CURRENT_BINARY_DIR}/version.c
149	-P ${CMAKE_CURRENT_SOURCE_DIR}/version.cmake
150	WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
151
152include(${CMAKE_CURRENT_SOURCE_DIR}/version.cmake)
153configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in ${CMAKE_CURRENT_BINARY_DIR}/version.c)
154configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/flags.h.in ${CMAKE_CURRENT_BINARY_DIR}/flags.h)
155install(FILES ${CMAKE_CURRENT_BINARY_DIR}/flags.h DESTINATION include/mgba COMPONENT lib${BINARY_NAME})
156
157list(APPEND UTIL_SRC ${CMAKE_CURRENT_BINARY_DIR}/version.c)
158source_group("Generated sources" FILES ${CMAKE_CURRENT_BINARY_DIR}/version.c)
159
160# Advanced settings
161set(BUILD_LTO ON CACHE BOOL "Build with link-time optimization")
162set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
163set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
164set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
165mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
166set(PGO_PRE_FLAGS "-fprofile-generate=${PGO_DIR} -fprofile-arcs")
167set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
168
169if(BUILD_PGO AND NOT PGO_STAGE_2)
170	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
171	set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
172	set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
173elseif(BUILD_PGO AND PGO_STAGE_2)
174	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
175	set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
176	set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
177endif()
178
179# Platform support
180if(WIN32)
181	set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
182	add_definitions(-D_WIN32_WINNT=0x0600)
183	list(APPEND OS_LIB ws2_32 shlwapi)
184	list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/vfs-w32.c)
185	file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/*.c)
186	source_group("Windows-specific code" FILES ${OS_SRC})
187	if(MSVC)
188		add_definitions(-DNOMINMAX -DWIN32_LEAN_AND_MEAN)
189	endif()
190elseif(UNIX)
191	add_definitions(-DUSE_PTHREADS)
192
193	if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
194		add_definitions(-D_GNU_SOURCE)
195	endif()
196	if(NOT APPLE AND NOT HAIKU)
197		set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
198	endif()
199
200	list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
201	file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/posix/*.c)
202	source_group("POSIX-specific code" FILES ${OS_SRC})
203endif()
204
205if(APPLE)
206	add_definitions(-D_DARWIN_C_SOURCE)
207	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
208endif()
209
210if(NOT HAIKU AND NOT MSVC AND NOT PSP2)
211	set(M_LIBRARY m)
212endif()
213list(APPEND OS_LIB ${M_LIBRARY})
214
215if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
216	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
217	set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
218endif()
219
220if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
221	if(NOT BUILD_EGL)
222		add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
223	endif()
224endif()
225
226if(BUILD_RASPI)
227	set(BUILD_GL OFF CACHE BOOL "OpenGL not supported" FORCE)
228endif()
229
230if(BUILD_PANDORA)
231	add_definitions(-DBUILD_PANDORA)
232endif()
233
234if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
235	enable_language(ASM)
236endif()
237
238if(PSP2 OR WII)
239	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-format")
240endif()
241
242if(DEFINED 3DS OR DEFINED PSP2 OR DEFINED WII)
243	set(USE_DEBUGGERS OFF)
244endif()
245
246if(NOT M_CORE_GBA)
247	set(USE_GDB_STUB OFF)
248endif()
249
250if(NOT USE_DEBUGGERS)
251	set(USE_EDITLINE OFF)
252	set(USE_GDB_STUB OFF)
253endif()
254
255if(WII)
256	add_definitions(-U__STRICT_ANSI__)
257endif()
258
259include(CheckFunctionExists)
260check_function_exists(strdup HAVE_STRDUP)
261check_function_exists(strndup HAVE_STRNDUP)
262check_function_exists(localtime_r HAVE_LOCALTIME_R)
263if(NOT CMAKE_SYSTEM_NAME STREQUAL "Generic")
264	check_function_exists(snprintf_l HAVE_SNPRINTF_L)
265	if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
266		# The strtof_l on Linux not actually exposed nor actually strtof_l
267		set(HAVE_STRTOF_L OFF)
268	else()
269		check_function_exists(strtof_l HAVE_STRTOF_L)
270	endif()
271	check_function_exists(newlocale HAVE_NEWLOCALE)
272	check_function_exists(freelocale HAVE_FREELOCALE)
273	check_function_exists(uselocale HAVE_USELOCALE)
274	check_function_exists(setlocale HAVE_SETLOCALE)
275else()
276	if(NOT DEFINED 3DS AND NOT DEFINED PSP2 AND NOT DEFINED WII)
277		set(DISABLE_DEPS ON CACHE BOOL "This platform cannot build with dependencies" FORCE)
278	endif()
279	set(DISABLE_FRONTENDS ON)
280	set(MINIMAL_CORE ON)
281endif()
282
283check_function_exists(chmod HAVE_CHMOD)
284check_function_exists(umask HAVE_UMASK)
285
286set(FUNCTION_DEFINES)
287
288if(HAVE_STRDUP)
289	list(APPEND FUNCTION_DEFINES HAVE_STRDUP)
290endif()
291
292if(HAVE_STRNDUP)
293	list(APPEND FUNCTION_DEFINES HAVE_STRNDUP)
294endif()
295
296if(HAVE_LOCALTIME_R)
297	list(APPEND FUNCTION_DEFINES HAVE_LOCALTIME_R)
298endif()
299
300if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE OR APPLE)
301	list(APPEND FUNCTION_DEFINES HAVE_LOCALE)
302	if (HAVE_STRTOF_L)
303		list(APPEND FUNCTION_DEFINES HAVE_STRTOF_L)
304	endif()
305	if (HAVE_SNPRINTF_L)
306		list(APPEND FUNCTION_DEFINES HAVE_SNPRINTF_L)
307	endif()
308endif()
309
310if(HAVE_SETLOCALE)
311	list(APPEND FUNCTION_DEFINES HAVE_SETLOCALE)
312endif()
313
314if(HAVE_CHMOD)
315	list(APPEND FUNCTION_DEFINES HAVE_CHMOD)
316endif()
317
318if(HAVE_UMASK)
319	list(APPEND FUNCTION_DEFINES HAVE_UMASK)
320endif()
321
322# Feature dependencies
323set(FEATURES)
324if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
325	set(LIBEDIT_LIBRARIES -ledit)
326	if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
327		list(APPEND LIBEDIT_LIBRARIES -ltermcap)
328	endif()
329else()
330	find_feature(USE_EDITLINE "libedit")
331endif()
332if(BUILD_GL)
333	find_package(OpenGL QUIET)
334	if(NOT OPENGL_FOUND)
335		set(BUILD_GL OFF CACHE BOOL "OpenGL not found" FORCE)
336	endif()
337endif()
338if(NOT BUILD_GL)
339	set(OPENGLE_LIBRARY "" CACHE PATH "" FORCE)
340endif()
341if(BUILD_GLES2 AND NOT BUILD_RASPI)
342	find_path(OPENGLES2_INCLUDE_DIR NAMES GLES2/gl2.h)
343	find_library(OPENGLES2_LIBRARY NAMES GLESv2 GLESv2_CM)
344	if(NOT OPENGLES2_INCLUDE_DIR OR NOT OPENGLES2_LIBRARY)
345		set(BUILD_GLES2 OFF CACHE BOOL "OpenGL|ES 2 not found" FORCE)
346	endif()
347endif()
348if(NOT BUILD_GLES2)
349	set(OPENGLES2_LIBRARY "" CACHE PATH "" FORCE)
350endif()
351set(WANT_ZLIB ${USE_ZLIB})
352set(WANT_PNG ${USE_PNG})
353set(WANT_LIBZIP ${USE_LIBZIP})
354set(USE_CMOCKA ${BUILD_SUITE})
355
356find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
357find_feature(USE_ZLIB "ZLIB")
358find_feature(USE_MINIZIP "minizip")
359find_feature(USE_PNG "PNG")
360find_feature(USE_LIBZIP "libzip")
361find_feature(USE_MAGICK "MagickWand")
362find_feature(USE_EPOXY "epoxy")
363find_feature(USE_CMOCKA "cmocka")
364
365# Features
366set(DEBUGGER_SRC
367	${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/debugger.c
368	${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/parser.c
369	${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/cli-debugger.c)
370
371set(FEATURE_SRC)
372set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
373
374if(DISABLE_DEPS)
375	set(USE_GDB_STUB OFF)
376endif()
377
378if(USE_EDITLINE)
379	list(APPEND FEATURES EDITLINE)
380	include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
381	link_directories(${LIBEDIT_LIBRARY_DIRS})
382	set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
383	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
384	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/editline/cli-el-backend.c")
385else()
386	set(DEBUGGER_LIB "")
387endif()
388
389if(USE_GDB_STUB)
390	list(APPEND FEATURES GDB_STUB)
391	list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/gdb-stub.c)
392endif()
393source_group("Debugger" FILES ${DEBUGGER_SRC})
394
395if(USE_FFMPEG)
396	list(APPEND FEATURES FFMPEG)
397	pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
398	if(NOT LIBSWRESAMPLE_FOUND)
399		list(APPEND FEATURES LIBAV)
400	endif()
401	include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
402	link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
403	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/ffmpeg/ffmpeg-encoder.c")
404	string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
405	string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
406	string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
407	string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
408	string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
409	list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
410	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR}|libavcodec-extra-${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
411	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavformat${LIBAVFORMAT_VERSION_MAJOR}|libavformat-ffmpeg${LIBAVFORMAT_VERSION_MAJOR}")
412	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavresample${LIBAVRESAMPLE_VERSION_MAJOR}|libavresample-ffmpeg${LIBAVRESAMPLE_VERSION_MAJOR}")
413	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavutil${LIBAVUTIL_VERSION_MAJOR}|libavutil-ffmpeg${LIBAVUTIL_VERSION_MAJOR}")
414	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libswscale${LIBSWSCALE_VERSION_MAJOR}|libswscale-ffmpeg${LIBSWSCALE_VERSION_MAJOR}")
415	set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
416	if(APPLE)
417		set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
418		set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
419	endif()
420endif()
421
422list(APPEND THIRD_PARTY_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
423
424if(USE_MAGICK)
425	list(APPEND FEATURES MAGICK)
426	include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
427	link_directories(${MAGICKWAND_LIBRARY_DIRS})
428	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/imagemagick/imagemagick-gif-encoder.c")
429	list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
430	string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
431	if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
432		set(MAGICKWAND_DEB_VERSION "5")
433	else()
434		set(MAGICKWAND_DEB_VERSION "-6.q16-2")
435	endif()
436	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
437endif()
438
439if(WANT_ZLIB AND NOT USE_ZLIB)
440	set(SKIP_INSTALL_ALL ON)
441	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib zlib)
442	set_property(TARGET zlibstatic PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/zlib;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib)
443	set_property(TARGET zlib PROPERTY EXCLUDE_FROM_ALL ON)
444	set_property(TARGET example PROPERTY EXCLUDE_FROM_ALL ON)
445	set_property(TARGET minigzip PROPERTY EXCLUDE_FROM_ALL ON)
446	set(ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
447	set(ZLIB_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
448	set(ZLIB_LIBRARY zlibstatic)
449	list(APPEND DEPENDENCY_LIB zlibstatic)
450	set(USE_ZLIB ON)
451endif()
452
453if(USE_ZLIB)
454	list(APPEND FEATURES ZLIB)
455	include_directories(AFTER ${ZLIB_INCLUDE_DIRS})
456	list(APPEND DEPENDENCY_LIB ${ZLIB_LIBRARIES})
457	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},zlib1g")
458endif()
459
460if(WANT_PNG AND USE_ZLIB AND NOT USE_PNG)
461	set(PNG_STATIC ON CACHE BOOL "" FORCE)
462	set(PNG_SHARED OFF CACHE BOOL "" FORCE)
463	set(PNG_TESTS OFF CACHE BOOL "" FORCE)
464	set(SKIP_INSTALL_ALL ON)
465	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng libpng)
466	set_property(TARGET png16_static PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/libpng;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng;${ZLIB_INCLUDE_DIRS})
467	set(PNG_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng ${CMAKE_CURRENT_BINARY_DIR}/libpng)
468	list(APPEND DEPENDENCY_LIB png16_static)
469	set(USE_PNG ON)
470endif()
471
472if(USE_PNG)
473	list(APPEND FEATURES PNG)
474	include_directories(AFTER ${PNG_INCLUDE_DIRS})
475	list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
476	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng12-0")
477endif()
478
479if(USE_LIBZIP)
480	include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
481	link_directories(${LIBZIP_LIBRARY_DIRS})
482	list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
483	list(APPEND FEATURES LIBZIP)
484	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
485	string(REGEX MATCH "^[0-9]+" LIBZIP_VERSION_MAJOR ${libzip_VERSION})
486	if (LIBZIP_VERSION_MAJOR LESS 1)
487		set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
488	elseif(LIBZIP_VERSION_MAJOR EQUAL 1)
489		set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip4")
490	else()
491		message(AUTHOR_WARNING Unknown version of libzip detected: ${libzip_VERSION})
492	endif()
493elseif(USE_MINIZIP)
494	include_directories(AFTER ${MINIZIP_INCLUDE_DIRS})
495	link_directories(${MINIZIP_LIBRARY_DIRS})
496	list(APPEND DEPENDENCY_LIB ${MINIZIP_LIBRARIES})
497	list(APPEND FEATURES MINIZIP)
498	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
499	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libminizip1")
500elseif(USE_ZLIB)
501	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c
502		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
503		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c)
504	set_source_files_properties(
505		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
506		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c
507		PROPERTIES COMPILE_FLAGS "-Wno-unused-parameter -Wno-implicit-function-declaration")
508endif()
509
510if (USE_LZMA)
511	include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/third-party/lzma)
512	add_definitions(-D_7ZIP_PPMD_SUPPPORT)
513	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-lzma.c)
514	set(LZMA_SRC
515		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
516		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
517		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
518		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
519		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
520		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
521		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zDec.c
522		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
523		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Delta.c
524		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
525		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
526		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra.c
527		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra86.c
528		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/BraIA64.c
529		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
530		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
531		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
532		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zFile.c
533		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
534	list(APPEND VFS_SRC ${LZMA_SRC})
535	list(APPEND FEATURES LZMA)
536endif()
537
538if(USE_EPOXY)
539	add_definitions(-DBUILD_GL -DBUILD_GLES2)
540	list(APPEND FEATURES EPOXY)
541	include_directories(AFTER ${EPOXY_INCLUDE_DIRS})
542	set(OPENGLES2_LIBRARY ${EPOXY_LIBRARIES})
543	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libepoxy0")
544endif()
545
546set(TEST_SRC ${CORE_TEST_SRC})
547if(M_CORE_GB)
548	add_definitions(-DM_CORE_GB)
549	list(APPEND CORE_SRC
550		${LR35902_SRC}
551		${GB_SRC}
552		${GB_RENDERER_SRC})
553	list(APPEND DEBUGGER_SRC
554		${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/cli-debugger.c
555		${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/debugger.c
556		${CMAKE_CURRENT_SOURCE_DIR}/src/gb/extra/cli.c)
557	list(APPEND TEST_SRC
558		${LR35902_TEST_SRC}
559		${GB_TEST_SRC})
560endif()
561
562if(M_CORE_GBA)
563	add_definitions(-DM_CORE_GBA)
564	list(APPEND CORE_SRC 
565		${ARM_SRC}
566		${GBA_SRC}
567		${GBA_CHEATS_SRC}
568		${GBA_RENDERER_SRC})
569	list(APPEND DEBUGGER_SRC
570		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c
571		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/debugger.c
572		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/memory-debugger.c
573		${CMAKE_CURRENT_SOURCE_DIR}/src/gba/extra/cli.c)
574	list(APPEND TEST_SRC
575		${ARM_TEST_SRC}
576		${GBA_TEST_SRC})
577	if(NOT M_CORE_GB)
578		list(APPEND CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/audio.c)
579	endif()
580endif()
581
582if(USE_DEBUGGERS)
583	list(APPEND FEATURE_SRC ${DEBUGGER_SRC})
584	list(APPEND FEATURES DEBUGGERS)
585endif()
586
587set(FEATURE_DEFINES)
588foreach(FEATURE IN LISTS FEATURES)
589	list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
590endforeach()
591
592source_group("Virtual files" FILES ${CORE_VFS_SRC} ${VFS_SRC})
593source_group("Extra features" FILES ${FEATURE_SRC})
594source_group("Third-party code" FILES ${THIRD_PARTY_SRC})
595
596# Platform binaries
597if(3DS)
598	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/3ds ${CMAKE_CURRENT_BINARY_DIR}/3ds)
599endif()
600
601if(WII)
602	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/wii ${CMAKE_CURRENT_BINARY_DIR}/wii)
603endif()
604
605if(PSP2)
606	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/psp2 ${CMAKE_CURRENT_BINARY_DIR}/psp2)
607endif()
608
609# Binaries
610list(APPEND CORE_SRC
611	${UTIL_SRC}
612	${CORE_VFS_SRC}
613	${OS_SRC}
614	${THIRD_PARTY_SRC})
615list(APPEND TEST_SRC ${UTIL_TEST_SRC})
616
617set(SRC ${CORE_SRC} ${VFS_SRC})
618if(NOT MINIMAL_CORE)
619	if(M_CORE_GBA)
620		list(APPEND SRC
621			${GBA_RR_SRC}
622			${GBA_EXTRA_SRC}
623			${SIO_SRC})
624	endif()
625	list(APPEND SRC
626		${FEATURE_SRC}
627		${CLI_SRC})
628endif()
629
630if(NOT SKIP_LIBRARY)
631	if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
632		set(BUILD_SHARED ON)
633	endif()
634
635	if(BUILD_SHARED)
636		add_library(${BINARY_NAME} SHARED ${SRC} ${VFS_SRC})
637		if(BUILD_STATIC)
638			add_library(${BINARY_NAME}-static STATIC ${SRC})
639			set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
640			install(TARGETS ${BINARY_NAME}-static DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
641			add_dependencies(${BINARY_NAME}-static version-info)
642		endif()
643	else()
644		add_library(${BINARY_NAME} STATIC ${SRC})
645	endif()
646
647	add_dependencies(${BINARY_NAME} version-info)
648	set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
649
650	target_link_libraries(${BINARY_NAME} ${DEBUGGER_LIB} ${DEPENDENCY_LIB} ${OS_LIB})
651	install(TARGETS ${BINARY_NAME} LIBRARY DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME} NAMELINK_SKIP ARCHIVE DESTINATION ${LIBDIR} RUNTIME DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
652	if(UNIX AND NOT APPLE)
653		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-16.png DESTINATION share/icons/hicolor/16x16/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
654		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-24.png DESTINATION share/icons/hicolor/24x24/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
655		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-32.png DESTINATION share/icons/hicolor/32x32/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
656		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-48.png DESTINATION share/icons/hicolor/48x48/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
657		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-64.png DESTINATION share/icons/hicolor/64x64/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
658		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-96.png DESTINATION share/icons/hicolor/96x96/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
659		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-128.png DESTINATION share/icons/hicolor/128x128/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
660		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-256.png DESTINATION share/icons/hicolor/256x256/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
661		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-512.png DESTINATION share/icons/hicolor/512x512/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
662	endif()
663else()
664	set(BUILD_SHARED OFF)
665	set(BUILD_STATIC OFF)
666	find_library(${BINARY_NAME} ${BINARY_NAME})
667	if(NOT ${BINARY_NAME}_FOUND)
668		set(DISABLE_FRONTENDS ON)
669		set(BUILD_PERF OFF)
670		set(BUILD_TEST OFF)
671		set(BUILD_SUITE OFF)
672	endif()
673endif()
674
675if(BUILD_GL)
676	add_definitions(-DBUILD_GL)
677endif()
678
679if(BUILD_GLES2)
680	add_definitions(-DBUILD_GLES2)
681endif()
682
683if(DISABLE_FRONTENDS)
684	set(BUILD_SDL OFF)
685	set(BUILD_QT OFF)
686endif()
687
688if(BUILD_LIBRETRO)
689	file(GLOB RETRO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/libretro/*.c)
690	add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
691	set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5;DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=2")
692	target_link_libraries(${BINARY_NAME}_libretro ${OS_LIB})
693	install(TARGETS ${BINARY_NAME}_libretro LIBRARY DESTINATION ${LIBRETRO_LIBDIR} COMPONENT ${BINARY_NAME}_libretro NAMELINK_SKIP)
694endif()
695
696if(BUILD_OPENEMU)
697	find_library(FOUNDATION Foundation)
698	find_library(OPENEMUBASE OpenEmuBase)
699	file(GLOB OE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/*.m)
700	add_library(${BINARY_NAME}-openemu MODULE ${CORE_SRC} ${OE_SRC})
701	set_target_properties(${BINARY_NAME}-openemu PROPERTIES
702		MACOSX_BUNDLE_INFO_PLIST ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/Info.plist.in
703		BUNDLE TRUE
704		BUNDLE_EXTENSION oecoreplugin
705		OUTPUT_NAME ${PROJECT_NAME}
706		COMPILE_DEFINITIONS "DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=1")
707	target_link_libraries(${BINARY_NAME}-openemu ${OS_LIB} ${FOUNDATION} ${OPENEMUBASE})
708	install(TARGETS ${BINARY_NAME}-openemu LIBRARY DESTINATION ${OE_LIBDIR} COMPONENT ${BINARY_NAME}.oecoreplugin NAMELINK_SKIP)
709endif()
710
711if(BUILD_SDL)
712	add_definitions(-DBUILD_SDL)
713	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/sdl ${CMAKE_CURRENT_BINARY_DIR}/sdl)
714endif()
715
716if(BUILD_QT)
717	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/qt ${CMAKE_CURRENT_BINARY_DIR}/qt)
718endif()
719
720if(BUILD_PERF)
721	set(PERF_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/perf-main.c ${CLI_SRC})
722	if(UNIX AND NOT APPLE)
723		list(APPEND PERF_LIB rt)
724	endif()
725
726	add_executable(${BINARY_NAME}-perf ${PERF_SRC})
727	target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB} ${OS_LIB})
728	set_target_properties(${BINARY_NAME}-perf PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
729	install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
730	install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
731endif()
732
733if(BUILD_TEST)
734	add_executable(${BINARY_NAME}-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/fuzz-main.c)
735	target_link_libraries(${BINARY_NAME}-fuzz ${BINARY_NAME})
736	set_target_properties(${BINARY_NAME}-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
737	add_executable(tbl-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/tbl-fuzz-main.c)
738	target_link_libraries(tbl-fuzz ${BINARY_NAME})
739	set_target_properties(tbl-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
740	install(TARGETS ${BINARY_NAME}-fuzz tbl-fuzz DESTINATION bin COMPONENT ${BINARY_NAME}-test)
741endif()
742
743if(NOT USE_CMOCKA)
744	set(BUILD_SUITE OFF)
745endif()
746if(BUILD_SUITE)
747	enable_testing()
748	include_directories(AFTER ${CMOCKA_INCLUDE_DIRS})
749	link_directories(${CMOCKA_LIBRARY_DIRS})
750
751	add_executable(${BINARY_NAME}-suite ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/suite-main.c ${TEST_SRC})
752	target_link_libraries(${BINARY_NAME}-suite ${BINARY_NAME} ${PLATFORM_LIBRARY} cmocka)
753	set_target_properties(${BINARY_NAME}-suite PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
754	add_test(${BINARY_NAME}-suite ${BINARY_NAME}-suite)
755endif()
756
757if(BUILD_PYTHON)
758	enable_testing()
759	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/python ${CMAKE_CURRENT_BINARY_DIR}/python)
760endif()
761
762if(BUILD_EXAMPLE)
763	add_executable(${BINARY_NAME}-example-server ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/server.c)
764	target_link_libraries(${BINARY_NAME}-example-server ${BINARY_NAME})
765	set_target_properties(${BINARY_NAME}-example-server PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
766
767	if(BUILD_SDL)
768		add_executable(${BINARY_NAME}-example-client ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/client.c)
769		target_link_libraries(${BINARY_NAME}-example-client ${BINARY_NAME} ${SDL_LIBRARY} ${SDLMAIN_LIBRARY} ${OPENGL_LIBRARY} ${OPENGLES2_LIBRARY})
770		set_target_properties(${BINARY_NAME}-example-client PROPERTIES
771		                      COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}"
772		                      INCLUDE_DIRECTORIES "${SDL_INCLUDE_DIR};${CMAKE_CURRENT_SOURCE_DIR}/src")
773	endif()
774endif()
775
776# Packaging
777set(CPACK_PACKAGE_VERSION ${VERSION_STRING})
778set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
779set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
780set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
781set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
782set(CPACK_RESOURCE_FILE_README ${CMAKE_CURRENT_SOURCE_DIR}/README.md)
783
784set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
785set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
786set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
787set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README.md")
788set(CPACK_DEBIAN_PACKAGE_SECTION "games")
789
790SET(CPACK_DEB_COMPONENT_INSTALL ON)
791
792set(CPACK_STRIP_FILES ${BINARY_NAME})
793
794install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/README.md ${CMAKE_CURRENT_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
795
796include(CPack)
797
798# Summaries
799set(SUMMARY_GL_LIST)
800if(USE_EPOXY)
801	set(SUMMARY_GL_LIST "libepoxy")
802else()
803	if(BUILD_GL)
804		list(APPEND SUMMARY_GL_LIST "OpenGL")
805	endif()
806	if(BUILD_GLES2)
807		list(APPEND SUMMARY_GL_LIST "OpenGL|ES 2")
808	endif()
809endif()
810if(NOT SUMMARY_GL_LIST)
811	set(SUMMARY_GL OFF)
812else()
813	string(REPLACE ";" ", " SUMMARY_GL "${SUMMARY_GL_LIST}")
814endif()
815if(USE_LIBZIP)
816	set(SUMMARY_ZIP libzip)
817elseif(USE_MINIZIP)
818	set(SUMMARY_ZIP "minizip (external)")
819elseif(USE_ZLIB)
820	set(SUMMARY_ZIP "minizip (included)")
821else()
822	set(SUMMARY_ZIP OFF)
823endif()
824
825if(NOT QUIET)
826	message(STATUS "Platforms:")
827	message(STATUS "	Game Boy Advance: ${M_CORE_GBA}")
828	message(STATUS "	Game Boy: ${M_CORE_GB}")
829	message(STATUS "Features:")
830	message(STATUS "	Debuggers: ${USE_DEBUGGERS}")
831	message(STATUS "	CLI debugger: ${USE_EDITLINE}")
832	message(STATUS "	GDB stub: ${USE_GDB_STUB}")
833	message(STATUS "	Video recording: ${USE_FFMPEG}")
834	message(STATUS "	GIF recording: ${USE_MAGICK}")
835	message(STATUS "	Screenshot/advanced savestate support: ${USE_PNG}")
836	message(STATUS "	ZIP support: ${SUMMARY_ZIP}")
837	message(STATUS "	7-Zip support: ${USE_LZMA}")
838	message(STATUS "	OpenGL support: ${SUMMARY_GL}")
839	message(STATUS "Frontends:")
840	message(STATUS "	Qt: ${BUILD_QT}")
841	message(STATUS "	SDL (${SDL_VERSION}): ${BUILD_SDL}")
842	message(STATUS "	Profiling: ${BUILD_PERF}")
843	message(STATUS "	Test harness: ${BUILD_TEST}")
844	message(STATUS "	Test suite: ${BUILD_SUITE}")
845	message(STATUS "	Python bindings: ${BUILD_PYTHON}")
846	message(STATUS "	Examples: ${BUILD_EXAMPLE}")
847	message(STATUS "Cores:")
848	message(STATUS "	Libretro core: ${BUILD_LIBRETRO}")
849	if(APPLE)
850		message(STATUS "	OpenEmu core: ${BUILD_OPENEMU}")
851	endif()
852	message(STATUS "Libraries:")
853	message(STATUS "	Static: ${BUILD_STATIC}")
854	message(STATUS "	Shared: ${BUILD_SHARED}")
855endif()