CMakeLists.txt (view raw)
1cmake_minimum_required(VERSION 2.6)
2project(mGBA C)
3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
4set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -std=gnu99")
5set(USE_CLI_DEBUGGER ON CACHE BOOL "Whether or not to enable the CLI-mode ARM debugger")
6set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
7set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
8set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
9set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable ZIP support")
10set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
11set(USE_BLIP ON CACHE BOOL "Whether or not to enable blip_buf support")
12set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
13set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
14set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
15set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
16set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
17set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
18set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
19file(GLOB ARM_SRC ${CMAKE_SOURCE_DIR}/src/arm/*.c)
20file(GLOB GBA_SRC ${CMAKE_SOURCE_DIR}/src/gba/*.c)
21file(GLOB GBA_RR_SRC ${CMAKE_SOURCE_DIR}/src/gba/rr/*.c)
22file(GLOB GBA_SV_SRC ${CMAKE_SOURCE_DIR}/src/gba/supervisor/*.c)
23file(GLOB UTIL_SRC ${CMAKE_SOURCE_DIR}/src/util/*.[cSs])
24file(GLOB VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/*.c)
25file(GLOB RENDERER_SRC ${CMAKE_SOURCE_DIR}/src/gba/renderers/video-software.c)
26file(GLOB THIRD_PARTY_SRC ${CMAKE_SOURCE_DIR}/src/third-party/inih/*.c)
27list(APPEND UTIL_SRC ${CMAKE_SOURCE_DIR}/src/platform/commandline.c)
28source_group("ARM core" FILES ${ARM_SRC})
29source_group("GBA board" FILES ${GBA_SRC} ${RENDERER_SRC})
30source_group("GBA supervisor" FILES ${GBA_SV_SRC} ${GBA_RR_SRC})
31source_group("Utilities" FILES ${UTIL_SRC} ${VFS_SRC}})
32include_directories(${CMAKE_SOURCE_DIR}/src/arm)
33include_directories(${CMAKE_SOURCE_DIR}/src)
34
35if(NOT CMAKE_BUILD_TYPE)
36 set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
37endif()
38
39set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
40
41include(GNUInstallDirs)
42
43# Function definitions
44include(FindPkgConfig)
45function(find_feature FEATURE_NAME FEATURE_REQUIRES)
46 if (NOT ${FEATURE_NAME})
47 return()
48 endif()
49 foreach(REQUIRE ${FEATURE_REQUIRES})
50 if(NOT ${REQUIRE}_FOUND)
51 find_package(${REQUIRE} QUIET)
52 if(NOT ${REQUIRE}_FOUND)
53 pkg_search_module(${REQUIRE} ${REQUIRE})
54 if (NOT ${REQUIRE}_FOUND)
55 message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
56 set(${FEATURE_NAME} OFF PARENT_SCOPE)
57 return()
58 endif()
59 endif()
60 endif()
61 string(TOUPPER ${REQUIRE} UREQUIRE)
62 set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
63 set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
64 set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
65 set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
66 set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
67 set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
68 endforeach()
69endfunction()
70
71# Version information
72set(LIB_VERSION_MAJOR 0)
73set(LIB_VERSION_MINOR 2)
74set(LIB_VERSION_PATCH 0)
75set(LIB_VERSION_ABI 0.2)
76set(LIB_VERSION_STRING ${LIB_VERSION_MAJOR}.${LIB_VERSION_MINOR}.${LIB_VERSION_PATCH})
77
78# Advanced settings
79set(BUILD_PGO CACHE BOOL "Build with profiling-guided optimization")
80set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
81set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
82mark_as_advanced(BUILD_PGO PGO_STAGE_2 PGO_DIR)
83set(PGO_PRE_FLAGS "-pg -fprofile-generate=${PGO_DIR} -fprofile-arcs")
84set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
85
86if(BUILD_PGO AND NOT PGO_STAGE_2)
87 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
88 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
89 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
90elseif(BUILD_PGO AND PGO_STAGE_2)
91 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
92 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
93 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
94endif()
95
96add_definitions(-DBINARY_NAME="${BINARY_NAME}" -DPROJECT_NAME="${PROJECT_NAME}" -DPROJECT_VERSION="${LIB_VERSION_STRING}")
97
98# Feature dependencies
99if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
100 set(LIBEDIT_LIBRARIES -ledit)
101else()
102 find_feature(USE_CLI_DEBUGGER "libedit")
103endif()
104find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
105find_feature(USE_PNG "ZLIB;PNG")
106find_feature(USE_LIBZIP "libzip")
107find_feature(USE_MAGICK "MagickWand")
108
109# Platform support
110if(WIN32)
111 add_definitions(-D_WIN32_WINNT=0x0600)
112 list(APPEND OS_LIB ws2_32)
113 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/windows/*.c)
114 source_group("Windows-specific code" FILES ${OS_SRC})
115else()
116 add_definitions(-DUSE_PTHREADS)
117 if(NOT APPLE)
118 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
119 endif()
120 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/posix/*.c)
121 source_group("POSIX-specific code" FILES ${OS_SRC})
122endif()
123
124if(APPLE)
125 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
126endif()
127
128if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU")
129 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
130 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
131endif()
132
133if(BUILD_BBB OR BUILD_RASPI)
134 enable_language(ASM)
135 if(NOT BUILD_EGL)
136 add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
137 endif()
138endif()
139
140include(CheckFunctionExists)
141check_function_exists(strndup HAVE_STRNDUP)
142check_function_exists(snprintf_l HAVE_SNPRINTF_L)
143if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
144 # The strtof_l on Linux not actually exposed nor actually strtof_l
145 set(HAVE_STRTOF_L OFF)
146else()
147 check_function_exists(strtof_l HAVE_STRTOF_L)
148endif()
149check_function_exists(newlocale HAVE_NEWLOCALE)
150check_function_exists(freelocale HAVE_FREELOCALE)
151check_function_exists(uselocale HAVE_USELOCALE)
152
153if(HAVE_STRNDUP)
154 add_definitions(-DHAVE_STRNDUP)
155endif()
156
157if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE)
158 add_definitions(-DHAVE_LOCALE)
159 if (HAVE_STRTOF_L)
160 add_definitions(-DHAVE_STRTOF_L)
161 endif()
162 if (HAVE_SNPRINTF_L)
163 add_definitions(-DHAVE_SNPRINTF_L)
164 endif()
165endif()
166
167
168# Features
169set(DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/debugger.c ${CMAKE_SOURCE_DIR}/src/debugger/memory-debugger.c)
170set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
171
172if(USE_CLI_DEBUGGER)
173 add_definitions(-DUSE_CLI_DEBUGGER)
174 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/cli-debugger.c)
175 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/parser.c)
176 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/gba/supervisor/cli.c)
177 include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
178 link_directories(${LIBEDIT_LIBRARY_DIRS})
179 set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
180 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
181else()
182 set(DEBUGGER_LIB "")
183endif()
184
185if(USE_GDB_STUB)
186 add_definitions(-DUSE_GDB_STUB)
187 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/gdb-stub.c)
188endif()
189source_group("ARM debugger" FILES ${DEBUGGER_SRC})
190
191if(USE_FFMPEG)
192 add_definitions(-DUSE_FFMPEG)
193 pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
194 if(NOT LIBSWRESAMPLE_FOUND)
195 add_definitions(-DUSE_LIBAV)
196 endif()
197 include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
198 link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
199 list(APPEND UTIL_SRC "${CMAKE_SOURCE_DIR}/src/platform/ffmpeg/ffmpeg-encoder.c")
200 string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
201 string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
202 string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
203 string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
204 string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
205 list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
206 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR},libavformat${LIBAVFORMAT_VERSION_MAJOR},libavresample${LIBAVRESAMPLE_VERSION_MAJOR},libavutil${LIBAVUTIL_VERSION_MAJOR},libswscale${LIBSWSCALE_VERSION_MAJOR}")
207 set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra")
208endif()
209
210if(USE_BLIP)
211 list(APPEND UTIL_SRC "${CMAKE_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
212 add_definitions(-DRESAMPLE_LIBRARY=RESAMPLE_BLIP_BUF)
213else()
214 add_definitions(-DRESAMPLE_LIBRARY=RESAMPLE_NN)
215endif()
216
217if(USE_MAGICK)
218 add_definitions(-DUSE_MAGICK)
219 include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
220 link_directories(${MAGICKWAND_LIBRARY_DIRS})
221 list(APPEND UTIL_SRC "${CMAKE_SOURCE_DIR}/src/platform/imagemagick/imagemagick-gif-encoder.c")
222 list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
223 string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
224 if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
225 set(MAGICKWAND_DEB_VERSION "5")
226 else()
227 set(MAGICKWAND_DEB_VERSION "-6.q16-2")
228 endif()
229 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
230endif()
231
232if(USE_PNG)
233 add_definitions(-DUSE_PNG)
234 include_directories(AFTER ${PNG_INCLUDE_DIRS})
235 list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
236 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng12-0,zlib1g")
237endif()
238
239if(USE_LIBZIP)
240 include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
241 link_directories(${LIBZIP_LIBRARY_DIRS})
242 list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
243 add_definitions(-DENABLE_LIBZIP)
244 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
245endif()
246
247if (USE_LZMA)
248 include_directories(AFTER ${CMAKE_SOURCE_DIR}/third-party/lzma)
249 add_definitions(-D_7ZIP_PPMD_SUPPPORT)
250 set(LZMA_SRC
251 ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-lzma.c
252 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
253 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
254 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
255 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
256 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
257 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
258 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zDec.c
259 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
260 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
261 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
262 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bra.c
263 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bra86.c
264 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
265 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
266 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
267 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zFile.c
268 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
269 list(APPEND UTIL_SRC ${LZMA_SRC})
270 add_definitions(-DENABLE_LZMA)
271endif()
272
273# Binaries
274set(SRC
275 ${ARM_SRC}
276 ${GBA_SRC}
277 ${GBA_RR_SRC}
278 ${GBA_SV_SRC}
279 ${DEBUGGER_SRC}
280 ${RENDERER_SRC}
281 ${UTIL_SRC}
282 ${VFS_SRC}
283 ${OS_SRC}
284 ${THIRD_PARTY_SRC})
285
286if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
287 set(BUILD_SHARED ON)
288endif()
289
290if(BUILD_SHARED)
291 add_library(${BINARY_NAME} SHARED ${SRC})
292 if(BUILD_STATIC)
293 add_library(${BINARY_NAME}-static STATIC ${SRC})
294 install(TARGETS ${BINARY_NAME}-static DESTINATION lib COMPONENT lib${BINARY_NAME})
295 endif()
296else()
297 add_library(${BINARY_NAME} STATIC ${SRC})
298endif()
299
300target_link_libraries(${BINARY_NAME} m ${DEBUGGER_LIB} ${OS_LIB} ${DEPENDENCY_LIB})
301install(TARGETS ${BINARY_NAME} DESTINATION lib COMPONENT lib${BINARY_NAME})
302set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI})
303
304if(BUILD_LIBRETRO)
305 add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
306 file(GLOB RETRO_SRC ${CMAKE_SOURCE_DIR}/src/platform/libretro/*.c)
307 add_library(${BINARY_NAME}-libretro SHARED ${RETRO_SRC})
308 target_link_libraries(${BINARY_NAME}-libretro ${BINARY_NAME} m ${DEBUGGER_LIB} ${OS_LIB} ${DEPENDENCY_LIB})
309endif()
310
311if(BUILD_SDL)
312 add_definitions(-DBUILD_SDL)
313 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/sdl ${CMAKE_BINARY_DIR}/sdl)
314endif()
315
316if(BUILD_QT)
317 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/qt ${CMAKE_BINARY_DIR}/qt)
318endif()
319
320if(BUILD_PERF)
321 set(PERF_SRC ${CMAKE_SOURCE_DIR}/src/platform/perf-main.c)
322 if(UNIX AND NOT APPLE)
323 list(APPEND PERF_LIB rt)
324 endif()
325
326 add_executable(${BINARY_NAME}-perf ${PERF_SRC})
327 target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB})
328 install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
329 install(FILES ${CMAKE_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
330endif()
331
332# Packaging
333set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
334set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
335set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
336set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_SOURCE_DIR}/LICENSE)
337set(CPACK_RESOURCE_FILE_README ${CMAKE_SOURCE_DIR}/README.md)
338
339set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
340set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
341set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
342set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_SOURCE_DIR}/README.md")
343set(CPACK_DEBIAN_PACKAGE_SECTION "games")
344
345SET(CPACK_DEB_COMPONENT_INSTALL ON)
346
347set(CPACK_STRIP_FILES ${BINARY_NAME})
348
349install(FILES ${CMAKE_SOURCE_DIR}/README.md ${CMAKE_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
350
351include(CPack)
352
353# Summaries
354message(STATUS "Feature summary:")
355message(STATUS " CLI debugger: ${USE_CLI_DEBUGGER}")
356message(STATUS " GDB stub: ${USE_GDB_STUB}")
357message(STATUS " Video recording: ${USE_FFMPEG}")
358message(STATUS " GIF recording: ${USE_MAGICK}")
359message(STATUS " Screenshot/advanced savestate support: ${USE_PNG}")
360message(STATUS " ZIP support: ${USE_LIBZIP}")
361message(STATUS " 7-Zip support: ${USE_LZMA}")
362message(STATUS " Better audio resampling: ${USE_BLIP}")
363message(STATUS "Frontend summary:")
364message(STATUS " Qt: ${BUILD_QT}")
365message(STATUS " SDL (${SDL_VERSION}): ${BUILD_SDL}")
366message(STATUS " Libretro core: ${BUILD_LIBRETRO}")
367message(STATUS " Profiling: ${BUILD_PERF}")
368message(STATUS "Library summary:")
369message(STATUS " Static: ${BUILD_STATIC}")
370message(STATUS " Shared: ${BUILD_SHARED}")