1cmake_minimum_required(VERSION 2.6)
  2project(medusa C)
  3set(BINARY_NAME medusa-emu CACHE INTERNAL "Name of output binaries")
  4if(NOT MSVC)
  5	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wno-missing-field-initializers -std=c99")
  6else()
  7	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_CRT_SECURE_NO_WARNINGS /wd4003 /wd4244 /wd4146")
  8endif()
  9set(USE_DEBUGGERS ON CACHE BOOL "Whether or not to enable the debugging infrastructure")
 10set(USE_EDITLINE ON CACHE BOOL "Whether or not to enable the CLI-mode debugger")
 11set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
 12set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
 13set(USE_ZLIB ON CACHE BOOL "Whether or not to enable zlib support")
 14set(USE_MINIZIP ON CACHE BOOL "Whether or not to enable external minizip support")
 15set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
 16set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable LIBZIP support")
 17set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
 18set(USE_SQLITE3 ON CACHE BOOL "Whether or not to enable SQLite3 support")
 19set(M_CORE_GBA ON CACHE BOOL "Build Game Boy Advance core")
 20set(M_CORE_GB ON CACHE BOOL "Build Game Boy core")
 21set(M_CORE_DS ON CACHE BOOL "Build DS core")
 22set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
 23set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
 24set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
 25set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
 26if(APPLE)
 27	set(BUILD_OPENEMU OFF CACHE BOOL "Build OpenEmu core")
 28endif()
 29set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
 30set(BUILD_TEST OFF CACHE BOOL "Build testing harness")
 31set(BUILD_SUITE OFF CACHE BOOL "Build test suite")
 32set(BUILD_EXAMPLE OFF CACHE BOOL "Build example frontends")
 33set(BUILD_PYTHON OFF CACHE BOOL "Build Python bindings")
 34set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
 35set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
 36set(SKIP_LIBRARY OFF CACHE BOOL "Skip building the library (useful for only building libretro or OpenEmu cores)")
 37set(BUILD_GL ON CACHE STRING "Build with OpenGL")
 38set(BUILD_GLES2 OFF CACHE STRING "Build with OpenGL|ES 2")
 39set(USE_EPOXY ON CACHE STRING "Build with libepoxy")
 40set(DISABLE_DEPS OFF CACHE BOOL "Build without dependencies")
 41file(GLOB ARM_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/*.c)
 42file(GLOB ARM_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/test/*.c)
 43file(GLOB LR35902_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/*.c)
 44file(GLOB LR35902_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/test/*.c)
 45file(GLOB GBA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/*.c)
 46file(GLOB GBA_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/test/*.c)
 47file(GLOB GB_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/*.c)
 48file(GLOB GB_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/test/*.c)
 49file(GLOB DS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/ds/*.c)
 50file(GLOB GBA_CHEATS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/cheats/*.c)
 51file(GLOB GBA_RR_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/rr/*.c)
 52file(GLOB CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/*.c)
 53file(GLOB CORE_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/test/*.c)
 54file(GLOB UTIL_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/*.[cSs])
 55file(GLOB UTIL_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/test/*.c)
 56file(GLOB GUI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/gui/*.c ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/gui/*.c)
 57file(GLOB GBA_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/renderers/*.c)
 58file(GLOB GBA_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/sio/lockstep.c)
 59file(GLOB GB_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/sio/lockstep.c)
 60file(GLOB GB_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/renderers/*.c)
 61file(GLOB DS_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/ds/renderers/*.c ${CMAKE_CURRENT_SOURCE_DIR}/src/ds/gx/*.c)
 62file(GLOB THIRD_PARTY_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/inih/*.c)
 63set(CLI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/commandline.c)
 64set(CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-mem.c)
 65set(VFS_SRC)
 66source_group("ARM core" FILES ${ARM_SRC})
 67source_group("LR35902 core" FILES ${LR35902_SRC})
 68source_group("GBA board" FILES ${GBA_SRC} ${GBA_RENDERER_SRC} ${GBA_SIO_SRC})
 69source_group("GBA extra" FILES ${GBA_CHEATS_SRC} ${GBA_RR_SRC})
 70source_group("GB board" FILES ${GB_SRC} ${GB_SIO_SRC})
 71source_group("DS board" FILES ${DS_SRC})
 72source_group("Utilities" FILES ${UTIL_SRC})
 73include_directories(BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/include ${CMAKE_CURRENT_SOURCE_DIR}/src)
 74
 75if(NOT CMAKE_BUILD_TYPE)
 76	set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
 77endif()
 78
 79include(GNUInstallDirs)
 80
 81set(LIBDIR "${CMAKE_INSTALL_LIBDIR}" CACHE PATH "Installed library directory")
 82mark_as_advanced(LIBDIR)
 83
 84if (BUILD_LIBRETRO)
 85	set(LIBRETRO_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (Libretro)")
 86	mark_as_advanced(LIBRETRO_LIBDIR)
 87endif()
 88
 89if (BUILD_OPENEMU)
 90	set(OE_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (OpenEmu)")
 91	mark_as_advanced(OE_LIBDIR)
 92endif()
 93
 94
 95set(CMAKE_INSTALL_RPATH "${LIBDIR}")
 96
 97if (NOT DEFINED MANDIR)
 98	set(MANDIR ${CMAKE_INSTALL_MANDIR})
 99endif()
100
101# Function definitions
102include(FindPkgConfig)
103function(find_feature FEATURE_NAME FEATURE_REQUIRES)
104	if (NOT ${FEATURE_NAME})
105		return()
106	endif()
107	if (DISABLE_DEPS)
108		set(${FEATURE_NAME} OFF PARENT_SCOPE)
109		return()
110	endif()
111	foreach(REQUIRE ${FEATURE_REQUIRES})
112		if(NOT ${REQUIRE}_FOUND)
113			find_package(${REQUIRE} QUIET)
114			if(NOT ${REQUIRE}_FOUND)
115				pkg_search_module(${REQUIRE} ${REQUIRE})
116				if (NOT ${REQUIRE}_FOUND)
117					message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
118					set(${FEATURE_NAME} OFF PARENT_SCOPE)
119					return()
120				endif()
121			endif()
122		endif()
123		string(TOUPPER ${REQUIRE} UREQUIRE)
124		set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
125		set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
126		set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
127		if (APPLE)
128			set(IS_FRAMEWORK OFF)
129			set(LIBS)
130			foreach(LIB IN LISTS ${REQUIRE}_LIBRARIES)
131				if(LIB STREQUAL "-framework")
132					set(IS_FRAMEWORK ON)
133				elseif(IS_FRAMEWORK)
134					list(APPEND LIBS "-framework ${LIB}")
135					set(IS_FRAMEWORK OFF)
136				else()
137					list(APPEND LIBS ${LIB})
138				endif()
139			endforeach()
140			set(${UREQUIRE}_LIBRARIES ${LIBS} PARENT_SCOPE)
141		else()
142			set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
143		endif()
144		set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
145		set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
146	endforeach()
147endfunction()
148
149# Version information
150add_custom_target(version-info ALL
151	COMMAND ${CMAKE_COMMAND}
152	-DBINARY_NAME=${BINARY_NAME}
153	-DCONFIG_FILE=${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in
154	-DOUT_FILE=${CMAKE_CURRENT_BINARY_DIR}/version.c
155	-P ${CMAKE_CURRENT_SOURCE_DIR}/version.cmake
156	WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
157
158include(${CMAKE_CURRENT_SOURCE_DIR}/version.cmake)
159configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in ${CMAKE_CURRENT_BINARY_DIR}/version.c)
160configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/flags.h.in ${CMAKE_CURRENT_BINARY_DIR}/flags.h)
161install(FILES ${CMAKE_CURRENT_BINARY_DIR}/flags.h DESTINATION include/mgba COMPONENT lib${BINARY_NAME})
162
163list(APPEND UTIL_SRC ${CMAKE_CURRENT_BINARY_DIR}/version.c)
164source_group("Generated sources" FILES ${CMAKE_CURRENT_BINARY_DIR}/version.c)
165
166# Advanced settings
167if(NOT DEFINED 3DS)
168	# LTO appears to make 3DS binary slower
169	set(DEFAULT_LTO ON)
170else()
171	set(DEFAULT_LTO OFF)
172endif()
173
174set(BUILD_LTO ${DEFAULT_LTO} CACHE BOOL "Build with link-time optimization")
175set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
176set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
177set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
178mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
179set(PGO_PRE_FLAGS "-fprofile-generate=${PGO_DIR} -fprofile-arcs")
180set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
181
182if(BUILD_PGO AND NOT PGO_STAGE_2)
183	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
184	set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
185	set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
186elseif(BUILD_PGO AND PGO_STAGE_2)
187	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
188	set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
189	set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
190endif()
191
192# Platform support
193if(WIN32)
194	set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
195	add_definitions(-D_WIN32_WINNT=0x0600)
196	list(APPEND OS_LIB ws2_32 shlwapi)
197	list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/vfs-w32.c)
198	file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/*.c)
199	source_group("Windows-specific code" FILES ${OS_SRC})
200	if(MSVC)
201		add_definitions(-DNOMINMAX -DWIN32_LEAN_AND_MEAN)
202		set(CMAKE_WINDOWS_EXPORT_ALL_SYMBOLS TRUE)
203	endif()
204elseif(UNIX)
205	add_definitions(-DUSE_PTHREADS)
206
207	if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
208		add_definitions(-D_GNU_SOURCE)
209	endif()
210	if(NOT APPLE AND NOT HAIKU)
211		set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
212	endif()
213
214	list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
215	file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/posix/*.c)
216	source_group("POSIX-specific code" FILES ${OS_SRC})
217endif()
218
219if(APPLE)
220	add_definitions(-D_DARWIN_C_SOURCE)
221	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
222endif()
223
224if(NOT HAIKU AND NOT MSVC AND NOT PSP2)
225	set(M_LIBRARY m)
226endif()
227list(APPEND OS_LIB ${M_LIBRARY})
228
229if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
230	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
231	set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
232endif()
233
234if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
235	if(NOT BUILD_EGL)
236		add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
237	endif()
238endif()
239
240if(BUILD_RASPI)
241	set(BUILD_GL OFF CACHE BOOL "OpenGL not supported" FORCE)
242endif()
243
244if(BUILD_PANDORA)
245	add_definitions(-DBUILD_PANDORA)
246endif()
247
248if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
249	enable_language(ASM)
250endif()
251
252if(PSP2 OR WII)
253	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-format")
254endif()
255
256if(DEFINED 3DS OR DEFINED PSP2 OR DEFINED WII)
257	set(USE_DEBUGGERS OFF)
258	set(USE_SQLITE3 OFF)
259endif()
260
261if(NOT M_CORE_GBA)
262	set(USE_GDB_STUB OFF)
263endif()
264
265if(NOT USE_DEBUGGERS)
266	set(USE_EDITLINE OFF)
267	set(USE_GDB_STUB OFF)
268endif()
269
270if(WII)
271	add_definitions(-U__STRICT_ANSI__)
272endif()
273
274if(DEFINED 3DS)
275	add_definitions(-D_GNU_SOURCE)
276endif()
277
278include(CheckFunctionExists)
279check_function_exists(strdup HAVE_STRDUP)
280check_function_exists(strndup HAVE_STRNDUP)
281check_function_exists(localtime_r HAVE_LOCALTIME_R)
282if(NOT CMAKE_SYSTEM_NAME STREQUAL "Generic")
283	check_function_exists(snprintf_l HAVE_SNPRINTF_L)
284	if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
285		# The strtof_l on Linux not actually exposed nor actually strtof_l
286		set(HAVE_STRTOF_L OFF)
287	else()
288		check_function_exists(strtof_l HAVE_STRTOF_L)
289	endif()
290	check_function_exists(newlocale HAVE_NEWLOCALE)
291	check_function_exists(freelocale HAVE_FREELOCALE)
292	check_function_exists(uselocale HAVE_USELOCALE)
293	check_function_exists(setlocale HAVE_SETLOCALE)
294else()
295	if(DEFINED 3DS)
296		check_function_exists(snprintf_l HAVE_SNPRINTF_L)
297		check_function_exists(strtof_l HAVE_STRTOF_L)
298		check_function_exists(newlocale HAVE_NEWLOCALE)
299		check_function_exists(freelocale HAVE_FREELOCALE)
300		check_function_exists(uselocale HAVE_USELOCALE)
301		check_function_exists(setlocale HAVE_SETLOCALE)
302	endif()
303	if(NOT DEFINED 3DS AND NOT DEFINED PSP2 AND NOT DEFINED WII)
304		set(DISABLE_DEPS ON CACHE BOOL "This platform cannot build with dependencies" FORCE)
305	endif()
306	set(DISABLE_FRONTENDS ON)
307	set(MINIMAL_CORE ON)
308endif()
309
310check_function_exists(chmod HAVE_CHMOD)
311check_function_exists(umask HAVE_UMASK)
312
313set(FUNCTION_DEFINES)
314
315if(HAVE_STRDUP)
316	list(APPEND FUNCTION_DEFINES HAVE_STRDUP)
317endif()
318
319if(HAVE_STRNDUP)
320	list(APPEND FUNCTION_DEFINES HAVE_STRNDUP)
321endif()
322
323if(HAVE_LOCALTIME_R)
324	list(APPEND FUNCTION_DEFINES HAVE_LOCALTIME_R)
325endif()
326
327if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE OR APPLE OR DEFINED 3DS)
328	list(APPEND FUNCTION_DEFINES HAVE_LOCALE)
329	if (HAVE_STRTOF_L)
330		list(APPEND FUNCTION_DEFINES HAVE_STRTOF_L)
331	endif()
332	if (HAVE_SNPRINTF_L)
333		list(APPEND FUNCTION_DEFINES HAVE_SNPRINTF_L)
334	endif()
335endif()
336
337if(HAVE_SETLOCALE)
338	list(APPEND FUNCTION_DEFINES HAVE_SETLOCALE)
339endif()
340
341if(HAVE_CHMOD)
342	list(APPEND FUNCTION_DEFINES HAVE_CHMOD)
343endif()
344
345if(HAVE_UMASK)
346	list(APPEND FUNCTION_DEFINES HAVE_UMASK)
347endif()
348
349# Feature dependencies
350set(FEATURE_DEFINES)
351set(FEATURES)
352if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
353	set(LIBEDIT_LIBRARIES -ledit)
354	if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
355		list(APPEND LIBEDIT_LIBRARIES -ltermcap)
356	endif()
357else()
358	find_feature(USE_EDITLINE "libedit")
359endif()
360if(BUILD_GL)
361	find_package(OpenGL QUIET)
362	if(NOT OPENGL_FOUND)
363		set(BUILD_GL OFF CACHE BOOL "OpenGL not found" FORCE)
364	endif()
365endif()
366if(NOT BUILD_GL)
367	set(OPENGLE_LIBRARY "" CACHE PATH "" FORCE)
368endif()
369if(BUILD_GLES2 AND NOT BUILD_RASPI)
370	find_path(OPENGLES2_INCLUDE_DIR NAMES GLES2/gl2.h)
371	find_library(OPENGLES2_LIBRARY NAMES GLESv2 GLESv2_CM)
372	if(NOT OPENGLES2_INCLUDE_DIR OR NOT OPENGLES2_LIBRARY)
373		set(BUILD_GLES2 OFF CACHE BOOL "OpenGL|ES 2 not found" FORCE)
374	endif()
375endif()
376if(NOT BUILD_GLES2)
377	set(OPENGLES2_LIBRARY "" CACHE PATH "" FORCE)
378endif()
379set(WANT_ZLIB ${USE_ZLIB})
380set(WANT_PNG ${USE_PNG})
381set(WANT_LIBZIP ${USE_LIBZIP})
382set(WANT_SQLITE3 ${USE_SQLITE3})
383set(USE_CMOCKA ${BUILD_SUITE})
384
385find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
386find_feature(USE_ZLIB "ZLIB")
387find_feature(USE_MINIZIP "minizip")
388find_feature(USE_PNG "PNG")
389find_feature(USE_LIBZIP "libzip")
390find_feature(USE_MAGICK "MagickWand")
391find_feature(USE_EPOXY "epoxy")
392find_feature(USE_CMOCKA "cmocka")
393find_feature(USE_SQLITE3 "sqlite3")
394
395# Features
396set(DEBUGGER_SRC
397	${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/debugger.c
398	${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/parser.c
399	${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/cli-debugger.c)
400
401set(FEATURE_SRC)
402set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
403
404if(DISABLE_DEPS)
405	set(USE_GDB_STUB OFF)
406endif()
407
408if(USE_EDITLINE)
409	list(APPEND FEATURES EDITLINE)
410	list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/cli-debugger.c)
411	list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/parser.c)
412	if(M_CORE_GBA)
413		list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c)
414		list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/extra/cli.c)
415	endif()
416	if(M_CORE_GB)
417		list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/cli-debugger.c)
418	endif()
419	if(M_CORE_DS)
420		list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c)
421		list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/ds/extra/cli.c)
422	endif()
423	include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
424	link_directories(${LIBEDIT_LIBRARY_DIRS})
425	set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
426	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
427	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/editline/cli-el-backend.c")
428else()
429	set(DEBUGGER_LIB "")
430endif()
431
432if(USE_GDB_STUB)
433	list(APPEND FEATURES GDB_STUB)
434	list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/gdb-stub.c)
435endif()
436source_group("Debugger" FILES ${DEBUGGER_SRC})
437
438if(USE_FFMPEG)
439	list(APPEND FEATURES FFMPEG)
440	pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
441	if(NOT LIBSWRESAMPLE_FOUND)
442		list(APPEND FEATURES LIBAV)
443	endif()
444	include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
445	link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
446	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/ffmpeg/ffmpeg-encoder.c")
447	string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
448	string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
449	string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
450	string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
451	string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
452	list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
453	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR}|libavcodec-extra-${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
454	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavformat${LIBAVFORMAT_VERSION_MAJOR}|libavformat-ffmpeg${LIBAVFORMAT_VERSION_MAJOR}")
455	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavresample${LIBAVRESAMPLE_VERSION_MAJOR}|libavresample-ffmpeg${LIBAVRESAMPLE_VERSION_MAJOR}")
456	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavutil${LIBAVUTIL_VERSION_MAJOR}|libavutil-ffmpeg${LIBAVUTIL_VERSION_MAJOR}")
457	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libswscale${LIBSWSCALE_VERSION_MAJOR}|libswscale-ffmpeg${LIBSWSCALE_VERSION_MAJOR}")
458	set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
459	if(APPLE)
460		set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
461		set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
462	endif()
463endif()
464
465list(APPEND THIRD_PARTY_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
466
467if(USE_MAGICK)
468	list(APPEND FEATURES MAGICK)
469	include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
470	link_directories(${MAGICKWAND_LIBRARY_DIRS})
471	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/imagemagick/imagemagick-gif-encoder.c")
472	list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
473	string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
474	string(REGEX MATCH "^[0-9]+" MAGICKWAND_VERSION_MAJOR ${MagickWand_VERSION})
475	if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
476		set(MAGICKWAND_DEB_VERSION "5")
477	elseif(${MagickWand_VERSION} EQUAL "6.9.7")
478		set(MAGICKWAND_DEB_VERSION "-6.q16-3")
479	else()
480		set(MAGICKWAND_DEB_VERSION "-6.q16-2")
481	endif()
482	list(APPEND FEATURE_DEFINES MAGICKWAND_VERSION_MAJOR=${MAGICKWAND_VERSION_MAJOR})
483
484	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
485endif()
486
487if(WANT_ZLIB AND NOT USE_ZLIB)
488	set(SKIP_INSTALL_ALL ON)
489	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib zlib)
490	set_property(TARGET zlibstatic PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/zlib;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib)
491	set_property(TARGET zlib PROPERTY EXCLUDE_FROM_ALL ON)
492	set_property(TARGET example PROPERTY EXCLUDE_FROM_ALL ON)
493	set_property(TARGET minigzip PROPERTY EXCLUDE_FROM_ALL ON)
494	set(ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
495	set(ZLIB_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
496	set(ZLIB_LIBRARY zlibstatic)
497	list(APPEND DEPENDENCY_LIB zlibstatic)
498	set(USE_ZLIB ON)
499endif()
500
501if(USE_ZLIB)
502	list(APPEND FEATURES ZLIB)
503	include_directories(AFTER ${ZLIB_INCLUDE_DIRS})
504	list(APPEND DEPENDENCY_LIB ${ZLIB_LIBRARIES})
505	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},zlib1g")
506endif()
507
508if(WANT_PNG AND USE_ZLIB AND NOT USE_PNG)
509	set(PNG_STATIC ON CACHE BOOL "" FORCE)
510	set(PNG_SHARED OFF CACHE BOOL "" FORCE)
511	set(PNG_TESTS OFF CACHE BOOL "" FORCE)
512	set(SKIP_INSTALL_ALL ON)
513	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng libpng)
514	set_property(TARGET png16_static PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/libpng;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng;${ZLIB_INCLUDE_DIRS})
515	set(PNG_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng ${CMAKE_CURRENT_BINARY_DIR}/libpng)
516	list(APPEND DEPENDENCY_LIB png16_static)
517	set(USE_PNG ON)
518endif()
519
520if(USE_PNG)
521	list(APPEND FEATURES PNG)
522	include_directories(AFTER ${PNG_INCLUDE_DIRS})
523	list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
524	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng12-0")
525endif()
526
527if(WANT_SQLITE3 AND NOT USE_SQLITE3)
528	list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/sqlite3.c)
529	include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/)
530	set(USE_SQLITE3 ON)
531endif()
532
533if(USE_LIBZIP)
534	include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
535	link_directories(${LIBZIP_LIBRARY_DIRS})
536	list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
537	list(APPEND FEATURES LIBZIP)
538	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
539	string(REGEX MATCH "^[0-9]+" LIBZIP_VERSION_MAJOR ${libzip_VERSION})
540	if (LIBZIP_VERSION_MAJOR LESS 1)
541		set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
542	elseif(LIBZIP_VERSION_MAJOR EQUAL 1)
543		set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip4")
544	else()
545		message(AUTHOR_WARNING Unknown version of libzip detected: ${libzip_VERSION})
546	endif()
547elseif(USE_MINIZIP)
548	include_directories(AFTER ${MINIZIP_INCLUDE_DIRS})
549	link_directories(${MINIZIP_LIBRARY_DIRS})
550	list(APPEND DEPENDENCY_LIB ${MINIZIP_LIBRARIES})
551	list(APPEND FEATURES MINIZIP)
552	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
553	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libminizip1")
554elseif(USE_ZLIB)
555	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c
556		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
557		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c)
558	if(NOT MSVC)
559		set_source_files_properties(
560			${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
561			${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c
562			PROPERTIES COMPILE_FLAGS "-Wno-unused-parameter -Wno-implicit-function-declaration")
563	endif()
564endif()
565
566if (USE_LZMA)
567	include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/third-party/lzma)
568	add_definitions(-D_7ZIP_PPMD_SUPPPORT)
569	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-lzma.c)
570	set(LZMA_SRC
571		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
572		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
573		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
574		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
575		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
576		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
577		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zDec.c
578		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
579		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Delta.c
580		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
581		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
582		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra.c
583		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra86.c
584		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/BraIA64.c
585		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
586		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
587		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
588		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zFile.c
589		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
590	list(APPEND VFS_SRC ${LZMA_SRC})
591	list(APPEND FEATURES LZMA)
592endif()
593
594if(USE_EPOXY)
595	add_definitions(-DBUILD_GL -DBUILD_GLES2)
596	list(APPEND FEATURES EPOXY)
597	include_directories(AFTER ${EPOXY_INCLUDE_DIRS})
598	set(OPENGLES2_LIBRARY ${EPOXY_LIBRARIES})
599	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libepoxy0")
600endif()
601
602if(USE_SQLITE3)
603	list(APPEND FEATURES SQLITE3)
604	include_directories(AFTER ${SQLITE3_INCLUDE_DIRS})
605	list(APPEND DEPENDENCY_LIB ${SQLITE3_LIBRARIES})
606	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libsqlite3-0")
607	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/sqlite3/no-intro.c")
608endif()
609
610set(TEST_SRC ${CORE_TEST_SRC})
611if(M_CORE_GB)
612	add_definitions(-DM_CORE_GB)
613	list(APPEND CORE_SRC
614		${LR35902_SRC}
615		${GB_SRC}
616		${GB_RENDERER_SRC})
617	list(APPEND DEBUGGER_SRC
618		${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/cli-debugger.c
619		${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/debugger.c
620		${CMAKE_CURRENT_SOURCE_DIR}/src/gb/extra/cli.c)
621	list(APPEND TEST_SRC
622		${LR35902_TEST_SRC}
623		${GB_TEST_SRC})
624endif()
625
626if(M_CORE_GBA)
627	add_definitions(-DM_CORE_GBA)
628	list(APPEND CORE_SRC
629		${ARM_SRC}
630		${GBA_SRC}
631		${GBA_CHEATS_SRC}
632		${GBA_RENDERER_SRC})
633	list(APPEND DEBUGGER_SRC
634		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c
635		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/debugger.c
636		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/memory-debugger.c
637		${CMAKE_CURRENT_SOURCE_DIR}/src/gba/extra/cli.c)
638	list(APPEND TEST_SRC
639		${ARM_TEST_SRC}
640		${GBA_TEST_SRC})
641	if(NOT M_CORE_GB)
642		list(APPEND CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/audio.c)
643	endif()
644endif()
645
646if(M_CORE_DS)
647	add_definitions(-DM_CORE_DS)
648	list(APPEND CORE_SRC 
649		${ARM_SRC}
650		${DS_SRC}
651		${DS_RENDERER_SRC})
652	list(APPEND DEBUGGER_SRC
653		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c
654		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/debugger.c
655		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/memory-debugger.c
656		${CMAKE_CURRENT_SOURCE_DIR}/src/ds/extra/cli.c)
657endif()
658
659if(USE_DEBUGGERS)
660	list(APPEND FEATURE_SRC ${DEBUGGER_SRC})
661	list(APPEND FEATURES DEBUGGERS)
662endif()
663
664foreach(FEATURE IN LISTS FEATURES)
665	list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
666endforeach()
667
668source_group("Virtual files" FILES ${CORE_VFS_SRC} ${VFS_SRC})
669source_group("Extra features" FILES ${FEATURE_SRC})
670source_group("Third-party code" FILES ${THIRD_PARTY_SRC})
671
672# Platform binaries
673if(DEFINED 3DS)
674	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/3ds ${CMAKE_CURRENT_BINARY_DIR}/3ds)
675endif()
676
677if(DEFINED WII)
678	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/wii ${CMAKE_CURRENT_BINARY_DIR}/wii)
679endif()
680
681if(DEFINED PSP2)
682	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/psp2 ${CMAKE_CURRENT_BINARY_DIR}/psp2)
683endif()
684
685# Binaries
686list(APPEND CORE_SRC
687	${UTIL_SRC}
688	${CORE_VFS_SRC}
689	${OS_SRC}
690	${THIRD_PARTY_SRC})
691list(APPEND TEST_SRC ${UTIL_TEST_SRC})
692
693set(SRC ${CORE_SRC} ${VFS_SRC})
694if(NOT MINIMAL_CORE)
695	if(M_CORE_GBA)
696		list(APPEND SRC
697			${GBA_RR_SRC}
698			${GBA_EXTRA_SRC}
699			${GBA_SIO_SRC})
700	endif()
701	if(M_CORE_GB)
702		list(APPEND SRC
703			${GB_SIO_SRC})
704	endif()
705	list(APPEND SRC
706		${FEATURE_SRC}
707		${CLI_SRC})
708endif()
709
710if(NOT SKIP_LIBRARY)
711	if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
712		set(BUILD_SHARED ON)
713	endif()
714
715	if(BUILD_SHARED)
716		add_library(${BINARY_NAME} SHARED ${SRC} ${VFS_SRC})
717		if(BUILD_STATIC)
718			add_library(${BINARY_NAME}-static STATIC ${SRC})
719			set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
720			install(TARGETS ${BINARY_NAME}-static DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
721			add_dependencies(${BINARY_NAME}-static version-info)
722		endif()
723	else()
724		add_library(${BINARY_NAME} STATIC ${SRC})
725	endif()
726
727	add_dependencies(${BINARY_NAME} version-info)
728	set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
729
730	target_link_libraries(${BINARY_NAME} ${DEBUGGER_LIB} ${DEPENDENCY_LIB} ${OS_LIB})
731	install(TARGETS ${BINARY_NAME} LIBRARY DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME} NAMELINK_SKIP ARCHIVE DESTINATION ${LIBDIR} RUNTIME DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
732	if(UNIX AND NOT APPLE)
733		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/${BINARY_NAME}-16.png DESTINATION share/icons/hicolor/16x16/apps RENAME ${BINARY_NAME}.png COMPONENT lib${BINARY_NAME})
734		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/${BINARY_NAME}-24.png DESTINATION share/icons/hicolor/24x24/apps RENAME ${BINARY_NAME}.png COMPONENT lib${BINARY_NAME})
735		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/${BINARY_NAME}-32.png DESTINATION share/icons/hicolor/32x32/apps RENAME ${BINARY_NAME}.png COMPONENT lib${BINARY_NAME})
736		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/${BINARY_NAME}-48.png DESTINATION share/icons/hicolor/48x48/apps RENAME ${BINARY_NAME}.png COMPONENT lib${BINARY_NAME})
737		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/${BINARY_NAME}-64.png DESTINATION share/icons/hicolor/64x64/apps RENAME ${BINARY_NAME}.png COMPONENT lib${BINARY_NAME})
738		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/${BINARY_NAME}-96.png DESTINATION share/icons/hicolor/96x96/apps RENAME ${BINARY_NAME}.png COMPONENT lib${BINARY_NAME})
739		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/${BINARY_NAME}-128.png DESTINATION share/icons/hicolor/128x128/apps RENAME ${BINARY_NAME}.png COMPONENT lib${BINARY_NAME})
740		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/${BINARY_NAME}-256.png DESTINATION share/icons/hicolor/256x256/apps RENAME ${BINARY_NAME}.png COMPONENT lib${BINARY_NAME})
741		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/${BINARY_NAME}-512.png DESTINATION share/icons/hicolor/512x512/apps RENAME ${BINARY_NAME}.png COMPONENT lib${BINARY_NAME})
742	endif()
743else()
744	set(BUILD_SHARED OFF)
745	set(BUILD_STATIC OFF)
746	find_library(${BINARY_NAME} ${BINARY_NAME})
747	if(NOT ${BINARY_NAME}_FOUND)
748		set(DISABLE_FRONTENDS ON)
749		set(BUILD_PERF OFF)
750		set(BUILD_TEST OFF)
751		set(BUILD_SUITE OFF)
752	endif()
753endif()
754
755if(BUILD_GL)
756	add_definitions(-DBUILD_GL)
757endif()
758
759if(BUILD_GLES2)
760	add_definitions(-DBUILD_GLES2)
761endif()
762
763if(DISABLE_FRONTENDS)
764	set(BUILD_SDL OFF)
765	set(BUILD_QT OFF)
766endif()
767
768if(BUILD_LIBRETRO)
769	file(GLOB RETRO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/libretro/*.c)
770	add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
771	set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5;DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=2")
772	target_link_libraries(${BINARY_NAME}_libretro ${OS_LIB})
773	install(TARGETS ${BINARY_NAME}_libretro LIBRARY DESTINATION ${LIBRETRO_LIBDIR} COMPONENT ${BINARY_NAME}_libretro NAMELINK_SKIP)
774endif()
775
776if(BUILD_OPENEMU)
777	find_library(FOUNDATION Foundation)
778	find_library(OPENEMUBASE OpenEmuBase)
779	file(GLOB OE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/*.m)
780	add_library(${BINARY_NAME}-openemu MODULE ${CORE_SRC} ${OE_SRC})
781	set_target_properties(${BINARY_NAME}-openemu PROPERTIES
782		MACOSX_BUNDLE_INFO_PLIST ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/Info.plist.in
783		BUNDLE TRUE
784		BUNDLE_EXTENSION oecoreplugin
785		OUTPUT_NAME ${PROJECT_NAME}
786		COMPILE_DEFINITIONS "DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=1")
787	target_link_libraries(${BINARY_NAME}-openemu ${OS_LIB} ${FOUNDATION} ${OPENEMUBASE})
788	install(TARGETS ${BINARY_NAME}-openemu LIBRARY DESTINATION ${OE_LIBDIR} COMPONENT ${BINARY_NAME}.oecoreplugin NAMELINK_SKIP)
789endif()
790
791if(BUILD_SDL)
792	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/sdl ${CMAKE_CURRENT_BINARY_DIR}/sdl)
793	# The SDL platform CMakeLists could decide to disable SDL, so check again before adding the define.
794	if(BUILD_SDL)
795		add_definitions(-DBUILD_SDL)
796	endif()
797endif()
798
799if(BUILD_QT)
800	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/qt ${CMAKE_CURRENT_BINARY_DIR}/qt)
801endif()
802
803if(BUILD_PERF)
804	set(PERF_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/perf-main.c ${CLI_SRC})
805	if(UNIX AND NOT APPLE)
806		list(APPEND PERF_LIB rt)
807	endif()
808
809	add_executable(${BINARY_NAME}-perf ${PERF_SRC})
810	target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB} ${OS_LIB})
811	set_target_properties(${BINARY_NAME}-perf PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
812	install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
813	install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
814endif()
815
816if(BUILD_TEST)
817	add_executable(${BINARY_NAME}-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/fuzz-main.c)
818	target_link_libraries(${BINARY_NAME}-fuzz ${BINARY_NAME})
819	set_target_properties(${BINARY_NAME}-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
820	add_executable(tbl-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/tbl-fuzz-main.c)
821	target_link_libraries(tbl-fuzz ${BINARY_NAME})
822	set_target_properties(tbl-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
823	install(TARGETS ${BINARY_NAME}-fuzz tbl-fuzz DESTINATION bin COMPONENT ${BINARY_NAME}-test)
824endif()
825
826if(NOT USE_CMOCKA)
827	set(BUILD_SUITE OFF)
828endif()
829if(BUILD_SUITE)
830	enable_testing()
831	include_directories(AFTER ${CMOCKA_INCLUDE_DIRS})
832	link_directories(${CMOCKA_LIBRARY_DIRS})
833
834	add_executable(${BINARY_NAME}-suite ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/suite-main.c ${TEST_SRC})
835	target_link_libraries(${BINARY_NAME}-suite ${BINARY_NAME} ${PLATFORM_LIBRARY} cmocka)
836	set_target_properties(${BINARY_NAME}-suite PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
837	add_test(${BINARY_NAME}-suite ${BINARY_NAME}-suite)
838endif()
839
840if(BUILD_PYTHON)
841	enable_testing()
842	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/python ${CMAKE_CURRENT_BINARY_DIR}/python)
843endif()
844
845if(BUILD_EXAMPLE)
846	add_executable(${BINARY_NAME}-example-server ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/server.c)
847	target_link_libraries(${BINARY_NAME}-example-server ${BINARY_NAME})
848	set_target_properties(${BINARY_NAME}-example-server PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
849
850	if(BUILD_SDL)
851		add_executable(${BINARY_NAME}-example-client ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/client.c)
852		target_link_libraries(${BINARY_NAME}-example-client ${BINARY_NAME} ${SDL_LIBRARY} ${SDLMAIN_LIBRARY} ${OPENGL_LIBRARY} ${OPENGLES2_LIBRARY})
853		set_target_properties(${BINARY_NAME}-example-client PROPERTIES
854		                      COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}"
855		                      INCLUDE_DIRECTORIES "${SDL_INCLUDE_DIR};${CMAKE_CURRENT_SOURCE_DIR}/src;${CMAKE_CURRENT_SOURCE_DIR}/include")
856	endif()
857endif()
858
859# Packaging
860set(CPACK_PACKAGE_VERSION ${VERSION_STRING})
861set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
862set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
863set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
864set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
865set(CPACK_RESOURCE_FILE_README ${CMAKE_CURRENT_SOURCE_DIR}/README.md)
866
867set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
868set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
869set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
870set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README.md")
871set(CPACK_DEBIAN_PACKAGE_SECTION "games")
872
873SET(CPACK_DEB_COMPONENT_INSTALL ON)
874
875set(CPACK_STRIP_FILES ${BINARY_NAME})
876
877install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/README.md ${CMAKE_CURRENT_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
878
879include(CPack)
880
881# Summaries
882set(SUMMARY_GL_LIST)
883if(USE_EPOXY)
884	set(SUMMARY_GL_LIST "libepoxy")
885else()
886	if(BUILD_GL)
887		list(APPEND SUMMARY_GL_LIST "OpenGL")
888	endif()
889	if(BUILD_GLES2)
890		list(APPEND SUMMARY_GL_LIST "OpenGL|ES 2")
891	endif()
892endif()
893if(NOT SUMMARY_GL_LIST)
894	set(SUMMARY_GL OFF)
895else()
896	string(REPLACE ";" ", " SUMMARY_GL "${SUMMARY_GL_LIST}")
897endif()
898if(USE_LIBZIP)
899	set(SUMMARY_ZIP libzip)
900elseif(USE_MINIZIP)
901	set(SUMMARY_ZIP "minizip (external)")
902elseif(USE_ZLIB)
903	set(SUMMARY_ZIP "minizip (included)")
904else()
905	set(SUMMARY_ZIP OFF)
906endif()
907
908if(NOT QUIET)
909	message(STATUS "Platforms:")
910	message(STATUS "	Game Boy Advance: ${M_CORE_GBA}")
911	message(STATUS "	Game Boy: ${M_CORE_GB}")
912	message(STATUS "	DS: ${M_CORE_DS}")
913	message(STATUS "Features:")
914	message(STATUS "	Debuggers: ${USE_DEBUGGERS}")
915	message(STATUS "	CLI debugger: ${USE_EDITLINE}")
916	message(STATUS "	GDB stub: ${USE_GDB_STUB}")
917	message(STATUS "	Video recording: ${USE_FFMPEG}")
918	message(STATUS "	GIF recording: ${USE_MAGICK}")
919	message(STATUS "	Screenshot/advanced savestate support: ${USE_PNG}")
920	message(STATUS "	ZIP support: ${SUMMARY_ZIP}")
921	message(STATUS "	7-Zip support: ${USE_LZMA}")
922	message(STATUS "	SQLite3 game database: ${USE_SQLITE3}")
923	message(STATUS "	OpenGL support: ${SUMMARY_GL}")
924	message(STATUS "Frontends:")
925	message(STATUS "	Qt: ${BUILD_QT}")
926	message(STATUS "	SDL (${SDL_VERSION}): ${BUILD_SDL}")
927	message(STATUS "	Profiling: ${BUILD_PERF}")
928	message(STATUS "	Test harness: ${BUILD_TEST}")
929	message(STATUS "	Test suite: ${BUILD_SUITE}")
930	message(STATUS "	Python bindings: ${BUILD_PYTHON}")
931	message(STATUS "	Examples: ${BUILD_EXAMPLE}")
932	message(STATUS "Cores:")
933	message(STATUS "	Libretro core: ${BUILD_LIBRETRO}")
934	if(APPLE)
935		message(STATUS "	OpenEmu core: ${BUILD_OPENEMU}")
936	endif()
937	message(STATUS "Libraries:")
938	message(STATUS "	Static: ${BUILD_STATIC}")
939	message(STATUS "	Shared: ${BUILD_SHARED}")
940endif()