1cmake_minimum_required(VERSION 2.8.11)
  2project(mGBA)
  3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
  4if(NOT MSVC)
  5	set(GCC_STD "c99")
  6        if(CMAKE_C_COMPILER_ID STREQUAL "GNU" AND CMAKE_COMPILER_VERSION VERSION_LESS "4.3")
  7		set(GCC_STD "gnu99")
  8	endif()
  9	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wno-missing-field-initializers -std=${GCC_STD}")
 10else()
 11	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_CRT_SECURE_NO_WARNINGS /wd4003 /wd4244 /wd4146")
 12endif()
 13set(USE_DEBUGGERS ON CACHE BOOL "Whether or not to enable the debugging infrastructure")
 14set(USE_EDITLINE ON CACHE BOOL "Whether or not to enable the CLI-mode debugger")
 15set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
 16set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
 17set(USE_ZLIB ON CACHE BOOL "Whether or not to enable zlib support")
 18set(USE_MINIZIP ON CACHE BOOL "Whether or not to enable external minizip support")
 19set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
 20set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable LIBZIP support")
 21set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
 22set(USE_SQLITE3 ON CACHE BOOL "Whether or not to enable SQLite3 support")
 23set(M_CORE_GBA ON CACHE BOOL "Build Game Boy Advance core")
 24set(M_CORE_GB ON CACHE BOOL "Build Game Boy core")
 25set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
 26set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
 27set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
 28set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
 29if(APPLE)
 30	set(BUILD_OPENEMU OFF CACHE BOOL "Build OpenEmu core")
 31endif()
 32set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
 33set(BUILD_TEST OFF CACHE BOOL "Build testing harness")
 34set(BUILD_SUITE OFF CACHE BOOL "Build test suite")
 35set(BUILD_EXAMPLE OFF CACHE BOOL "Build example frontends")
 36set(BUILD_PYTHON OFF CACHE BOOL "Build Python bindings")
 37set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
 38set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
 39set(SKIP_LIBRARY OFF CACHE BOOL "Skip building the library (useful for only building libretro or OpenEmu cores)")
 40set(BUILD_GL ON CACHE STRING "Build with OpenGL")
 41set(BUILD_GLES2 OFF CACHE STRING "Build with OpenGL|ES 2")
 42set(USE_EPOXY ON CACHE STRING "Build with libepoxy")
 43set(DISABLE_DEPS OFF CACHE BOOL "Build without dependencies")
 44if(WIN32)
 45	set(WIN32_UNIX_PATHS OFF CACHE BOOL "Use Unix-like paths")
 46	mark_as_advanced(WIN32_UNIX_PATHS)
 47endif()
 48file(GLOB ARM_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/*.c)
 49file(GLOB ARM_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/test/*.c)
 50file(GLOB LR35902_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/*.c)
 51file(GLOB LR35902_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/test/*.c)
 52file(GLOB GBA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/*.c)
 53file(GLOB GBA_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/test/*.c)
 54file(GLOB GB_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/*.c)
 55file(GLOB GB_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/test/*.c)
 56file(GLOB GBA_CHEATS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/cheats/*.c)
 57file(GLOB GBA_RR_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/rr/*.c)
 58file(GLOB CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/*.c)
 59file(GLOB CORE_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/test/*.c)
 60file(GLOB UTIL_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/*.[cSs])
 61file(GLOB UTIL_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/test/*.c)
 62file(GLOB GUI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/gui/*.c ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/gui/*.c)
 63file(GLOB GBA_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/renderers/*.c)
 64file(GLOB GBA_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/sio/lockstep.c)
 65file(GLOB GBA_EXTRA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/extra/*.c)
 66file(GLOB GB_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/sio/lockstep.c)
 67file(GLOB GB_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/renderers/*.c)
 68file(GLOB GB_EXTRA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/extra/*.c)
 69file(GLOB THIRD_PARTY_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/inih/*.c)
 70file(GLOB EXTRA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/*.c)
 71set(CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-mem.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fifo.c)
 72set(VFS_SRC)
 73source_group("ARM core" FILES ${ARM_SRC})
 74source_group("LR35902 core" FILES ${LR35902_SRC})
 75source_group("GBA board" FILES ${GBA_SRC} ${GBA_RENDERER_SRC} ${GBA_SIO_SRC})
 76source_group("GBA extra" FILES ${GBA_CHEATS_SRC} ${GBA_RR_SRC})
 77source_group("GB board" FILES ${GB_SRC} ${GB_SIO_SRC})
 78source_group("Utilities" FILES ${UTIL_SRC})
 79include_directories(BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/include ${CMAKE_CURRENT_SOURCE_DIR}/src)
 80
 81if(NOT CMAKE_BUILD_TYPE)
 82	set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
 83endif()
 84
 85if(NOT WIN32 OR WIN32_UNIX_PATHS)
 86	include(GNUInstallDirs)
 87else()
 88	set(CMAKE_INSTALL_LIBDIR ".")
 89	set(CMAKE_INSTALL_BINDIR ".")
 90	set(CMAKE_INSTALL_DATADIR ".")
 91	set(CMAKE_INSTALL_DOCDIR ".")
 92	set(CMAKE_INSTALL_INCLUDEDIR "include")
 93endif()
 94
 95set(LIBDIR "${CMAKE_INSTALL_LIBDIR}" CACHE PATH "Installed library directory")
 96mark_as_advanced(LIBDIR)
 97
 98if (BUILD_LIBRETRO)
 99	set(LIBRETRO_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (Libretro)")
100	mark_as_advanced(LIBRETRO_LIBDIR)
101endif()
102
103if (BUILD_OPENEMU)
104	set(OE_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (OpenEmu)")
105	mark_as_advanced(OE_LIBDIR)
106endif()
107
108
109set(CMAKE_INSTALL_RPATH "${LIBDIR}")
110
111if (NOT DEFINED MANDIR)
112	set(MANDIR ${CMAKE_INSTALL_MANDIR})
113endif()
114
115# Function definitions
116include(FindPkgConfig)
117function(find_feature FEATURE_NAME FEATURE_REQUIRES)
118	if (NOT ${FEATURE_NAME})
119		return()
120	endif()
121	if (DISABLE_DEPS)
122		set(${FEATURE_NAME} OFF PARENT_SCOPE)
123		return()
124	endif()
125	foreach(REQUIRE ${FEATURE_REQUIRES})
126		if(NOT ${REQUIRE}_FOUND)
127			find_package(${REQUIRE} QUIET)
128			if(NOT ${REQUIRE}_FOUND)
129				pkg_search_module(${REQUIRE} ${REQUIRE})
130				if (NOT ${REQUIRE}_FOUND)
131					message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
132					set(${FEATURE_NAME} OFF PARENT_SCOPE)
133					return()
134				endif()
135			endif()
136		endif()
137		string(TOUPPER ${REQUIRE} UREQUIRE)
138		set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
139		set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
140		set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
141		set(${UREQUIRE}_VERSION_STRING ${${REQUIRE}_VERSION_STRING} PARENT_SCOPE)
142		if (APPLE)
143			set(IS_FRAMEWORK OFF)
144			set(LIBS)
145			foreach(LIB IN LISTS ${REQUIRE}_LIBRARIES)
146				if(LIB STREQUAL "-framework")
147					set(IS_FRAMEWORK ON)
148				elseif(IS_FRAMEWORK)
149					list(APPEND LIBS "-framework ${LIB}")
150					set(IS_FRAMEWORK OFF)
151				else()
152					list(APPEND LIBS ${LIB})
153				endif()
154			endforeach()
155			set(${UREQUIRE}_LIBRARIES ${LIBS} PARENT_SCOPE)
156		else()
157			set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
158		endif()
159		set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
160		set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
161	endforeach()
162endfunction()
163
164# Version information
165add_custom_target(version-info ALL
166	COMMAND ${CMAKE_COMMAND}
167	-DBINARY_NAME=${BINARY_NAME}
168	-DCONFIG_FILE=${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in
169	-DOUT_FILE=${CMAKE_CURRENT_BINARY_DIR}/version.c
170	-P ${CMAKE_CURRENT_SOURCE_DIR}/version.cmake
171	WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
172
173include(${CMAKE_CURRENT_SOURCE_DIR}/version.cmake)
174configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in ${CMAKE_CURRENT_BINARY_DIR}/version.c)
175
176list(APPEND UTIL_SRC ${CMAKE_CURRENT_BINARY_DIR}/version.c)
177source_group("Generated sources" FILES ${CMAKE_CURRENT_BINARY_DIR}/version.c)
178
179# Advanced settings
180if(NOT DEFINED 3DS)
181	# LTO appears to make 3DS binary slower
182	set(DEFAULT_LTO ON)
183else()
184	set(DEFAULT_LTO OFF)
185endif()
186
187set(BUILD_LTO ${DEFAULT_LTO} CACHE BOOL "Build with link-time optimization")
188set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
189set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
190set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
191mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
192set(PGO_PRE_FLAGS "-fprofile-generate=${PGO_DIR} -fprofile-arcs")
193set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
194
195if(BUILD_PGO AND NOT PGO_STAGE_2)
196	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
197	set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
198	set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
199elseif(BUILD_PGO AND PGO_STAGE_2)
200	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
201	set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
202	set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
203endif()
204
205# Platform support
206if(WIN32)
207	set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
208	add_definitions(-D_WIN32_WINNT=0x0600)
209	list(APPEND OS_LIB ws2_32 shlwapi)
210	list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/vfs-w32.c)
211	file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/*.c)
212	source_group("Windows-specific code" FILES ${OS_SRC})
213	if(MSVC)
214		add_definitions(-DNOMINMAX -DWIN32_LEAN_AND_MEAN)
215		set(CMAKE_WINDOWS_EXPORT_ALL_SYMBOLS TRUE)
216	endif()
217elseif(UNIX)
218	set(USE_PTHREADS ON)
219	add_definitions(-DUSE_PTHREADS)
220
221	if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
222		add_definitions(-D_GNU_SOURCE)
223	endif()
224	if(NOT APPLE AND NOT HAIKU)
225		set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
226		set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -pthread")
227	endif()
228
229	list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
230	file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/posix/*.c)
231	source_group("POSIX-specific code" FILES ${OS_SRC})
232endif()
233
234if(APPLE)
235	add_definitions(-D_DARWIN_C_SOURCE)
236	if(CMAKE_SYSTEM_VERSION VERSION_GREATER "10.5.8")
237		set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
238	endif()
239endif()
240
241if(NOT HAIKU AND NOT MSVC AND NOT PSP2)
242	set(M_LIBRARY m)
243endif()
244list(APPEND OS_LIB ${M_LIBRARY})
245
246if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
247	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
248	set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
249endif()
250
251if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
252	if(NOT BUILD_EGL)
253		add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
254	endif()
255endif()
256
257if(BUILD_RASPI)
258	set(BUILD_GL OFF CACHE BOOL "OpenGL not supported" FORCE)
259endif()
260
261if(BUILD_PANDORA)
262	add_definitions(-DBUILD_PANDORA)
263endif()
264
265if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
266	enable_language(ASM)
267endif()
268
269if(PSP2 OR WII)
270	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-format")
271endif()
272
273if(DEFINED 3DS OR DEFINED PSP2 OR DEFINED WII)
274	set(USE_DEBUGGERS OFF)
275	set(USE_SQLITE3 OFF)
276endif()
277
278if(NOT M_CORE_GBA)
279	set(USE_GDB_STUB OFF)
280endif()
281
282if(NOT USE_DEBUGGERS)
283	set(USE_EDITLINE OFF)
284	set(USE_GDB_STUB OFF)
285endif()
286
287if(WII)
288	add_definitions(-U__STRICT_ANSI__)
289endif()
290
291if(DEFINED 3DS)
292	add_definitions(-D_GNU_SOURCE)
293endif()
294
295include(CheckFunctionExists)
296check_function_exists(strdup HAVE_STRDUP)
297check_function_exists(strndup HAVE_STRNDUP)
298if(NOT DEFINED PSP2)
299	check_function_exists(localtime_r HAVE_LOCALTIME_R)
300endif()
301if(NOT CMAKE_SYSTEM_NAME STREQUAL "Generic")
302	check_function_exists(snprintf_l HAVE_SNPRINTF_L)
303	if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
304		# The strtof_l on Linux not actually exposed nor actually strtof_l
305		set(HAVE_STRTOF_L OFF)
306	else()
307		check_function_exists(strtof_l HAVE_STRTOF_L)
308	endif()
309	check_function_exists(newlocale HAVE_NEWLOCALE)
310	check_function_exists(freelocale HAVE_FREELOCALE)
311	check_function_exists(uselocale HAVE_USELOCALE)
312	check_function_exists(setlocale HAVE_SETLOCALE)
313else()
314	if(DEFINED 3DS OR DEFINED WII)
315		set(CMAKE_REQUIRED_FLAGS -Wl,--require-defined,snprintf_l)
316		check_function_exists(snprintf_l HAVE_SNPRINTF_L)
317		set(CMAKE_REQUIRED_FLAGS -Wl,--require-defined,strtof_l)
318		check_function_exists(strtof_l HAVE_STRTOF_L)
319		set(CMAKE_REQUIRED_FLAGS -Wl,--require-defined,newlocale)
320		check_function_exists(newlocale HAVE_NEWLOCALE)
321		set(CMAKE_REQUIRED_FLAGS -Wl,--require-defined,freelocale)
322		check_function_exists(freelocale HAVE_FREELOCALE)
323		set(CMAKE_REQUIRED_FLAGS -Wl,--require-defined,uselocale)
324		check_function_exists(uselocale HAVE_USELOCALE)
325		set(CMAKE_REQUIRED_FLAGS -Wl,--require-defined,setlocale)
326		check_function_exists(setlocale HAVE_SETLOCALE)
327		unset(CMAKE_REQUIRED_FLAGS)
328	endif()
329	if(NOT DEFINED 3DS AND NOT DEFINED PSP2 AND NOT DEFINED WII)
330		set(DISABLE_DEPS ON CACHE BOOL "This platform cannot build with dependencies" FORCE)
331	endif()
332	set(DISABLE_FRONTENDS ON)
333	set(MINIMAL_CORE ON)
334	set(ENABLE_EXTRA ON)
335endif()
336
337check_function_exists(chmod HAVE_CHMOD)
338check_function_exists(umask HAVE_UMASK)
339
340set(FUNCTION_DEFINES)
341
342if(HAVE_STRDUP)
343	list(APPEND FUNCTION_DEFINES HAVE_STRDUP)
344endif()
345
346if(HAVE_STRNDUP)
347	list(APPEND FUNCTION_DEFINES HAVE_STRNDUP)
348endif()
349
350if(HAVE_LOCALTIME_R)
351	list(APPEND FUNCTION_DEFINES HAVE_LOCALTIME_R)
352endif()
353
354if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE OR APPLE)
355	list(APPEND FUNCTION_DEFINES HAVE_LOCALE)
356	if (HAVE_STRTOF_L)
357		list(APPEND FUNCTION_DEFINES HAVE_STRTOF_L)
358	endif()
359	if (HAVE_SNPRINTF_L)
360		list(APPEND FUNCTION_DEFINES HAVE_SNPRINTF_L)
361	endif()
362endif()
363
364if(HAVE_SETLOCALE)
365	list(APPEND FUNCTION_DEFINES HAVE_SETLOCALE)
366endif()
367
368if(HAVE_CHMOD)
369	list(APPEND FUNCTION_DEFINES HAVE_CHMOD)
370endif()
371
372if(HAVE_UMASK)
373	list(APPEND FUNCTION_DEFINES HAVE_UMASK)
374endif()
375
376# Feature dependencies
377set(FEATURE_DEFINES)
378set(FEATURE_FLAGS)
379set(FEATURES)
380if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
381	set(LIBEDIT_LIBRARIES -ledit)
382	if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
383		list(APPEND LIBEDIT_LIBRARIES -ltermcap)
384	endif()
385else()
386	find_feature(USE_EDITLINE "libedit")
387endif()
388if(BUILD_GL)
389	find_package(OpenGL QUIET)
390	if(NOT OPENGL_FOUND)
391		set(BUILD_GL OFF CACHE BOOL "OpenGL not found" FORCE)
392	endif()
393endif()
394if(NOT BUILD_GL)
395	set(OPENGLE_LIBRARY "" CACHE PATH "" FORCE)
396endif()
397if(BUILD_GLES2 AND NOT BUILD_RASPI)
398	find_path(OPENGLES2_INCLUDE_DIR NAMES GLES2/gl2.h)
399	find_library(OPENGLES2_LIBRARY NAMES GLESv2 GLESv2_CM)
400	if(NOT OPENGLES2_INCLUDE_DIR OR NOT OPENGLES2_LIBRARY)
401		set(BUILD_GLES2 OFF CACHE BOOL "OpenGL|ES 2 not found" FORCE)
402	endif()
403endif()
404if(NOT BUILD_GLES2)
405	set(OPENGLES2_LIBRARY "" CACHE PATH "" FORCE)
406endif()
407set(WANT_ZLIB ${USE_ZLIB})
408set(WANT_PNG ${USE_PNG})
409set(WANT_LIBZIP ${USE_LIBZIP})
410set(WANT_SQLITE3 ${USE_SQLITE3})
411set(USE_CMOCKA ${BUILD_SUITE})
412
413find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
414find_feature(USE_ZLIB "ZLIB")
415find_feature(USE_MINIZIP "minizip")
416find_feature(USE_PNG "PNG")
417find_feature(USE_LIBZIP "libzip")
418find_feature(USE_MAGICK "MagickWand")
419find_feature(USE_EPOXY "epoxy")
420find_feature(USE_CMOCKA "cmocka")
421find_feature(USE_SQLITE3 "sqlite3")
422
423# Features
424set(DEBUGGER_SRC
425	${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/debugger.c
426	${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/parser.c
427	${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/symbols.c
428	${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/cli-debugger.c)
429
430set(FEATURE_SRC)
431set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
432
433if(DISABLE_DEPS)
434	set(USE_GDB_STUB OFF)
435endif()
436
437if(USE_EDITLINE)
438	list(APPEND FEATURES EDITLINE)
439	include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
440	link_directories(${LIBEDIT_LIBRARY_DIRS})
441	set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
442	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
443	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/editline/cli-el-backend.c")
444else()
445	set(DEBUGGER_LIB "")
446endif()
447
448if(USE_GDB_STUB)
449	list(APPEND FEATURES GDB_STUB)
450	list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/gdb-stub.c)
451endif()
452source_group("Debugger" FILES ${DEBUGGER_SRC})
453
454if(USE_FFMPEG)
455	list(APPEND FEATURES FFMPEG)
456	pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
457	if(NOT LIBSWRESAMPLE_FOUND)
458		list(APPEND FEATURES LIBAV)
459	endif()
460	include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
461	link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
462	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/ffmpeg/ffmpeg-encoder.c")
463	string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
464	string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
465	string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
466	string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
467	string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
468	list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
469	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR}|libavcodec-extra-${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
470	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavformat${LIBAVFORMAT_VERSION_MAJOR}|libavformat-ffmpeg${LIBAVFORMAT_VERSION_MAJOR}")
471	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavresample${LIBAVRESAMPLE_VERSION_MAJOR}|libavresample-ffmpeg${LIBAVRESAMPLE_VERSION_MAJOR}")
472	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavutil${LIBAVUTIL_VERSION_MAJOR}|libavutil-ffmpeg${LIBAVUTIL_VERSION_MAJOR}")
473	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libswscale${LIBSWSCALE_VERSION_MAJOR}|libswscale-ffmpeg${LIBSWSCALE_VERSION_MAJOR}")
474	set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
475	if(APPLE)
476		set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
477		set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
478	endif()
479endif()
480
481list(APPEND THIRD_PARTY_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
482
483if(USE_MAGICK)
484	list(APPEND FEATURES MAGICK)
485	include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
486	link_directories(${MAGICKWAND_LIBRARY_DIRS})
487	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/imagemagick/imagemagick-gif-encoder.c")
488	list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
489	string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
490	string(REGEX MATCH "^[0-9]+" MAGICKWAND_VERSION_MAJOR ${MagickWand_VERSION})
491	if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
492		set(MAGICKWAND_DEB_VERSION "5")
493	elseif(${MagickWand_VERSION} EQUAL "6.9.7")
494		set(MAGICKWAND_DEB_VERSION "-6.q16-3")
495	else()
496		set(MAGICKWAND_DEB_VERSION "-6.q16-2")
497	endif()
498	list(APPEND FEATURE_DEFINES MAGICKWAND_VERSION_MAJOR=${MAGICKWAND_VERSION_MAJOR})
499	list(APPEND FEATURE_FLAGS ${MAGICKWAND_CFLAGS_OTHER})
500
501	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
502endif()
503
504if(WANT_ZLIB AND NOT USE_ZLIB)
505	set(SKIP_INSTALL_ALL ON)
506	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib zlib)
507	set_property(TARGET zlibstatic PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/zlib;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib)
508	set_property(TARGET zlib PROPERTY EXCLUDE_FROM_ALL ON)
509	set_property(TARGET example PROPERTY EXCLUDE_FROM_ALL ON)
510	set_property(TARGET minigzip PROPERTY EXCLUDE_FROM_ALL ON)
511	set(ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
512	set(ZLIB_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
513	set(ZLIB_LIBRARY zlibstatic)
514	list(APPEND DEPENDENCY_LIB zlibstatic)
515	set(USE_ZLIB ON)
516endif()
517
518if(USE_ZLIB)
519	list(APPEND FEATURES ZLIB)
520	include_directories(AFTER ${ZLIB_INCLUDE_DIRS})
521	list(APPEND DEPENDENCY_LIB ${ZLIB_LIBRARIES})
522	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},zlib1g")
523endif()
524
525if(WANT_PNG AND USE_ZLIB AND NOT USE_PNG)
526	set(PNG_STATIC ON CACHE BOOL "" FORCE)
527	set(PNG_SHARED OFF CACHE BOOL "" FORCE)
528	set(PNG_TESTS OFF CACHE BOOL "" FORCE)
529	set(SKIP_INSTALL_ALL ON)
530	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng libpng)
531	set_property(TARGET png16_static PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/libpng;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng;${ZLIB_INCLUDE_DIRS})
532	set(PNG_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng ${CMAKE_CURRENT_BINARY_DIR}/libpng)
533	list(APPEND DEPENDENCY_LIB png16_static)
534	set(USE_PNG ON)
535endif()
536
537if(USE_PNG)
538	list(APPEND FEATURES PNG)
539	include_directories(AFTER ${PNG_INCLUDE_DIRS})
540	list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
541	if(PNG_VERSION_STRING)
542		string(REGEX MATCH "^[0-9]+\\.[0-9]+" PNG_VERSION_PARTIAL ${PNG_VERSION_STRING})
543		if(${PNG_VERSION_PARTIAL} STREQUAL "1.6")
544			set(PNG_DEB_VERSION "16-16")
545		else()
546			set(PNG_DEB_VERSION "12-0")
547		endif()
548		set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng${PNG_DEB_VERSION}")
549	endif()
550endif()
551
552if(WANT_SQLITE3 AND NOT USE_SQLITE3)
553	list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/sqlite3.c)
554	include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/)
555	set(USE_SQLITE3 ON)
556endif()
557
558if(USE_LIBZIP)
559	include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
560	link_directories(${LIBZIP_LIBRARY_DIRS})
561	list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
562	list(APPEND FEATURES LIBZIP)
563	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
564	string(REGEX MATCH "^[0-9]+" LIBZIP_VERSION_MAJOR ${libzip_VERSION})
565	if (LIBZIP_VERSION_MAJOR LESS 1)
566		set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
567	elseif(LIBZIP_VERSION_MAJOR EQUAL 1)
568		set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip4")
569	else()
570		message(AUTHOR_WARNING Unknown version of libzip detected: ${libzip_VERSION})
571	endif()
572elseif(USE_MINIZIP)
573	include_directories(AFTER ${MINIZIP_INCLUDE_DIRS})
574	link_directories(${MINIZIP_LIBRARY_DIRS})
575	list(APPEND DEPENDENCY_LIB ${MINIZIP_LIBRARIES})
576	list(APPEND FEATURES MINIZIP)
577	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
578	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libminizip1")
579elseif(USE_ZLIB)
580	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c
581		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
582		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c)
583	if(NOT MSVC)
584		set_source_files_properties(
585			${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
586			${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c
587			PROPERTIES COMPILE_FLAGS "-Wno-unused-parameter -Wno-implicit-function-declaration")
588	endif()
589endif()
590
591if (USE_LZMA)
592	include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma)
593	add_definitions(-D_7ZIP_PPMD_SUPPPORT)
594	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-lzma.c)
595	set(LZMA_SRC
596		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
597		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
598		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
599		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
600		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
601		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
602		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zDec.c
603		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
604		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Delta.c
605		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
606		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
607		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra.c
608		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra86.c
609		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/BraIA64.c
610		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
611		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
612		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
613		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zFile.c
614		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
615	list(APPEND VFS_SRC ${LZMA_SRC})
616	list(APPEND FEATURES LZMA)
617endif()
618
619if(USE_EPOXY)
620	add_definitions(-DBUILD_GL -DBUILD_GLES2)
621	list(APPEND FEATURES EPOXY)
622	include_directories(AFTER ${EPOXY_INCLUDE_DIRS})
623	set(OPENGLES2_LIBRARY ${EPOXY_LIBRARIES})
624	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libepoxy0")
625endif()
626
627if(USE_SQLITE3)
628	list(APPEND FEATURES SQLITE3)
629	include_directories(AFTER ${SQLITE3_INCLUDE_DIRS})
630	list(APPEND DEPENDENCY_LIB ${SQLITE3_LIBRARIES})
631	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libsqlite3-0")
632	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/sqlite3/no-intro.c")
633endif()
634
635set(TEST_SRC ${CORE_TEST_SRC})
636if(M_CORE_GB)
637	add_definitions(-DM_CORE_GB)
638	list(APPEND CORE_SRC
639		${LR35902_SRC}
640		${GB_SRC}
641		${GB_RENDERER_SRC})
642	list(APPEND DEBUGGER_SRC
643		${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/cli-debugger.c
644		${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/debugger.c
645		${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/memory-debugger.c
646		${CMAKE_CURRENT_SOURCE_DIR}/src/gb/debugger/cli.c
647		${CMAKE_CURRENT_SOURCE_DIR}/src/gb/debugger/symbols.c)
648	list(APPEND TEST_SRC
649		${LR35902_TEST_SRC}
650		${GB_TEST_SRC})
651endif()
652
653if(M_CORE_GBA)
654	add_definitions(-DM_CORE_GBA)
655	list(APPEND CORE_SRC
656		${ARM_SRC}
657		${GBA_SRC}
658		${GBA_CHEATS_SRC}
659		${GBA_RENDERER_SRC})
660	list(APPEND DEBUGGER_SRC
661		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c
662		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/debugger.c
663		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/memory-debugger.c
664		${CMAKE_CURRENT_SOURCE_DIR}/src/gba/debugger/cli.c)
665	list(APPEND TEST_SRC
666		${ARM_TEST_SRC}
667		${GBA_TEST_SRC})
668	if(NOT M_CORE_GB)
669		list(APPEND CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/audio.c)
670	endif()
671endif()
672
673if(USE_DEBUGGERS)
674	list(APPEND FEATURE_SRC ${DEBUGGER_SRC})
675	list(APPEND FEATURES DEBUGGERS)
676endif()
677
678foreach(FEATURE IN LISTS FEATURES)
679	list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
680endforeach()
681
682source_group("Virtual files" FILES ${CORE_VFS_SRC} ${VFS_SRC})
683source_group("Extra features" FILES ${FEATURE_SRC})
684source_group("Third-party code" FILES ${THIRD_PARTY_SRC})
685
686# Platform binaries
687if(DEFINED 3DS)
688	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/3ds ${CMAKE_CURRENT_BINARY_DIR}/3ds)
689endif()
690
691if(DEFINED WII)
692	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/wii ${CMAKE_CURRENT_BINARY_DIR}/wii)
693endif()
694
695if(DEFINED PSP2)
696	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/psp2 ${CMAKE_CURRENT_BINARY_DIR}/psp2)
697endif()
698
699# Binaries
700list(APPEND CORE_SRC
701	${UTIL_SRC}
702	${CORE_VFS_SRC}
703	${OS_SRC}
704	${THIRD_PARTY_SRC})
705list(APPEND TEST_SRC ${UTIL_TEST_SRC})
706
707set(SRC ${CORE_SRC} ${VFS_SRC})
708if(NOT MINIMAL_CORE)
709	set(ENABLE_EXTRA ON)
710	if(M_CORE_GBA)
711		list(APPEND SRC
712			${GBA_SIO_SRC})
713	endif()
714	if(M_CORE_GB)
715		list(APPEND SRC
716			${GB_SIO_SRC})
717	endif()
718	list(APPEND SRC
719		${FEATURE_SRC})
720endif()
721
722if(ENABLE_EXTRA)
723	if(M_CORE_GBA)
724		list(APPEND SRC
725			${GBA_RR_SRC}
726			${GBA_EXTRA_SRC})
727	endif()
728	if(M_CORE_GB)
729		list(APPEND SRC
730			${GB_EXTRA_SRC})
731	endif()
732	list(APPEND SRC
733		${EXTRA_SRC})
734endif()
735
736if(NOT SKIP_LIBRARY)
737	if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
738		set(BUILD_SHARED ON)
739	endif()
740
741	if(BUILD_SHARED)
742		add_library(${BINARY_NAME} SHARED ${SRC} ${VFS_SRC})
743		if(BUILD_STATIC)
744			add_library(${BINARY_NAME}-static STATIC ${SRC})
745			set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}" COMPILE_OPTIONS "${FEATURE_FLAGS}")
746			install(TARGETS ${BINARY_NAME}-static DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
747			add_dependencies(${BINARY_NAME}-static version-info)
748		endif()
749	else()
750		add_library(${BINARY_NAME} STATIC ${SRC})
751	endif()
752
753	add_dependencies(${BINARY_NAME} version-info)
754	set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}" COMPILE_OPTIONS "${FEATURE_FLAGS}")
755
756	target_link_libraries(${BINARY_NAME} ${DEBUGGER_LIB} ${DEPENDENCY_LIB} ${OS_LIB})
757	install(TARGETS ${BINARY_NAME} LIBRARY DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME} NAMELINK_SKIP ARCHIVE DESTINATION ${LIBDIR} RUNTIME DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
758	if(UNIX AND NOT APPLE AND NOT HAIKU)
759		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-16.png DESTINATION share/icons/hicolor/16x16/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
760		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-24.png DESTINATION share/icons/hicolor/24x24/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
761		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-32.png DESTINATION share/icons/hicolor/32x32/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
762		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-48.png DESTINATION share/icons/hicolor/48x48/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
763		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-64.png DESTINATION share/icons/hicolor/64x64/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
764		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-96.png DESTINATION share/icons/hicolor/96x96/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
765		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-128.png DESTINATION share/icons/hicolor/128x128/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
766		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-256.png DESTINATION share/icons/hicolor/256x256/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
767		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-512.png DESTINATION share/icons/hicolor/512x512/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
768	endif()
769else()
770	set(BUILD_SHARED OFF)
771	set(BUILD_STATIC OFF)
772	find_library(${BINARY_NAME} ${BINARY_NAME})
773	if(NOT ${BINARY_NAME}_FOUND)
774		set(DISABLE_FRONTENDS ON)
775		set(BUILD_PERF OFF)
776		set(BUILD_TEST OFF)
777		set(BUILD_SUITE OFF)
778	endif()
779endif()
780
781if(BUILD_GL)
782	add_definitions(-DBUILD_GL)
783endif()
784
785if(BUILD_GLES2)
786	add_definitions(-DBUILD_GLES2)
787endif()
788
789if(DISABLE_FRONTENDS)
790	set(BUILD_SDL OFF)
791	set(BUILD_QT OFF)
792endif()
793
794if(BUILD_LIBRETRO)
795	file(GLOB RETRO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/libretro/*.c)
796	add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
797	set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5;DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=2")
798	target_link_libraries(${BINARY_NAME}_libretro ${OS_LIB})
799	install(TARGETS ${BINARY_NAME}_libretro LIBRARY DESTINATION ${LIBRETRO_LIBDIR} COMPONENT ${BINARY_NAME}_libretro NAMELINK_SKIP)
800endif()
801
802if(BUILD_OPENEMU)
803	find_library(FOUNDATION Foundation)
804	find_library(OPENEMUBASE OpenEmuBase)
805	file(GLOB OE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/*.m)
806	add_library(${BINARY_NAME}-openemu MODULE ${CORE_SRC} ${OE_SRC})
807	set_target_properties(${BINARY_NAME}-openemu PROPERTIES
808		MACOSX_BUNDLE_INFO_PLIST ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/Info.plist.in
809		BUNDLE TRUE
810		BUNDLE_EXTENSION oecoreplugin
811		OUTPUT_NAME ${PROJECT_NAME}
812		COMPILE_DEFINITIONS "DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=1")
813	target_link_libraries(${BINARY_NAME}-openemu ${OS_LIB} ${FOUNDATION} ${OPENEMUBASE})
814	install(TARGETS ${BINARY_NAME}-openemu LIBRARY DESTINATION ${OE_LIBDIR} COMPONENT ${BINARY_NAME}.oecoreplugin NAMELINK_SKIP)
815endif()
816
817if(BUILD_SDL)
818	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/sdl ${CMAKE_CURRENT_BINARY_DIR}/sdl)
819	# The SDL platform CMakeLists could decide to disable SDL, so check again before adding the define.
820	if(BUILD_SDL)
821		add_definitions(-DBUILD_SDL)
822	endif()
823endif()
824
825if(BUILD_QT)
826	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/qt ${CMAKE_CURRENT_BINARY_DIR}/qt)
827endif()
828
829if(BUILD_PERF)
830	set(PERF_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/perf-main.c)
831	if(UNIX AND NOT APPLE)
832		list(APPEND PERF_LIB rt)
833	endif()
834
835	add_executable(${BINARY_NAME}-perf ${PERF_SRC})
836	target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB} ${OS_LIB})
837	set_target_properties(${BINARY_NAME}-perf PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
838	install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
839	install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
840endif()
841
842if(BUILD_TEST)
843	add_executable(${BINARY_NAME}-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/fuzz-main.c)
844	target_link_libraries(${BINARY_NAME}-fuzz ${BINARY_NAME})
845	set_target_properties(${BINARY_NAME}-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
846	add_executable(tbl-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/tbl-fuzz-main.c)
847	target_link_libraries(tbl-fuzz ${BINARY_NAME})
848	set_target_properties(tbl-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
849	install(TARGETS ${BINARY_NAME}-fuzz tbl-fuzz DESTINATION bin COMPONENT ${BINARY_NAME}-test)
850endif()
851
852if(NOT USE_CMOCKA)
853	set(BUILD_SUITE OFF)
854endif()
855if(BUILD_SUITE)
856	enable_testing()
857	include_directories(AFTER ${CMOCKA_INCLUDE_DIRS})
858	link_directories(${CMOCKA_LIBRARY_DIRS})
859
860	add_executable(${BINARY_NAME}-suite ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/suite-main.c ${TEST_SRC})
861	target_link_libraries(${BINARY_NAME}-suite ${BINARY_NAME} ${PLATFORM_LIBRARY} cmocka)
862	set_target_properties(${BINARY_NAME}-suite PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
863	add_test(${BINARY_NAME}-suite ${BINARY_NAME}-suite)
864endif()
865
866if(BUILD_PYTHON)
867	enable_testing()
868	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/python ${CMAKE_CURRENT_BINARY_DIR}/python)
869endif()
870
871if(BUILD_EXAMPLE)
872	add_executable(${BINARY_NAME}-example-server ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/server.c)
873	target_link_libraries(${BINARY_NAME}-example-server ${BINARY_NAME})
874	set_target_properties(${BINARY_NAME}-example-server PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
875
876	if(BUILD_SDL)
877		add_executable(${BINARY_NAME}-example-client ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/client.c)
878		target_link_libraries(${BINARY_NAME}-example-client ${BINARY_NAME} ${SDL_LIBRARY} ${SDLMAIN_LIBRARY} ${OPENGL_LIBRARY} ${OPENGLES2_LIBRARY})
879		set_target_properties(${BINARY_NAME}-example-client PROPERTIES
880		                      COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}"
881		                      INCLUDE_DIRECTORIES "${SDL_INCLUDE_DIR};${CMAKE_CURRENT_SOURCE_DIR}/src;${CMAKE_CURRENT_SOURCE_DIR}/include")
882	endif()
883endif()
884
885configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/flags.h.in ${CMAKE_CURRENT_BINARY_DIR}/flags.h)
886install(FILES ${CMAKE_CURRENT_BINARY_DIR}/flags.h DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/mgba COMPONENT lib${BINARY_NAME})
887
888# Packaging
889set(CPACK_PACKAGE_VERSION ${VERSION_STRING})
890set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
891set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
892set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
893set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
894set(CPACK_RESOURCE_FILE_README ${CMAKE_CURRENT_SOURCE_DIR}/README.md)
895
896set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
897set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
898set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
899set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README.md")
900set(CPACK_DEBIAN_PACKAGE_SECTION "games")
901
902SET(CPACK_DEB_COMPONENT_INSTALL ON)
903
904set(CPACK_STRIP_FILES ${BINARY_NAME})
905
906install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/README.md ${CMAKE_CURRENT_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
907
908include(CPack)
909
910# Summaries
911set(SUMMARY_GL_LIST)
912if(USE_EPOXY)
913	set(SUMMARY_GL_LIST "libepoxy")
914else()
915	if(BUILD_GL)
916		list(APPEND SUMMARY_GL_LIST "OpenGL")
917	endif()
918	if(BUILD_GLES2)
919		list(APPEND SUMMARY_GL_LIST "OpenGL|ES 2")
920	endif()
921endif()
922if(NOT SUMMARY_GL_LIST)
923	set(SUMMARY_GL OFF)
924else()
925	string(REPLACE ";" ", " SUMMARY_GL "${SUMMARY_GL_LIST}")
926endif()
927if(USE_LIBZIP)
928	set(SUMMARY_ZIP libzip)
929elseif(USE_MINIZIP)
930	set(SUMMARY_ZIP "minizip (external)")
931elseif(USE_ZLIB)
932	set(SUMMARY_ZIP "minizip (included)")
933else()
934	set(SUMMARY_ZIP OFF)
935endif()
936
937if(NOT QUIET)
938	message(STATUS "Build type: ${CMAKE_BUILD_TYPE}")
939	message(STATUS "Platforms:")
940	message(STATUS "	Game Boy Advance: ${M_CORE_GBA}")
941	message(STATUS "	Game Boy: ${M_CORE_GB}")
942	message(STATUS "Features:")
943	message(STATUS "	Debuggers: ${USE_DEBUGGERS}")
944	message(STATUS "	CLI debugger: ${USE_EDITLINE}")
945	message(STATUS "	GDB stub: ${USE_GDB_STUB}")
946	message(STATUS "	Video recording: ${USE_FFMPEG}")
947	message(STATUS "	GIF recording: ${USE_MAGICK}")
948	message(STATUS "	Screenshot/advanced savestate support: ${USE_PNG}")
949	message(STATUS "	ZIP support: ${SUMMARY_ZIP}")
950	message(STATUS "	7-Zip support: ${USE_LZMA}")
951	message(STATUS "	SQLite3 game database: ${USE_SQLITE3}")
952	message(STATUS "	OpenGL support: ${SUMMARY_GL}")
953	message(STATUS "Frontends:")
954	message(STATUS "	Qt: ${BUILD_QT}")
955	message(STATUS "	SDL (${SDL_VERSION}): ${BUILD_SDL}")
956	message(STATUS "	Profiling: ${BUILD_PERF}")
957	message(STATUS "	Test harness: ${BUILD_TEST}")
958	message(STATUS "	Test suite: ${BUILD_SUITE}")
959	message(STATUS "	Python bindings: ${BUILD_PYTHON}")
960	message(STATUS "	Examples: ${BUILD_EXAMPLE}")
961	message(STATUS "Cores:")
962	message(STATUS "	Libretro core: ${BUILD_LIBRETRO}")
963	if(APPLE)
964		message(STATUS "	OpenEmu core: ${BUILD_OPENEMU}")
965	endif()
966	message(STATUS "Libraries:")
967	message(STATUS "	Static: ${BUILD_STATIC}")
968	message(STATUS "	Shared: ${BUILD_SHARED}")
969endif()