CMakeLists.txt (view raw)
1cmake_minimum_required(VERSION 2.6)
2project(mGBA C)
3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
4if(NOT MSVC)
5 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wno-missing-field-initializers -std=c99")
6else()
7 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_CRT_SECURE_NO_WARNINGS /wd4003 /wd4244 /wd4146")
8endif()
9set(USE_DEBUGGERS ON CACHE BOOL "Whether or not to enable the debugging infrastructure")
10set(USE_EDITLINE ON CACHE BOOL "Whether or not to enable the CLI-mode debugger")
11set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
12set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
13set(USE_ZLIB ON CACHE BOOL "Whether or not to enable zlib support")
14set(USE_MINIZIP ON CACHE BOOL "Whether or not to enable external minizip support")
15set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
16set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable LIBZIP support")
17set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
18set(USE_SQLITE3 ON CACHE BOOL "Whether or not to enable SQLite3 support")
19set(M_CORE_GBA ON CACHE BOOL "Build Game Boy Advance core")
20set(M_CORE_GB ON CACHE BOOL "Build Game Boy core")
21set(M_CORE_DS ON CACHE BOOL "Build DS core")
22set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
23set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
24set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
25set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
26if(APPLE)
27 set(BUILD_OPENEMU OFF CACHE BOOL "Build OpenEmu core")
28endif()
29set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
30set(BUILD_TEST OFF CACHE BOOL "Build testing harness")
31set(BUILD_SUITE OFF CACHE BOOL "Build test suite")
32set(BUILD_EXAMPLE OFF CACHE BOOL "Build example frontends")
33set(BUILD_PYTHON OFF CACHE BOOL "Build Python bindings")
34set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
35set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
36set(SKIP_LIBRARY OFF CACHE BOOL "Skip building the library (useful for only building libretro or OpenEmu cores)")
37set(BUILD_GL ON CACHE STRING "Build with OpenGL")
38set(BUILD_GLES2 OFF CACHE STRING "Build with OpenGL|ES 2")
39set(USE_EPOXY ON CACHE STRING "Build with libepoxy")
40set(DISABLE_DEPS OFF CACHE BOOL "Build without dependencies")
41file(GLOB ARM_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/*.c)
42file(GLOB ARM_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/test/*.c)
43file(GLOB LR35902_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/*.c)
44file(GLOB LR35902_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/test/*.c)
45file(GLOB GBA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/*.c)
46file(GLOB GBA_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/test/*.c)
47file(GLOB GB_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/*.c)
48file(GLOB GB_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/test/*.c)
49file(GLOB DS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/ds/*.c)
50file(GLOB GBA_CHEATS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/cheats/*.c)
51file(GLOB GBA_RR_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/rr/*.c)
52file(GLOB CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/*.c)
53file(GLOB CORE_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/test/*.c)
54file(GLOB UTIL_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/*.[cSs])
55file(GLOB UTIL_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/test/*.c)
56file(GLOB GUI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/gui/*.c ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/gui/*.c)
57file(GLOB GBA_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/renderers/*.c)
58file(GLOB GBA_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/sio/lockstep.c)
59file(GLOB GB_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/sio/lockstep.c)
60file(GLOB GB_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/renderers/*.c)
61file(GLOB DS_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/ds/renderers/*.c ${CMAKE_CURRENT_SOURCE_DIR}/src/ds/gx/*.c)
62file(GLOB THIRD_PARTY_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/inih/*.c)
63set(CLI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/commandline.c)
64set(CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-mem.c)
65set(VFS_SRC)
66source_group("ARM core" FILES ${ARM_SRC})
67source_group("LR35902 core" FILES ${LR35902_SRC})
68source_group("GBA board" FILES ${GBA_SRC} ${GBA_RENDERER_SRC} ${GBA_SIO_SRC})
69source_group("GBA extra" FILES ${GBA_CHEATS_SRC} ${GBA_RR_SRC})
70source_group("GB board" FILES ${GB_SRC} ${GB_SIO_SRC})
71source_group("DS board" FILES ${DS_SRC})
72source_group("Utilities" FILES ${UTIL_SRC})
73include_directories(BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/include ${CMAKE_CURRENT_SOURCE_DIR}/src)
74
75if(NOT CMAKE_BUILD_TYPE)
76 set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
77endif()
78
79include(GNUInstallDirs)
80
81set(LIBDIR "${CMAKE_INSTALL_LIBDIR}" CACHE PATH "Installed library directory")
82mark_as_advanced(LIBDIR)
83
84if (BUILD_LIBRETRO)
85 set(LIBRETRO_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (Libretro)")
86 mark_as_advanced(LIBRETRO_LIBDIR)
87endif()
88
89if (BUILD_OPENEMU)
90 set(OE_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (OpenEmu)")
91 mark_as_advanced(OE_LIBDIR)
92endif()
93
94
95set(CMAKE_INSTALL_RPATH "${LIBDIR}")
96
97if (NOT DEFINED MANDIR)
98 set(MANDIR ${CMAKE_INSTALL_MANDIR})
99endif()
100
101# Function definitions
102include(FindPkgConfig)
103function(find_feature FEATURE_NAME FEATURE_REQUIRES)
104 if (NOT ${FEATURE_NAME})
105 return()
106 endif()
107 if (DISABLE_DEPS)
108 set(${FEATURE_NAME} OFF PARENT_SCOPE)
109 return()
110 endif()
111 foreach(REQUIRE ${FEATURE_REQUIRES})
112 if(NOT ${REQUIRE}_FOUND)
113 find_package(${REQUIRE} QUIET)
114 if(NOT ${REQUIRE}_FOUND)
115 pkg_search_module(${REQUIRE} ${REQUIRE})
116 if (NOT ${REQUIRE}_FOUND)
117 message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
118 set(${FEATURE_NAME} OFF PARENT_SCOPE)
119 return()
120 endif()
121 endif()
122 endif()
123 string(TOUPPER ${REQUIRE} UREQUIRE)
124 set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
125 set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
126 set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
127 if (APPLE)
128 set(IS_FRAMEWORK OFF)
129 set(LIBS)
130 foreach(LIB IN LISTS ${REQUIRE}_LIBRARIES)
131 if(LIB STREQUAL "-framework")
132 set(IS_FRAMEWORK ON)
133 elseif(IS_FRAMEWORK)
134 list(APPEND LIBS "-framework ${LIB}")
135 set(IS_FRAMEWORK OFF)
136 else()
137 list(APPEND LIBS ${LIB})
138 endif()
139 endforeach()
140 set(${UREQUIRE}_LIBRARIES ${LIBS} PARENT_SCOPE)
141 else()
142 set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
143 endif()
144 set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
145 set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
146 endforeach()
147endfunction()
148
149# Version information
150add_custom_target(version-info ALL
151 COMMAND ${CMAKE_COMMAND}
152 -DBINARY_NAME=${BINARY_NAME}
153 -DCONFIG_FILE=${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in
154 -DOUT_FILE=${CMAKE_CURRENT_BINARY_DIR}/version.c
155 -P ${CMAKE_CURRENT_SOURCE_DIR}/version.cmake
156 WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
157
158include(${CMAKE_CURRENT_SOURCE_DIR}/version.cmake)
159configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in ${CMAKE_CURRENT_BINARY_DIR}/version.c)
160configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/flags.h.in ${CMAKE_CURRENT_BINARY_DIR}/flags.h)
161install(FILES ${CMAKE_CURRENT_BINARY_DIR}/flags.h DESTINATION include/mgba COMPONENT lib${BINARY_NAME})
162
163list(APPEND UTIL_SRC ${CMAKE_CURRENT_BINARY_DIR}/version.c)
164source_group("Generated sources" FILES ${CMAKE_CURRENT_BINARY_DIR}/version.c)
165
166# Advanced settings
167if(NOT 3DS)
168 # LTO appears to make 3DS binary slower
169 set(DEFAULT_LTO ON)
170else()
171 set(DEFAULT_LTO OFF)
172endif()
173
174set(BUILD_LTO ${DEFAULT_LTO} CACHE BOOL "Build with link-time optimization")
175set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
176set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
177set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
178mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
179set(PGO_PRE_FLAGS "-fprofile-generate=${PGO_DIR} -fprofile-arcs")
180set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
181
182if(BUILD_PGO AND NOT PGO_STAGE_2)
183 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
184 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
185 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
186elseif(BUILD_PGO AND PGO_STAGE_2)
187 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
188 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
189 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
190endif()
191
192# Platform support
193if(WIN32)
194 set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
195 add_definitions(-D_WIN32_WINNT=0x0600)
196 list(APPEND OS_LIB ws2_32 shlwapi)
197 list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/vfs-w32.c)
198 file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/*.c)
199 source_group("Windows-specific code" FILES ${OS_SRC})
200 if(MSVC)
201 add_definitions(-DNOMINMAX -DWIN32_LEAN_AND_MEAN)
202 endif()
203elseif(UNIX)
204 add_definitions(-DUSE_PTHREADS)
205
206 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
207 add_definitions(-D_GNU_SOURCE)
208 endif()
209 if(NOT APPLE AND NOT HAIKU)
210 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
211 endif()
212
213 list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
214 file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/posix/*.c)
215 source_group("POSIX-specific code" FILES ${OS_SRC})
216endif()
217
218if(APPLE)
219 add_definitions(-D_DARWIN_C_SOURCE)
220 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
221endif()
222
223if(NOT HAIKU AND NOT MSVC AND NOT PSP2)
224 set(M_LIBRARY m)
225endif()
226list(APPEND OS_LIB ${M_LIBRARY})
227
228if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
229 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
230 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
231endif()
232
233if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
234 if(NOT BUILD_EGL)
235 add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
236 endif()
237endif()
238
239if(BUILD_RASPI)
240 set(BUILD_GL OFF CACHE BOOL "OpenGL not supported" FORCE)
241endif()
242
243if(BUILD_PANDORA)
244 add_definitions(-DBUILD_PANDORA)
245endif()
246
247if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
248 enable_language(ASM)
249endif()
250
251if(PSP2 OR WII)
252 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-format")
253endif()
254
255if(DEFINED 3DS OR DEFINED PSP2 OR DEFINED WII)
256 set(USE_DEBUGGERS OFF)
257 set(USE_SQLITE3 OFF)
258endif()
259
260if(NOT M_CORE_GBA)
261 set(USE_GDB_STUB OFF)
262endif()
263
264if(NOT USE_DEBUGGERS)
265 set(USE_EDITLINE OFF)
266 set(USE_GDB_STUB OFF)
267endif()
268
269if(WII)
270 add_definitions(-U__STRICT_ANSI__)
271endif()
272
273include(CheckFunctionExists)
274check_function_exists(strdup HAVE_STRDUP)
275check_function_exists(strndup HAVE_STRNDUP)
276check_function_exists(localtime_r HAVE_LOCALTIME_R)
277if(NOT CMAKE_SYSTEM_NAME STREQUAL "Generic")
278 check_function_exists(snprintf_l HAVE_SNPRINTF_L)
279 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
280 # The strtof_l on Linux not actually exposed nor actually strtof_l
281 set(HAVE_STRTOF_L OFF)
282 else()
283 check_function_exists(strtof_l HAVE_STRTOF_L)
284 endif()
285 check_function_exists(newlocale HAVE_NEWLOCALE)
286 check_function_exists(freelocale HAVE_FREELOCALE)
287 check_function_exists(uselocale HAVE_USELOCALE)
288 check_function_exists(setlocale HAVE_SETLOCALE)
289else()
290 if(NOT DEFINED 3DS AND NOT DEFINED PSP2 AND NOT DEFINED WII)
291 set(DISABLE_DEPS ON CACHE BOOL "This platform cannot build with dependencies" FORCE)
292 endif()
293 set(DISABLE_FRONTENDS ON)
294 set(MINIMAL_CORE ON)
295endif()
296
297check_function_exists(chmod HAVE_CHMOD)
298check_function_exists(umask HAVE_UMASK)
299
300set(FUNCTION_DEFINES)
301
302if(HAVE_STRDUP)
303 list(APPEND FUNCTION_DEFINES HAVE_STRDUP)
304endif()
305
306if(HAVE_STRNDUP)
307 list(APPEND FUNCTION_DEFINES HAVE_STRNDUP)
308endif()
309
310if(HAVE_LOCALTIME_R)
311 list(APPEND FUNCTION_DEFINES HAVE_LOCALTIME_R)
312endif()
313
314if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE OR APPLE)
315 list(APPEND FUNCTION_DEFINES HAVE_LOCALE)
316 if (HAVE_STRTOF_L)
317 list(APPEND FUNCTION_DEFINES HAVE_STRTOF_L)
318 endif()
319 if (HAVE_SNPRINTF_L)
320 list(APPEND FUNCTION_DEFINES HAVE_SNPRINTF_L)
321 endif()
322endif()
323
324if(HAVE_SETLOCALE)
325 list(APPEND FUNCTION_DEFINES HAVE_SETLOCALE)
326endif()
327
328if(HAVE_CHMOD)
329 list(APPEND FUNCTION_DEFINES HAVE_CHMOD)
330endif()
331
332if(HAVE_UMASK)
333 list(APPEND FUNCTION_DEFINES HAVE_UMASK)
334endif()
335
336# Feature dependencies
337set(FEATURE_DEFINES)
338set(FEATURES)
339if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
340 set(LIBEDIT_LIBRARIES -ledit)
341 if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
342 list(APPEND LIBEDIT_LIBRARIES -ltermcap)
343 endif()
344else()
345 find_feature(USE_EDITLINE "libedit")
346endif()
347if(BUILD_GL)
348 find_package(OpenGL QUIET)
349 if(NOT OPENGL_FOUND)
350 set(BUILD_GL OFF CACHE BOOL "OpenGL not found" FORCE)
351 endif()
352endif()
353if(NOT BUILD_GL)
354 set(OPENGLE_LIBRARY "" CACHE PATH "" FORCE)
355endif()
356if(BUILD_GLES2 AND NOT BUILD_RASPI)
357 find_path(OPENGLES2_INCLUDE_DIR NAMES GLES2/gl2.h)
358 find_library(OPENGLES2_LIBRARY NAMES GLESv2 GLESv2_CM)
359 if(NOT OPENGLES2_INCLUDE_DIR OR NOT OPENGLES2_LIBRARY)
360 set(BUILD_GLES2 OFF CACHE BOOL "OpenGL|ES 2 not found" FORCE)
361 endif()
362endif()
363if(NOT BUILD_GLES2)
364 set(OPENGLES2_LIBRARY "" CACHE PATH "" FORCE)
365endif()
366set(WANT_ZLIB ${USE_ZLIB})
367set(WANT_PNG ${USE_PNG})
368set(WANT_LIBZIP ${USE_LIBZIP})
369set(WANT_SQLITE3 ${USE_SQLITE3})
370set(USE_CMOCKA ${BUILD_SUITE})
371
372find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
373find_feature(USE_ZLIB "ZLIB")
374find_feature(USE_MINIZIP "minizip")
375find_feature(USE_PNG "PNG")
376find_feature(USE_LIBZIP "libzip")
377find_feature(USE_MAGICK "MagickWand")
378find_feature(USE_EPOXY "epoxy")
379find_feature(USE_CMOCKA "cmocka")
380find_feature(USE_SQLITE3 "sqlite3")
381
382# Features
383set(DEBUGGER_SRC
384 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/debugger.c
385 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/parser.c
386 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/cli-debugger.c)
387
388set(FEATURE_SRC)
389set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
390
391if(DISABLE_DEPS)
392 set(USE_GDB_STUB OFF)
393endif()
394
395if(USE_EDITLINE)
396 list(APPEND FEATURES EDITLINE)
397 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/cli-debugger.c)
398 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/parser.c)
399 if(M_CORE_GBA)
400 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c)
401 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/extra/cli.c)
402 endif()
403 if(M_CORE_GB)
404 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/cli-debugger.c)
405 endif()
406 if(M_CORE_DS)
407 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c)
408 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/ds/extra/cli.c)
409 endif()
410 include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
411 link_directories(${LIBEDIT_LIBRARY_DIRS})
412 set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
413 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
414 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/editline/cli-el-backend.c")
415else()
416 set(DEBUGGER_LIB "")
417endif()
418
419if(USE_GDB_STUB)
420 list(APPEND FEATURES GDB_STUB)
421 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/gdb-stub.c)
422endif()
423source_group("Debugger" FILES ${DEBUGGER_SRC})
424
425if(USE_FFMPEG)
426 list(APPEND FEATURES FFMPEG)
427 pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
428 if(NOT LIBSWRESAMPLE_FOUND)
429 list(APPEND FEATURES LIBAV)
430 endif()
431 include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
432 link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
433 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/ffmpeg/ffmpeg-encoder.c")
434 string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
435 string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
436 string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
437 string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
438 string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
439 list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
440 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR}|libavcodec-extra-${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
441 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavformat${LIBAVFORMAT_VERSION_MAJOR}|libavformat-ffmpeg${LIBAVFORMAT_VERSION_MAJOR}")
442 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavresample${LIBAVRESAMPLE_VERSION_MAJOR}|libavresample-ffmpeg${LIBAVRESAMPLE_VERSION_MAJOR}")
443 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavutil${LIBAVUTIL_VERSION_MAJOR}|libavutil-ffmpeg${LIBAVUTIL_VERSION_MAJOR}")
444 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libswscale${LIBSWSCALE_VERSION_MAJOR}|libswscale-ffmpeg${LIBSWSCALE_VERSION_MAJOR}")
445 set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
446 if(APPLE)
447 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
448 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
449 endif()
450endif()
451
452list(APPEND THIRD_PARTY_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
453
454if(USE_MAGICK)
455 list(APPEND FEATURES MAGICK)
456 include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
457 link_directories(${MAGICKWAND_LIBRARY_DIRS})
458 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/imagemagick/imagemagick-gif-encoder.c")
459 list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
460 string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
461 string(REGEX MATCH "^[0-9]+" MAGICKWAND_VERSION_MAJOR ${MagickWand_VERSION})
462 if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
463 set(MAGICKWAND_DEB_VERSION "5")
464 elseif(${MagickWand_VERSION} EQUAL "6.9.7")
465 set(MAGICKWAND_DEB_VERSION "-6.q16-3")
466 else()
467 set(MAGICKWAND_DEB_VERSION "-6.q16-2")
468 endif()
469 list(APPEND FEATURE_DEFINES MAGICKWAND_VERSION_MAJOR=${MAGICKWAND_VERSION_MAJOR})
470
471 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
472endif()
473
474if(WANT_ZLIB AND NOT USE_ZLIB)
475 set(SKIP_INSTALL_ALL ON)
476 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib zlib)
477 set_property(TARGET zlibstatic PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/zlib;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib)
478 set_property(TARGET zlib PROPERTY EXCLUDE_FROM_ALL ON)
479 set_property(TARGET example PROPERTY EXCLUDE_FROM_ALL ON)
480 set_property(TARGET minigzip PROPERTY EXCLUDE_FROM_ALL ON)
481 set(ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
482 set(ZLIB_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
483 set(ZLIB_LIBRARY zlibstatic)
484 list(APPEND DEPENDENCY_LIB zlibstatic)
485 set(USE_ZLIB ON)
486endif()
487
488if(USE_ZLIB)
489 list(APPEND FEATURES ZLIB)
490 include_directories(AFTER ${ZLIB_INCLUDE_DIRS})
491 list(APPEND DEPENDENCY_LIB ${ZLIB_LIBRARIES})
492 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},zlib1g")
493endif()
494
495if(WANT_PNG AND USE_ZLIB AND NOT USE_PNG)
496 set(PNG_STATIC ON CACHE BOOL "" FORCE)
497 set(PNG_SHARED OFF CACHE BOOL "" FORCE)
498 set(PNG_TESTS OFF CACHE BOOL "" FORCE)
499 set(SKIP_INSTALL_ALL ON)
500 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng libpng)
501 set_property(TARGET png16_static PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/libpng;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng;${ZLIB_INCLUDE_DIRS})
502 set(PNG_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng ${CMAKE_CURRENT_BINARY_DIR}/libpng)
503 list(APPEND DEPENDENCY_LIB png16_static)
504 set(USE_PNG ON)
505endif()
506
507if(USE_PNG)
508 list(APPEND FEATURES PNG)
509 include_directories(AFTER ${PNG_INCLUDE_DIRS})
510 list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
511 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng12-0")
512endif()
513
514if(WANT_SQLITE3 AND NOT USE_SQLITE3)
515 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/sqlite3.c)
516 include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/)
517 set(USE_SQLITE3 ON)
518endif()
519
520if(USE_LIBZIP)
521 include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
522 link_directories(${LIBZIP_LIBRARY_DIRS})
523 list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
524 list(APPEND FEATURES LIBZIP)
525 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
526 string(REGEX MATCH "^[0-9]+" LIBZIP_VERSION_MAJOR ${libzip_VERSION})
527 if (LIBZIP_VERSION_MAJOR LESS 1)
528 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
529 elseif(LIBZIP_VERSION_MAJOR EQUAL 1)
530 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip4")
531 else()
532 message(AUTHOR_WARNING Unknown version of libzip detected: ${libzip_VERSION})
533 endif()
534elseif(USE_MINIZIP)
535 include_directories(AFTER ${MINIZIP_INCLUDE_DIRS})
536 link_directories(${MINIZIP_LIBRARY_DIRS})
537 list(APPEND DEPENDENCY_LIB ${MINIZIP_LIBRARIES})
538 list(APPEND FEATURES MINIZIP)
539 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
540 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libminizip1")
541elseif(USE_ZLIB)
542 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c
543 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
544 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c)
545 set_source_files_properties(
546 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
547 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c
548 PROPERTIES COMPILE_FLAGS "-Wno-unused-parameter -Wno-implicit-function-declaration")
549endif()
550
551if (USE_LZMA)
552 include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/third-party/lzma)
553 add_definitions(-D_7ZIP_PPMD_SUPPPORT)
554 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-lzma.c)
555 set(LZMA_SRC
556 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
557 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
558 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
559 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
560 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
561 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
562 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zDec.c
563 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
564 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Delta.c
565 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
566 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
567 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra.c
568 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra86.c
569 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/BraIA64.c
570 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
571 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
572 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
573 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zFile.c
574 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
575 list(APPEND VFS_SRC ${LZMA_SRC})
576 list(APPEND FEATURES LZMA)
577endif()
578
579if(USE_EPOXY)
580 add_definitions(-DBUILD_GL -DBUILD_GLES2)
581 list(APPEND FEATURES EPOXY)
582 include_directories(AFTER ${EPOXY_INCLUDE_DIRS})
583 set(OPENGLES2_LIBRARY ${EPOXY_LIBRARIES})
584 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libepoxy0")
585endif()
586
587if(USE_SQLITE3)
588 list(APPEND FEATURES SQLITE3)
589 include_directories(AFTER ${SQLITE3_INCLUDE_DIRS})
590 list(APPEND DEPENDENCY_LIB ${SQLITE3_LIBRARIES})
591 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libsqlite3-0")
592 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/sqlite3/no-intro.c")
593endif()
594
595set(TEST_SRC ${CORE_TEST_SRC})
596if(M_CORE_GB)
597 add_definitions(-DM_CORE_GB)
598 list(APPEND CORE_SRC
599 ${LR35902_SRC}
600 ${GB_SRC}
601 ${GB_RENDERER_SRC})
602 list(APPEND DEBUGGER_SRC
603 ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/cli-debugger.c
604 ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/debugger.c
605 ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/extra/cli.c)
606 list(APPEND TEST_SRC
607 ${LR35902_TEST_SRC}
608 ${GB_TEST_SRC})
609endif()
610
611if(M_CORE_GBA)
612 add_definitions(-DM_CORE_GBA)
613 list(APPEND CORE_SRC
614 ${ARM_SRC}
615 ${GBA_SRC}
616 ${GBA_CHEATS_SRC}
617 ${GBA_RENDERER_SRC})
618 list(APPEND DEBUGGER_SRC
619 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c
620 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/debugger.c
621 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/memory-debugger.c
622 ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/extra/cli.c)
623 list(APPEND TEST_SRC
624 ${ARM_TEST_SRC}
625 ${GBA_TEST_SRC})
626 if(NOT M_CORE_GB)
627 list(APPEND CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/audio.c)
628 endif()
629endif()
630
631if(M_CORE_DS)
632 add_definitions(-DM_CORE_DS)
633 list(APPEND CORE_SRC
634 ${ARM_SRC}
635 ${DS_SRC}
636 ${DS_RENDERER_SRC})
637 list(APPEND DEBUGGER_SRC
638 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c
639 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/debugger.c
640 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/memory-debugger.c
641 ${CMAKE_CURRENT_SOURCE_DIR}/src/ds/extra/cli.c)
642endif()
643
644if(USE_DEBUGGERS)
645 list(APPEND FEATURE_SRC ${DEBUGGER_SRC})
646 list(APPEND FEATURES DEBUGGERS)
647endif()
648
649foreach(FEATURE IN LISTS FEATURES)
650 list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
651endforeach()
652
653source_group("Virtual files" FILES ${CORE_VFS_SRC} ${VFS_SRC})
654source_group("Extra features" FILES ${FEATURE_SRC})
655source_group("Third-party code" FILES ${THIRD_PARTY_SRC})
656
657# Platform binaries
658if(3DS)
659 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/3ds ${CMAKE_CURRENT_BINARY_DIR}/3ds)
660endif()
661
662if(WII)
663 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/wii ${CMAKE_CURRENT_BINARY_DIR}/wii)
664endif()
665
666if(PSP2)
667 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/psp2 ${CMAKE_CURRENT_BINARY_DIR}/psp2)
668endif()
669
670# Binaries
671list(APPEND CORE_SRC
672 ${UTIL_SRC}
673 ${CORE_VFS_SRC}
674 ${OS_SRC}
675 ${THIRD_PARTY_SRC})
676list(APPEND TEST_SRC ${UTIL_TEST_SRC})
677
678set(SRC ${CORE_SRC} ${VFS_SRC})
679if(NOT MINIMAL_CORE)
680 if(M_CORE_GBA)
681 list(APPEND SRC
682 ${GBA_RR_SRC}
683 ${GBA_EXTRA_SRC}
684 ${GBA_SIO_SRC})
685 endif()
686 if(M_CORE_GB)
687 list(APPEND SRC
688 ${GB_SIO_SRC})
689 endif()
690 list(APPEND SRC
691 ${FEATURE_SRC}
692 ${CLI_SRC})
693endif()
694
695if(NOT SKIP_LIBRARY)
696 if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
697 set(BUILD_SHARED ON)
698 endif()
699
700 if(BUILD_SHARED)
701 add_library(${BINARY_NAME} SHARED ${SRC} ${VFS_SRC})
702 if(BUILD_STATIC)
703 add_library(${BINARY_NAME}-static STATIC ${SRC})
704 set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
705 install(TARGETS ${BINARY_NAME}-static DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
706 add_dependencies(${BINARY_NAME}-static version-info)
707 endif()
708 else()
709 add_library(${BINARY_NAME} STATIC ${SRC})
710 endif()
711
712 add_dependencies(${BINARY_NAME} version-info)
713 set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
714
715 target_link_libraries(${BINARY_NAME} ${DEBUGGER_LIB} ${DEPENDENCY_LIB} ${OS_LIB})
716 install(TARGETS ${BINARY_NAME} LIBRARY DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME} NAMELINK_SKIP ARCHIVE DESTINATION ${LIBDIR} RUNTIME DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
717 if(UNIX AND NOT APPLE)
718 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-16.png DESTINATION share/icons/hicolor/16x16/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
719 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-24.png DESTINATION share/icons/hicolor/24x24/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
720 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-32.png DESTINATION share/icons/hicolor/32x32/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
721 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-48.png DESTINATION share/icons/hicolor/48x48/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
722 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-64.png DESTINATION share/icons/hicolor/64x64/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
723 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-96.png DESTINATION share/icons/hicolor/96x96/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
724 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-128.png DESTINATION share/icons/hicolor/128x128/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
725 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-256.png DESTINATION share/icons/hicolor/256x256/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
726 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-512.png DESTINATION share/icons/hicolor/512x512/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
727 endif()
728else()
729 set(BUILD_SHARED OFF)
730 set(BUILD_STATIC OFF)
731 find_library(${BINARY_NAME} ${BINARY_NAME})
732 if(NOT ${BINARY_NAME}_FOUND)
733 set(DISABLE_FRONTENDS ON)
734 set(BUILD_PERF OFF)
735 set(BUILD_TEST OFF)
736 set(BUILD_SUITE OFF)
737 endif()
738endif()
739
740if(BUILD_GL)
741 add_definitions(-DBUILD_GL)
742endif()
743
744if(BUILD_GLES2)
745 add_definitions(-DBUILD_GLES2)
746endif()
747
748if(DISABLE_FRONTENDS)
749 set(BUILD_SDL OFF)
750 set(BUILD_QT OFF)
751endif()
752
753if(BUILD_LIBRETRO)
754 file(GLOB RETRO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/libretro/*.c)
755 add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
756 set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5;DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=2")
757 target_link_libraries(${BINARY_NAME}_libretro ${OS_LIB})
758 install(TARGETS ${BINARY_NAME}_libretro LIBRARY DESTINATION ${LIBRETRO_LIBDIR} COMPONENT ${BINARY_NAME}_libretro NAMELINK_SKIP)
759endif()
760
761if(BUILD_OPENEMU)
762 find_library(FOUNDATION Foundation)
763 find_library(OPENEMUBASE OpenEmuBase)
764 file(GLOB OE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/*.m)
765 add_library(${BINARY_NAME}-openemu MODULE ${CORE_SRC} ${OE_SRC})
766 set_target_properties(${BINARY_NAME}-openemu PROPERTIES
767 MACOSX_BUNDLE_INFO_PLIST ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/Info.plist.in
768 BUNDLE TRUE
769 BUNDLE_EXTENSION oecoreplugin
770 OUTPUT_NAME ${PROJECT_NAME}
771 COMPILE_DEFINITIONS "DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=1")
772 target_link_libraries(${BINARY_NAME}-openemu ${OS_LIB} ${FOUNDATION} ${OPENEMUBASE})
773 install(TARGETS ${BINARY_NAME}-openemu LIBRARY DESTINATION ${OE_LIBDIR} COMPONENT ${BINARY_NAME}.oecoreplugin NAMELINK_SKIP)
774endif()
775
776if(BUILD_SDL)
777 add_definitions(-DBUILD_SDL)
778 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/sdl ${CMAKE_CURRENT_BINARY_DIR}/sdl)
779endif()
780
781if(BUILD_QT)
782 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/qt ${CMAKE_CURRENT_BINARY_DIR}/qt)
783endif()
784
785if(BUILD_PERF)
786 set(PERF_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/perf-main.c ${CLI_SRC})
787 if(UNIX AND NOT APPLE)
788 list(APPEND PERF_LIB rt)
789 endif()
790
791 add_executable(${BINARY_NAME}-perf ${PERF_SRC})
792 target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB} ${OS_LIB})
793 set_target_properties(${BINARY_NAME}-perf PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
794 install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
795 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
796endif()
797
798if(BUILD_TEST)
799 add_executable(${BINARY_NAME}-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/fuzz-main.c)
800 target_link_libraries(${BINARY_NAME}-fuzz ${BINARY_NAME})
801 set_target_properties(${BINARY_NAME}-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
802 add_executable(tbl-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/tbl-fuzz-main.c)
803 target_link_libraries(tbl-fuzz ${BINARY_NAME})
804 set_target_properties(tbl-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
805 install(TARGETS ${BINARY_NAME}-fuzz tbl-fuzz DESTINATION bin COMPONENT ${BINARY_NAME}-test)
806endif()
807
808if(NOT USE_CMOCKA)
809 set(BUILD_SUITE OFF)
810endif()
811if(BUILD_SUITE)
812 enable_testing()
813 include_directories(AFTER ${CMOCKA_INCLUDE_DIRS})
814 link_directories(${CMOCKA_LIBRARY_DIRS})
815
816 add_executable(${BINARY_NAME}-suite ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/suite-main.c ${TEST_SRC})
817 target_link_libraries(${BINARY_NAME}-suite ${BINARY_NAME} ${PLATFORM_LIBRARY} cmocka)
818 set_target_properties(${BINARY_NAME}-suite PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
819 add_test(${BINARY_NAME}-suite ${BINARY_NAME}-suite)
820endif()
821
822if(BUILD_PYTHON)
823 enable_testing()
824 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/python ${CMAKE_CURRENT_BINARY_DIR}/python)
825endif()
826
827if(BUILD_EXAMPLE)
828 add_executable(${BINARY_NAME}-example-server ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/server.c)
829 target_link_libraries(${BINARY_NAME}-example-server ${BINARY_NAME})
830 set_target_properties(${BINARY_NAME}-example-server PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
831
832 if(BUILD_SDL)
833 add_executable(${BINARY_NAME}-example-client ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/client.c)
834 target_link_libraries(${BINARY_NAME}-example-client ${BINARY_NAME} ${SDL_LIBRARY} ${SDLMAIN_LIBRARY} ${OPENGL_LIBRARY} ${OPENGLES2_LIBRARY})
835 set_target_properties(${BINARY_NAME}-example-client PROPERTIES
836 COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}"
837 INCLUDE_DIRECTORIES "${SDL_INCLUDE_DIR};${CMAKE_CURRENT_SOURCE_DIR}/src;${CMAKE_CURRENT_SOURCE_DIR}/include")
838 endif()
839endif()
840
841# Packaging
842set(CPACK_PACKAGE_VERSION ${VERSION_STRING})
843set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
844set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
845set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
846set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
847set(CPACK_RESOURCE_FILE_README ${CMAKE_CURRENT_SOURCE_DIR}/README.md)
848
849set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
850set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
851set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
852set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README.md")
853set(CPACK_DEBIAN_PACKAGE_SECTION "games")
854
855SET(CPACK_DEB_COMPONENT_INSTALL ON)
856
857set(CPACK_STRIP_FILES ${BINARY_NAME})
858
859install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/README.md ${CMAKE_CURRENT_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
860
861include(CPack)
862
863# Summaries
864set(SUMMARY_GL_LIST)
865if(USE_EPOXY)
866 set(SUMMARY_GL_LIST "libepoxy")
867else()
868 if(BUILD_GL)
869 list(APPEND SUMMARY_GL_LIST "OpenGL")
870 endif()
871 if(BUILD_GLES2)
872 list(APPEND SUMMARY_GL_LIST "OpenGL|ES 2")
873 endif()
874endif()
875if(NOT SUMMARY_GL_LIST)
876 set(SUMMARY_GL OFF)
877else()
878 string(REPLACE ";" ", " SUMMARY_GL "${SUMMARY_GL_LIST}")
879endif()
880if(USE_LIBZIP)
881 set(SUMMARY_ZIP libzip)
882elseif(USE_MINIZIP)
883 set(SUMMARY_ZIP "minizip (external)")
884elseif(USE_ZLIB)
885 set(SUMMARY_ZIP "minizip (included)")
886else()
887 set(SUMMARY_ZIP OFF)
888endif()
889
890if(NOT QUIET)
891 message(STATUS "Platforms:")
892 message(STATUS " Game Boy Advance: ${M_CORE_GBA}")
893 message(STATUS " Game Boy: ${M_CORE_GB}")
894 message(STATUS " DS: ${M_CORE_DS}")
895 message(STATUS "Features:")
896 message(STATUS " Debuggers: ${USE_DEBUGGERS}")
897 message(STATUS " CLI debugger: ${USE_EDITLINE}")
898 message(STATUS " GDB stub: ${USE_GDB_STUB}")
899 message(STATUS " Video recording: ${USE_FFMPEG}")
900 message(STATUS " GIF recording: ${USE_MAGICK}")
901 message(STATUS " Screenshot/advanced savestate support: ${USE_PNG}")
902 message(STATUS " ZIP support: ${SUMMARY_ZIP}")
903 message(STATUS " 7-Zip support: ${USE_LZMA}")
904 message(STATUS " SQLite3 game database: ${USE_SQLITE3}")
905 message(STATUS " OpenGL support: ${SUMMARY_GL}")
906 message(STATUS "Frontends:")
907 message(STATUS " Qt: ${BUILD_QT}")
908 message(STATUS " SDL (${SDL_VERSION}): ${BUILD_SDL}")
909 message(STATUS " Profiling: ${BUILD_PERF}")
910 message(STATUS " Test harness: ${BUILD_TEST}")
911 message(STATUS " Test suite: ${BUILD_SUITE}")
912 message(STATUS " Python bindings: ${BUILD_PYTHON}")
913 message(STATUS " Examples: ${BUILD_EXAMPLE}")
914 message(STATUS "Cores:")
915 message(STATUS " Libretro core: ${BUILD_LIBRETRO}")
916 if(APPLE)
917 message(STATUS " OpenEmu core: ${BUILD_OPENEMU}")
918 endif()
919 message(STATUS "Libraries:")
920 message(STATUS " Static: ${BUILD_STATIC}")
921 message(STATUS " Shared: ${BUILD_SHARED}")
922endif()