CMakeLists.txt (view raw)
1cmake_minimum_required(VERSION 2.6)
2project(mGBA C)
3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
4if(NOT MSVC)
5 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -std=c99")
6else()
7 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_CRT_SECURE_NO_WARNINGS /wd4003 /wd4244 /wd4146")
8endif()
9set(USE_CLI_DEBUGGER ON CACHE BOOL "Whether or not to enable the CLI-mode ARM debugger")
10set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
11set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
12set(USE_ZLIB ON CACHE BOOL "Whether or not to enable zlib support")
13set(USE_MINIZIP ON CACHE BOOL "Whether or not to enable external minizip support")
14set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
15set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable LIBZIP support")
16set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
17set(USE_BLIP ON CACHE BOOL "Whether or not to enable blip_buf support")
18set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
19set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
20set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
21set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
22if(APPLE)
23 set(BUILD_OPENEMU OFF CACHE BOOL "Build OpenEmu core")
24endif()
25set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
26set(BUILD_TEST OFF CACHE BOOL "Build testing harness")
27set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
28set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
29set(SKIP_LIBRARY OFF CACHE BOOL "Skip building the library (useful for only building libretro or OpenEmu cores)")
30set(BUILD_GL ON CACHE STRING "Build with OpenGL")
31set(BUILD_GLES2 OFF CACHE STRING "Build with OpenGL|ES 2")
32set(USE_EPOXY ON CACHE STRING "Build with libepoxy")
33set(DISABLE_DEPS OFF CACHE BOOL "Build without dependencies")
34file(GLOB ARM_SRC ${CMAKE_SOURCE_DIR}/src/arm/*.c)
35file(GLOB GBA_SRC ${CMAKE_SOURCE_DIR}/src/gba/*.c)
36file(GLOB GBA_CHEATS_SRC ${CMAKE_SOURCE_DIR}/src/gba/cheats/*.c)
37file(GLOB GBA_RR_SRC ${CMAKE_SOURCE_DIR}/src/gba/rr/*.c)
38file(GLOB GBA_SV_SRC ${CMAKE_SOURCE_DIR}/src/gba/supervisor/*.c)
39file(GLOB GBA_CTX_SRC ${CMAKE_SOURCE_DIR}/src/gba/context/*.c)
40file(GLOB UTIL_SRC ${CMAKE_SOURCE_DIR}/src/util/*.[cSs])
41file(GLOB GUI_SRC ${CMAKE_SOURCE_DIR}/src/util/gui/*.c ${CMAKE_SOURCE_DIR}/src/gba/gui/*.c)
42file(GLOB RENDERER_SRC ${CMAKE_SOURCE_DIR}/src/gba/renderers/*.c)
43file(GLOB SIO_SRC ${CMAKE_SOURCE_DIR}/src/gba/sio/lockstep.c)
44file(GLOB THIRD_PARTY_SRC ${CMAKE_SOURCE_DIR}/src/third-party/inih/*.c)
45list(APPEND GBA_SV_SRC ${CMAKE_SOURCE_DIR}/src/platform/commandline.c)
46set(CORE_VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-mem.c)
47set(VFS_SRC)
48source_group("ARM core" FILES ${ARM_SRC})
49source_group("GBA board" FILES ${GBA_SRC} ${RENDERER_SRC} ${SIO_SRC})
50source_group("GBA extra" FILES ${GBA_CHEATS_SRC} ${GBA_CTX_SRC} ${GBA_SV_SRC} ${GBA_RR_SRC})
51source_group("Utilities" FILES ${UTIL_SRC})
52include_directories(${CMAKE_SOURCE_DIR}/src/arm)
53include_directories(${CMAKE_SOURCE_DIR}/src)
54
55if(NOT CMAKE_BUILD_TYPE)
56 set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
57endif()
58
59set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${LIBDIR}")
60
61include(GNUInstallDirs)
62
63if (NOT DEFINED LIBDIR)
64 set(LIBDIR "lib")
65endif()
66
67if (NOT DEFINED MANDIR)
68 set(MANDIR ${CMAKE_INSTALL_MANDIR})
69endif()
70
71# Function definitions
72include(FindPkgConfig)
73function(find_feature FEATURE_NAME FEATURE_REQUIRES)
74 if (NOT ${FEATURE_NAME})
75 return()
76 endif()
77 if (DISABLE_DEPS)
78 set(${FEATURE_NAME} OFF PARENT_SCOPE)
79 return()
80 endif()
81 foreach(REQUIRE ${FEATURE_REQUIRES})
82 if(NOT ${REQUIRE}_FOUND)
83 find_package(${REQUIRE} QUIET)
84 if(NOT ${REQUIRE}_FOUND)
85 pkg_search_module(${REQUIRE} ${REQUIRE})
86 if (NOT ${REQUIRE}_FOUND)
87 message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
88 set(${FEATURE_NAME} OFF PARENT_SCOPE)
89 return()
90 endif()
91 endif()
92 endif()
93 string(TOUPPER ${REQUIRE} UREQUIRE)
94 set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
95 set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
96 set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
97 set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
98 set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
99 set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
100 endforeach()
101endfunction()
102
103# Version information
104add_custom_target(version-info ALL ${CMAKE_COMMAND} -E touch ${CMAKE_SOURCE_DIR}/src/util/version.c.in
105 COMMAND ${CMAKE_COMMAND}
106 -DBINARY_NAME=${BINARY_NAME}
107 -DCONFIG_FILE=${CMAKE_SOURCE_DIR}/src/util/version.c.in
108 -DOUT_FILE=${CMAKE_CURRENT_BINARY_DIR}/version.c
109 -P ${CMAKE_SOURCE_DIR}/version.cmake
110 WORKING_DIRECTORY ${CMAKE_BINARY_DIR})
111
112include(${CMAKE_SOURCE_DIR}/version.cmake)
113configure_file(${CMAKE_SOURCE_DIR}/src/util/version.c.in ${CMAKE_CURRENT_BINARY_DIR}/version.c)
114list(APPEND UTIL_SRC ${CMAKE_BINARY_DIR}/version.c)
115source_group("Generated sources" FILES ${CMAKE_BINARY_DIR}/version.c)
116
117# Advanced settings
118set(BUILD_LTO ON CACHE BOOL "Build with link-time optimization")
119set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
120set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
121set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
122mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
123set(PGO_PRE_FLAGS "-fprofile-generate=${PGO_DIR} -fprofile-arcs")
124set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
125
126if(BUILD_PGO AND NOT PGO_STAGE_2)
127 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
128 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
129 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
130elseif(BUILD_PGO AND PGO_STAGE_2)
131 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
132 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
133 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
134endif()
135
136# Platform support
137if(WIN32)
138 set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
139 add_definitions(-D_WIN32_WINNT=0x0600)
140 list(APPEND OS_LIB ws2_32 shlwapi)
141 list(APPEND CORE_VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
142 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/windows/*.c)
143 source_group("Windows-specific code" FILES ${OS_SRC})
144elseif(UNIX)
145 add_definitions(-DUSE_PTHREADS)
146
147 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
148 add_definitions(-D_GNU_SOURCE)
149 endif()
150 if(NOT APPLE AND NOT HAIKU)
151 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
152 endif()
153
154 list(APPEND CORE_VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
155 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/posix/*.c)
156 source_group("POSIX-specific code" FILES ${OS_SRC})
157endif()
158
159if(APPLE)
160 add_definitions(-D_DARWIN_C_SOURCE)
161 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
162endif()
163
164if(NOT HAIKU AND NOT MSVC AND NOT PSP2)
165 set(M_LIBRARY m)
166endif()
167list(APPEND OS_LIB ${M_LIBRARY})
168
169if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
170 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
171 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
172 set_source_files_properties(${CMAKE_SOURCE_DIR}/src/arm/isa-arm.c ${CMAKE_SOURCE_DIR}/src/arm/isa-thumb.c PROPERTIES COMPILE_FLAGS -fno-lto)
173endif()
174
175if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
176 if(NOT BUILD_EGL)
177 add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
178 endif()
179endif()
180
181if(BUILD_RASPI)
182 set(BUILD_GL OFF CACHE BOOL "OpenGL not supported" FORCE)
183endif()
184
185if(BUILD_PANDORA)
186 add_definitions(-DBUILD_PANDORA)
187endif()
188
189if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
190 enable_language(ASM)
191endif()
192
193if(PSP2 OR WII)
194 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-format")
195endif()
196
197if(DEFINED 3DS OR DEFINED PSP2 OR DEFINED WII)
198 set(USE_GDB_STUB OFF)
199endif()
200
201if(WII)
202 add_definitions(-U__STRICT_ANSI__)
203endif()
204
205include(CheckFunctionExists)
206check_function_exists(strdup HAVE_STRDUP)
207check_function_exists(strndup HAVE_STRNDUP)
208check_function_exists(localtime_r HAVE_LOCALTIME_R)
209if(NOT CMAKE_SYSTEM_NAME STREQUAL "Generic")
210 check_function_exists(snprintf_l HAVE_SNPRINTF_L)
211 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
212 # The strtof_l on Linux not actually exposed nor actually strtof_l
213 set(HAVE_STRTOF_L OFF)
214 else()
215 check_function_exists(strtof_l HAVE_STRTOF_L)
216 endif()
217 check_function_exists(newlocale HAVE_NEWLOCALE)
218 check_function_exists(freelocale HAVE_FREELOCALE)
219 check_function_exists(uselocale HAVE_USELOCALE)
220 check_function_exists(setlocale HAVE_SETLOCALE)
221else()
222 if(NOT DEFINED 3DS AND NOT DEFINED PSP2 AND NOT DEFINED WII)
223 set(DISABLE_DEPS ON CACHE BOOL "This platform cannot build with dependencies" FORCE)
224 endif()
225 set(DISABLE_FRONTENDS ON)
226 set(MINIMAL_CORE ON)
227endif()
228
229check_function_exists(chmod HAVE_CHMOD)
230check_function_exists(umask HAVE_UMASK)
231
232set(FUNCTION_DEFINES)
233
234if(HAVE_STRDUP)
235 list(APPEND FUNCTION_DEFINES HAVE_STRDUP)
236endif()
237
238if(HAVE_STRNDUP)
239 list(APPEND FUNCTION_DEFINES HAVE_STRNDUP)
240endif()
241
242if(HAVE_LOCALTIME_R)
243 list(APPEND FUNCTION_DEFINES HAVE_LOCALTIME_R)
244endif()
245
246if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE)
247 list(APPEND FUNCTION_DEFINES HAVE_LOCALE)
248 if (HAVE_STRTOF_L)
249 list(APPEND FUNCTION_DEFINES HAVE_STRTOF_L)
250 endif()
251 if (HAVE_SNPRINTF_L)
252 list(APPEND FUNCTION_DEFINES HAVE_SNPRINTF_L)
253 endif()
254endif()
255
256if(HAVE_SETLOCALE)
257 list(APPEND FUNCTION_DEFINES HAVE_SETLOCALE)
258endif()
259
260if(HAVE_CHMOD)
261 list(APPEND FUNCTION_DEFINES HAVE_CHMOD)
262endif()
263
264if(HAVE_UMASK)
265 list(APPEND FUNCTION_DEFINES HAVE_UMASK)
266endif()
267
268# Feature dependencies
269set(FEATURES)
270if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
271 set(LIBEDIT_LIBRARIES -ledit)
272 if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
273 list(APPEND LIBEDIT_LIBRARIES -ltermcap)
274 endif()
275else()
276 find_feature(USE_CLI_DEBUGGER "libedit")
277endif()
278if(BUILD_GL)
279 find_package(OpenGL QUIET)
280 if(NOT OPENGL_FOUND)
281 set(BUILD_GL OFF CACHE BOOL "OpenGL not found" FORCE)
282 endif()
283endif()
284if(NOT BUILD_GL)
285 set(OPENGLE_LIBRARY "" CACHE PATH "" FORCE)
286endif()
287if(BUILD_GLES2 AND NOT BUILD_RASPI)
288 find_path(OPENGLES2_INCLUDE_DIR NAMES GLES2/gl2.h)
289 find_library(OPENGLES2_LIBRARY NAMES GLESv2 GLESv2_CM)
290 if(NOT OPENGLES2_INCLUDE_DIR OR NOT OPENGLES2_LIBRARY)
291 set(BUILD_GLES2 OFF CACHE BOOL "OpenGL|ES 2 not found" FORCE)
292 endif()
293endif()
294if(NOT BUILD_GLES2)
295 set(OPENGLES2_LIBRARY "" CACHE PATH "" FORCE)
296endif()
297set(WANT_ZLIB ${USE_ZLIB})
298set(WANT_PNG ${USE_PNG})
299set(WANT_LIBZIP ${USE_LIBZIP})
300
301find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
302find_feature(USE_ZLIB "ZLIB")
303find_feature(USE_MINIZIP "minizip")
304find_feature(USE_PNG "PNG")
305find_feature(USE_LIBZIP "libzip")
306find_feature(USE_MAGICK "MagickWand")
307find_feature(USE_EPOXY "epoxy")
308
309# Features
310set(DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/debugger.c ${CMAKE_SOURCE_DIR}/src/debugger/memory-debugger.c)
311set(FEATURE_SRC)
312set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
313
314if(DISABLE_DEPS)
315 set(USE_GDB_STUB OFF)
316endif()
317
318if(USE_CLI_DEBUGGER)
319 list(APPEND FEATURES CLI_DEBUGGER)
320 list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/debugger/cli-debugger.c)
321 list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/debugger/parser.c)
322 list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/gba/supervisor/cli.c)
323 include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
324 link_directories(${LIBEDIT_LIBRARY_DIRS})
325 set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
326 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
327else()
328 set(DEBUGGER_LIB "")
329endif()
330
331if(USE_GDB_STUB)
332 list(APPEND FEATURES GDB_STUB)
333 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/gdb-stub.c)
334endif()
335source_group("ARM debugger" FILES ${DEBUGGER_SRC})
336
337if(USE_FFMPEG)
338 list(APPEND FEATURES FFMPEG)
339 pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
340 if(NOT LIBSWRESAMPLE_FOUND)
341 list(APPEND FEATURES LIBAV)
342 endif()
343 include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
344 link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
345 list(APPEND FEATURE_SRC "${CMAKE_SOURCE_DIR}/src/platform/ffmpeg/ffmpeg-encoder.c")
346 string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
347 string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
348 string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
349 string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
350 string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
351 list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
352 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR}|libavcodec-extra-${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
353 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavformat${LIBAVFORMAT_VERSION_MAJOR}|libavformat-ffmpeg${LIBAVFORMAT_VERSION_MAJOR}")
354 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavresample${LIBAVRESAMPLE_VERSION_MAJOR}|libavresample-ffmpeg${LIBAVRESAMPLE_VERSION_MAJOR}")
355 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavutil${LIBAVUTIL_VERSION_MAJOR}|libavutil-ffmpeg${LIBAVUTIL_VERSION_MAJOR}")
356 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libswscale${LIBSWSCALE_VERSION_MAJOR}|libswscale-ffmpeg${LIBSWSCALE_VERSION_MAJOR}")
357 set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
358 if(APPLE)
359 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
360 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
361 endif()
362endif()
363
364if(USE_BLIP)
365 list(APPEND THIRD_PARTY_SRC "${CMAKE_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
366 add_definitions(-DRESAMPLE_LIBRARY=RESAMPLE_BLIP_BUF)
367else()
368 add_definitions(-DRESAMPLE_LIBRARY=RESAMPLE_NN)
369endif()
370
371if(USE_MAGICK)
372 list(APPEND FEATURES MAGICK)
373 include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
374 link_directories(${MAGICKWAND_LIBRARY_DIRS})
375 list(APPEND FEATURE_SRC "${CMAKE_SOURCE_DIR}/src/platform/imagemagick/imagemagick-gif-encoder.c")
376 list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
377 string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
378 if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
379 set(MAGICKWAND_DEB_VERSION "5")
380 else()
381 set(MAGICKWAND_DEB_VERSION "-6.q16-2")
382 endif()
383 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
384endif()
385
386if(WANT_ZLIB AND NOT USE_ZLIB)
387 set(SKIP_INSTALL_ALL ON)
388 add_subdirectory(${CMAKE_SOURCE_DIR}/src/third-party/zlib zlib)
389 set_property(TARGET zlibstatic PROPERTY INCLUDE_DIRECTORIES ${CMAKE_BINARY_DIR}/zlib;${CMAKE_SOURCE_DIR}/src/third-party/zlib)
390 set_property(TARGET zlib PROPERTY EXCLUDE_FROM_ALL ON)
391 set_property(TARGET example PROPERTY EXCLUDE_FROM_ALL ON)
392 set_property(TARGET minigzip PROPERTY EXCLUDE_FROM_ALL ON)
393 set(ZLIB_INCLUDE_DIRS ${CMAKE_SOURCE_DIR}/src/third-party/zlib ${CMAKE_BINARY_DIR}/zlib)
394 set(ZLIB_INCLUDE_DIR ${CMAKE_SOURCE_DIR}/src/third-party/zlib ${CMAKE_BINARY_DIR}/zlib)
395 set(ZLIB_LIBRARY zlibstatic)
396 list(APPEND DEPENDENCY_LIB zlibstatic)
397 set(USE_ZLIB ON)
398endif()
399
400if(USE_ZLIB)
401 list(APPEND FEATURES ZLIB)
402 include_directories(AFTER ${ZLIB_INCLUDE_DIRS})
403 list(APPEND DEPENDENCY_LIB ${ZLIB_LIBRARIES})
404 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},zlib1g")
405endif()
406
407if(WANT_PNG AND USE_ZLIB AND NOT USE_PNG)
408 set(PNG_STATIC ON CACHE BOOL "" FORCE)
409 set(PNG_SHARED OFF CACHE BOOL "" FORCE)
410 set(PNG_TESTS OFF CACHE BOOL "" FORCE)
411 set(SKIP_INSTALL_ALL ON)
412 add_subdirectory(${CMAKE_SOURCE_DIR}/src/third-party/libpng libpng)
413 set_property(TARGET png16_static PROPERTY INCLUDE_DIRECTORIES ${CMAKE_BINARY_DIR}/libpng;${CMAKE_SOURCE_DIR}/src/third-party/libpng;${ZLIB_INCLUDE_DIRS})
414 set(PNG_INCLUDE_DIRS ${CMAKE_SOURCE_DIR}/src/third-party/libpng ${CMAKE_BINARY_DIR}/libpng)
415 list(APPEND DEPENDENCY_LIB png16_static)
416 set(USE_PNG ON)
417endif()
418
419if(USE_PNG)
420 list(APPEND FEATURES PNG)
421 include_directories(AFTER ${PNG_INCLUDE_DIRS})
422 list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
423 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng12-0")
424endif()
425
426if(USE_LIBZIP)
427 include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
428 link_directories(${LIBZIP_LIBRARY_DIRS})
429 list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
430 list(APPEND FEATURES LIBZIP)
431 list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
432 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
433elseif(USE_MINIZIP)
434 include_directories(AFTER ${MINIZIP_INCLUDE_DIRS})
435 link_directories(${MINIZIP_LIBRARY_DIRS})
436 list(APPEND DEPENDENCY_LIB ${MINIZIP_LIBRARIES})
437 list(APPEND FEATURES MINIZIP)
438 list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
439 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libminizip1")
440elseif(USE_ZLIB)
441 list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-zip.c
442 ${CMAKE_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
443 ${CMAKE_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c)
444endif()
445
446if (USE_LZMA)
447 include_directories(AFTER ${CMAKE_SOURCE_DIR}/third-party/lzma)
448 add_definitions(-D_7ZIP_PPMD_SUPPPORT)
449 list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-lzma.c)
450 set(LZMA_SRC
451 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
452 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
453 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
454 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
455 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
456 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
457 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zDec.c
458 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
459 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Delta.c
460 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
461 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
462 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bra.c
463 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bra86.c
464 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/BraIA64.c
465 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
466 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
467 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
468 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zFile.c
469 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
470 list(APPEND VFS_SRC ${LZMA_SRC})
471 list(APPEND FEATURES LZMA)
472endif()
473
474if(USE_EPOXY)
475 add_definitions(-DBUILD_GL -DBUILD_GLES2)
476 list(APPEND FEATURES EPOXY)
477 include_directories(AFTER ${EPOXY_INCLUDE_DIRS})
478 set(OPENGLES2_LIBRARY ${EPOXY_LIBRARIES})
479 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libepoxy0")
480endif()
481
482
483set(FEATURE_DEFINES)
484foreach(FEATURE IN LISTS FEATURES)
485 list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
486endforeach()
487
488source_group("Virtual files" FILES ${CORE_VFS_SRC} ${VFS_SRC})
489source_group("Extra features" FILES ${FEATURE_SRC})
490source_group("Third-party code" FILES ${THIRD_PARTY_SRC})
491
492# Platform binaries
493if(3DS)
494 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/3ds ${CMAKE_BINARY_DIR}/3ds)
495endif()
496
497if(WII)
498 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/wii ${CMAKE_BINARY_DIR}/wii)
499endif()
500
501if(PSP2)
502 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/psp2 ${CMAKE_BINARY_DIR}/psp2)
503endif()
504
505# Binaries
506set(CORE_SRC
507 ${ARM_SRC}
508 ${GBA_SRC}
509 ${GBA_CHEATS_SRC}
510 ${GBA_CTX_SRC}
511 ${DEBUGGER_SRC}
512 ${RENDERER_SRC}
513 ${UTIL_SRC}
514 ${CORE_VFS_SRC}
515 ${OS_SRC}
516 ${THIRD_PARTY_SRC})
517
518if(NOT MINIMAL_CORE)
519 set(SRC
520 ${CORE_SRC}
521 ${GBA_RR_SRC}
522 ${GBA_SV_SRC}
523 ${SIO_SRC}
524 ${FEATURE_SRC}
525 ${VFS_SRC})
526else()
527 set(SRC ${CORE_SRC} ${VFS_SRC})
528endif()
529
530if(NOT SKIP_LIBRARY)
531 if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
532 set(BUILD_SHARED ON)
533 endif()
534
535 if(BUILD_SHARED)
536 add_library(${BINARY_NAME} SHARED ${SRC} ${VFS_SRC})
537 if(BUILD_STATIC)
538 add_library(${BINARY_NAME}-static STATIC ${SRC})
539 set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
540 install(TARGETS ${BINARY_NAME}-static DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
541 add_dependencies(${BINARY_NAME}-static version-info)
542 endif()
543 else()
544 add_library(${BINARY_NAME} STATIC ${SRC})
545 endif()
546
547 add_dependencies(${BINARY_NAME} version-info)
548 set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
549
550 target_link_libraries(${BINARY_NAME} ${DEBUGGER_LIB} ${DEPENDENCY_LIB} ${OS_LIB})
551 install(TARGETS ${BINARY_NAME} LIBRARY DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME} NAMELINK_SKIP ARCHIVE DESTINATION ${LIBDIR} RUNTIME DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
552 if(UNIX AND NOT APPLE)
553 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-16.png DESTINATION share/icons/hicolor/16x16/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
554 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-24.png DESTINATION share/icons/hicolor/24x24/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
555 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-32.png DESTINATION share/icons/hicolor/32x32/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
556 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-48.png DESTINATION share/icons/hicolor/48x48/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
557 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-64.png DESTINATION share/icons/hicolor/64x64/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
558 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-96.png DESTINATION share/icons/hicolor/96x96/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
559 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-128.png DESTINATION share/icons/hicolor/128x128/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
560 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-256.png DESTINATION share/icons/hicolor/256x256/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
561 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-512.png DESTINATION share/icons/hicolor/512x512/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
562 endif()
563else()
564 set(BUILD_SHARED OFF)
565 set(BUILD_STATIC OFF)
566 find_library(${BINARY_NAME} ${BINARY_NAME})
567 if(NOT ${BINARY_NAME}_FOUND)
568 set(DISABLE_FRONTENDS ON)
569 set(BUILD_PERF OFF)
570 set(BUILD_TEST OFF)
571 endif()
572endif()
573
574if(BUILD_GL)
575 add_definitions(-DBUILD_GL)
576endif()
577
578if(BUILD_GLES2)
579 add_definitions(-DBUILD_GLES2)
580endif()
581
582if(DISABLE_FRONTENDS)
583 set(BUILD_SDL OFF)
584 set(BUILD_QT OFF)
585endif()
586
587if(BUILD_LIBRETRO)
588 file(GLOB RETRO_SRC ${CMAKE_SOURCE_DIR}/src/platform/libretro/*.c)
589 add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
590 set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5;DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=2")
591 target_link_libraries(${BINARY_NAME}_libretro ${OS_LIB})
592 install(TARGETS ${BINARY_NAME}_libretro LIBRARY DESTINATION ${LIBDIR} COMPONENT ${BINARY_NAME}_libretro NAMELINK_SKIP)
593endif()
594
595if(BUILD_OPENEMU)
596 find_library(FOUNDATION Foundation)
597 find_library(OPENEMUBASE OpenEmuBase)
598 file(GLOB OE_SRC ${CMAKE_SOURCE_DIR}/src/platform/openemu/*.m)
599 add_library(${BINARY_NAME}-openemu MODULE ${CORE_SRC} ${OE_SRC})
600 set_target_properties(${BINARY_NAME}-openemu PROPERTIES
601 MACOSX_BUNDLE_INFO_PLIST ${CMAKE_SOURCE_DIR}/src/platform/openemu/Info.plist.in
602 BUNDLE TRUE
603 BUNDLE_EXTENSION oecoreplugin
604 OUTPUT_NAME ${PROJECT_NAME}
605 COMPILE_DEFINITIONS "DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=1")
606 target_link_libraries(${BINARY_NAME}-openemu ${OS_LIB} ${FOUNDATION} ${OPENEMUBASE})
607 install(TARGETS ${BINARY_NAME}-openemu LIBRARY DESTINATION ${LIBDIR} COMPONENT ${BINARY_NAME}.oecoreplugin NAMELINK_SKIP)
608endif()
609
610if(BUILD_SDL)
611 add_definitions(-DBUILD_SDL)
612 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/sdl ${CMAKE_BINARY_DIR}/sdl)
613endif()
614
615if(BUILD_QT)
616 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/qt ${CMAKE_BINARY_DIR}/qt)
617endif()
618
619if(BUILD_PERF)
620 set(PERF_SRC ${CMAKE_SOURCE_DIR}/src/platform/test/perf-main.c)
621 if(UNIX AND NOT APPLE)
622 list(APPEND PERF_LIB rt)
623 endif()
624
625 add_executable(${BINARY_NAME}-perf ${PERF_SRC})
626 target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB})
627 set_target_properties(${BINARY_NAME}-perf PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
628 install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
629 install(FILES ${CMAKE_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
630endif()
631
632if(BUILD_TEST)
633 add_executable(${BINARY_NAME}-fuzz ${CMAKE_SOURCE_DIR}/src/platform/test/fuzz-main.c)
634 target_link_libraries(${BINARY_NAME}-fuzz ${BINARY_NAME})
635 set_target_properties(${BINARY_NAME}-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
636 install(TARGETS ${BINARY_NAME}-fuzz DESTINATION bin COMPONENT ${BINARY_NAME}-test)
637endif()
638
639# Packaging
640set(CPACK_PACKAGE_VERSION ${VERSION_STRING})
641set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
642set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
643set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
644set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_SOURCE_DIR}/LICENSE)
645set(CPACK_RESOURCE_FILE_README ${CMAKE_SOURCE_DIR}/README.md)
646
647set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
648set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
649set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
650set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_SOURCE_DIR}/README.md")
651set(CPACK_DEBIAN_PACKAGE_SECTION "games")
652
653SET(CPACK_DEB_COMPONENT_INSTALL ON)
654
655set(CPACK_STRIP_FILES ${BINARY_NAME})
656
657install(FILES ${CMAKE_SOURCE_DIR}/README.md ${CMAKE_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
658
659include(CPack)
660
661# Summaries
662set(SUMMARY_GL_LIST)
663if(USE_EPOXY)
664 set(SUMMARY_GL_LIST "libepoxy")
665else()
666 if(BUILD_GL)
667 list(APPEND SUMMARY_GL_LIST "OpenGL")
668 endif()
669 if(BUILD_GLES2)
670 list(APPEND SUMMARY_GL_LIST "OpenGL|ES 2")
671 endif()
672endif()
673if(NOT SUMMARY_GL_LIST)
674 set(SUMMARY_GL OFF)
675else()
676 string(REPLACE ";" ", " SUMMARY_GL "${SUMMARY_GL_LIST}")
677endif()
678if(USE_LIBZIP)
679 set(SUMMARY_ZIP libzip)
680elseif(USE_MINIZIP)
681 set(SUMMARY_ZIP "minizip (external)")
682elseif(USE_ZLIB)
683 set(SUMMARY_ZIP "minizip (included)")
684else()
685 set(SUMMARY_ZIP OFF)
686endif()
687
688message(STATUS "Features:")
689message(STATUS " CLI debugger: ${USE_CLI_DEBUGGER}")
690message(STATUS " GDB stub: ${USE_GDB_STUB}")
691message(STATUS " Video recording: ${USE_FFMPEG}")
692message(STATUS " GIF recording: ${USE_MAGICK}")
693message(STATUS " Screenshot/advanced savestate support: ${USE_PNG}")
694message(STATUS " ZIP support: ${SUMMARY_ZIP}")
695message(STATUS " 7-Zip support: ${USE_LZMA}")
696message(STATUS " Better audio resampling: ${USE_BLIP}")
697message(STATUS " OpenGL support: ${SUMMARY_GL}")
698message(STATUS "Frontends:")
699message(STATUS " Qt: ${BUILD_QT}")
700message(STATUS " SDL (${SDL_VERSION}): ${BUILD_SDL}")
701message(STATUS " Profiling: ${BUILD_PERF}")
702message(STATUS " Test harness: ${BUILD_TEST}")
703message(STATUS "Cores:")
704message(STATUS " Libretro core: ${BUILD_LIBRETRO}")
705if(APPLE)
706 message(STATUS " OpenEmu core: ${BUILD_OPENEMU}")
707endif()
708message(STATUS "Libraries:")
709message(STATUS " Static: ${BUILD_STATIC}")
710message(STATUS " Shared: ${BUILD_SHARED}")