CMakeLists.txt (view raw)
1cmake_minimum_required(VERSION 2.6)
2project(mGBA C)
3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
4if(NOT MSVC)
5 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -std=c99")
6else()
7 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_CRT_SECURE_NO_WARNINGS /wd4003 /wd4244 /wd4146")
8endif()
9set(USE_CLI_DEBUGGER ON CACHE BOOL "Whether or not to enable the CLI-mode ARM debugger")
10set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
11set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
12set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
13set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable ZIP support")
14set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
15set(USE_BLIP ON CACHE BOOL "Whether or not to enable blip_buf support")
16set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
17set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
18set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
19set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
20set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
21set(BUILD_TEST OFF CACHE BOOL "Build testing harness")
22set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
23set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
24set(BUILD_GL ON CACHE STRING "Build with OpenGL")
25set(BUILD_GLES2 OFF CACHE STRING "Build with OpenGL|ES 2")
26file(GLOB ARM_SRC ${CMAKE_SOURCE_DIR}/src/arm/*.c)
27file(GLOB GBA_SRC ${CMAKE_SOURCE_DIR}/src/gba/*.c)
28file(GLOB GBA_CHEATS_SRC ${CMAKE_SOURCE_DIR}/src/gba/cheats/*.c)
29file(GLOB GBA_RR_SRC ${CMAKE_SOURCE_DIR}/src/gba/rr/*.c)
30file(GLOB GBA_SV_SRC ${CMAKE_SOURCE_DIR}/src/gba/supervisor/*.c)
31file(GLOB GUI_SRC ${CMAKE_SOURCE_DIR}/src/gui/*.c)
32file(GLOB UTIL_SRC ${CMAKE_SOURCE_DIR}/src/util/*.[cSs])
33file(GLOB RENDERER_SRC ${CMAKE_SOURCE_DIR}/src/gba/renderers/*.c)
34file(GLOB SIO_SRC ${CMAKE_SOURCE_DIR}/src/gba/sio/lockstep.c)
35file(GLOB THIRD_PARTY_SRC ${CMAKE_SOURCE_DIR}/src/third-party/inih/*.c)
36list(APPEND UTIL_SRC ${CMAKE_SOURCE_DIR}/src/platform/commandline.c)
37set(VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-mem.c)
38source_group("ARM core" FILES ${ARM_SRC})
39source_group("GBA board" FILES ${GBA_SRC} ${RENDERER_SRC} ${SIO_SRC})
40source_group("GBA supervisor" FILES ${GBA_CHEATS_SRC} ${GBA_SV_SRC} ${GBA_RR_SRC})
41source_group("Utilities" FILES ${UTIL_SRC})
42include_directories(${CMAKE_SOURCE_DIR}/src/arm)
43include_directories(${CMAKE_SOURCE_DIR}/src)
44
45if(NOT CMAKE_BUILD_TYPE)
46 set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
47endif()
48
49set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${LIBDIR}")
50
51include(GNUInstallDirs)
52
53if (NOT DEFINED LIBDIR)
54 set(LIBDIR "lib")
55endif()
56
57if (NOT DEFINED MANDIR)
58 set(MANDIR ${CMAKE_INSTALL_MANDIR})
59endif()
60
61# Function definitions
62include(FindPkgConfig)
63function(find_feature FEATURE_NAME FEATURE_REQUIRES)
64 if (NOT ${FEATURE_NAME})
65 return()
66 endif()
67 foreach(REQUIRE ${FEATURE_REQUIRES})
68 if(NOT ${REQUIRE}_FOUND)
69 find_package(${REQUIRE} QUIET)
70 if(NOT ${REQUIRE}_FOUND)
71 pkg_search_module(${REQUIRE} ${REQUIRE})
72 if (NOT ${REQUIRE}_FOUND)
73 message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
74 set(${FEATURE_NAME} OFF PARENT_SCOPE)
75 return()
76 endif()
77 endif()
78 endif()
79 string(TOUPPER ${REQUIRE} UREQUIRE)
80 set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
81 set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
82 set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
83 set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
84 set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
85 set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
86 endforeach()
87endfunction()
88
89# Version information
90add_custom_target(version-info ALL ${CMAKE_COMMAND} -E touch ${CMAKE_SOURCE_DIR}/src/util/version.c.in
91 COMMAND ${CMAKE_COMMAND}
92 -DBINARY_NAME=${BINARY_NAME}
93 -DCONFIG_FILE=${CMAKE_SOURCE_DIR}/src/util/version.c.in
94 -DOUT_FILE=${CMAKE_CURRENT_BINARY_DIR}/version.c
95 -P ${CMAKE_SOURCE_DIR}/version.cmake
96 WORKING_DIRECTORY ${CMAKE_BINARY_DIR})
97
98include(${CMAKE_SOURCE_DIR}/version.cmake)
99configure_file(${CMAKE_SOURCE_DIR}/src/util/version.c.in ${CMAKE_CURRENT_BINARY_DIR}/version.c)
100list(APPEND UTIL_SRC ${CMAKE_BINARY_DIR}/version.c)
101source_group("Generated sources" FILES ${CMAKE_BINARY_DIR}/version.c)
102
103# Advanced settings
104set(BUILD_LTO ON CACHE BOOL "Build with link-time optimization")
105set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
106set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
107set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
108mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
109set(PGO_PRE_FLAGS "-pg -fprofile-generate=${PGO_DIR} -fprofile-arcs")
110set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
111
112if(BUILD_PGO AND NOT PGO_STAGE_2)
113 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
114 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
115 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
116elseif(BUILD_PGO AND PGO_STAGE_2)
117 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
118 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
119 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
120endif()
121
122# Feature dependencies
123set(FEATURES)
124if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
125 set(LIBEDIT_LIBRARIES -ledit)
126 if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
127 list(APPEND LIBEDIT_LIBRARIES -ltermcap)
128 endif()
129else()
130 find_feature(USE_CLI_DEBUGGER "libedit")
131endif()
132if(BUILD_GL)
133 find_package(OpenGL QUIET)
134 if(NOT OPENGL_FOUND)
135 set(BUILD_GL OFF CACHE BOOL "OpenGL not found" FORCE)
136 endif()
137endif()
138if(BUILD_GLES2 AND NOT BUILD_RASPI)
139 find_path(OPENGLES2_INCLUDE_DIR NAMES GLES2/gl2.h)
140 find_library(OPENGLES2_LIBRARY NAMES GLESv2 GLESv2_CM)
141 if(NOT OPENGLES2_INCLUDE_DIR OR NOT OPENGLES2_LIBRARY)
142 set(BUILD_GLES2 OFF CACHE BOOL "OpenGL|ES 2 not found" FORCE)
143 endif()
144endif()
145find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
146find_feature(USE_PNG "ZLIB;PNG")
147find_feature(USE_LIBZIP "libzip")
148find_feature(USE_MAGICK "MagickWand")
149
150# Platform support
151if(WIN32)
152 set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
153 add_definitions(-D_WIN32_WINNT=0x0600)
154 list(APPEND OS_LIB ws2_32 shlwapi)
155 list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
156 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/windows/*.c)
157 source_group("Windows-specific code" FILES ${OS_SRC})
158elseif(UNIX)
159 add_definitions(-DUSE_PTHREADS)
160
161 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
162 add_definitions(-D_GNU_SOURCE)
163 endif()
164 if(NOT APPLE AND NOT HAIKU)
165 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
166 endif()
167
168 list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
169 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/posix/*.c)
170 source_group("POSIX-specific code" FILES ${OS_SRC})
171endif()
172
173if(APPLE)
174 add_definitions(-D_DARWIN_C_SOURCE)
175 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
176endif()
177
178if(NOT HAIKU AND NOT MSVC)
179 list(APPEND OS_LIB m)
180endif()
181
182if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
183 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
184 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
185endif()
186
187if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
188 if(NOT BUILD_EGL)
189 add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
190 endif()
191endif()
192
193if(BUILD_RASPI)
194 set(BUILD_GL OFF CACHE BOOL "OpenGL not supported" FORCE)
195endif()
196
197if(BUILD_PANDORA)
198 add_definitions(-DBUILD_PANDORA)
199endif()
200
201if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
202 enable_language(ASM)
203endif()
204
205include(CheckFunctionExists)
206check_function_exists(strdup HAVE_STRDUP)
207check_function_exists(strndup HAVE_STRNDUP)
208check_function_exists(snprintf_l HAVE_SNPRINTF_L)
209if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
210 # The strtof_l on Linux not actually exposed nor actually strtof_l
211 set(HAVE_STRTOF_L OFF)
212else()
213 check_function_exists(strtof_l HAVE_STRTOF_L)
214endif()
215check_function_exists(newlocale HAVE_NEWLOCALE)
216check_function_exists(freelocale HAVE_FREELOCALE)
217check_function_exists(uselocale HAVE_USELOCALE)
218check_function_exists(setlocale HAVE_SETLOCALE)
219
220if(HAVE_STRDUP)
221 add_definitions(-DHAVE_STRDUP)
222endif()
223
224if(HAVE_STRNDUP)
225 add_definitions(-DHAVE_STRNDUP)
226endif()
227
228if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE)
229 add_definitions(-DHAVE_LOCALE)
230 if (HAVE_STRTOF_L)
231 add_definitions(-DHAVE_STRTOF_L)
232 endif()
233 if (HAVE_SNPRINTF_L)
234 add_definitions(-DHAVE_SNPRINTF_L)
235 endif()
236endif()
237
238if(HAVE_SETLOCALE)
239 add_definitions(-DHAVE_SETLOCALE)
240endif()
241
242# Features
243set(DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/debugger.c ${CMAKE_SOURCE_DIR}/src/debugger/memory-debugger.c)
244set(FEATURE_SRC)
245set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
246
247if(USE_CLI_DEBUGGER)
248 list(APPEND FEATURES CLI_DEBUGGER)
249 list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/debugger/cli-debugger.c)
250 list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/debugger/parser.c)
251 list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/gba/supervisor/cli.c)
252 include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
253 link_directories(${LIBEDIT_LIBRARY_DIRS})
254 set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
255 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
256else()
257 set(DEBUGGER_LIB "")
258endif()
259
260if(USE_GDB_STUB)
261 list(APPEND FEATURES GDB_STUB)
262 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/gdb-stub.c)
263endif()
264source_group("ARM debugger" FILES ${DEBUGGER_SRC})
265
266if(USE_FFMPEG)
267 list(APPEND FEATURES FFMPEG)
268 pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
269 if(NOT LIBSWRESAMPLE_FOUND)
270 list(APPEND FEATURES LIBAV)
271 endif()
272 include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
273 link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
274 list(APPEND FEATURE_SRC "${CMAKE_SOURCE_DIR}/src/platform/ffmpeg/ffmpeg-encoder.c")
275 string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
276 string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
277 string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
278 string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
279 string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
280 list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
281 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR}|libavcodec-extra-${LIBAVCODEC_VERSION_MAJOR},libavformat${LIBAVFORMAT_VERSION_MAJOR},libavresample${LIBAVRESAMPLE_VERSION_MAJOR},libavutil${LIBAVUTIL_VERSION_MAJOR},libswscale${LIBSWSCALE_VERSION_MAJOR}")
282 set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra")
283 if(APPLE)
284 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
285 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
286 endif()
287endif()
288
289if(USE_BLIP)
290 list(APPEND THIRD_PARTY_SRC "${CMAKE_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
291 add_definitions(-DRESAMPLE_LIBRARY=RESAMPLE_BLIP_BUF)
292else()
293 add_definitions(-DRESAMPLE_LIBRARY=RESAMPLE_NN)
294endif()
295
296if(USE_MAGICK)
297 list(APPEND FEATURES MAGICK)
298 include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
299 link_directories(${MAGICKWAND_LIBRARY_DIRS})
300 list(APPEND FEATURE_SRC "${CMAKE_SOURCE_DIR}/src/platform/imagemagick/imagemagick-gif-encoder.c")
301 list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
302 string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
303 if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
304 set(MAGICKWAND_DEB_VERSION "5")
305 else()
306 set(MAGICKWAND_DEB_VERSION "-6.q16-2")
307 endif()
308 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
309endif()
310
311if(USE_PNG)
312 list(APPEND FEATURES PNG)
313 include_directories(AFTER ${PNG_INCLUDE_DIRS})
314 list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
315 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng12-0,zlib1g")
316endif()
317
318if(USE_LIBZIP)
319 include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
320 link_directories(${LIBZIP_LIBRARY_DIRS})
321 list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
322 list(APPEND FEATURES LIBZIP)
323 list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
324 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
325endif()
326
327if (USE_LZMA)
328 include_directories(AFTER ${CMAKE_SOURCE_DIR}/third-party/lzma)
329 add_definitions(-D_7ZIP_PPMD_SUPPPORT)
330 list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-lzma.c)
331 set(LZMA_SRC
332 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
333 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
334 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
335 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
336 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
337 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
338 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zDec.c
339 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
340 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
341 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
342 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bra.c
343 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bra86.c
344 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
345 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
346 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
347 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zFile.c
348 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
349 list(APPEND FEATURE_SRC ${LZMA_SRC})
350 list(APPEND FEATURES LZMA)
351endif()
352
353set(FEATURE_DEFINES)
354foreach(FEATURE IN LISTS FEATURES)
355 list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
356endforeach()
357
358source_group("Virtual files" FILES ${VFS_SRC})
359source_group("Extra features" FILES ${FEATURE_SRC})
360source_group("Third-party code" FILES ${THIRD_PARTY_SRC})
361
362# Binaries
363set(CORE_SRC
364 ${ARM_SRC}
365 ${GBA_SRC}
366 ${GBA_CHEATS_SRC}
367 ${GBA_RR_SRC}
368 ${GBA_SV_SRC}
369 ${DEBUGGER_SRC}
370 ${RENDERER_SRC}
371 ${SIO_SRC}
372 ${UTIL_SRC}
373 ${VFS_SRC}
374 ${OS_SRC}
375 ${THIRD_PARTY_SRC})
376
377set(SRC
378 ${CORE_SRC}
379 ${FEATURE_SRC})
380
381if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
382 set(BUILD_SHARED ON)
383endif()
384
385if(BUILD_SHARED)
386 add_library(${BINARY_NAME} SHARED ${SRC})
387 set_target_properties(${BINARY_NAME} PROPERTIES SOVERSION ${LIB_VERSION_ABI})
388 if(BUILD_STATIC)
389 add_library(${BINARY_NAME}-static STATIC ${SRC})
390 set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${FEATURE_DEFINES}")
391 install(TARGETS ${BINARY_NAME}-static DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
392 add_dependencies(${BINARY_NAME}-static version-info)
393 endif()
394else()
395 add_library(${BINARY_NAME} STATIC ${SRC})
396endif()
397
398add_dependencies(${BINARY_NAME} version-info)
399
400target_link_libraries(${BINARY_NAME} ${DEBUGGER_LIB} ${DEPENDENCY_LIB} ${OS_LIB})
401install(TARGETS ${BINARY_NAME} LIBRARY DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME} NAMELINK_SKIP ARCHIVE DESTINATION ${LIBDIR} RUNTIME DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
402if(UNIX AND NOT APPLE)
403 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-16.png DESTINATION share/icons/hicolor/16x16/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
404 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-24.png DESTINATION share/icons/hicolor/24x24/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
405 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-32.png DESTINATION share/icons/hicolor/32x32/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
406 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-48.png DESTINATION share/icons/hicolor/48x48/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
407 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-64.png DESTINATION share/icons/hicolor/64x64/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
408 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-96.png DESTINATION share/icons/hicolor/96x96/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
409 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-128.png DESTINATION share/icons/hicolor/128x128/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
410 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-256.png DESTINATION share/icons/hicolor/256x256/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
411 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-512.png DESTINATION share/icons/hicolor/512x512/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
412endif()
413set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${FEATURE_DEFINES}")
414
415if(BUILD_GL)
416 add_definitions(-DBUILD_GL)
417endif()
418
419if(BUILD_GLES2)
420 add_definitions(-DBUILD_GLES2)
421endif()
422
423if(BUILD_LIBRETRO)
424 file(GLOB RETRO_SRC ${CMAKE_SOURCE_DIR}/src/platform/libretro/*.c)
425 add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
426 set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5")
427 target_link_libraries(${BINARY_NAME}_libretro ${OS_LIB})
428endif()
429
430if(BUILD_SDL)
431 add_definitions(-DBUILD_SDL)
432 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/sdl ${CMAKE_BINARY_DIR}/sdl)
433endif()
434
435if(BUILD_QT)
436 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/qt ${CMAKE_BINARY_DIR}/qt)
437endif()
438
439if(BUILD_PERF)
440 set(PERF_SRC ${CMAKE_SOURCE_DIR}/src/platform/test/perf-main.c)
441 if(UNIX AND NOT APPLE)
442 list(APPEND PERF_LIB rt)
443 endif()
444
445 add_executable(${BINARY_NAME}-perf ${PERF_SRC})
446 target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB})
447 install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
448 install(FILES ${CMAKE_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
449endif()
450
451if(BUILD_TEST)
452 add_executable(${BINARY_NAME}-fuzz ${CMAKE_SOURCE_DIR}/src/platform/test/fuzz-main.c)
453 target_link_libraries(${BINARY_NAME}-fuzz ${BINARY_NAME})
454 install(TARGETS ${BINARY_NAME}-fuzz DESTINATION bin COMPONENT ${BINARY_NAME}-test)
455endif()
456
457# Packaging
458set(CPACK_PACKAGE_VERSION ${VERSION_STRING})
459set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
460set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
461set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
462set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_SOURCE_DIR}/LICENSE)
463set(CPACK_RESOURCE_FILE_README ${CMAKE_SOURCE_DIR}/README.md)
464
465set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
466set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
467set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
468set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_SOURCE_DIR}/README.md")
469set(CPACK_DEBIAN_PACKAGE_SECTION "games")
470
471SET(CPACK_DEB_COMPONENT_INSTALL ON)
472
473set(CPACK_STRIP_FILES ${BINARY_NAME})
474
475install(FILES ${CMAKE_SOURCE_DIR}/README.md ${CMAKE_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
476
477include(CPack)
478
479# Summaries
480message(STATUS "Feature summary:")
481message(STATUS " CLI debugger: ${USE_CLI_DEBUGGER}")
482message(STATUS " GDB stub: ${USE_GDB_STUB}")
483message(STATUS " Video recording: ${USE_FFMPEG}")
484message(STATUS " GIF recording: ${USE_MAGICK}")
485message(STATUS " Screenshot/advanced savestate support: ${USE_PNG}")
486message(STATUS " ZIP support: ${USE_LIBZIP}")
487message(STATUS " 7-Zip support: ${USE_LZMA}")
488message(STATUS " Better audio resampling: ${USE_BLIP}")
489message(STATUS "Frontend summary:")
490message(STATUS " Qt: ${BUILD_QT}")
491message(STATUS " SDL (${SDL_VERSION}): ${BUILD_SDL}")
492message(STATUS " Libretro core: ${BUILD_LIBRETRO}")
493message(STATUS " Profiling: ${BUILD_PERF}")
494message(STATUS " Test harness: ${BUILD_TEST}")
495message(STATUS "Library summary:")
496message(STATUS " Static: ${BUILD_STATIC}")
497message(STATUS " Shared: ${BUILD_SHARED}")