1cmake_minimum_required(VERSION 2.6)
  2project(mGBA C)
  3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
  4if(NOT MSVC)
  5	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wno-missing-field-initializers -std=c99")
  6else()
  7	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_CRT_SECURE_NO_WARNINGS /wd4003 /wd4244 /wd4146")
  8endif()
  9set(USE_DEBUGGERS ON CACHE BOOL "Whether or not to enable the debugging infrastructure")
 10set(USE_EDITLINE ON CACHE BOOL "Whether or not to enable the CLI-mode debugger")
 11set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
 12set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
 13set(USE_ZLIB ON CACHE BOOL "Whether or not to enable zlib support")
 14set(USE_MINIZIP ON CACHE BOOL "Whether or not to enable external minizip support")
 15set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
 16set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable LIBZIP support")
 17set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
 18set(USE_SQLITE3 ON CACHE BOOL "Whether or not to enable SQLite3 support")
 19set(M_CORE_GBA ON CACHE BOOL "Build Game Boy Advance core")
 20set(M_CORE_GB ON CACHE BOOL "Build Game Boy core")
 21set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
 22set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
 23set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
 24set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
 25if(APPLE)
 26	set(BUILD_OPENEMU OFF CACHE BOOL "Build OpenEmu core")
 27endif()
 28set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
 29set(BUILD_TEST OFF CACHE BOOL "Build testing harness")
 30set(BUILD_SUITE OFF CACHE BOOL "Build test suite")
 31set(BUILD_EXAMPLE OFF CACHE BOOL "Build example frontends")
 32set(BUILD_PYTHON OFF CACHE BOOL "Build Python bindings")
 33set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
 34set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
 35set(SKIP_LIBRARY OFF CACHE BOOL "Skip building the library (useful for only building libretro or OpenEmu cores)")
 36set(BUILD_GL ON CACHE STRING "Build with OpenGL")
 37set(BUILD_GLES2 OFF CACHE STRING "Build with OpenGL|ES 2")
 38set(USE_EPOXY ON CACHE STRING "Build with libepoxy")
 39set(DISABLE_DEPS OFF CACHE BOOL "Build without dependencies")
 40file(GLOB ARM_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/*.c)
 41file(GLOB ARM_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/test/*.c)
 42file(GLOB LR35902_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/*.c)
 43file(GLOB LR35902_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/test/*.c)
 44file(GLOB GBA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/*.c)
 45file(GLOB GBA_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/test/*.c)
 46file(GLOB GB_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/*.c)
 47file(GLOB GB_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/test/*.c)
 48file(GLOB GBA_CHEATS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/cheats/*.c)
 49file(GLOB GBA_RR_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/rr/*.c)
 50file(GLOB CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/*.c)
 51file(GLOB CORE_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/test/*.c)
 52file(GLOB UTIL_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/*.[cSs])
 53file(GLOB UTIL_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/test/*.c)
 54file(GLOB GUI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/gui/*.c ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/gui/*.c)
 55file(GLOB GBA_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/renderers/*.c)
 56file(GLOB GBA_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/sio/lockstep.c)
 57file(GLOB GB_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/sio/lockstep.c)
 58file(GLOB GB_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/renderers/*.c)
 59file(GLOB THIRD_PARTY_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/inih/*.c)
 60set(CLI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/commandline.c)
 61set(CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-mem.c)
 62set(VFS_SRC)
 63source_group("ARM core" FILES ${ARM_SRC})
 64source_group("LR35902 core" FILES ${LR35902_SRC})
 65source_group("GBA board" FILES ${GBA_SRC} ${GBA_RENDERER_SRC} ${GBA_SIO_SRC})
 66source_group("GBA extra" FILES ${GBA_CHEATS_SRC} ${GBA_RR_SRC})
 67source_group("GB board" FILES ${GB_SRC} ${GB_SIO_SRC})
 68source_group("Utilities" FILES ${UTIL_SRC})
 69include_directories(BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/include ${CMAKE_CURRENT_SOURCE_DIR}/src)
 70
 71if(NOT CMAKE_BUILD_TYPE)
 72	set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
 73endif()
 74
 75include(GNUInstallDirs)
 76
 77set(LIBDIR "${CMAKE_INSTALL_LIBDIR}" CACHE PATH "Installed library directory")
 78mark_as_advanced(LIBDIR)
 79
 80if (BUILD_LIBRETRO)
 81	set(LIBRETRO_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (Libretro)")
 82	mark_as_advanced(LIBRETRO_LIBDIR)
 83endif()
 84
 85if (BUILD_OPENEMU)
 86	set(OE_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (OpenEmu)")
 87	mark_as_advanced(OE_LIBDIR)
 88endif()
 89
 90
 91set(CMAKE_INSTALL_RPATH "${LIBDIR}")
 92
 93if (NOT DEFINED MANDIR)
 94	set(MANDIR ${CMAKE_INSTALL_MANDIR})
 95endif()
 96
 97# Function definitions
 98include(FindPkgConfig)
 99function(find_feature FEATURE_NAME FEATURE_REQUIRES)
100	if (NOT ${FEATURE_NAME})
101		return()
102	endif()
103	if (DISABLE_DEPS)
104		set(${FEATURE_NAME} OFF PARENT_SCOPE)
105		return()
106	endif()
107	foreach(REQUIRE ${FEATURE_REQUIRES})
108		if(NOT ${REQUIRE}_FOUND)
109			find_package(${REQUIRE} QUIET)
110			if(NOT ${REQUIRE}_FOUND)
111				pkg_search_module(${REQUIRE} ${REQUIRE})
112				if (NOT ${REQUIRE}_FOUND)
113					message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
114					set(${FEATURE_NAME} OFF PARENT_SCOPE)
115					return()
116				endif()
117			endif()
118		endif()
119		string(TOUPPER ${REQUIRE} UREQUIRE)
120		set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
121		set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
122		set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
123		if (APPLE)
124			set(IS_FRAMEWORK OFF)
125			set(LIBS)
126			foreach(LIB IN LISTS ${REQUIRE}_LIBRARIES)
127				if(LIB STREQUAL "-framework")
128					set(IS_FRAMEWORK ON)
129				elseif(IS_FRAMEWORK)
130					list(APPEND LIBS "-framework ${LIB}")
131					set(IS_FRAMEWORK OFF)
132				else()
133					list(APPEND LIBS ${LIB})
134				endif()
135			endforeach()
136			set(${UREQUIRE}_LIBRARIES ${LIBS} PARENT_SCOPE)
137		else()
138			set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
139		endif()
140		set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
141		set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
142	endforeach()
143endfunction()
144
145# Version information
146add_custom_target(version-info ALL
147	COMMAND ${CMAKE_COMMAND}
148	-DBINARY_NAME=${BINARY_NAME}
149	-DCONFIG_FILE=${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in
150	-DOUT_FILE=${CMAKE_CURRENT_BINARY_DIR}/version.c
151	-P ${CMAKE_CURRENT_SOURCE_DIR}/version.cmake
152	WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
153
154include(${CMAKE_CURRENT_SOURCE_DIR}/version.cmake)
155configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in ${CMAKE_CURRENT_BINARY_DIR}/version.c)
156configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/flags.h.in ${CMAKE_CURRENT_BINARY_DIR}/flags.h)
157install(FILES ${CMAKE_CURRENT_BINARY_DIR}/flags.h DESTINATION include/mgba COMPONENT lib${BINARY_NAME})
158
159list(APPEND UTIL_SRC ${CMAKE_CURRENT_BINARY_DIR}/version.c)
160source_group("Generated sources" FILES ${CMAKE_CURRENT_BINARY_DIR}/version.c)
161
162# Advanced settings
163set(BUILD_LTO ON CACHE BOOL "Build with link-time optimization")
164set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
165set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
166set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
167mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
168set(PGO_PRE_FLAGS "-fprofile-generate=${PGO_DIR} -fprofile-arcs")
169set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
170
171if(BUILD_PGO AND NOT PGO_STAGE_2)
172	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
173	set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
174	set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
175elseif(BUILD_PGO AND PGO_STAGE_2)
176	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
177	set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
178	set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
179endif()
180
181# Platform support
182if(WIN32)
183	set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
184	add_definitions(-D_WIN32_WINNT=0x0600)
185	list(APPEND OS_LIB ws2_32 shlwapi)
186	list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/vfs-w32.c)
187	file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/*.c)
188	source_group("Windows-specific code" FILES ${OS_SRC})
189	if(MSVC)
190		add_definitions(-DNOMINMAX -DWIN32_LEAN_AND_MEAN)
191	endif()
192elseif(UNIX)
193	add_definitions(-DUSE_PTHREADS)
194
195	if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
196		add_definitions(-D_GNU_SOURCE)
197	endif()
198	if(NOT APPLE AND NOT HAIKU)
199		set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
200	endif()
201
202	list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
203	file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/posix/*.c)
204	source_group("POSIX-specific code" FILES ${OS_SRC})
205endif()
206
207if(APPLE)
208	add_definitions(-D_DARWIN_C_SOURCE)
209	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
210endif()
211
212if(NOT HAIKU AND NOT MSVC AND NOT PSP2)
213	set(M_LIBRARY m)
214endif()
215list(APPEND OS_LIB ${M_LIBRARY})
216
217if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
218	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
219	set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
220endif()
221
222if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
223	if(NOT BUILD_EGL)
224		add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
225	endif()
226endif()
227
228if(BUILD_RASPI)
229	set(BUILD_GL OFF CACHE BOOL "OpenGL not supported" FORCE)
230endif()
231
232if(BUILD_PANDORA)
233	add_definitions(-DBUILD_PANDORA)
234endif()
235
236if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
237	enable_language(ASM)
238endif()
239
240if(PSP2 OR WII)
241	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-format")
242endif()
243
244if(DEFINED 3DS OR DEFINED PSP2 OR DEFINED WII)
245	set(USE_DEBUGGERS OFF)
246	set(USE_SQLITE3 OFF)
247endif()
248
249if(NOT M_CORE_GBA)
250	set(USE_GDB_STUB OFF)
251endif()
252
253if(NOT USE_DEBUGGERS)
254	set(USE_EDITLINE OFF)
255	set(USE_GDB_STUB OFF)
256endif()
257
258if(WII)
259	add_definitions(-U__STRICT_ANSI__)
260endif()
261
262include(CheckFunctionExists)
263check_function_exists(strdup HAVE_STRDUP)
264check_function_exists(strndup HAVE_STRNDUP)
265check_function_exists(localtime_r HAVE_LOCALTIME_R)
266if(NOT CMAKE_SYSTEM_NAME STREQUAL "Generic")
267	check_function_exists(snprintf_l HAVE_SNPRINTF_L)
268	if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
269		# The strtof_l on Linux not actually exposed nor actually strtof_l
270		set(HAVE_STRTOF_L OFF)
271	else()
272		check_function_exists(strtof_l HAVE_STRTOF_L)
273	endif()
274	check_function_exists(newlocale HAVE_NEWLOCALE)
275	check_function_exists(freelocale HAVE_FREELOCALE)
276	check_function_exists(uselocale HAVE_USELOCALE)
277	check_function_exists(setlocale HAVE_SETLOCALE)
278else()
279	if(NOT DEFINED 3DS AND NOT DEFINED PSP2 AND NOT DEFINED WII)
280		set(DISABLE_DEPS ON CACHE BOOL "This platform cannot build with dependencies" FORCE)
281	endif()
282	set(DISABLE_FRONTENDS ON)
283	set(MINIMAL_CORE ON)
284endif()
285
286check_function_exists(chmod HAVE_CHMOD)
287check_function_exists(umask HAVE_UMASK)
288
289set(FUNCTION_DEFINES)
290
291if(HAVE_STRDUP)
292	list(APPEND FUNCTION_DEFINES HAVE_STRDUP)
293endif()
294
295if(HAVE_STRNDUP)
296	list(APPEND FUNCTION_DEFINES HAVE_STRNDUP)
297endif()
298
299if(HAVE_LOCALTIME_R)
300	list(APPEND FUNCTION_DEFINES HAVE_LOCALTIME_R)
301endif()
302
303if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE OR APPLE)
304	list(APPEND FUNCTION_DEFINES HAVE_LOCALE)
305	if (HAVE_STRTOF_L)
306		list(APPEND FUNCTION_DEFINES HAVE_STRTOF_L)
307	endif()
308	if (HAVE_SNPRINTF_L)
309		list(APPEND FUNCTION_DEFINES HAVE_SNPRINTF_L)
310	endif()
311endif()
312
313if(HAVE_SETLOCALE)
314	list(APPEND FUNCTION_DEFINES HAVE_SETLOCALE)
315endif()
316
317if(HAVE_CHMOD)
318	list(APPEND FUNCTION_DEFINES HAVE_CHMOD)
319endif()
320
321if(HAVE_UMASK)
322	list(APPEND FUNCTION_DEFINES HAVE_UMASK)
323endif()
324
325# Feature dependencies
326set(FEATURE_DEFINES)
327set(FEATURES)
328if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
329	set(LIBEDIT_LIBRARIES -ledit)
330	if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
331		list(APPEND LIBEDIT_LIBRARIES -ltermcap)
332	endif()
333else()
334	find_feature(USE_EDITLINE "libedit")
335endif()
336if(BUILD_GL)
337	find_package(OpenGL QUIET)
338	if(NOT OPENGL_FOUND)
339		set(BUILD_GL OFF CACHE BOOL "OpenGL not found" FORCE)
340	endif()
341endif()
342if(NOT BUILD_GL)
343	set(OPENGLE_LIBRARY "" CACHE PATH "" FORCE)
344endif()
345if(BUILD_GLES2 AND NOT BUILD_RASPI)
346	find_path(OPENGLES2_INCLUDE_DIR NAMES GLES2/gl2.h)
347	find_library(OPENGLES2_LIBRARY NAMES GLESv2 GLESv2_CM)
348	if(NOT OPENGLES2_INCLUDE_DIR OR NOT OPENGLES2_LIBRARY)
349		set(BUILD_GLES2 OFF CACHE BOOL "OpenGL|ES 2 not found" FORCE)
350	endif()
351endif()
352if(NOT BUILD_GLES2)
353	set(OPENGLES2_LIBRARY "" CACHE PATH "" FORCE)
354endif()
355set(WANT_ZLIB ${USE_ZLIB})
356set(WANT_PNG ${USE_PNG})
357set(WANT_LIBZIP ${USE_LIBZIP})
358set(WANT_SQLITE3 ${USE_SQLITE3})
359set(USE_CMOCKA ${BUILD_SUITE})
360
361find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
362find_feature(USE_ZLIB "ZLIB")
363find_feature(USE_MINIZIP "minizip")
364find_feature(USE_PNG "PNG")
365find_feature(USE_LIBZIP "libzip")
366find_feature(USE_MAGICK "MagickWand")
367find_feature(USE_EPOXY "epoxy")
368find_feature(USE_CMOCKA "cmocka")
369find_feature(USE_SQLITE3 "sqlite3")
370
371# Features
372set(DEBUGGER_SRC
373	${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/debugger.c
374	${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/parser.c
375	${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/cli-debugger.c)
376
377set(FEATURE_SRC)
378set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
379
380if(DISABLE_DEPS)
381	set(USE_GDB_STUB OFF)
382endif()
383
384if(USE_EDITLINE)
385	list(APPEND FEATURES EDITLINE)
386	include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
387	link_directories(${LIBEDIT_LIBRARY_DIRS})
388	set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
389	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
390	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/editline/cli-el-backend.c")
391else()
392	set(DEBUGGER_LIB "")
393endif()
394
395if(USE_GDB_STUB)
396	list(APPEND FEATURES GDB_STUB)
397	list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/gdb-stub.c)
398endif()
399source_group("Debugger" FILES ${DEBUGGER_SRC})
400
401if(USE_FFMPEG)
402	list(APPEND FEATURES FFMPEG)
403	pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
404	if(NOT LIBSWRESAMPLE_FOUND)
405		list(APPEND FEATURES LIBAV)
406	endif()
407	include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
408	link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
409	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/ffmpeg/ffmpeg-encoder.c")
410	string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
411	string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
412	string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
413	string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
414	string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
415	list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
416	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR}|libavcodec-extra-${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
417	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavformat${LIBAVFORMAT_VERSION_MAJOR}|libavformat-ffmpeg${LIBAVFORMAT_VERSION_MAJOR}")
418	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavresample${LIBAVRESAMPLE_VERSION_MAJOR}|libavresample-ffmpeg${LIBAVRESAMPLE_VERSION_MAJOR}")
419	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavutil${LIBAVUTIL_VERSION_MAJOR}|libavutil-ffmpeg${LIBAVUTIL_VERSION_MAJOR}")
420	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libswscale${LIBSWSCALE_VERSION_MAJOR}|libswscale-ffmpeg${LIBSWSCALE_VERSION_MAJOR}")
421	set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
422	if(APPLE)
423		set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
424		set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
425	endif()
426endif()
427
428list(APPEND THIRD_PARTY_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
429
430if(USE_MAGICK)
431	list(APPEND FEATURES MAGICK)
432	include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
433	link_directories(${MAGICKWAND_LIBRARY_DIRS})
434	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/imagemagick/imagemagick-gif-encoder.c")
435	list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
436	string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
437	string(REGEX MATCH "^[0-9]+" MAGICKWAND_VERSION_MAJOR ${MagickWand_VERSION})
438	if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
439		set(MAGICKWAND_DEB_VERSION "5")
440	elseif(${MagickWand_VERSION} EQUAL "6.9.7")
441		set(MAGICKWAND_DEB_VERSION "-6.q16-3")
442	else()
443		set(MAGICKWAND_DEB_VERSION "-6.q16-2")
444	endif()
445	list(APPEND FEATURE_DEFINES MAGICKWAND_VERSION_MAJOR=${MAGICKWAND_VERSION_MAJOR})
446
447	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
448endif()
449
450if(WANT_ZLIB AND NOT USE_ZLIB)
451	set(SKIP_INSTALL_ALL ON)
452	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib zlib)
453	set_property(TARGET zlibstatic PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/zlib;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib)
454	set_property(TARGET zlib PROPERTY EXCLUDE_FROM_ALL ON)
455	set_property(TARGET example PROPERTY EXCLUDE_FROM_ALL ON)
456	set_property(TARGET minigzip PROPERTY EXCLUDE_FROM_ALL ON)
457	set(ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
458	set(ZLIB_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
459	set(ZLIB_LIBRARY zlibstatic)
460	list(APPEND DEPENDENCY_LIB zlibstatic)
461	set(USE_ZLIB ON)
462endif()
463
464if(USE_ZLIB)
465	list(APPEND FEATURES ZLIB)
466	include_directories(AFTER ${ZLIB_INCLUDE_DIRS})
467	list(APPEND DEPENDENCY_LIB ${ZLIB_LIBRARIES})
468	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},zlib1g")
469endif()
470
471if(WANT_PNG AND USE_ZLIB AND NOT USE_PNG)
472	set(PNG_STATIC ON CACHE BOOL "" FORCE)
473	set(PNG_SHARED OFF CACHE BOOL "" FORCE)
474	set(PNG_TESTS OFF CACHE BOOL "" FORCE)
475	set(SKIP_INSTALL_ALL ON)
476	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng libpng)
477	set_property(TARGET png16_static PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/libpng;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng;${ZLIB_INCLUDE_DIRS})
478	set(PNG_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng ${CMAKE_CURRENT_BINARY_DIR}/libpng)
479	list(APPEND DEPENDENCY_LIB png16_static)
480	set(USE_PNG ON)
481endif()
482
483if(USE_PNG)
484	list(APPEND FEATURES PNG)
485	include_directories(AFTER ${PNG_INCLUDE_DIRS})
486	list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
487	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng12-0")
488endif()
489
490if(WANT_SQLITE3 AND NOT USE_SQLITE3)
491	list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/sqlite3.c)
492	include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/)
493	set(USE_SQLITE3 ON)
494endif()
495
496if(USE_LIBZIP)
497	include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
498	link_directories(${LIBZIP_LIBRARY_DIRS})
499	list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
500	list(APPEND FEATURES LIBZIP)
501	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
502	string(REGEX MATCH "^[0-9]+" LIBZIP_VERSION_MAJOR ${libzip_VERSION})
503	if (LIBZIP_VERSION_MAJOR LESS 1)
504		set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
505	elseif(LIBZIP_VERSION_MAJOR EQUAL 1)
506		set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip4")
507	else()
508		message(AUTHOR_WARNING Unknown version of libzip detected: ${libzip_VERSION})
509	endif()
510elseif(USE_MINIZIP)
511	include_directories(AFTER ${MINIZIP_INCLUDE_DIRS})
512	link_directories(${MINIZIP_LIBRARY_DIRS})
513	list(APPEND DEPENDENCY_LIB ${MINIZIP_LIBRARIES})
514	list(APPEND FEATURES MINIZIP)
515	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
516	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libminizip1")
517elseif(USE_ZLIB)
518	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c
519		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
520		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c)
521	set_source_files_properties(
522		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
523		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c
524		PROPERTIES COMPILE_FLAGS "-Wno-unused-parameter -Wno-implicit-function-declaration")
525endif()
526
527if (USE_LZMA)
528	include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/third-party/lzma)
529	add_definitions(-D_7ZIP_PPMD_SUPPPORT)
530	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-lzma.c)
531	set(LZMA_SRC
532		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
533		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
534		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
535		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
536		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
537		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
538		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zDec.c
539		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
540		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Delta.c
541		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
542		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
543		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra.c
544		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra86.c
545		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/BraIA64.c
546		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
547		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
548		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
549		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zFile.c
550		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
551	list(APPEND VFS_SRC ${LZMA_SRC})
552	list(APPEND FEATURES LZMA)
553endif()
554
555if(USE_EPOXY)
556	add_definitions(-DBUILD_GL -DBUILD_GLES2)
557	list(APPEND FEATURES EPOXY)
558	include_directories(AFTER ${EPOXY_INCLUDE_DIRS})
559	set(OPENGLES2_LIBRARY ${EPOXY_LIBRARIES})
560	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libepoxy0")
561endif()
562
563if(USE_SQLITE3)
564	list(APPEND FEATURES SQLITE3)
565	include_directories(AFTER ${SQLITE3_INCLUDE_DIRS})
566	list(APPEND DEPENDENCY_LIB ${SQLITE3_LIBRARIES})
567	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libsqlite3-0")
568	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/sqlite3/no-intro.c")
569endif()
570
571set(TEST_SRC ${CORE_TEST_SRC})
572if(M_CORE_GB)
573	add_definitions(-DM_CORE_GB)
574	list(APPEND CORE_SRC
575		${LR35902_SRC}
576		${GB_SRC}
577		${GB_RENDERER_SRC})
578	list(APPEND DEBUGGER_SRC
579		${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/cli-debugger.c
580		${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/debugger.c
581		${CMAKE_CURRENT_SOURCE_DIR}/src/gb/extra/cli.c)
582	list(APPEND TEST_SRC
583		${LR35902_TEST_SRC}
584		${GB_TEST_SRC})
585endif()
586
587if(M_CORE_GBA)
588	add_definitions(-DM_CORE_GBA)
589	list(APPEND CORE_SRC 
590		${ARM_SRC}
591		${GBA_SRC}
592		${GBA_CHEATS_SRC}
593		${GBA_RENDERER_SRC})
594	list(APPEND DEBUGGER_SRC
595		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c
596		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/debugger.c
597		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/memory-debugger.c
598		${CMAKE_CURRENT_SOURCE_DIR}/src/gba/extra/cli.c)
599	list(APPEND TEST_SRC
600		${ARM_TEST_SRC}
601		${GBA_TEST_SRC})
602	if(NOT M_CORE_GB)
603		list(APPEND CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/audio.c)
604	endif()
605endif()
606
607if(USE_DEBUGGERS)
608	list(APPEND FEATURE_SRC ${DEBUGGER_SRC})
609	list(APPEND FEATURES DEBUGGERS)
610endif()
611
612foreach(FEATURE IN LISTS FEATURES)
613	list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
614endforeach()
615
616source_group("Virtual files" FILES ${CORE_VFS_SRC} ${VFS_SRC})
617source_group("Extra features" FILES ${FEATURE_SRC})
618source_group("Third-party code" FILES ${THIRD_PARTY_SRC})
619
620# Platform binaries
621if(3DS)
622	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/3ds ${CMAKE_CURRENT_BINARY_DIR}/3ds)
623endif()
624
625if(WII)
626	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/wii ${CMAKE_CURRENT_BINARY_DIR}/wii)
627endif()
628
629if(PSP2)
630	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/psp2 ${CMAKE_CURRENT_BINARY_DIR}/psp2)
631endif()
632
633# Binaries
634list(APPEND CORE_SRC
635	${UTIL_SRC}
636	${CORE_VFS_SRC}
637	${OS_SRC}
638	${THIRD_PARTY_SRC})
639list(APPEND TEST_SRC ${UTIL_TEST_SRC})
640
641set(SRC ${CORE_SRC} ${VFS_SRC})
642if(NOT MINIMAL_CORE)
643	if(M_CORE_GBA)
644		list(APPEND SRC
645			${GBA_RR_SRC}
646			${GBA_EXTRA_SRC}
647			${GBA_SIO_SRC})
648	endif()
649	if(M_CORE_GB)
650		list(APPEND SRC
651			${GB_SIO_SRC})
652	endif()
653	list(APPEND SRC
654		${FEATURE_SRC}
655		${CLI_SRC})
656endif()
657
658if(NOT SKIP_LIBRARY)
659	if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
660		set(BUILD_SHARED ON)
661	endif()
662
663	if(BUILD_SHARED)
664		add_library(${BINARY_NAME} SHARED ${SRC} ${VFS_SRC})
665		if(BUILD_STATIC)
666			add_library(${BINARY_NAME}-static STATIC ${SRC})
667			set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
668			install(TARGETS ${BINARY_NAME}-static DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
669			add_dependencies(${BINARY_NAME}-static version-info)
670		endif()
671	else()
672		add_library(${BINARY_NAME} STATIC ${SRC})
673	endif()
674
675	add_dependencies(${BINARY_NAME} version-info)
676	set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
677
678	target_link_libraries(${BINARY_NAME} ${DEBUGGER_LIB} ${DEPENDENCY_LIB} ${OS_LIB})
679	install(TARGETS ${BINARY_NAME} LIBRARY DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME} NAMELINK_SKIP ARCHIVE DESTINATION ${LIBDIR} RUNTIME DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
680	if(UNIX AND NOT APPLE)
681		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-16.png DESTINATION share/icons/hicolor/16x16/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
682		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-24.png DESTINATION share/icons/hicolor/24x24/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
683		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-32.png DESTINATION share/icons/hicolor/32x32/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
684		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-48.png DESTINATION share/icons/hicolor/48x48/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
685		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-64.png DESTINATION share/icons/hicolor/64x64/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
686		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-96.png DESTINATION share/icons/hicolor/96x96/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
687		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-128.png DESTINATION share/icons/hicolor/128x128/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
688		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-256.png DESTINATION share/icons/hicolor/256x256/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
689		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-512.png DESTINATION share/icons/hicolor/512x512/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
690	endif()
691else()
692	set(BUILD_SHARED OFF)
693	set(BUILD_STATIC OFF)
694	find_library(${BINARY_NAME} ${BINARY_NAME})
695	if(NOT ${BINARY_NAME}_FOUND)
696		set(DISABLE_FRONTENDS ON)
697		set(BUILD_PERF OFF)
698		set(BUILD_TEST OFF)
699		set(BUILD_SUITE OFF)
700	endif()
701endif()
702
703if(BUILD_GL)
704	add_definitions(-DBUILD_GL)
705endif()
706
707if(BUILD_GLES2)
708	add_definitions(-DBUILD_GLES2)
709endif()
710
711if(DISABLE_FRONTENDS)
712	set(BUILD_SDL OFF)
713	set(BUILD_QT OFF)
714endif()
715
716if(BUILD_LIBRETRO)
717	file(GLOB RETRO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/libretro/*.c)
718	add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
719	set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5;DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=2")
720	target_link_libraries(${BINARY_NAME}_libretro ${OS_LIB})
721	install(TARGETS ${BINARY_NAME}_libretro LIBRARY DESTINATION ${LIBRETRO_LIBDIR} COMPONENT ${BINARY_NAME}_libretro NAMELINK_SKIP)
722endif()
723
724if(BUILD_OPENEMU)
725	find_library(FOUNDATION Foundation)
726	find_library(OPENEMUBASE OpenEmuBase)
727	file(GLOB OE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/*.m)
728	add_library(${BINARY_NAME}-openemu MODULE ${CORE_SRC} ${OE_SRC})
729	set_target_properties(${BINARY_NAME}-openemu PROPERTIES
730		MACOSX_BUNDLE_INFO_PLIST ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/Info.plist.in
731		BUNDLE TRUE
732		BUNDLE_EXTENSION oecoreplugin
733		OUTPUT_NAME ${PROJECT_NAME}
734		COMPILE_DEFINITIONS "DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=1")
735	target_link_libraries(${BINARY_NAME}-openemu ${OS_LIB} ${FOUNDATION} ${OPENEMUBASE})
736	install(TARGETS ${BINARY_NAME}-openemu LIBRARY DESTINATION ${OE_LIBDIR} COMPONENT ${BINARY_NAME}.oecoreplugin NAMELINK_SKIP)
737endif()
738
739if(BUILD_SDL)
740	add_definitions(-DBUILD_SDL)
741	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/sdl ${CMAKE_CURRENT_BINARY_DIR}/sdl)
742endif()
743
744if(BUILD_QT)
745	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/qt ${CMAKE_CURRENT_BINARY_DIR}/qt)
746endif()
747
748if(BUILD_PERF)
749	set(PERF_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/perf-main.c ${CLI_SRC})
750	if(UNIX AND NOT APPLE)
751		list(APPEND PERF_LIB rt)
752	endif()
753
754	add_executable(${BINARY_NAME}-perf ${PERF_SRC})
755	target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB} ${OS_LIB})
756	set_target_properties(${BINARY_NAME}-perf PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
757	install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
758	install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
759endif()
760
761if(BUILD_TEST)
762	add_executable(${BINARY_NAME}-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/fuzz-main.c)
763	target_link_libraries(${BINARY_NAME}-fuzz ${BINARY_NAME})
764	set_target_properties(${BINARY_NAME}-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
765	add_executable(tbl-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/tbl-fuzz-main.c)
766	target_link_libraries(tbl-fuzz ${BINARY_NAME})
767	set_target_properties(tbl-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
768	install(TARGETS ${BINARY_NAME}-fuzz tbl-fuzz DESTINATION bin COMPONENT ${BINARY_NAME}-test)
769endif()
770
771if(NOT USE_CMOCKA)
772	set(BUILD_SUITE OFF)
773endif()
774if(BUILD_SUITE)
775	enable_testing()
776	include_directories(AFTER ${CMOCKA_INCLUDE_DIRS})
777	link_directories(${CMOCKA_LIBRARY_DIRS})
778
779	add_executable(${BINARY_NAME}-suite ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/suite-main.c ${TEST_SRC})
780	target_link_libraries(${BINARY_NAME}-suite ${BINARY_NAME} ${PLATFORM_LIBRARY} cmocka)
781	set_target_properties(${BINARY_NAME}-suite PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
782	add_test(${BINARY_NAME}-suite ${BINARY_NAME}-suite)
783endif()
784
785if(BUILD_PYTHON)
786	enable_testing()
787	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/python ${CMAKE_CURRENT_BINARY_DIR}/python)
788endif()
789
790if(BUILD_EXAMPLE)
791	add_executable(${BINARY_NAME}-example-server ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/server.c)
792	target_link_libraries(${BINARY_NAME}-example-server ${BINARY_NAME})
793	set_target_properties(${BINARY_NAME}-example-server PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
794
795	if(BUILD_SDL)
796		add_executable(${BINARY_NAME}-example-client ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/client.c)
797		target_link_libraries(${BINARY_NAME}-example-client ${BINARY_NAME} ${SDL_LIBRARY} ${SDLMAIN_LIBRARY} ${OPENGL_LIBRARY} ${OPENGLES2_LIBRARY})
798		set_target_properties(${BINARY_NAME}-example-client PROPERTIES
799		                      COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}"
800		                      INCLUDE_DIRECTORIES "${SDL_INCLUDE_DIR};${CMAKE_CURRENT_SOURCE_DIR}/src;${CMAKE_CURRENT_SOURCE_DIR}/include")
801	endif()
802endif()
803
804# Packaging
805set(CPACK_PACKAGE_VERSION ${VERSION_STRING})
806set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
807set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
808set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
809set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
810set(CPACK_RESOURCE_FILE_README ${CMAKE_CURRENT_SOURCE_DIR}/README.md)
811
812set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
813set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
814set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
815set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README.md")
816set(CPACK_DEBIAN_PACKAGE_SECTION "games")
817
818SET(CPACK_DEB_COMPONENT_INSTALL ON)
819
820set(CPACK_STRIP_FILES ${BINARY_NAME})
821
822install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/README.md ${CMAKE_CURRENT_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
823
824include(CPack)
825
826# Summaries
827set(SUMMARY_GL_LIST)
828if(USE_EPOXY)
829	set(SUMMARY_GL_LIST "libepoxy")
830else()
831	if(BUILD_GL)
832		list(APPEND SUMMARY_GL_LIST "OpenGL")
833	endif()
834	if(BUILD_GLES2)
835		list(APPEND SUMMARY_GL_LIST "OpenGL|ES 2")
836	endif()
837endif()
838if(NOT SUMMARY_GL_LIST)
839	set(SUMMARY_GL OFF)
840else()
841	string(REPLACE ";" ", " SUMMARY_GL "${SUMMARY_GL_LIST}")
842endif()
843if(USE_LIBZIP)
844	set(SUMMARY_ZIP libzip)
845elseif(USE_MINIZIP)
846	set(SUMMARY_ZIP "minizip (external)")
847elseif(USE_ZLIB)
848	set(SUMMARY_ZIP "minizip (included)")
849else()
850	set(SUMMARY_ZIP OFF)
851endif()
852
853if(NOT QUIET)
854	message(STATUS "Platforms:")
855	message(STATUS "	Game Boy Advance: ${M_CORE_GBA}")
856	message(STATUS "	Game Boy: ${M_CORE_GB}")
857	message(STATUS "Features:")
858	message(STATUS "	Debuggers: ${USE_DEBUGGERS}")
859	message(STATUS "	CLI debugger: ${USE_EDITLINE}")
860	message(STATUS "	GDB stub: ${USE_GDB_STUB}")
861	message(STATUS "	Video recording: ${USE_FFMPEG}")
862	message(STATUS "	GIF recording: ${USE_MAGICK}")
863	message(STATUS "	Screenshot/advanced savestate support: ${USE_PNG}")
864	message(STATUS "	ZIP support: ${SUMMARY_ZIP}")
865	message(STATUS "	7-Zip support: ${USE_LZMA}")
866	message(STATUS "	SQLite3 game database: ${USE_SQLITE3}")
867	message(STATUS "	OpenGL support: ${SUMMARY_GL}")
868	message(STATUS "Frontends:")
869	message(STATUS "	Qt: ${BUILD_QT}")
870	message(STATUS "	SDL (${SDL_VERSION}): ${BUILD_SDL}")
871	message(STATUS "	Profiling: ${BUILD_PERF}")
872	message(STATUS "	Test harness: ${BUILD_TEST}")
873	message(STATUS "	Test suite: ${BUILD_SUITE}")
874	message(STATUS "	Python bindings: ${BUILD_PYTHON}")
875	message(STATUS "	Examples: ${BUILD_EXAMPLE}")
876	message(STATUS "Cores:")
877	message(STATUS "	Libretro core: ${BUILD_LIBRETRO}")
878	if(APPLE)
879		message(STATUS "	OpenEmu core: ${BUILD_OPENEMU}")
880	endif()
881	message(STATUS "Libraries:")
882	message(STATUS "	Static: ${BUILD_STATIC}")
883	message(STATUS "	Shared: ${BUILD_SHARED}")
884endif()