1cmake_minimum_required(VERSION 2.6)
  2project(mGBA C)
  3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
  4set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -std=gnu99")
  5set(USE_CLI_DEBUGGER ON CACHE BOOL "Whether or not to enable the CLI-mode ARM debugger")
  6set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
  7set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
  8set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
  9set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable ZIP support")
 10set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
 11set(USE_BLIP ON CACHE BOOL "Whether or not to enable blip_buf support")
 12set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
 13set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
 14set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
 15set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
 16file(GLOB ARM_SRC ${CMAKE_SOURCE_DIR}/src/arm/*.c)
 17file(GLOB GBA_SRC ${CMAKE_SOURCE_DIR}/src/gba/*.c)
 18file(GLOB UTIL_SRC ${CMAKE_SOURCE_DIR}/src/util/*.[cSs])
 19file(GLOB VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/*.c)
 20file(GLOB RENDERER_SRC ${CMAKE_SOURCE_DIR}/src/gba/renderers/video-software.c)
 21file(GLOB THIRD_PARTY_SRC ${CMAKE_SOURCE_DIR}/src/third-party/inih/*.c)
 22list(APPEND UTIL_SRC ${CMAKE_SOURCE_DIR}/src/platform/commandline.c)
 23source_group("ARM core" FILES ${ARM_SRC})
 24source_group("GBA board" FILES ${GBA_SRC} ${RENDERER_SRC})
 25source_group("Utilities" FILES ${UTIL_SRC} ${VFS_SRC}})
 26include_directories(${CMAKE_SOURCE_DIR}/src/arm)
 27include_directories(${CMAKE_SOURCE_DIR}/src/gba)
 28include_directories(${CMAKE_SOURCE_DIR}/src)
 29
 30if(NOT CMAKE_BUILD_TYPE)
 31	set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
 32endif()
 33
 34include(GNUInstallDirs)
 35
 36# Function definitions
 37include(FindPkgConfig)
 38function(find_feature FEATURE_NAME FEATURE_REQUIRES)
 39	if (NOT ${FEATURE_NAME})
 40		return()
 41	endif()
 42	foreach(REQUIRE ${FEATURE_REQUIRES})
 43		if(NOT ${REQUIRE}_FOUND)
 44			find_package(${REQUIRE} QUIET)
 45			if(NOT ${REQUIRE}_FOUND)
 46				pkg_search_module(${REQUIRE} ${REQUIRE})
 47				if (NOT ${REQUIRE}_FOUND)
 48					message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
 49					set(${FEATURE_NAME} OFF PARENT_SCOPE)
 50					return()
 51				endif()
 52			endif()
 53		endif()
 54		string(TOUPPER ${REQUIRE} UREQUIRE)
 55		set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
 56		set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
 57		set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
 58		set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
 59		set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
 60		set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
 61	endforeach()
 62endfunction()
 63
 64# Version information
 65set(LIB_VERSION_MAJOR 0)
 66set(LIB_VERSION_MINOR 2)
 67set(LIB_VERSION_PATCH 0)
 68set(LIB_VERSION_ABI 0.2)
 69set(LIB_VERSION_STRING ${LIB_VERSION_MAJOR}.${LIB_VERSION_MINOR}.${LIB_VERSION_PATCH})
 70
 71# Advanced settings
 72set(BUILD_PGO CACHE BOOL "Build with profiling-guided optimization")
 73set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
 74set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
 75mark_as_advanced(BUILD_PGO PGO_STAGE_2 PGO_DIR)
 76set(PGO_PRE_FLAGS "-pg -fprofile-generate=${PGO_DIR} -fprofile-arcs")
 77set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
 78
 79if(BUILD_PGO AND NOT PGO_STAGE_2)
 80	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
 81	set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
 82	set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
 83elseif(BUILD_PGO AND PGO_STAGE_2)
 84	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
 85	set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
 86	set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
 87endif()
 88
 89add_definitions(-DBINARY_NAME="${BINARY_NAME}" -DPROJECT_NAME="${PROJECT_NAME}" -DPROJECT_VERSION="${LIB_VERSION_STRING}")
 90
 91# Feature dependencies
 92find_feature(USE_CLI_DEBUGGER "libedit")
 93find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
 94find_feature(USE_PNG "ZLIB;PNG")
 95find_feature(USE_LIBZIP "libzip")
 96find_feature(USE_MAGICK "MagickWand")
 97
 98include(CheckFunctionExists)
 99check_function_exists(strndup HAVE_STRNDUP)
100
101if(HAVE_STRNDUP)
102	add_definitions(-DHAVE_STRNDUP)
103endif()
104
105# Platform support
106if(WIN32)
107	add_definitions(-D_WIN32_WINNT=0x0600)
108	list(APPEND OS_LIB ws2_32)
109	file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/windows/*.c)
110	source_group("Windows-specific code" FILES ${OS_SRC})
111else()
112	add_definitions(-DUSE_PTHREADS)
113	list(APPEND OS_LIB pthread)
114	file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/posix/*.c)
115	source_group("POSIX-specific code" FILES ${OS_SRC})
116endif()
117
118if(APPLE)
119	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
120endif()
121
122if(BUILD_BBB OR BUILD_RASPI)
123	enable_language(ASM)
124	if(NOT BUILD_EGL)
125		add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
126	endif()
127endif()
128
129# Features
130set(DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/debugger.c ${CMAKE_SOURCE_DIR}/src/debugger/memory-debugger.c)
131set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
132
133if(USE_CLI_DEBUGGER)
134	add_definitions(-DUSE_CLI_DEBUGGER)
135	list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/cli-debugger.c)
136	list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/parser.c)
137	list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/gba/gba-cli.c)
138	include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
139	link_directories(${LIBEDIT_LIBRARY_DIRS})
140	set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
141	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
142else()
143	set(DEBUGGER_LIB "")
144endif()
145
146if(USE_GDB_STUB)
147	add_definitions(-DUSE_GDB_STUB)
148	list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/gdb-stub.c)
149endif()
150source_group("ARM debugger" FILES ${DEBUGGER_SRC})
151
152if(USE_FFMPEG)
153	add_definitions(-DUSE_FFMPEG)
154	pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
155	if(NOT LIBSWRESAMPLE_FOUND)
156		add_definitions(-DUSE_LIBAV)
157	endif()
158	include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
159	link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
160	list(APPEND UTIL_SRC "${CMAKE_SOURCE_DIR}/src/platform/ffmpeg/ffmpeg-encoder.c")
161	string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
162	string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
163	string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
164	string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
165	string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
166	list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
167	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR},libavformat${LIBAVFORMAT_VERSION_MAJOR},libavresample${LIBAVRESAMPLE_VERSION_MAJOR},libavutil${LIBAVUTIL_VERSION_MAJOR},libswscale${LIBSWSCALE_VERSION_MAJOR}")
168	set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra")
169endif()
170
171if(USE_BLIP)
172	list(APPEND UTIL_SRC "${CMAKE_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
173	add_definitions(-DRESAMPLE_LIBRARY=RESAMPLE_BLIP_BUF)
174else()
175	add_definitions(-DRESAMPLE_LIBRARY=RESAMPLE_NN)
176endif()
177
178if(USE_MAGICK)
179	add_definitions(-DUSE_MAGICK)
180	include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
181	link_directories(${MAGICKWAND_LIBRARY_DIRS})
182	list(APPEND UTIL_SRC "${CMAKE_SOURCE_DIR}/src/platform/imagemagick/imagemagick-gif-encoder.c")
183	list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
184	string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
185	if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
186		set(MAGICKWAND_DEB_VERSION "5")
187	else()
188		set(MAGICKWAND_DEB_VERSION "-6.q16-2")
189	endif()
190	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
191endif()
192
193if(USE_PNG)
194	add_definitions(-DUSE_PNG)
195	include_directories(AFTER ${PNG_INCLUDE_DIRS})
196	list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
197	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng12-0,zlib1g")
198endif()
199
200if(USE_LIBZIP)
201	include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
202	link_directories(${LIBZIP_LIBRARY_DIRS})
203	list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
204	add_definitions(-DENABLE_LIBZIP)
205	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
206endif()
207
208if (USE_LZMA)
209	include_directories(AFTER ${CMAKE_SOURCE_DIR}/third-party/lzma)
210	add_definitions(-D_7ZIP_PPMD_SUPPPORT)
211	set(LZMA_SRC
212		${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-lzma.c
213		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
214		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
215		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
216		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
217		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
218		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
219		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zDec.c
220		${CMAKE_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
221		${CMAKE_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
222		${CMAKE_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
223		${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bra.c
224		${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bra86.c
225		${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
226		${CMAKE_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
227		${CMAKE_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
228		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zFile.c
229		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
230	list(APPEND UTIL_SRC ${LZMA_SRC})
231	add_definitions(-DENABLE_LZMA)
232endif()
233
234# Binaries
235add_library(${BINARY_NAME} SHARED
236	${ARM_SRC}
237	${GBA_SRC}
238	${DEBUGGER_SRC}
239	${RENDERER_SRC}
240	${UTIL_SRC}
241	${VFS_SRC}
242	${OS_SRC}
243	${THIRD_PARTY_SRC})
244target_link_libraries(${BINARY_NAME} m ${DEBUGGER_LIB} ${OS_LIB} ${DEPENDENCY_LIB})
245install(TARGETS ${BINARY_NAME} DESTINATION lib COMPONENT lib${BINARY_NAME})
246set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI})
247
248if(BUILD_SDL)
249	add_definitions(-DBUILD_SDL)
250	add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/sdl ${CMAKE_BINARY_DIR}/sdl)
251endif()
252
253if(BUILD_QT)
254	add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/qt ${CMAKE_BINARY_DIR}/qt)
255endif()
256
257if(BUILD_PERF)
258	set(PERF_SRC ${CMAKE_SOURCE_DIR}/src/platform/perf-main.c)
259	if(UNIX AND NOT APPLE)
260		list(APPEND PERF_LIB rt)
261	endif()
262
263	add_executable(${BINARY_NAME}-perf ${PERF_SRC})
264	target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB})
265	install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
266	install(FILES ${CMAKE_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
267endif()
268
269# Packaging
270set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
271set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
272set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
273set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_SOURCE_DIR}/LICENSE)
274set(CPACK_RESOURCE_FILE_README ${CMAKE_SOURCE_DIR}/LICENSE)
275
276set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
277set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
278set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
279set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_SOURCE_DIR}/README.md")
280
281set(CPACK_STRIP_FILES ${BINARY_NAME})
282
283include(CPack)
284
285# Summaries
286message(STATUS "Feature summary:")
287message(STATUS "	CLI debugger: ${USE_CLI_DEBUGGER}")
288message(STATUS "	GDB stub: ${USE_GDB_STUB}")
289message(STATUS "	Video recording: ${USE_FFMPEG}")
290message(STATUS "	GIF recording: ${USE_MAGICK}")
291message(STATUS "	Screenshot/advanced savestate support: ${USE_PNG}")
292message(STATUS "	ZIP support: ${USE_LIBZIP}")
293message(STATUS "	7-Zip support: ${USE_LZMA}")
294message(STATUS "	Better audio resampling: ${USE_BLIP}")
295message(STATUS "Frontend summary:")
296message(STATUS "	Qt: ${BUILD_QT}")
297message(STATUS "	SDL (${SDL_VERSION}): ${BUILD_SDL}")
298message(STATUS "	Profiling: ${BUILD_PERF}")