1cmake_minimum_required(VERSION 2.6)
  2project(mGBA C)
  3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
  4if(NOT MSVC)
  5	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -std=c99")
  6else()
  7	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_CRT_SECURE_NO_WARNINGS /wd4003 /wd4244 /wd4146")
  8endif()
  9set(USE_CLI_DEBUGGER ON CACHE BOOL "Whether or not to enable the CLI-mode ARM debugger")
 10set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
 11set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
 12set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
 13set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable ZIP support")
 14set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
 15set(USE_BLIP ON CACHE BOOL "Whether or not to enable blip_buf support")
 16set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
 17set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
 18set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
 19set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
 20set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
 21set(BUILD_TEST OFF CACHE BOOL "Build testing harness")
 22set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
 23set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
 24set(BUILD_GL ON CACHE STRING "Build with OpenGL")
 25set(BUILD_GLES2 OFF CACHE STRING "Build with OpenGL|ES 2")
 26file(GLOB ARM_SRC ${CMAKE_SOURCE_DIR}/src/arm/*.c)
 27file(GLOB GBA_SRC ${CMAKE_SOURCE_DIR}/src/gba/*.c)
 28file(GLOB GBA_CHEATS_SRC ${CMAKE_SOURCE_DIR}/src/gba/cheats/*.c)
 29file(GLOB GBA_RR_SRC ${CMAKE_SOURCE_DIR}/src/gba/rr/*.c)
 30file(GLOB GBA_SV_SRC ${CMAKE_SOURCE_DIR}/src/gba/supervisor/*.c)
 31file(GLOB UTIL_SRC ${CMAKE_SOURCE_DIR}/src/util/*.[cSs])
 32file(GLOB GUI_SRC ${CMAKE_SOURCE_DIR}/src/util/gui/*.c)
 33file(GLOB RENDERER_SRC ${CMAKE_SOURCE_DIR}/src/gba/renderers/*.c)
 34file(GLOB SIO_SRC ${CMAKE_SOURCE_DIR}/src/gba/sio/lockstep.c)
 35file(GLOB THIRD_PARTY_SRC ${CMAKE_SOURCE_DIR}/src/third-party/inih/*.c)
 36list(APPEND UTIL_SRC ${CMAKE_SOURCE_DIR}/src/platform/commandline.c)
 37set(VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-mem.c)
 38source_group("ARM core" FILES ${ARM_SRC})
 39source_group("GBA board" FILES ${GBA_SRC} ${RENDERER_SRC} ${SIO_SRC})
 40source_group("GBA supervisor" FILES ${GBA_CHEATS_SRC} ${GBA_SV_SRC} ${GBA_RR_SRC})
 41source_group("Utilities" FILES ${UTIL_SRC})
 42include_directories(${CMAKE_SOURCE_DIR}/src/arm)
 43include_directories(${CMAKE_SOURCE_DIR}/src)
 44
 45if(NOT CMAKE_BUILD_TYPE)
 46	set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
 47endif()
 48
 49set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${LIBDIR}")
 50
 51include(GNUInstallDirs)
 52
 53if (NOT DEFINED LIBDIR)
 54	set(LIBDIR "lib")
 55endif()
 56
 57if (NOT DEFINED MANDIR)
 58	set(MANDIR ${CMAKE_INSTALL_MANDIR})
 59endif()
 60
 61# Function definitions
 62include(FindPkgConfig)
 63function(find_feature FEATURE_NAME FEATURE_REQUIRES)
 64	if (NOT ${FEATURE_NAME})
 65		return()
 66	endif()
 67	foreach(REQUIRE ${FEATURE_REQUIRES})
 68		if(NOT ${REQUIRE}_FOUND)
 69			find_package(${REQUIRE} QUIET)
 70			if(NOT ${REQUIRE}_FOUND)
 71				pkg_search_module(${REQUIRE} ${REQUIRE})
 72				if (NOT ${REQUIRE}_FOUND)
 73					message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
 74					set(${FEATURE_NAME} OFF PARENT_SCOPE)
 75					return()
 76				endif()
 77			endif()
 78		endif()
 79		string(TOUPPER ${REQUIRE} UREQUIRE)
 80		set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
 81		set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
 82		set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
 83		set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
 84		set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
 85		set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
 86	endforeach()
 87endfunction()
 88
 89# Version information
 90add_custom_target(version-info ALL ${CMAKE_COMMAND} -E touch ${CMAKE_SOURCE_DIR}/src/util/version.c.in
 91	COMMAND ${CMAKE_COMMAND}
 92	-DBINARY_NAME=${BINARY_NAME}
 93	-DCONFIG_FILE=${CMAKE_SOURCE_DIR}/src/util/version.c.in
 94	-DOUT_FILE=${CMAKE_CURRENT_BINARY_DIR}/version.c
 95	-P ${CMAKE_SOURCE_DIR}/version.cmake
 96	WORKING_DIRECTORY ${CMAKE_BINARY_DIR})
 97
 98include(${CMAKE_SOURCE_DIR}/version.cmake)
 99configure_file(${CMAKE_SOURCE_DIR}/src/util/version.c.in ${CMAKE_CURRENT_BINARY_DIR}/version.c)
100list(APPEND UTIL_SRC ${CMAKE_BINARY_DIR}/version.c)
101source_group("Generated sources" FILES ${CMAKE_BINARY_DIR}/version.c)
102
103# Advanced settings
104set(BUILD_LTO ON CACHE BOOL "Build with link-time optimization")
105set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
106set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
107set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
108mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
109set(PGO_PRE_FLAGS "-pg -fprofile-generate=${PGO_DIR} -fprofile-arcs")
110set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
111
112if(BUILD_PGO AND NOT PGO_STAGE_2)
113	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
114	set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
115	set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
116elseif(BUILD_PGO AND PGO_STAGE_2)
117	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
118	set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
119	set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
120endif()
121
122# Feature dependencies
123set(FEATURES)
124if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
125	set(LIBEDIT_LIBRARIES -ledit)
126	if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
127		list(APPEND LIBEDIT_LIBRARIES -ltermcap)
128	endif()
129else()
130	find_feature(USE_CLI_DEBUGGER "libedit")
131endif()
132if(BUILD_GL)
133	find_package(OpenGL QUIET)
134	if(NOT OPENGL_FOUND)
135		set(BUILD_GL OFF CACHE BOOL "OpenGL not found" FORCE)
136	endif()
137endif()
138if(BUILD_GLES2 AND NOT BUILD_RASPI)
139	find_path(OPENGLES2_INCLUDE_DIR NAMES GLES2/gl2.h)
140	find_library(OPENGLES2_LIBRARY NAMES GLESv2 GLESv2_CM)
141	if(NOT OPENGLES2_INCLUDE_DIR OR NOT OPENGLES2_LIBRARY)
142		set(BUILD_GLES2 OFF CACHE BOOL "OpenGL|ES 2 not found" FORCE)
143	endif()
144endif()
145find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
146find_feature(USE_PNG "ZLIB;PNG")
147find_feature(USE_LIBZIP "libzip")
148find_feature(USE_MAGICK "MagickWand")
149
150# Platform support
151if(WIN32)
152	set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
153	add_definitions(-D_WIN32_WINNT=0x0600)
154	list(APPEND OS_LIB ws2_32 shlwapi)
155	list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
156	file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/windows/*.c)
157	source_group("Windows-specific code" FILES ${OS_SRC})
158elseif(UNIX)
159	add_definitions(-DUSE_PTHREADS)
160
161	if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
162		add_definitions(-D_GNU_SOURCE)
163	endif()
164	if(NOT APPLE AND NOT HAIKU)
165		set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
166	endif()
167
168	list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
169	file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/posix/*.c)
170	source_group("POSIX-specific code" FILES ${OS_SRC})
171elseif(3DS)
172	set(M_LIBRARY m)
173	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-format")
174	add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
175	execute_process(COMMAND ${RAW2C} ${CMAKE_SOURCE_DIR}/src/platform/3ds/font.raw)
176	include_directories(${CMAKE_BINARY_DIR})
177	list(APPEND OS_LIB sf2d ctru)
178	file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/3ds/*.c ${CMAKE_BINARY_DIR}/font.c)
179	source_group("3DS-specific code" FILES ${OS_SRC})
180endif()
181
182if(APPLE)
183	add_definitions(-D_DARWIN_C_SOURCE)
184	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
185endif()
186
187if(NOT HAIKU AND NOT MSVC)
188	list(APPEND OS_LIB m)
189endif()
190
191if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
192	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
193	set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
194endif()
195
196if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
197	if(NOT BUILD_EGL)
198		add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
199	endif()
200endif()
201
202if(BUILD_RASPI)
203	set(BUILD_GL OFF CACHE BOOL "OpenGL not supported" FORCE)
204endif()
205
206if(BUILD_PANDORA)
207	add_definitions(-DBUILD_PANDORA)
208endif()
209
210if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
211	enable_language(ASM)
212endif()
213
214include(CheckFunctionExists)
215check_function_exists(strdup HAVE_STRDUP)
216check_function_exists(strndup HAVE_STRNDUP)
217check_function_exists(snprintf_l HAVE_SNPRINTF_L)
218if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
219	# The strtof_l on Linux not actually exposed nor actually strtof_l
220	set(HAVE_STRTOF_L OFF)
221else()
222	check_function_exists(strtof_l HAVE_STRTOF_L)
223endif()
224check_function_exists(newlocale HAVE_NEWLOCALE)
225check_function_exists(freelocale HAVE_FREELOCALE)
226check_function_exists(uselocale HAVE_USELOCALE)
227check_function_exists(setlocale HAVE_SETLOCALE)
228
229if(HAVE_STRDUP)
230	add_definitions(-DHAVE_STRDUP)
231endif()
232
233if(HAVE_STRNDUP)
234	add_definitions(-DHAVE_STRNDUP)
235endif()
236
237if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE)
238	add_definitions(-DHAVE_LOCALE)
239	if (HAVE_STRTOF_L)
240		add_definitions(-DHAVE_STRTOF_L)
241	endif()
242	if (HAVE_SNPRINTF_L)
243		add_definitions(-DHAVE_SNPRINTF_L)
244	endif()
245endif()
246
247if(HAVE_SETLOCALE)
248	add_definitions(-DHAVE_SETLOCALE)
249endif()
250
251# Features
252set(DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/debugger.c ${CMAKE_SOURCE_DIR}/src/debugger/memory-debugger.c)
253set(FEATURE_SRC)
254set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
255
256if(USE_CLI_DEBUGGER)
257	list(APPEND FEATURES CLI_DEBUGGER)
258	list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/debugger/cli-debugger.c)
259	list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/debugger/parser.c)
260	list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/gba/supervisor/cli.c)
261	include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
262	link_directories(${LIBEDIT_LIBRARY_DIRS})
263	set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
264	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
265else()
266	set(DEBUGGER_LIB "")
267endif()
268
269if(USE_GDB_STUB)
270	list(APPEND FEATURES GDB_STUB)
271	list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/gdb-stub.c)
272endif()
273source_group("ARM debugger" FILES ${DEBUGGER_SRC})
274
275if(USE_FFMPEG)
276	list(APPEND FEATURES FFMPEG)
277	pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
278	if(NOT LIBSWRESAMPLE_FOUND)
279		list(APPEND FEATURES LIBAV)
280	endif()
281	include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
282	link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
283	list(APPEND FEATURE_SRC "${CMAKE_SOURCE_DIR}/src/platform/ffmpeg/ffmpeg-encoder.c")
284	string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
285	string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
286	string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
287	string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
288	string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
289	list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
290	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR}|libavcodec-extra-${LIBAVCODEC_VERSION_MAJOR},libavformat${LIBAVFORMAT_VERSION_MAJOR},libavresample${LIBAVRESAMPLE_VERSION_MAJOR},libavutil${LIBAVUTIL_VERSION_MAJOR},libswscale${LIBSWSCALE_VERSION_MAJOR}")
291	set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra")
292	if(APPLE)
293		set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
294		set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
295	endif()
296endif()
297
298if(USE_BLIP)
299	list(APPEND THIRD_PARTY_SRC "${CMAKE_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
300	add_definitions(-DRESAMPLE_LIBRARY=RESAMPLE_BLIP_BUF)
301else()
302	add_definitions(-DRESAMPLE_LIBRARY=RESAMPLE_NN)
303endif()
304
305if(USE_MAGICK)
306	list(APPEND FEATURES MAGICK)
307	include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
308	link_directories(${MAGICKWAND_LIBRARY_DIRS})
309	list(APPEND FEATURE_SRC "${CMAKE_SOURCE_DIR}/src/platform/imagemagick/imagemagick-gif-encoder.c")
310	list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
311	string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
312	if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
313		set(MAGICKWAND_DEB_VERSION "5")
314	else()
315		set(MAGICKWAND_DEB_VERSION "-6.q16-2")
316	endif()
317	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
318endif()
319
320if(USE_PNG)
321	list(APPEND FEATURES PNG)
322	include_directories(AFTER ${PNG_INCLUDE_DIRS})
323	list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
324	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng12-0,zlib1g")
325endif()
326
327if(USE_LIBZIP)
328	include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
329	link_directories(${LIBZIP_LIBRARY_DIRS})
330	list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
331	list(APPEND FEATURES LIBZIP)
332	list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
333	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
334endif()
335
336if (USE_LZMA)
337	include_directories(AFTER ${CMAKE_SOURCE_DIR}/third-party/lzma)
338	add_definitions(-D_7ZIP_PPMD_SUPPPORT)
339	list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-lzma.c)
340	set(LZMA_SRC
341		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
342		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
343		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
344		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
345		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
346		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
347		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zDec.c
348		${CMAKE_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
349		${CMAKE_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
350		${CMAKE_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
351		${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bra.c
352		${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bra86.c
353		${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
354		${CMAKE_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
355		${CMAKE_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
356		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zFile.c
357		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
358	list(APPEND FEATURE_SRC ${LZMA_SRC})
359	list(APPEND FEATURES LZMA)
360endif()
361
362set(FEATURE_DEFINES)
363foreach(FEATURE IN LISTS FEATURES)
364	list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
365endforeach()
366
367source_group("Virtual files" FILES ${VFS_SRC})
368source_group("Extra features" FILES ${FEATURE_SRC})
369source_group("Third-party code" FILES ${THIRD_PARTY_SRC})
370
371# Binaries
372set(CORE_SRC
373	${ARM_SRC}
374	${GBA_SRC}
375	${GBA_CHEATS_SRC}
376	${GBA_RR_SRC}
377	${GBA_SV_SRC}
378	${DEBUGGER_SRC}
379	${RENDERER_SRC}
380	${SIO_SRC}
381	${UTIL_SRC}
382	${VFS_SRC}
383	${OS_SRC}
384	${THIRD_PARTY_SRC})
385
386set(SRC
387	${CORE_SRC}
388	${FEATURE_SRC})
389
390if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
391	set(BUILD_SHARED ON)
392endif()
393
394if(BUILD_SHARED)
395	add_library(${BINARY_NAME} SHARED ${SRC})
396	set_target_properties(${BINARY_NAME} PROPERTIES SOVERSION ${LIB_VERSION_ABI})
397	if(BUILD_STATIC)
398		add_library(${BINARY_NAME}-static STATIC ${SRC})
399		set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${FEATURE_DEFINES}")
400		install(TARGETS ${BINARY_NAME}-static DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
401		add_dependencies(${BINARY_NAME}-static version-info)
402	endif()
403else()
404	add_library(${BINARY_NAME} STATIC ${SRC})
405endif()
406
407add_dependencies(${BINARY_NAME} version-info)
408
409target_link_libraries(${BINARY_NAME} ${DEBUGGER_LIB} ${DEPENDENCY_LIB} ${OS_LIB})
410install(TARGETS ${BINARY_NAME} LIBRARY DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME} NAMELINK_SKIP ARCHIVE DESTINATION ${LIBDIR} RUNTIME DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
411if(UNIX AND NOT APPLE)
412	install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-16.png DESTINATION share/icons/hicolor/16x16/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
413	install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-24.png DESTINATION share/icons/hicolor/24x24/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
414	install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-32.png DESTINATION share/icons/hicolor/32x32/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
415	install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-48.png DESTINATION share/icons/hicolor/48x48/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
416	install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-64.png DESTINATION share/icons/hicolor/64x64/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
417	install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-96.png DESTINATION share/icons/hicolor/96x96/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
418	install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-128.png DESTINATION share/icons/hicolor/128x128/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
419	install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-256.png DESTINATION share/icons/hicolor/256x256/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
420	install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-512.png DESTINATION share/icons/hicolor/512x512/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
421endif()
422set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${FEATURE_DEFINES}")
423
424if(BUILD_GL)
425	add_definitions(-DBUILD_GL)
426endif()
427
428if(BUILD_GLES2)
429	add_definitions(-DBUILD_GLES2)
430endif()
431
432if(BUILD_LIBRETRO)
433	file(GLOB RETRO_SRC ${CMAKE_SOURCE_DIR}/src/platform/libretro/*.c)
434	add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
435	set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5")
436	target_link_libraries(${BINARY_NAME}_libretro ${OS_LIB})
437endif()
438
439if(BUILD_SDL)
440	add_definitions(-DBUILD_SDL)
441	add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/sdl ${CMAKE_BINARY_DIR}/sdl)
442endif()
443
444if(BUILD_QT)
445	add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/qt ${CMAKE_BINARY_DIR}/qt)
446endif()
447
448if(3DS)
449	add_executable(${BINARY_NAME}.elf ${GUI_SRC})
450	target_link_libraries(${BINARY_NAME}.elf ${BINARY_NAME} m ${OS_LIB})
451	add_custom_command(TARGET ${BINARY_NAME}.elf POST_BUILD COMMAND ${3DSXTOOL} ${BINARY_NAME}.elf ${BINARY_NAME}.3dsx)
452endif()
453
454if(BUILD_PERF)
455	set(PERF_SRC ${CMAKE_SOURCE_DIR}/src/platform/test/perf-main.c)
456	if(UNIX AND NOT APPLE)
457		list(APPEND PERF_LIB rt)
458	endif()
459
460	add_executable(${BINARY_NAME}-perf ${PERF_SRC})
461	target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB})
462	install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
463	install(FILES ${CMAKE_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
464endif()
465
466if(BUILD_TEST)
467	add_executable(${BINARY_NAME}-fuzz ${CMAKE_SOURCE_DIR}/src/platform/test/fuzz-main.c)
468	target_link_libraries(${BINARY_NAME}-fuzz ${BINARY_NAME})
469	install(TARGETS ${BINARY_NAME}-fuzz DESTINATION bin COMPONENT ${BINARY_NAME}-test)
470endif()
471
472# Packaging
473set(CPACK_PACKAGE_VERSION ${VERSION_STRING})
474set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
475set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
476set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
477set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_SOURCE_DIR}/LICENSE)
478set(CPACK_RESOURCE_FILE_README ${CMAKE_SOURCE_DIR}/README.md)
479
480set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
481set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
482set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
483set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_SOURCE_DIR}/README.md")
484set(CPACK_DEBIAN_PACKAGE_SECTION "games")
485
486SET(CPACK_DEB_COMPONENT_INSTALL ON)
487
488set(CPACK_STRIP_FILES ${BINARY_NAME})
489
490install(FILES ${CMAKE_SOURCE_DIR}/README.md ${CMAKE_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
491
492include(CPack)
493
494# Summaries
495message(STATUS "Feature summary:")
496message(STATUS "	CLI debugger: ${USE_CLI_DEBUGGER}")
497message(STATUS "	GDB stub: ${USE_GDB_STUB}")
498message(STATUS "	Video recording: ${USE_FFMPEG}")
499message(STATUS "	GIF recording: ${USE_MAGICK}")
500message(STATUS "	Screenshot/advanced savestate support: ${USE_PNG}")
501message(STATUS "	ZIP support: ${USE_LIBZIP}")
502message(STATUS "	7-Zip support: ${USE_LZMA}")
503message(STATUS "	Better audio resampling: ${USE_BLIP}")
504message(STATUS "Frontend summary:")
505message(STATUS "	Qt: ${BUILD_QT}")
506message(STATUS "	SDL (${SDL_VERSION}): ${BUILD_SDL}")
507message(STATUS "	Libretro core: ${BUILD_LIBRETRO}")
508message(STATUS "	Profiling: ${BUILD_PERF}")
509message(STATUS "	Test harness: ${BUILD_TEST}")
510message(STATUS "Library summary:")
511message(STATUS "	Static: ${BUILD_STATIC}")
512message(STATUS "	Shared: ${BUILD_SHARED}")