CMakeLists.txt (view raw)
1cmake_minimum_required(VERSION 2.6)
2project(mGBA C)
3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
4set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -std=gnu99")
5set(USE_CLI_DEBUGGER ON CACHE BOOL "Whether or not to enable the CLI-mode ARM debugger")
6set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
7set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
8set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
9set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable ZIP support")
10set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
11set(USE_BLIP ON CACHE BOOL "Whether or not to enable blip_buf support")
12set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
13set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
14set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
15set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
16set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
17set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
18file(GLOB ARM_SRC ${CMAKE_SOURCE_DIR}/src/arm/*.c)
19file(GLOB GBA_SRC ${CMAKE_SOURCE_DIR}/src/gba/*.c)
20file(GLOB GBA_SV_SRC ${CMAKE_SOURCE_DIR}/src/gba/supervisor/*.c)
21file(GLOB UTIL_SRC ${CMAKE_SOURCE_DIR}/src/util/*.[cSs])
22file(GLOB VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/*.c)
23file(GLOB RENDERER_SRC ${CMAKE_SOURCE_DIR}/src/gba/renderers/video-software.c)
24file(GLOB THIRD_PARTY_SRC ${CMAKE_SOURCE_DIR}/src/third-party/inih/*.c)
25list(APPEND UTIL_SRC ${CMAKE_SOURCE_DIR}/src/platform/commandline.c)
26source_group("ARM core" FILES ${ARM_SRC})
27source_group("GBA board" FILES ${GBA_SRC} ${RENDERER_SRC})
28source_group("GBA supervisor" FILES ${GBA_SV_SRC})
29source_group("Utilities" FILES ${UTIL_SRC} ${VFS_SRC}})
30include_directories(${CMAKE_SOURCE_DIR}/src/arm)
31include_directories(${CMAKE_SOURCE_DIR}/src)
32
33if(NOT CMAKE_BUILD_TYPE)
34 set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
35endif()
36
37include(GNUInstallDirs)
38
39# Function definitions
40include(FindPkgConfig)
41function(find_feature FEATURE_NAME FEATURE_REQUIRES)
42 if (NOT ${FEATURE_NAME})
43 return()
44 endif()
45 foreach(REQUIRE ${FEATURE_REQUIRES})
46 if(NOT ${REQUIRE}_FOUND)
47 find_package(${REQUIRE} QUIET)
48 if(NOT ${REQUIRE}_FOUND)
49 pkg_search_module(${REQUIRE} ${REQUIRE})
50 if (NOT ${REQUIRE}_FOUND)
51 message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
52 set(${FEATURE_NAME} OFF PARENT_SCOPE)
53 return()
54 endif()
55 endif()
56 endif()
57 string(TOUPPER ${REQUIRE} UREQUIRE)
58 set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
59 set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
60 set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
61 set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
62 set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
63 set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
64 endforeach()
65endfunction()
66
67# Version information
68set(LIB_VERSION_MAJOR 0)
69set(LIB_VERSION_MINOR 2)
70set(LIB_VERSION_PATCH 0)
71set(LIB_VERSION_ABI 0.2)
72set(LIB_VERSION_STRING ${LIB_VERSION_MAJOR}.${LIB_VERSION_MINOR}.${LIB_VERSION_PATCH})
73
74# Advanced settings
75set(BUILD_PGO CACHE BOOL "Build with profiling-guided optimization")
76set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
77set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
78mark_as_advanced(BUILD_PGO PGO_STAGE_2 PGO_DIR)
79set(PGO_PRE_FLAGS "-pg -fprofile-generate=${PGO_DIR} -fprofile-arcs")
80set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
81
82if(BUILD_PGO AND NOT PGO_STAGE_2)
83 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
84 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
85 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
86elseif(BUILD_PGO AND PGO_STAGE_2)
87 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
88 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
89 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
90endif()
91
92add_definitions(-DBINARY_NAME="${BINARY_NAME}" -DPROJECT_NAME="${PROJECT_NAME}" -DPROJECT_VERSION="${LIB_VERSION_STRING}")
93
94# Feature dependencies
95if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
96 set(LIBEDIT_LIBRARIES -ledit)
97else()
98 find_feature(USE_CLI_DEBUGGER "libedit")
99endif()
100find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
101find_feature(USE_PNG "ZLIB;PNG")
102find_feature(USE_LIBZIP "libzip")
103find_feature(USE_MAGICK "MagickWand")
104
105# Platform support
106if(WIN32)
107 add_definitions(-D_WIN32_WINNT=0x0600)
108 list(APPEND OS_LIB ws2_32)
109 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/windows/*.c)
110 source_group("Windows-specific code" FILES ${OS_SRC})
111else()
112 add_definitions(-DUSE_PTHREADS)
113 if(NOT APPLE)
114 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
115 endif()
116 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/posix/*.c)
117 source_group("POSIX-specific code" FILES ${OS_SRC})
118endif()
119
120if(APPLE)
121 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
122endif()
123
124if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU")
125 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
126 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
127endif()
128
129if(BUILD_BBB OR BUILD_RASPI)
130 enable_language(ASM)
131 if(NOT BUILD_EGL)
132 add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
133 endif()
134endif()
135
136include(CheckFunctionExists)
137check_function_exists(strndup HAVE_STRNDUP)
138check_function_exists(snprintf_l HAVE_SNPRINTF_L)
139check_function_exists(strtof_l HAVE_STRTOF_L)
140check_function_exists(newlocale HAVE_NEWLOCALE)
141check_function_exists(freelocale HAVE_FREELOCALE)
142check_function_exists(uselocale HAVE_USELOCALE)
143
144if(HAVE_STRNDUP)
145 add_definitions(-DHAVE_STRNDUP)
146endif()
147
148if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE)
149 add_definitions(-DHAVE_LOCALE)
150 if (HAVE_STRTOF_L)
151 add_definitions(-DHAVE_STRTOF_L)
152 endif()
153 if (HAVE_SNPRINTF_L)
154 add_definitions(-DHAVE_SNPRINTF_L)
155 endif()
156endif()
157
158
159# Features
160set(DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/debugger.c ${CMAKE_SOURCE_DIR}/src/debugger/memory-debugger.c)
161set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
162
163if(USE_CLI_DEBUGGER)
164 add_definitions(-DUSE_CLI_DEBUGGER)
165 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/cli-debugger.c)
166 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/parser.c)
167 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/gba/supervisor/cli.c)
168 include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
169 link_directories(${LIBEDIT_LIBRARY_DIRS})
170 set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
171 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
172else()
173 set(DEBUGGER_LIB "")
174endif()
175
176if(USE_GDB_STUB)
177 add_definitions(-DUSE_GDB_STUB)
178 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/gdb-stub.c)
179endif()
180source_group("ARM debugger" FILES ${DEBUGGER_SRC})
181
182if(USE_FFMPEG)
183 add_definitions(-DUSE_FFMPEG)
184 pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
185 if(NOT LIBSWRESAMPLE_FOUND)
186 add_definitions(-DUSE_LIBAV)
187 endif()
188 include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
189 link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
190 list(APPEND UTIL_SRC "${CMAKE_SOURCE_DIR}/src/platform/ffmpeg/ffmpeg-encoder.c")
191 string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
192 string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
193 string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
194 string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
195 string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
196 list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
197 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR},libavformat${LIBAVFORMAT_VERSION_MAJOR},libavresample${LIBAVRESAMPLE_VERSION_MAJOR},libavutil${LIBAVUTIL_VERSION_MAJOR},libswscale${LIBSWSCALE_VERSION_MAJOR}")
198 set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra")
199endif()
200
201if(USE_BLIP)
202 list(APPEND UTIL_SRC "${CMAKE_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
203 add_definitions(-DRESAMPLE_LIBRARY=RESAMPLE_BLIP_BUF)
204else()
205 add_definitions(-DRESAMPLE_LIBRARY=RESAMPLE_NN)
206endif()
207
208if(USE_MAGICK)
209 add_definitions(-DUSE_MAGICK)
210 include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
211 link_directories(${MAGICKWAND_LIBRARY_DIRS})
212 list(APPEND UTIL_SRC "${CMAKE_SOURCE_DIR}/src/platform/imagemagick/imagemagick-gif-encoder.c")
213 list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
214 string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
215 if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
216 set(MAGICKWAND_DEB_VERSION "5")
217 else()
218 set(MAGICKWAND_DEB_VERSION "-6.q16-2")
219 endif()
220 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
221endif()
222
223if(USE_PNG)
224 add_definitions(-DUSE_PNG)
225 include_directories(AFTER ${PNG_INCLUDE_DIRS})
226 list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
227 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng12-0,zlib1g")
228endif()
229
230if(USE_LIBZIP)
231 include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
232 link_directories(${LIBZIP_LIBRARY_DIRS})
233 list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
234 add_definitions(-DENABLE_LIBZIP)
235 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
236endif()
237
238if (USE_LZMA)
239 include_directories(AFTER ${CMAKE_SOURCE_DIR}/third-party/lzma)
240 add_definitions(-D_7ZIP_PPMD_SUPPPORT)
241 set(LZMA_SRC
242 ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-lzma.c
243 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
244 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
245 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
246 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
247 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
248 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
249 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zDec.c
250 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
251 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
252 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
253 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bra.c
254 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bra86.c
255 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
256 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
257 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
258 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zFile.c
259 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
260 list(APPEND UTIL_SRC ${LZMA_SRC})
261 add_definitions(-DENABLE_LZMA)
262endif()
263
264# Binaries
265set(SRC
266 ${ARM_SRC}
267 ${GBA_SRC}
268 ${GBA_SV_SRC}
269 ${DEBUGGER_SRC}
270 ${RENDERER_SRC}
271 ${UTIL_SRC}
272 ${VFS_SRC}
273 ${OS_SRC}
274 ${THIRD_PARTY_SRC})
275
276if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
277 set(BUILD_SHARED ON)
278endif()
279
280if(BUILD_SHARED)
281 add_library(${BINARY_NAME} SHARED ${SRC})
282 if(BUILD_STATIC)
283 add_library(${BINARY_NAME}-static STATIC ${SRC})
284 install(TARGETS ${BINARY_NAME}-static DESTINATION lib COMPONENT lib${BINARY_NAME})
285 endif()
286else()
287 add_library(${BINARY_NAME} STATIC ${SRC})
288endif()
289
290target_link_libraries(${BINARY_NAME} m ${DEBUGGER_LIB} ${OS_LIB} ${DEPENDENCY_LIB})
291install(TARGETS ${BINARY_NAME} DESTINATION lib COMPONENT lib${BINARY_NAME})
292set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI})
293
294if(BUILD_SDL)
295 add_definitions(-DBUILD_SDL)
296 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/sdl ${CMAKE_BINARY_DIR}/sdl)
297endif()
298
299if(BUILD_QT)
300 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/qt ${CMAKE_BINARY_DIR}/qt)
301endif()
302
303if(BUILD_PERF)
304 set(PERF_SRC ${CMAKE_SOURCE_DIR}/src/platform/perf-main.c)
305 if(UNIX AND NOT APPLE)
306 list(APPEND PERF_LIB rt)
307 endif()
308
309 add_executable(${BINARY_NAME}-perf ${PERF_SRC})
310 target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB})
311 install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
312 install(FILES ${CMAKE_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
313endif()
314
315# Packaging
316set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
317set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
318set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
319set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_SOURCE_DIR}/LICENSE)
320set(CPACK_RESOURCE_FILE_README ${CMAKE_SOURCE_DIR}/README.md)
321
322set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
323set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
324set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
325set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_SOURCE_DIR}/README.md")
326set(CPACK_DEBIAN_PACKAGE_SECTION "games")
327
328SET(CPACK_DEB_COMPONENT_INSTALL ON)
329
330set(CPACK_STRIP_FILES ${BINARY_NAME})
331
332install(FILES ${CMAKE_SOURCE_DIR}/README.md ${CMAKE_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
333
334include(CPack)
335
336# Summaries
337message(STATUS "Feature summary:")
338message(STATUS " CLI debugger: ${USE_CLI_DEBUGGER}")
339message(STATUS " GDB stub: ${USE_GDB_STUB}")
340message(STATUS " Video recording: ${USE_FFMPEG}")
341message(STATUS " GIF recording: ${USE_MAGICK}")
342message(STATUS " Screenshot/advanced savestate support: ${USE_PNG}")
343message(STATUS " ZIP support: ${USE_LIBZIP}")
344message(STATUS " 7-Zip support: ${USE_LZMA}")
345message(STATUS " Better audio resampling: ${USE_BLIP}")
346message(STATUS "Frontend summary:")
347message(STATUS " Qt: ${BUILD_QT}")
348message(STATUS " SDL (${SDL_VERSION}): ${BUILD_SDL}")
349message(STATUS " Profiling: ${BUILD_PERF}")
350message(STATUS "Library summary:")
351message(STATUS " Static: ${BUILD_STATIC}")
352message(STATUS " Shared: ${BUILD_SHARED}")