CMakeLists.txt (view raw)
1cmake_minimum_required(VERSION 2.8.11)
2project(mGBA)
3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
4if(NOT MSVC)
5 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wno-missing-field-initializers -std=c99")
6else()
7 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_CRT_SECURE_NO_WARNINGS /wd4003 /wd4244 /wd4146")
8endif()
9set(USE_DEBUGGERS ON CACHE BOOL "Whether or not to enable the debugging infrastructure")
10set(USE_EDITLINE ON CACHE BOOL "Whether or not to enable the CLI-mode debugger")
11set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
12set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
13set(USE_ZLIB ON CACHE BOOL "Whether or not to enable zlib support")
14set(USE_MINIZIP ON CACHE BOOL "Whether or not to enable external minizip support")
15set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
16set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable LIBZIP support")
17set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
18set(USE_SQLITE3 ON CACHE BOOL "Whether or not to enable SQLite3 support")
19set(M_CORE_GBA ON CACHE BOOL "Build Game Boy Advance core")
20set(M_CORE_GB ON CACHE BOOL "Build Game Boy core")
21set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
22set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
23set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
24set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
25if(APPLE)
26 set(BUILD_OPENEMU OFF CACHE BOOL "Build OpenEmu core")
27endif()
28set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
29set(BUILD_TEST OFF CACHE BOOL "Build testing harness")
30set(BUILD_SUITE OFF CACHE BOOL "Build test suite")
31set(BUILD_EXAMPLE OFF CACHE BOOL "Build example frontends")
32set(BUILD_PYTHON OFF CACHE BOOL "Build Python bindings")
33set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
34set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
35set(SKIP_LIBRARY OFF CACHE BOOL "Skip building the library (useful for only building libretro or OpenEmu cores)")
36set(BUILD_GL ON CACHE STRING "Build with OpenGL")
37set(BUILD_GLES2 OFF CACHE STRING "Build with OpenGL|ES 2")
38set(USE_EPOXY ON CACHE STRING "Build with libepoxy")
39set(DISABLE_DEPS OFF CACHE BOOL "Build without dependencies")
40file(GLOB ARM_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/*.c)
41file(GLOB ARM_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/test/*.c)
42file(GLOB LR35902_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/*.c)
43file(GLOB LR35902_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/test/*.c)
44file(GLOB GBA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/*.c)
45file(GLOB GBA_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/test/*.c)
46file(GLOB GB_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/*.c)
47file(GLOB GB_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/test/*.c)
48file(GLOB GBA_CHEATS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/cheats/*.c)
49file(GLOB GBA_RR_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/rr/*.c)
50file(GLOB CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/*.c)
51file(GLOB CORE_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/test/*.c)
52file(GLOB UTIL_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/*.[cSs])
53file(GLOB UTIL_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/test/*.c)
54file(GLOB GUI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/gui/*.c ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/gui/*.c)
55file(GLOB GBA_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/renderers/*.c)
56file(GLOB GBA_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/sio/lockstep.c)
57file(GLOB GBA_EXTRA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/extra/*.c)
58file(GLOB GB_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/sio/lockstep.c)
59file(GLOB GB_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/renderers/*.c)
60file(GLOB GB_EXTRA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/extra/*.c)
61file(GLOB THIRD_PARTY_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/inih/*.c)
62file(GLOB EXTRA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/*.c)
63set(CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-mem.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fifo.c)
64set(VFS_SRC)
65source_group("ARM core" FILES ${ARM_SRC})
66source_group("LR35902 core" FILES ${LR35902_SRC})
67source_group("GBA board" FILES ${GBA_SRC} ${GBA_RENDERER_SRC} ${GBA_SIO_SRC})
68source_group("GBA extra" FILES ${GBA_CHEATS_SRC} ${GBA_RR_SRC})
69source_group("GB board" FILES ${GB_SRC} ${GB_SIO_SRC})
70source_group("Utilities" FILES ${UTIL_SRC})
71include_directories(BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/include ${CMAKE_CURRENT_SOURCE_DIR}/src)
72
73if(NOT CMAKE_BUILD_TYPE)
74 set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
75endif()
76
77include(GNUInstallDirs)
78
79set(LIBDIR "${CMAKE_INSTALL_LIBDIR}" CACHE PATH "Installed library directory")
80mark_as_advanced(LIBDIR)
81
82if (BUILD_LIBRETRO)
83 set(LIBRETRO_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (Libretro)")
84 mark_as_advanced(LIBRETRO_LIBDIR)
85endif()
86
87if (BUILD_OPENEMU)
88 set(OE_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (OpenEmu)")
89 mark_as_advanced(OE_LIBDIR)
90endif()
91
92
93set(CMAKE_INSTALL_RPATH "${LIBDIR}")
94
95if (NOT DEFINED MANDIR)
96 set(MANDIR ${CMAKE_INSTALL_MANDIR})
97endif()
98
99# Function definitions
100include(FindPkgConfig)
101function(find_feature FEATURE_NAME FEATURE_REQUIRES)
102 if (NOT ${FEATURE_NAME})
103 return()
104 endif()
105 if (DISABLE_DEPS)
106 set(${FEATURE_NAME} OFF PARENT_SCOPE)
107 return()
108 endif()
109 foreach(REQUIRE ${FEATURE_REQUIRES})
110 if(NOT ${REQUIRE}_FOUND)
111 find_package(${REQUIRE} QUIET)
112 if(NOT ${REQUIRE}_FOUND)
113 pkg_search_module(${REQUIRE} ${REQUIRE})
114 if (NOT ${REQUIRE}_FOUND)
115 message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
116 set(${FEATURE_NAME} OFF PARENT_SCOPE)
117 return()
118 endif()
119 endif()
120 endif()
121 string(TOUPPER ${REQUIRE} UREQUIRE)
122 set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
123 set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
124 set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
125 if (APPLE)
126 set(IS_FRAMEWORK OFF)
127 set(LIBS)
128 foreach(LIB IN LISTS ${REQUIRE}_LIBRARIES)
129 if(LIB STREQUAL "-framework")
130 set(IS_FRAMEWORK ON)
131 elseif(IS_FRAMEWORK)
132 list(APPEND LIBS "-framework ${LIB}")
133 set(IS_FRAMEWORK OFF)
134 else()
135 list(APPEND LIBS ${LIB})
136 endif()
137 endforeach()
138 set(${UREQUIRE}_LIBRARIES ${LIBS} PARENT_SCOPE)
139 else()
140 set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
141 endif()
142 set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
143 set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
144 endforeach()
145endfunction()
146
147# Version information
148add_custom_target(version-info ALL
149 COMMAND ${CMAKE_COMMAND}
150 -DBINARY_NAME=${BINARY_NAME}
151 -DCONFIG_FILE=${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in
152 -DOUT_FILE=${CMAKE_CURRENT_BINARY_DIR}/version.c
153 -P ${CMAKE_CURRENT_SOURCE_DIR}/version.cmake
154 WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
155
156include(${CMAKE_CURRENT_SOURCE_DIR}/version.cmake)
157configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in ${CMAKE_CURRENT_BINARY_DIR}/version.c)
158configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/flags.h.in ${CMAKE_CURRENT_BINARY_DIR}/flags.h)
159install(FILES ${CMAKE_CURRENT_BINARY_DIR}/flags.h DESTINATION include/mgba COMPONENT lib${BINARY_NAME})
160
161list(APPEND UTIL_SRC ${CMAKE_CURRENT_BINARY_DIR}/version.c)
162source_group("Generated sources" FILES ${CMAKE_CURRENT_BINARY_DIR}/version.c)
163
164# Advanced settings
165if(NOT DEFINED 3DS)
166 # LTO appears to make 3DS binary slower
167 set(DEFAULT_LTO ON)
168else()
169 set(DEFAULT_LTO OFF)
170endif()
171
172set(BUILD_LTO ${DEFAULT_LTO} CACHE BOOL "Build with link-time optimization")
173set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
174set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
175set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
176mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
177set(PGO_PRE_FLAGS "-fprofile-generate=${PGO_DIR} -fprofile-arcs")
178set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
179
180if(BUILD_PGO AND NOT PGO_STAGE_2)
181 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
182 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
183 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
184elseif(BUILD_PGO AND PGO_STAGE_2)
185 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
186 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
187 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
188endif()
189
190# Platform support
191if(WIN32)
192 set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
193 add_definitions(-D_WIN32_WINNT=0x0600)
194 list(APPEND OS_LIB ws2_32 shlwapi)
195 list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/vfs-w32.c)
196 file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/*.c)
197 source_group("Windows-specific code" FILES ${OS_SRC})
198 if(MSVC)
199 add_definitions(-DNOMINMAX -DWIN32_LEAN_AND_MEAN)
200 set(CMAKE_WINDOWS_EXPORT_ALL_SYMBOLS TRUE)
201 endif()
202elseif(UNIX)
203 add_definitions(-DUSE_PTHREADS)
204
205 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
206 add_definitions(-D_GNU_SOURCE)
207 endif()
208 if(NOT APPLE AND NOT HAIKU)
209 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
210 endif()
211
212 list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
213 file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/posix/*.c)
214 source_group("POSIX-specific code" FILES ${OS_SRC})
215endif()
216
217if(APPLE)
218 add_definitions(-D_DARWIN_C_SOURCE)
219 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
220endif()
221
222if(NOT HAIKU AND NOT MSVC AND NOT PSP2)
223 set(M_LIBRARY m)
224endif()
225list(APPEND OS_LIB ${M_LIBRARY})
226
227if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
228 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
229 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
230endif()
231
232if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
233 if(NOT BUILD_EGL)
234 add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
235 endif()
236endif()
237
238if(BUILD_RASPI)
239 set(BUILD_GL OFF CACHE BOOL "OpenGL not supported" FORCE)
240endif()
241
242if(BUILD_PANDORA)
243 add_definitions(-DBUILD_PANDORA)
244endif()
245
246if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
247 enable_language(ASM)
248endif()
249
250if(PSP2 OR WII)
251 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-format")
252endif()
253
254if(DEFINED 3DS OR DEFINED PSP2 OR DEFINED WII)
255 set(USE_DEBUGGERS OFF)
256 set(USE_SQLITE3 OFF)
257endif()
258
259if(NOT M_CORE_GBA)
260 set(USE_GDB_STUB OFF)
261endif()
262
263if(NOT USE_DEBUGGERS)
264 set(USE_EDITLINE OFF)
265 set(USE_GDB_STUB OFF)
266endif()
267
268if(WII)
269 add_definitions(-U__STRICT_ANSI__)
270endif()
271
272if(DEFINED 3DS)
273 add_definitions(-D_GNU_SOURCE)
274endif()
275
276include(CheckFunctionExists)
277check_function_exists(strdup HAVE_STRDUP)
278check_function_exists(strndup HAVE_STRNDUP)
279check_function_exists(localtime_r HAVE_LOCALTIME_R)
280if(NOT CMAKE_SYSTEM_NAME STREQUAL "Generic")
281 check_function_exists(snprintf_l HAVE_SNPRINTF_L)
282 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
283 # The strtof_l on Linux not actually exposed nor actually strtof_l
284 set(HAVE_STRTOF_L OFF)
285 else()
286 check_function_exists(strtof_l HAVE_STRTOF_L)
287 endif()
288 check_function_exists(newlocale HAVE_NEWLOCALE)
289 check_function_exists(freelocale HAVE_FREELOCALE)
290 check_function_exists(uselocale HAVE_USELOCALE)
291 check_function_exists(setlocale HAVE_SETLOCALE)
292else()
293 if(DEFINED 3DS)
294 check_function_exists(snprintf_l HAVE_SNPRINTF_L)
295 check_function_exists(strtof_l HAVE_STRTOF_L)
296 check_function_exists(newlocale HAVE_NEWLOCALE)
297 check_function_exists(freelocale HAVE_FREELOCALE)
298 check_function_exists(uselocale HAVE_USELOCALE)
299 check_function_exists(setlocale HAVE_SETLOCALE)
300 endif()
301 if(NOT DEFINED 3DS AND NOT DEFINED PSP2 AND NOT DEFINED WII)
302 set(DISABLE_DEPS ON CACHE BOOL "This platform cannot build with dependencies" FORCE)
303 endif()
304 set(DISABLE_FRONTENDS ON)
305 set(MINIMAL_CORE ON)
306 set(ENABLE_EXTRA ON)
307endif()
308
309check_function_exists(chmod HAVE_CHMOD)
310check_function_exists(umask HAVE_UMASK)
311
312set(FUNCTION_DEFINES)
313
314if(HAVE_STRDUP)
315 list(APPEND FUNCTION_DEFINES HAVE_STRDUP)
316endif()
317
318if(HAVE_STRNDUP)
319 list(APPEND FUNCTION_DEFINES HAVE_STRNDUP)
320endif()
321
322if(HAVE_LOCALTIME_R)
323 list(APPEND FUNCTION_DEFINES HAVE_LOCALTIME_R)
324endif()
325
326if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE OR APPLE OR DEFINED 3DS)
327 list(APPEND FUNCTION_DEFINES HAVE_LOCALE)
328 if (HAVE_STRTOF_L)
329 list(APPEND FUNCTION_DEFINES HAVE_STRTOF_L)
330 endif()
331 if (HAVE_SNPRINTF_L)
332 list(APPEND FUNCTION_DEFINES HAVE_SNPRINTF_L)
333 endif()
334endif()
335
336if(HAVE_SETLOCALE)
337 list(APPEND FUNCTION_DEFINES HAVE_SETLOCALE)
338endif()
339
340if(HAVE_CHMOD)
341 list(APPEND FUNCTION_DEFINES HAVE_CHMOD)
342endif()
343
344if(HAVE_UMASK)
345 list(APPEND FUNCTION_DEFINES HAVE_UMASK)
346endif()
347
348# Feature dependencies
349set(FEATURE_DEFINES)
350set(FEATURES)
351if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
352 set(LIBEDIT_LIBRARIES -ledit)
353 if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
354 list(APPEND LIBEDIT_LIBRARIES -ltermcap)
355 endif()
356else()
357 find_feature(USE_EDITLINE "libedit")
358endif()
359if(BUILD_GL)
360 find_package(OpenGL QUIET)
361 if(NOT OPENGL_FOUND)
362 set(BUILD_GL OFF CACHE BOOL "OpenGL not found" FORCE)
363 endif()
364endif()
365if(NOT BUILD_GL)
366 set(OPENGLE_LIBRARY "" CACHE PATH "" FORCE)
367endif()
368if(BUILD_GLES2 AND NOT BUILD_RASPI)
369 find_path(OPENGLES2_INCLUDE_DIR NAMES GLES2/gl2.h)
370 find_library(OPENGLES2_LIBRARY NAMES GLESv2 GLESv2_CM)
371 if(NOT OPENGLES2_INCLUDE_DIR OR NOT OPENGLES2_LIBRARY)
372 set(BUILD_GLES2 OFF CACHE BOOL "OpenGL|ES 2 not found" FORCE)
373 endif()
374endif()
375if(NOT BUILD_GLES2)
376 set(OPENGLES2_LIBRARY "" CACHE PATH "" FORCE)
377endif()
378set(WANT_ZLIB ${USE_ZLIB})
379set(WANT_PNG ${USE_PNG})
380set(WANT_LIBZIP ${USE_LIBZIP})
381set(WANT_SQLITE3 ${USE_SQLITE3})
382set(USE_CMOCKA ${BUILD_SUITE})
383
384find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
385find_feature(USE_ZLIB "ZLIB")
386find_feature(USE_MINIZIP "minizip")
387find_feature(USE_PNG "PNG")
388find_feature(USE_LIBZIP "libzip")
389find_feature(USE_MAGICK "MagickWand")
390find_feature(USE_EPOXY "epoxy")
391find_feature(USE_CMOCKA "cmocka")
392find_feature(USE_SQLITE3 "sqlite3")
393
394# Features
395set(DEBUGGER_SRC
396 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/debugger.c
397 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/parser.c
398 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/cli-debugger.c)
399
400set(FEATURE_SRC)
401set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
402
403if(DISABLE_DEPS)
404 set(USE_GDB_STUB OFF)
405endif()
406
407if(USE_EDITLINE)
408 list(APPEND FEATURES EDITLINE)
409 include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
410 link_directories(${LIBEDIT_LIBRARY_DIRS})
411 set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
412 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
413 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/editline/cli-el-backend.c")
414else()
415 set(DEBUGGER_LIB "")
416endif()
417
418if(USE_GDB_STUB)
419 list(APPEND FEATURES GDB_STUB)
420 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/gdb-stub.c)
421endif()
422source_group("Debugger" FILES ${DEBUGGER_SRC})
423
424if(USE_FFMPEG)
425 list(APPEND FEATURES FFMPEG)
426 pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
427 if(NOT LIBSWRESAMPLE_FOUND)
428 list(APPEND FEATURES LIBAV)
429 endif()
430 include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
431 link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
432 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/ffmpeg/ffmpeg-encoder.c")
433 string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
434 string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
435 string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
436 string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
437 string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
438 list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
439 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR}|libavcodec-extra-${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
440 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavformat${LIBAVFORMAT_VERSION_MAJOR}|libavformat-ffmpeg${LIBAVFORMAT_VERSION_MAJOR}")
441 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavresample${LIBAVRESAMPLE_VERSION_MAJOR}|libavresample-ffmpeg${LIBAVRESAMPLE_VERSION_MAJOR}")
442 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavutil${LIBAVUTIL_VERSION_MAJOR}|libavutil-ffmpeg${LIBAVUTIL_VERSION_MAJOR}")
443 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libswscale${LIBSWSCALE_VERSION_MAJOR}|libswscale-ffmpeg${LIBSWSCALE_VERSION_MAJOR}")
444 set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
445 if(APPLE)
446 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
447 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
448 endif()
449endif()
450
451list(APPEND THIRD_PARTY_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
452
453if(USE_MAGICK)
454 list(APPEND FEATURES MAGICK)
455 include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
456 link_directories(${MAGICKWAND_LIBRARY_DIRS})
457 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/imagemagick/imagemagick-gif-encoder.c")
458 list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
459 string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
460 string(REGEX MATCH "^[0-9]+" MAGICKWAND_VERSION_MAJOR ${MagickWand_VERSION})
461 if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
462 set(MAGICKWAND_DEB_VERSION "5")
463 elseif(${MagickWand_VERSION} EQUAL "6.9.7")
464 set(MAGICKWAND_DEB_VERSION "-6.q16-3")
465 else()
466 set(MAGICKWAND_DEB_VERSION "-6.q16-2")
467 endif()
468 list(APPEND FEATURE_DEFINES MAGICKWAND_VERSION_MAJOR=${MAGICKWAND_VERSION_MAJOR})
469
470 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
471endif()
472
473if(WANT_ZLIB AND NOT USE_ZLIB)
474 set(SKIP_INSTALL_ALL ON)
475 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib zlib)
476 set_property(TARGET zlibstatic PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/zlib;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib)
477 set_property(TARGET zlib PROPERTY EXCLUDE_FROM_ALL ON)
478 set_property(TARGET example PROPERTY EXCLUDE_FROM_ALL ON)
479 set_property(TARGET minigzip PROPERTY EXCLUDE_FROM_ALL ON)
480 set(ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
481 set(ZLIB_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
482 set(ZLIB_LIBRARY zlibstatic)
483 list(APPEND DEPENDENCY_LIB zlibstatic)
484 set(USE_ZLIB ON)
485endif()
486
487if(USE_ZLIB)
488 list(APPEND FEATURES ZLIB)
489 include_directories(AFTER ${ZLIB_INCLUDE_DIRS})
490 list(APPEND DEPENDENCY_LIB ${ZLIB_LIBRARIES})
491 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},zlib1g")
492endif()
493
494if(WANT_PNG AND USE_ZLIB AND NOT USE_PNG)
495 set(PNG_STATIC ON CACHE BOOL "" FORCE)
496 set(PNG_SHARED OFF CACHE BOOL "" FORCE)
497 set(PNG_TESTS OFF CACHE BOOL "" FORCE)
498 set(SKIP_INSTALL_ALL ON)
499 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng libpng)
500 set_property(TARGET png16_static PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/libpng;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng;${ZLIB_INCLUDE_DIRS})
501 set(PNG_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng ${CMAKE_CURRENT_BINARY_DIR}/libpng)
502 list(APPEND DEPENDENCY_LIB png16_static)
503 set(USE_PNG ON)
504endif()
505
506if(USE_PNG)
507 list(APPEND FEATURES PNG)
508 include_directories(AFTER ${PNG_INCLUDE_DIRS})
509 list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
510 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng12-0")
511endif()
512
513if(WANT_SQLITE3 AND NOT USE_SQLITE3)
514 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/sqlite3.c)
515 include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/)
516 set(USE_SQLITE3 ON)
517endif()
518
519if(USE_LIBZIP)
520 include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
521 link_directories(${LIBZIP_LIBRARY_DIRS})
522 list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
523 list(APPEND FEATURES LIBZIP)
524 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
525 string(REGEX MATCH "^[0-9]+" LIBZIP_VERSION_MAJOR ${libzip_VERSION})
526 if (LIBZIP_VERSION_MAJOR LESS 1)
527 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
528 elseif(LIBZIP_VERSION_MAJOR EQUAL 1)
529 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip4")
530 else()
531 message(AUTHOR_WARNING Unknown version of libzip detected: ${libzip_VERSION})
532 endif()
533elseif(USE_MINIZIP)
534 include_directories(AFTER ${MINIZIP_INCLUDE_DIRS})
535 link_directories(${MINIZIP_LIBRARY_DIRS})
536 list(APPEND DEPENDENCY_LIB ${MINIZIP_LIBRARIES})
537 list(APPEND FEATURES MINIZIP)
538 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
539 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libminizip1")
540elseif(USE_ZLIB)
541 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c
542 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
543 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c)
544 if(NOT MSVC)
545 set_source_files_properties(
546 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
547 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c
548 PROPERTIES COMPILE_FLAGS "-Wno-unused-parameter -Wno-implicit-function-declaration")
549 endif()
550endif()
551
552if (USE_LZMA)
553 include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/third-party/lzma)
554 add_definitions(-D_7ZIP_PPMD_SUPPPORT)
555 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-lzma.c)
556 set(LZMA_SRC
557 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
558 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
559 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
560 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
561 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
562 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
563 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zDec.c
564 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
565 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Delta.c
566 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
567 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
568 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra.c
569 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra86.c
570 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/BraIA64.c
571 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
572 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
573 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
574 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zFile.c
575 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
576 list(APPEND VFS_SRC ${LZMA_SRC})
577 list(APPEND FEATURES LZMA)
578endif()
579
580if(USE_EPOXY)
581 add_definitions(-DBUILD_GL -DBUILD_GLES2)
582 list(APPEND FEATURES EPOXY)
583 include_directories(AFTER ${EPOXY_INCLUDE_DIRS})
584 set(OPENGLES2_LIBRARY ${EPOXY_LIBRARIES})
585 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libepoxy0")
586endif()
587
588if(USE_SQLITE3)
589 list(APPEND FEATURES SQLITE3)
590 include_directories(AFTER ${SQLITE3_INCLUDE_DIRS})
591 list(APPEND DEPENDENCY_LIB ${SQLITE3_LIBRARIES})
592 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libsqlite3-0")
593 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/sqlite3/no-intro.c")
594endif()
595
596set(TEST_SRC ${CORE_TEST_SRC})
597if(M_CORE_GB)
598 add_definitions(-DM_CORE_GB)
599 list(APPEND CORE_SRC
600 ${LR35902_SRC}
601 ${GB_SRC}
602 ${GB_RENDERER_SRC})
603 list(APPEND DEBUGGER_SRC
604 ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/cli-debugger.c
605 ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/debugger.c
606 ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/debugger/cli.c)
607 list(APPEND TEST_SRC
608 ${LR35902_TEST_SRC}
609 ${GB_TEST_SRC})
610endif()
611
612if(M_CORE_GBA)
613 add_definitions(-DM_CORE_GBA)
614 list(APPEND CORE_SRC
615 ${ARM_SRC}
616 ${GBA_SRC}
617 ${GBA_CHEATS_SRC}
618 ${GBA_RENDERER_SRC})
619 list(APPEND DEBUGGER_SRC
620 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c
621 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/debugger.c
622 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/memory-debugger.c
623 ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/debugger/cli.c)
624 list(APPEND TEST_SRC
625 ${ARM_TEST_SRC}
626 ${GBA_TEST_SRC})
627 if(NOT M_CORE_GB)
628 list(APPEND CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/audio.c)
629 endif()
630endif()
631
632if(USE_DEBUGGERS)
633 list(APPEND FEATURE_SRC ${DEBUGGER_SRC})
634 list(APPEND FEATURES DEBUGGERS)
635endif()
636
637foreach(FEATURE IN LISTS FEATURES)
638 list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
639endforeach()
640
641source_group("Virtual files" FILES ${CORE_VFS_SRC} ${VFS_SRC})
642source_group("Extra features" FILES ${FEATURE_SRC})
643source_group("Third-party code" FILES ${THIRD_PARTY_SRC})
644
645# Platform binaries
646if(DEFINED 3DS)
647 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/3ds ${CMAKE_CURRENT_BINARY_DIR}/3ds)
648endif()
649
650if(DEFINED WII)
651 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/wii ${CMAKE_CURRENT_BINARY_DIR}/wii)
652endif()
653
654if(DEFINED PSP2)
655 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/psp2 ${CMAKE_CURRENT_BINARY_DIR}/psp2)
656endif()
657
658# Binaries
659list(APPEND CORE_SRC
660 ${UTIL_SRC}
661 ${CORE_VFS_SRC}
662 ${OS_SRC}
663 ${THIRD_PARTY_SRC})
664list(APPEND TEST_SRC ${UTIL_TEST_SRC})
665
666set(SRC ${CORE_SRC} ${VFS_SRC})
667if(NOT MINIMAL_CORE)
668 set(ENABLE_EXTRA ON)
669 if(M_CORE_GBA)
670 list(APPEND SRC
671 ${GBA_SIO_SRC})
672 endif()
673 if(M_CORE_GB)
674 list(APPEND SRC
675 ${GB_SIO_SRC})
676 endif()
677 list(APPEND SRC
678 ${FEATURE_SRC})
679endif()
680
681if(ENABLE_EXTRA)
682 if(M_CORE_GBA)
683 list(APPEND SRC
684 ${GBA_RR_SRC}
685 ${GBA_EXTRA_SRC})
686 endif()
687 if(M_CORE_GB)
688 list(APPEND SRC
689 ${GB_EXTRA_SRC})
690 endif()
691 list(APPEND SRC
692 ${EXTRA_SRC})
693endif()
694
695if(NOT SKIP_LIBRARY)
696 if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
697 set(BUILD_SHARED ON)
698 endif()
699
700 if(BUILD_SHARED)
701 add_library(${BINARY_NAME} SHARED ${SRC} ${VFS_SRC})
702 if(BUILD_STATIC)
703 add_library(${BINARY_NAME}-static STATIC ${SRC})
704 set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
705 install(TARGETS ${BINARY_NAME}-static DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
706 add_dependencies(${BINARY_NAME}-static version-info)
707 endif()
708 else()
709 add_library(${BINARY_NAME} STATIC ${SRC})
710 endif()
711
712 add_dependencies(${BINARY_NAME} version-info)
713 set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
714
715 target_link_libraries(${BINARY_NAME} ${DEBUGGER_LIB} ${DEPENDENCY_LIB} ${OS_LIB})
716 install(TARGETS ${BINARY_NAME} LIBRARY DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME} NAMELINK_SKIP ARCHIVE DESTINATION ${LIBDIR} RUNTIME DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
717 if(UNIX AND NOT APPLE)
718 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-16.png DESTINATION share/icons/hicolor/16x16/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
719 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-24.png DESTINATION share/icons/hicolor/24x24/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
720 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-32.png DESTINATION share/icons/hicolor/32x32/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
721 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-48.png DESTINATION share/icons/hicolor/48x48/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
722 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-64.png DESTINATION share/icons/hicolor/64x64/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
723 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-96.png DESTINATION share/icons/hicolor/96x96/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
724 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-128.png DESTINATION share/icons/hicolor/128x128/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
725 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-256.png DESTINATION share/icons/hicolor/256x256/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
726 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-512.png DESTINATION share/icons/hicolor/512x512/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
727 endif()
728else()
729 set(BUILD_SHARED OFF)
730 set(BUILD_STATIC OFF)
731 find_library(${BINARY_NAME} ${BINARY_NAME})
732 if(NOT ${BINARY_NAME}_FOUND)
733 set(DISABLE_FRONTENDS ON)
734 set(BUILD_PERF OFF)
735 set(BUILD_TEST OFF)
736 set(BUILD_SUITE OFF)
737 endif()
738endif()
739
740if(BUILD_GL)
741 add_definitions(-DBUILD_GL)
742endif()
743
744if(BUILD_GLES2)
745 add_definitions(-DBUILD_GLES2)
746endif()
747
748if(DISABLE_FRONTENDS)
749 set(BUILD_SDL OFF)
750 set(BUILD_QT OFF)
751endif()
752
753if(BUILD_LIBRETRO)
754 file(GLOB RETRO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/libretro/*.c)
755 add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
756 set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5;DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=2")
757 target_link_libraries(${BINARY_NAME}_libretro ${OS_LIB})
758 install(TARGETS ${BINARY_NAME}_libretro LIBRARY DESTINATION ${LIBRETRO_LIBDIR} COMPONENT ${BINARY_NAME}_libretro NAMELINK_SKIP)
759endif()
760
761if(BUILD_OPENEMU)
762 find_library(FOUNDATION Foundation)
763 find_library(OPENEMUBASE OpenEmuBase)
764 file(GLOB OE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/*.m)
765 add_library(${BINARY_NAME}-openemu MODULE ${CORE_SRC} ${OE_SRC})
766 set_target_properties(${BINARY_NAME}-openemu PROPERTIES
767 MACOSX_BUNDLE_INFO_PLIST ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/Info.plist.in
768 BUNDLE TRUE
769 BUNDLE_EXTENSION oecoreplugin
770 OUTPUT_NAME ${PROJECT_NAME}
771 COMPILE_DEFINITIONS "DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=1")
772 target_link_libraries(${BINARY_NAME}-openemu ${OS_LIB} ${FOUNDATION} ${OPENEMUBASE})
773 install(TARGETS ${BINARY_NAME}-openemu LIBRARY DESTINATION ${OE_LIBDIR} COMPONENT ${BINARY_NAME}.oecoreplugin NAMELINK_SKIP)
774endif()
775
776if(BUILD_SDL)
777 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/sdl ${CMAKE_CURRENT_BINARY_DIR}/sdl)
778 # The SDL platform CMakeLists could decide to disable SDL, so check again before adding the define.
779 if(BUILD_SDL)
780 add_definitions(-DBUILD_SDL)
781 endif()
782endif()
783
784if(BUILD_QT)
785 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/qt ${CMAKE_CURRENT_BINARY_DIR}/qt)
786endif()
787
788if(BUILD_PERF)
789 set(PERF_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/perf-main.c)
790 if(UNIX AND NOT APPLE)
791 list(APPEND PERF_LIB rt)
792 endif()
793
794 add_executable(${BINARY_NAME}-perf ${PERF_SRC})
795 target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB} ${OS_LIB})
796 set_target_properties(${BINARY_NAME}-perf PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
797 install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
798 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
799endif()
800
801if(BUILD_TEST)
802 add_executable(${BINARY_NAME}-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/fuzz-main.c)
803 target_link_libraries(${BINARY_NAME}-fuzz ${BINARY_NAME})
804 set_target_properties(${BINARY_NAME}-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
805 add_executable(tbl-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/tbl-fuzz-main.c)
806 target_link_libraries(tbl-fuzz ${BINARY_NAME})
807 set_target_properties(tbl-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
808 install(TARGETS ${BINARY_NAME}-fuzz tbl-fuzz DESTINATION bin COMPONENT ${BINARY_NAME}-test)
809endif()
810
811if(NOT USE_CMOCKA)
812 set(BUILD_SUITE OFF)
813endif()
814if(BUILD_SUITE)
815 enable_testing()
816 include_directories(AFTER ${CMOCKA_INCLUDE_DIRS})
817 link_directories(${CMOCKA_LIBRARY_DIRS})
818
819 add_executable(${BINARY_NAME}-suite ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/suite-main.c ${TEST_SRC})
820 target_link_libraries(${BINARY_NAME}-suite ${BINARY_NAME} ${PLATFORM_LIBRARY} cmocka)
821 set_target_properties(${BINARY_NAME}-suite PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
822 add_test(${BINARY_NAME}-suite ${BINARY_NAME}-suite)
823endif()
824
825if(BUILD_PYTHON)
826 enable_testing()
827 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/python ${CMAKE_CURRENT_BINARY_DIR}/python)
828endif()
829
830if(BUILD_EXAMPLE)
831 add_executable(${BINARY_NAME}-example-server ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/server.c)
832 target_link_libraries(${BINARY_NAME}-example-server ${BINARY_NAME})
833 set_target_properties(${BINARY_NAME}-example-server PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
834
835 if(BUILD_SDL)
836 add_executable(${BINARY_NAME}-example-client ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/client.c)
837 target_link_libraries(${BINARY_NAME}-example-client ${BINARY_NAME} ${SDL_LIBRARY} ${SDLMAIN_LIBRARY} ${OPENGL_LIBRARY} ${OPENGLES2_LIBRARY})
838 set_target_properties(${BINARY_NAME}-example-client PROPERTIES
839 COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}"
840 INCLUDE_DIRECTORIES "${SDL_INCLUDE_DIR};${CMAKE_CURRENT_SOURCE_DIR}/src;${CMAKE_CURRENT_SOURCE_DIR}/include")
841 endif()
842endif()
843
844# Packaging
845set(CPACK_PACKAGE_VERSION ${VERSION_STRING})
846set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
847set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
848set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
849set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
850set(CPACK_RESOURCE_FILE_README ${CMAKE_CURRENT_SOURCE_DIR}/README.md)
851
852set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
853set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
854set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
855set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README.md")
856set(CPACK_DEBIAN_PACKAGE_SECTION "games")
857
858SET(CPACK_DEB_COMPONENT_INSTALL ON)
859
860set(CPACK_STRIP_FILES ${BINARY_NAME})
861
862install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/README.md ${CMAKE_CURRENT_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
863
864include(CPack)
865
866# Summaries
867set(SUMMARY_GL_LIST)
868if(USE_EPOXY)
869 set(SUMMARY_GL_LIST "libepoxy")
870else()
871 if(BUILD_GL)
872 list(APPEND SUMMARY_GL_LIST "OpenGL")
873 endif()
874 if(BUILD_GLES2)
875 list(APPEND SUMMARY_GL_LIST "OpenGL|ES 2")
876 endif()
877endif()
878if(NOT SUMMARY_GL_LIST)
879 set(SUMMARY_GL OFF)
880else()
881 string(REPLACE ";" ", " SUMMARY_GL "${SUMMARY_GL_LIST}")
882endif()
883if(USE_LIBZIP)
884 set(SUMMARY_ZIP libzip)
885elseif(USE_MINIZIP)
886 set(SUMMARY_ZIP "minizip (external)")
887elseif(USE_ZLIB)
888 set(SUMMARY_ZIP "minizip (included)")
889else()
890 set(SUMMARY_ZIP OFF)
891endif()
892
893if(NOT QUIET)
894 message(STATUS "Platforms:")
895 message(STATUS " Game Boy Advance: ${M_CORE_GBA}")
896 message(STATUS " Game Boy: ${M_CORE_GB}")
897 message(STATUS "Features:")
898 message(STATUS " Debuggers: ${USE_DEBUGGERS}")
899 message(STATUS " CLI debugger: ${USE_EDITLINE}")
900 message(STATUS " GDB stub: ${USE_GDB_STUB}")
901 message(STATUS " Video recording: ${USE_FFMPEG}")
902 message(STATUS " GIF recording: ${USE_MAGICK}")
903 message(STATUS " Screenshot/advanced savestate support: ${USE_PNG}")
904 message(STATUS " ZIP support: ${SUMMARY_ZIP}")
905 message(STATUS " 7-Zip support: ${USE_LZMA}")
906 message(STATUS " SQLite3 game database: ${USE_SQLITE3}")
907 message(STATUS " OpenGL support: ${SUMMARY_GL}")
908 message(STATUS "Frontends:")
909 message(STATUS " Qt: ${BUILD_QT}")
910 message(STATUS " SDL (${SDL_VERSION}): ${BUILD_SDL}")
911 message(STATUS " Profiling: ${BUILD_PERF}")
912 message(STATUS " Test harness: ${BUILD_TEST}")
913 message(STATUS " Test suite: ${BUILD_SUITE}")
914 message(STATUS " Python bindings: ${BUILD_PYTHON}")
915 message(STATUS " Examples: ${BUILD_EXAMPLE}")
916 message(STATUS "Cores:")
917 message(STATUS " Libretro core: ${BUILD_LIBRETRO}")
918 if(APPLE)
919 message(STATUS " OpenEmu core: ${BUILD_OPENEMU}")
920 endif()
921 message(STATUS "Libraries:")
922 message(STATUS " Static: ${BUILD_STATIC}")
923 message(STATUS " Shared: ${BUILD_SHARED}")
924endif()