1cmake_minimum_required(VERSION 2.6)
  2project(mGBA C)
  3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
  4if(NOT MSVC)
  5	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wno-missing-field-initializers -std=c99")
  6else()
  7	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_CRT_SECURE_NO_WARNINGS /wd4003 /wd4244 /wd4146")
  8endif()
  9set(USE_DEBUGGERS ON CACHE BOOL "Whether or not to enable the debugging infrastructure")
 10set(USE_EDITLINE ON CACHE BOOL "Whether or not to enable the CLI-mode debugger")
 11set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
 12set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
 13set(USE_ZLIB ON CACHE BOOL "Whether or not to enable zlib support")
 14set(USE_MINIZIP ON CACHE BOOL "Whether or not to enable external minizip support")
 15set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
 16set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable LIBZIP support")
 17set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
 18set(USE_SQLITE3 ON CACHE BOOL "Whether or not to enable SQLite3 support")
 19set(M_CORE_GBA ON CACHE BOOL "Build Game Boy Advance core")
 20set(M_CORE_GB ON CACHE BOOL "Build Game Boy core")
 21set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
 22set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
 23set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
 24set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
 25if(APPLE)
 26	set(BUILD_OPENEMU OFF CACHE BOOL "Build OpenEmu core")
 27endif()
 28set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
 29set(BUILD_TEST OFF CACHE BOOL "Build testing harness")
 30set(BUILD_SUITE OFF CACHE BOOL "Build test suite")
 31set(BUILD_EXAMPLE OFF CACHE BOOL "Build example frontends")
 32set(BUILD_PYTHON OFF CACHE BOOL "Build Python bindings")
 33set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
 34set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
 35set(SKIP_LIBRARY OFF CACHE BOOL "Skip building the library (useful for only building libretro or OpenEmu cores)")
 36set(BUILD_GL ON CACHE STRING "Build with OpenGL")
 37set(BUILD_GLES2 OFF CACHE STRING "Build with OpenGL|ES 2")
 38set(USE_EPOXY ON CACHE STRING "Build with libepoxy")
 39set(DISABLE_DEPS OFF CACHE BOOL "Build without dependencies")
 40file(GLOB ARM_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/*.c)
 41file(GLOB ARM_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/test/*.c)
 42file(GLOB LR35902_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/*.c)
 43file(GLOB LR35902_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/test/*.c)
 44file(GLOB GBA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/*.c)
 45file(GLOB GBA_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/test/*.c)
 46file(GLOB GB_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/*.c)
 47file(GLOB GB_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/test/*.c)
 48file(GLOB GBA_CHEATS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/cheats/*.c)
 49file(GLOB GBA_RR_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/rr/*.c)
 50file(GLOB CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/*.c)
 51file(GLOB CORE_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/test/*.c)
 52file(GLOB UTIL_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/*.[cSs])
 53file(GLOB UTIL_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/test/*.c)
 54file(GLOB GUI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/gui/*.c ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/gui/*.c)
 55file(GLOB GBA_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/renderers/*.c)
 56file(GLOB GBA_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/sio/lockstep.c)
 57file(GLOB GB_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/sio/lockstep.c)
 58file(GLOB GB_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/renderers/*.c)
 59file(GLOB THIRD_PARTY_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/inih/*.c)
 60set(CLI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/commandline.c)
 61set(CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-mem.c)
 62set(VFS_SRC)
 63source_group("ARM core" FILES ${ARM_SRC})
 64source_group("LR35902 core" FILES ${LR35902_SRC})
 65source_group("GBA board" FILES ${GBA_SRC} ${GBA_RENDERER_SRC} ${GBA_SIO_SRC})
 66source_group("GBA extra" FILES ${GBA_CHEATS_SRC} ${GBA_RR_SRC})
 67source_group("GB board" FILES ${GB_SRC} ${GB_SIO_SRC})
 68source_group("Utilities" FILES ${UTIL_SRC})
 69include_directories(BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/include ${CMAKE_CURRENT_SOURCE_DIR}/src)
 70
 71if(NOT CMAKE_BUILD_TYPE)
 72	set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
 73endif()
 74
 75include(GNUInstallDirs)
 76
 77set(LIBDIR "${CMAKE_INSTALL_LIBDIR}" CACHE PATH "Installed library directory")
 78mark_as_advanced(LIBDIR)
 79
 80if (BUILD_LIBRETRO)
 81	set(LIBRETRO_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (Libretro)")
 82	mark_as_advanced(LIBRETRO_LIBDIR)
 83endif()
 84
 85if (BUILD_OPENEMU)
 86	set(OE_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (OpenEmu)")
 87	mark_as_advanced(OE_LIBDIR)
 88endif()
 89
 90
 91set(CMAKE_INSTALL_RPATH "${LIBDIR}")
 92
 93if (NOT DEFINED MANDIR)
 94	set(MANDIR ${CMAKE_INSTALL_MANDIR})
 95endif()
 96
 97# Function definitions
 98include(FindPkgConfig)
 99function(find_feature FEATURE_NAME FEATURE_REQUIRES)
100	if (NOT ${FEATURE_NAME})
101		return()
102	endif()
103	if (DISABLE_DEPS)
104		set(${FEATURE_NAME} OFF PARENT_SCOPE)
105		return()
106	endif()
107	foreach(REQUIRE ${FEATURE_REQUIRES})
108		if(NOT ${REQUIRE}_FOUND)
109			find_package(${REQUIRE} QUIET)
110			if(NOT ${REQUIRE}_FOUND)
111				pkg_search_module(${REQUIRE} ${REQUIRE})
112				if (NOT ${REQUIRE}_FOUND)
113					message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
114					set(${FEATURE_NAME} OFF PARENT_SCOPE)
115					return()
116				endif()
117			endif()
118		endif()
119		string(TOUPPER ${REQUIRE} UREQUIRE)
120		set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
121		set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
122		set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
123		if (APPLE)
124			set(IS_FRAMEWORK OFF)
125			set(LIBS)
126			foreach(LIB IN LISTS ${REQUIRE}_LIBRARIES)
127				if(LIB STREQUAL "-framework")
128					set(IS_FRAMEWORK ON)
129				elseif(IS_FRAMEWORK)
130					list(APPEND LIBS "-framework ${LIB}")
131					set(IS_FRAMEWORK OFF)
132				else()
133					list(APPEND LIBS ${LIB})
134				endif()
135			endforeach()
136			set(${UREQUIRE}_LIBRARIES ${LIBS} PARENT_SCOPE)
137		else()
138			set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
139		endif()
140		set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
141		set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
142	endforeach()
143endfunction()
144
145# Version information
146add_custom_target(version-info ALL
147	COMMAND ${CMAKE_COMMAND}
148	-DBINARY_NAME=${BINARY_NAME}
149	-DCONFIG_FILE=${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in
150	-DOUT_FILE=${CMAKE_CURRENT_BINARY_DIR}/version.c
151	-P ${CMAKE_CURRENT_SOURCE_DIR}/version.cmake
152	WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
153
154include(${CMAKE_CURRENT_SOURCE_DIR}/version.cmake)
155configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in ${CMAKE_CURRENT_BINARY_DIR}/version.c)
156configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/flags.h.in ${CMAKE_CURRENT_BINARY_DIR}/flags.h)
157install(FILES ${CMAKE_CURRENT_BINARY_DIR}/flags.h DESTINATION include/mgba COMPONENT lib${BINARY_NAME})
158
159list(APPEND UTIL_SRC ${CMAKE_CURRENT_BINARY_DIR}/version.c)
160source_group("Generated sources" FILES ${CMAKE_CURRENT_BINARY_DIR}/version.c)
161
162# Advanced settings
163if(NOT 3DS)
164	# LTO appears to make 3DS binary slower
165	set(DEFAULT_LTO ON)
166else()
167	set(DEFAULT_LTO OFF)
168endif()
169
170set(BUILD_LTO ${DEFAULT_LTO} CACHE BOOL "Build with link-time optimization")
171set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
172set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
173set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
174mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
175set(PGO_PRE_FLAGS "-fprofile-generate=${PGO_DIR} -fprofile-arcs")
176set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
177
178if(BUILD_PGO AND NOT PGO_STAGE_2)
179	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
180	set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
181	set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
182elseif(BUILD_PGO AND PGO_STAGE_2)
183	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
184	set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
185	set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
186endif()
187
188# Platform support
189if(WIN32)
190	set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
191	add_definitions(-D_WIN32_WINNT=0x0600)
192	list(APPEND OS_LIB ws2_32 shlwapi)
193	list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/vfs-w32.c)
194	file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/*.c)
195	source_group("Windows-specific code" FILES ${OS_SRC})
196	if(MSVC)
197		add_definitions(-DNOMINMAX -DWIN32_LEAN_AND_MEAN)
198		set(CMAKE_WINDOWS_EXPORT_ALL_SYMBOLS TRUE)
199	endif()
200elseif(UNIX)
201	add_definitions(-DUSE_PTHREADS)
202
203	if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
204		add_definitions(-D_GNU_SOURCE)
205	endif()
206	if(NOT APPLE AND NOT HAIKU)
207		set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
208	endif()
209
210	list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
211	file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/posix/*.c)
212	source_group("POSIX-specific code" FILES ${OS_SRC})
213endif()
214
215if(APPLE)
216	add_definitions(-D_DARWIN_C_SOURCE)
217	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
218endif()
219
220if(NOT HAIKU AND NOT MSVC AND NOT PSP2)
221	set(M_LIBRARY m)
222endif()
223list(APPEND OS_LIB ${M_LIBRARY})
224
225if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
226	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
227	set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
228endif()
229
230if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
231	if(NOT BUILD_EGL)
232		add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
233	endif()
234endif()
235
236if(BUILD_RASPI)
237	set(BUILD_GL OFF CACHE BOOL "OpenGL not supported" FORCE)
238endif()
239
240if(BUILD_PANDORA)
241	add_definitions(-DBUILD_PANDORA)
242endif()
243
244if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
245	enable_language(ASM)
246endif()
247
248if(PSP2 OR WII)
249	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-format")
250endif()
251
252if(DEFINED 3DS OR DEFINED PSP2 OR DEFINED WII)
253	set(USE_DEBUGGERS OFF)
254	set(USE_SQLITE3 OFF)
255endif()
256
257if(NOT M_CORE_GBA)
258	set(USE_GDB_STUB OFF)
259endif()
260
261if(NOT USE_DEBUGGERS)
262	set(USE_EDITLINE OFF)
263	set(USE_GDB_STUB OFF)
264endif()
265
266if(WII)
267	add_definitions(-U__STRICT_ANSI__)
268endif()
269
270include(CheckFunctionExists)
271check_function_exists(strdup HAVE_STRDUP)
272check_function_exists(strndup HAVE_STRNDUP)
273check_function_exists(localtime_r HAVE_LOCALTIME_R)
274if(NOT CMAKE_SYSTEM_NAME STREQUAL "Generic")
275	check_function_exists(snprintf_l HAVE_SNPRINTF_L)
276	if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
277		# The strtof_l on Linux not actually exposed nor actually strtof_l
278		set(HAVE_STRTOF_L OFF)
279	else()
280		check_function_exists(strtof_l HAVE_STRTOF_L)
281	endif()
282	check_function_exists(newlocale HAVE_NEWLOCALE)
283	check_function_exists(freelocale HAVE_FREELOCALE)
284	check_function_exists(uselocale HAVE_USELOCALE)
285	check_function_exists(setlocale HAVE_SETLOCALE)
286else()
287	if(NOT DEFINED 3DS AND NOT DEFINED PSP2 AND NOT DEFINED WII)
288		set(DISABLE_DEPS ON CACHE BOOL "This platform cannot build with dependencies" FORCE)
289	endif()
290	set(DISABLE_FRONTENDS ON)
291	set(MINIMAL_CORE ON)
292endif()
293
294check_function_exists(chmod HAVE_CHMOD)
295check_function_exists(umask HAVE_UMASK)
296
297set(FUNCTION_DEFINES)
298
299if(HAVE_STRDUP)
300	list(APPEND FUNCTION_DEFINES HAVE_STRDUP)
301endif()
302
303if(HAVE_STRNDUP)
304	list(APPEND FUNCTION_DEFINES HAVE_STRNDUP)
305endif()
306
307if(HAVE_LOCALTIME_R)
308	list(APPEND FUNCTION_DEFINES HAVE_LOCALTIME_R)
309endif()
310
311if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE OR APPLE)
312	list(APPEND FUNCTION_DEFINES HAVE_LOCALE)
313	if (HAVE_STRTOF_L)
314		list(APPEND FUNCTION_DEFINES HAVE_STRTOF_L)
315	endif()
316	if (HAVE_SNPRINTF_L)
317		list(APPEND FUNCTION_DEFINES HAVE_SNPRINTF_L)
318	endif()
319endif()
320
321if(HAVE_SETLOCALE)
322	list(APPEND FUNCTION_DEFINES HAVE_SETLOCALE)
323endif()
324
325if(HAVE_CHMOD)
326	list(APPEND FUNCTION_DEFINES HAVE_CHMOD)
327endif()
328
329if(HAVE_UMASK)
330	list(APPEND FUNCTION_DEFINES HAVE_UMASK)
331endif()
332
333# Feature dependencies
334set(FEATURE_DEFINES)
335set(FEATURES)
336if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
337	set(LIBEDIT_LIBRARIES -ledit)
338	if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
339		list(APPEND LIBEDIT_LIBRARIES -ltermcap)
340	endif()
341else()
342	find_feature(USE_EDITLINE "libedit")
343endif()
344if(BUILD_GL)
345	find_package(OpenGL QUIET)
346	if(NOT OPENGL_FOUND)
347		set(BUILD_GL OFF CACHE BOOL "OpenGL not found" FORCE)
348	endif()
349endif()
350if(NOT BUILD_GL)
351	set(OPENGLE_LIBRARY "" CACHE PATH "" FORCE)
352endif()
353if(BUILD_GLES2 AND NOT BUILD_RASPI)
354	find_path(OPENGLES2_INCLUDE_DIR NAMES GLES2/gl2.h)
355	find_library(OPENGLES2_LIBRARY NAMES GLESv2 GLESv2_CM)
356	if(NOT OPENGLES2_INCLUDE_DIR OR NOT OPENGLES2_LIBRARY)
357		set(BUILD_GLES2 OFF CACHE BOOL "OpenGL|ES 2 not found" FORCE)
358	endif()
359endif()
360if(NOT BUILD_GLES2)
361	set(OPENGLES2_LIBRARY "" CACHE PATH "" FORCE)
362endif()
363set(WANT_ZLIB ${USE_ZLIB})
364set(WANT_PNG ${USE_PNG})
365set(WANT_LIBZIP ${USE_LIBZIP})
366set(WANT_SQLITE3 ${USE_SQLITE3})
367set(USE_CMOCKA ${BUILD_SUITE})
368
369find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
370find_feature(USE_ZLIB "ZLIB")
371find_feature(USE_MINIZIP "minizip")
372find_feature(USE_PNG "PNG")
373find_feature(USE_LIBZIP "libzip")
374find_feature(USE_MAGICK "MagickWand")
375find_feature(USE_EPOXY "epoxy")
376find_feature(USE_CMOCKA "cmocka")
377find_feature(USE_SQLITE3 "sqlite3")
378
379# Features
380set(DEBUGGER_SRC
381	${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/debugger.c
382	${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/parser.c
383	${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/cli-debugger.c)
384
385set(FEATURE_SRC)
386set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
387
388if(DISABLE_DEPS)
389	set(USE_GDB_STUB OFF)
390endif()
391
392if(USE_EDITLINE)
393	list(APPEND FEATURES EDITLINE)
394	include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
395	link_directories(${LIBEDIT_LIBRARY_DIRS})
396	set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
397	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
398	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/editline/cli-el-backend.c")
399else()
400	set(DEBUGGER_LIB "")
401endif()
402
403if(USE_GDB_STUB)
404	list(APPEND FEATURES GDB_STUB)
405	list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/gdb-stub.c)
406endif()
407source_group("Debugger" FILES ${DEBUGGER_SRC})
408
409if(USE_FFMPEG)
410	list(APPEND FEATURES FFMPEG)
411	pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
412	if(NOT LIBSWRESAMPLE_FOUND)
413		list(APPEND FEATURES LIBAV)
414	endif()
415	include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
416	link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
417	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/ffmpeg/ffmpeg-encoder.c")
418	string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
419	string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
420	string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
421	string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
422	string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
423	list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
424	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR}|libavcodec-extra-${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
425	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavformat${LIBAVFORMAT_VERSION_MAJOR}|libavformat-ffmpeg${LIBAVFORMAT_VERSION_MAJOR}")
426	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavresample${LIBAVRESAMPLE_VERSION_MAJOR}|libavresample-ffmpeg${LIBAVRESAMPLE_VERSION_MAJOR}")
427	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavutil${LIBAVUTIL_VERSION_MAJOR}|libavutil-ffmpeg${LIBAVUTIL_VERSION_MAJOR}")
428	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libswscale${LIBSWSCALE_VERSION_MAJOR}|libswscale-ffmpeg${LIBSWSCALE_VERSION_MAJOR}")
429	set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
430	if(APPLE)
431		set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
432		set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
433	endif()
434endif()
435
436list(APPEND THIRD_PARTY_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
437
438if(USE_MAGICK)
439	list(APPEND FEATURES MAGICK)
440	include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
441	link_directories(${MAGICKWAND_LIBRARY_DIRS})
442	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/imagemagick/imagemagick-gif-encoder.c")
443	list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
444	string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
445	string(REGEX MATCH "^[0-9]+" MAGICKWAND_VERSION_MAJOR ${MagickWand_VERSION})
446	if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
447		set(MAGICKWAND_DEB_VERSION "5")
448	elseif(${MagickWand_VERSION} EQUAL "6.9.7")
449		set(MAGICKWAND_DEB_VERSION "-6.q16-3")
450	else()
451		set(MAGICKWAND_DEB_VERSION "-6.q16-2")
452	endif()
453	list(APPEND FEATURE_DEFINES MAGICKWAND_VERSION_MAJOR=${MAGICKWAND_VERSION_MAJOR})
454
455	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
456endif()
457
458if(WANT_ZLIB AND NOT USE_ZLIB)
459	set(SKIP_INSTALL_ALL ON)
460	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib zlib)
461	set_property(TARGET zlibstatic PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/zlib;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib)
462	set_property(TARGET zlib PROPERTY EXCLUDE_FROM_ALL ON)
463	set_property(TARGET example PROPERTY EXCLUDE_FROM_ALL ON)
464	set_property(TARGET minigzip PROPERTY EXCLUDE_FROM_ALL ON)
465	set(ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
466	set(ZLIB_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
467	set(ZLIB_LIBRARY zlibstatic)
468	list(APPEND DEPENDENCY_LIB zlibstatic)
469	set(USE_ZLIB ON)
470endif()
471
472if(USE_ZLIB)
473	list(APPEND FEATURES ZLIB)
474	include_directories(AFTER ${ZLIB_INCLUDE_DIRS})
475	list(APPEND DEPENDENCY_LIB ${ZLIB_LIBRARIES})
476	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},zlib1g")
477endif()
478
479if(WANT_PNG AND USE_ZLIB AND NOT USE_PNG)
480	set(PNG_STATIC ON CACHE BOOL "" FORCE)
481	set(PNG_SHARED OFF CACHE BOOL "" FORCE)
482	set(PNG_TESTS OFF CACHE BOOL "" FORCE)
483	set(SKIP_INSTALL_ALL ON)
484	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng libpng)
485	set_property(TARGET png16_static PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/libpng;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng;${ZLIB_INCLUDE_DIRS})
486	set(PNG_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng ${CMAKE_CURRENT_BINARY_DIR}/libpng)
487	list(APPEND DEPENDENCY_LIB png16_static)
488	set(USE_PNG ON)
489endif()
490
491if(USE_PNG)
492	list(APPEND FEATURES PNG)
493	include_directories(AFTER ${PNG_INCLUDE_DIRS})
494	list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
495	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng12-0")
496endif()
497
498if(WANT_SQLITE3 AND NOT USE_SQLITE3)
499	list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/sqlite3.c)
500	include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/)
501	set(USE_SQLITE3 ON)
502endif()
503
504if(USE_LIBZIP)
505	include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
506	link_directories(${LIBZIP_LIBRARY_DIRS})
507	list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
508	list(APPEND FEATURES LIBZIP)
509	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
510	string(REGEX MATCH "^[0-9]+" LIBZIP_VERSION_MAJOR ${libzip_VERSION})
511	if (LIBZIP_VERSION_MAJOR LESS 1)
512		set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
513	elseif(LIBZIP_VERSION_MAJOR EQUAL 1)
514		set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip4")
515	else()
516		message(AUTHOR_WARNING Unknown version of libzip detected: ${libzip_VERSION})
517	endif()
518elseif(USE_MINIZIP)
519	include_directories(AFTER ${MINIZIP_INCLUDE_DIRS})
520	link_directories(${MINIZIP_LIBRARY_DIRS})
521	list(APPEND DEPENDENCY_LIB ${MINIZIP_LIBRARIES})
522	list(APPEND FEATURES MINIZIP)
523	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
524	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libminizip1")
525elseif(USE_ZLIB)
526	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c
527		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
528		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c)
529	if(NOT MSVC)
530		set_source_files_properties(
531			${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
532			${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c
533			PROPERTIES COMPILE_FLAGS "-Wno-unused-parameter -Wno-implicit-function-declaration")
534	endif()
535endif()
536
537if (USE_LZMA)
538	include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/third-party/lzma)
539	add_definitions(-D_7ZIP_PPMD_SUPPPORT)
540	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-lzma.c)
541	set(LZMA_SRC
542		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
543		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
544		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
545		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
546		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
547		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
548		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zDec.c
549		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
550		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Delta.c
551		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
552		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
553		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra.c
554		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra86.c
555		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/BraIA64.c
556		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
557		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
558		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
559		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zFile.c
560		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
561	list(APPEND VFS_SRC ${LZMA_SRC})
562	list(APPEND FEATURES LZMA)
563endif()
564
565if(USE_EPOXY)
566	add_definitions(-DBUILD_GL -DBUILD_GLES2)
567	list(APPEND FEATURES EPOXY)
568	include_directories(AFTER ${EPOXY_INCLUDE_DIRS})
569	set(OPENGLES2_LIBRARY ${EPOXY_LIBRARIES})
570	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libepoxy0")
571endif()
572
573if(USE_SQLITE3)
574	list(APPEND FEATURES SQLITE3)
575	include_directories(AFTER ${SQLITE3_INCLUDE_DIRS})
576	list(APPEND DEPENDENCY_LIB ${SQLITE3_LIBRARIES})
577	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libsqlite3-0")
578	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/sqlite3/no-intro.c")
579endif()
580
581set(TEST_SRC ${CORE_TEST_SRC})
582if(M_CORE_GB)
583	add_definitions(-DM_CORE_GB)
584	list(APPEND CORE_SRC
585		${LR35902_SRC}
586		${GB_SRC}
587		${GB_RENDERER_SRC})
588	list(APPEND DEBUGGER_SRC
589		${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/cli-debugger.c
590		${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/debugger.c
591		${CMAKE_CURRENT_SOURCE_DIR}/src/gb/extra/cli.c)
592	list(APPEND TEST_SRC
593		${LR35902_TEST_SRC}
594		${GB_TEST_SRC})
595endif()
596
597if(M_CORE_GBA)
598	add_definitions(-DM_CORE_GBA)
599	list(APPEND CORE_SRC
600		${ARM_SRC}
601		${GBA_SRC}
602		${GBA_CHEATS_SRC}
603		${GBA_RENDERER_SRC})
604	list(APPEND DEBUGGER_SRC
605		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c
606		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/debugger.c
607		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/memory-debugger.c
608		${CMAKE_CURRENT_SOURCE_DIR}/src/gba/extra/cli.c)
609	list(APPEND TEST_SRC
610		${ARM_TEST_SRC}
611		${GBA_TEST_SRC})
612	if(NOT M_CORE_GB)
613		list(APPEND CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/audio.c)
614	endif()
615endif()
616
617if(USE_DEBUGGERS)
618	list(APPEND FEATURE_SRC ${DEBUGGER_SRC})
619	list(APPEND FEATURES DEBUGGERS)
620endif()
621
622foreach(FEATURE IN LISTS FEATURES)
623	list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
624endforeach()
625
626source_group("Virtual files" FILES ${CORE_VFS_SRC} ${VFS_SRC})
627source_group("Extra features" FILES ${FEATURE_SRC})
628source_group("Third-party code" FILES ${THIRD_PARTY_SRC})
629
630# Platform binaries
631if(3DS)
632	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/3ds ${CMAKE_CURRENT_BINARY_DIR}/3ds)
633endif()
634
635if(WII)
636	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/wii ${CMAKE_CURRENT_BINARY_DIR}/wii)
637endif()
638
639if(PSP2)
640	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/psp2 ${CMAKE_CURRENT_BINARY_DIR}/psp2)
641endif()
642
643# Binaries
644list(APPEND CORE_SRC
645	${UTIL_SRC}
646	${CORE_VFS_SRC}
647	${OS_SRC}
648	${THIRD_PARTY_SRC})
649list(APPEND TEST_SRC ${UTIL_TEST_SRC})
650
651set(SRC ${CORE_SRC} ${VFS_SRC})
652if(NOT MINIMAL_CORE)
653	if(M_CORE_GBA)
654		list(APPEND SRC
655			${GBA_RR_SRC}
656			${GBA_EXTRA_SRC}
657			${GBA_SIO_SRC})
658	endif()
659	if(M_CORE_GB)
660		list(APPEND SRC
661			${GB_SIO_SRC})
662	endif()
663	list(APPEND SRC
664		${FEATURE_SRC}
665		${CLI_SRC})
666endif()
667
668if(NOT SKIP_LIBRARY)
669	if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
670		set(BUILD_SHARED ON)
671	endif()
672
673	if(BUILD_SHARED)
674		add_library(${BINARY_NAME} SHARED ${SRC} ${VFS_SRC})
675		if(BUILD_STATIC)
676			add_library(${BINARY_NAME}-static STATIC ${SRC})
677			set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
678			install(TARGETS ${BINARY_NAME}-static DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
679			add_dependencies(${BINARY_NAME}-static version-info)
680		endif()
681	else()
682		add_library(${BINARY_NAME} STATIC ${SRC})
683	endif()
684
685	add_dependencies(${BINARY_NAME} version-info)
686	set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
687
688	target_link_libraries(${BINARY_NAME} ${DEBUGGER_LIB} ${DEPENDENCY_LIB} ${OS_LIB})
689	install(TARGETS ${BINARY_NAME} LIBRARY DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME} NAMELINK_SKIP ARCHIVE DESTINATION ${LIBDIR} RUNTIME DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
690	if(UNIX AND NOT APPLE)
691		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-16.png DESTINATION share/icons/hicolor/16x16/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
692		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-24.png DESTINATION share/icons/hicolor/24x24/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
693		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-32.png DESTINATION share/icons/hicolor/32x32/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
694		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-48.png DESTINATION share/icons/hicolor/48x48/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
695		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-64.png DESTINATION share/icons/hicolor/64x64/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
696		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-96.png DESTINATION share/icons/hicolor/96x96/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
697		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-128.png DESTINATION share/icons/hicolor/128x128/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
698		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-256.png DESTINATION share/icons/hicolor/256x256/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
699		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-512.png DESTINATION share/icons/hicolor/512x512/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
700	endif()
701else()
702	set(BUILD_SHARED OFF)
703	set(BUILD_STATIC OFF)
704	find_library(${BINARY_NAME} ${BINARY_NAME})
705	if(NOT ${BINARY_NAME}_FOUND)
706		set(DISABLE_FRONTENDS ON)
707		set(BUILD_PERF OFF)
708		set(BUILD_TEST OFF)
709		set(BUILD_SUITE OFF)
710	endif()
711endif()
712
713if(BUILD_GL)
714	add_definitions(-DBUILD_GL)
715endif()
716
717if(BUILD_GLES2)
718	add_definitions(-DBUILD_GLES2)
719endif()
720
721if(DISABLE_FRONTENDS)
722	set(BUILD_SDL OFF)
723	set(BUILD_QT OFF)
724endif()
725
726if(BUILD_LIBRETRO)
727	file(GLOB RETRO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/libretro/*.c)
728	add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
729	set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5;DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=2")
730	target_link_libraries(${BINARY_NAME}_libretro ${OS_LIB})
731	install(TARGETS ${BINARY_NAME}_libretro LIBRARY DESTINATION ${LIBRETRO_LIBDIR} COMPONENT ${BINARY_NAME}_libretro NAMELINK_SKIP)
732endif()
733
734if(BUILD_OPENEMU)
735	find_library(FOUNDATION Foundation)
736	find_library(OPENEMUBASE OpenEmuBase)
737	file(GLOB OE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/*.m)
738	add_library(${BINARY_NAME}-openemu MODULE ${CORE_SRC} ${OE_SRC})
739	set_target_properties(${BINARY_NAME}-openemu PROPERTIES
740		MACOSX_BUNDLE_INFO_PLIST ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/Info.plist.in
741		BUNDLE TRUE
742		BUNDLE_EXTENSION oecoreplugin
743		OUTPUT_NAME ${PROJECT_NAME}
744		COMPILE_DEFINITIONS "DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=1")
745	target_link_libraries(${BINARY_NAME}-openemu ${OS_LIB} ${FOUNDATION} ${OPENEMUBASE})
746	install(TARGETS ${BINARY_NAME}-openemu LIBRARY DESTINATION ${OE_LIBDIR} COMPONENT ${BINARY_NAME}.oecoreplugin NAMELINK_SKIP)
747endif()
748
749if(BUILD_SDL)
750	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/sdl ${CMAKE_CURRENT_BINARY_DIR}/sdl)
751	# The SDL platform CMakeLists could decide to disable SDL, so check again before adding the define.
752	if(BUILD_SDL)
753		add_definitions(-DBUILD_SDL)
754	endif()
755endif()
756
757if(BUILD_QT)
758	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/qt ${CMAKE_CURRENT_BINARY_DIR}/qt)
759endif()
760
761if(BUILD_PERF)
762	set(PERF_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/perf-main.c ${CLI_SRC})
763	if(UNIX AND NOT APPLE)
764		list(APPEND PERF_LIB rt)
765	endif()
766
767	add_executable(${BINARY_NAME}-perf ${PERF_SRC})
768	target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB} ${OS_LIB})
769	set_target_properties(${BINARY_NAME}-perf PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
770	install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
771	install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
772endif()
773
774if(BUILD_TEST)
775	add_executable(${BINARY_NAME}-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/fuzz-main.c)
776	target_link_libraries(${BINARY_NAME}-fuzz ${BINARY_NAME})
777	set_target_properties(${BINARY_NAME}-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
778	add_executable(tbl-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/tbl-fuzz-main.c)
779	target_link_libraries(tbl-fuzz ${BINARY_NAME})
780	set_target_properties(tbl-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
781	install(TARGETS ${BINARY_NAME}-fuzz tbl-fuzz DESTINATION bin COMPONENT ${BINARY_NAME}-test)
782endif()
783
784if(NOT USE_CMOCKA)
785	set(BUILD_SUITE OFF)
786endif()
787if(BUILD_SUITE)
788	enable_testing()
789	include_directories(AFTER ${CMOCKA_INCLUDE_DIRS})
790	link_directories(${CMOCKA_LIBRARY_DIRS})
791
792	add_executable(${BINARY_NAME}-suite ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/suite-main.c ${TEST_SRC})
793	target_link_libraries(${BINARY_NAME}-suite ${BINARY_NAME} ${PLATFORM_LIBRARY} cmocka)
794	set_target_properties(${BINARY_NAME}-suite PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
795	add_test(${BINARY_NAME}-suite ${BINARY_NAME}-suite)
796endif()
797
798if(BUILD_PYTHON)
799	enable_testing()
800	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/python ${CMAKE_CURRENT_BINARY_DIR}/python)
801endif()
802
803if(BUILD_EXAMPLE)
804	add_executable(${BINARY_NAME}-example-server ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/server.c)
805	target_link_libraries(${BINARY_NAME}-example-server ${BINARY_NAME})
806	set_target_properties(${BINARY_NAME}-example-server PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
807
808	if(BUILD_SDL)
809		add_executable(${BINARY_NAME}-example-client ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/client.c)
810		target_link_libraries(${BINARY_NAME}-example-client ${BINARY_NAME} ${SDL_LIBRARY} ${SDLMAIN_LIBRARY} ${OPENGL_LIBRARY} ${OPENGLES2_LIBRARY})
811		set_target_properties(${BINARY_NAME}-example-client PROPERTIES
812		                      COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}"
813		                      INCLUDE_DIRECTORIES "${SDL_INCLUDE_DIR};${CMAKE_CURRENT_SOURCE_DIR}/src;${CMAKE_CURRENT_SOURCE_DIR}/include")
814	endif()
815endif()
816
817# Packaging
818set(CPACK_PACKAGE_VERSION ${VERSION_STRING})
819set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
820set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
821set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
822set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
823set(CPACK_RESOURCE_FILE_README ${CMAKE_CURRENT_SOURCE_DIR}/README.md)
824
825set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
826set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
827set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
828set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README.md")
829set(CPACK_DEBIAN_PACKAGE_SECTION "games")
830
831SET(CPACK_DEB_COMPONENT_INSTALL ON)
832
833set(CPACK_STRIP_FILES ${BINARY_NAME})
834
835install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/README.md ${CMAKE_CURRENT_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
836
837include(CPack)
838
839# Summaries
840set(SUMMARY_GL_LIST)
841if(USE_EPOXY)
842	set(SUMMARY_GL_LIST "libepoxy")
843else()
844	if(BUILD_GL)
845		list(APPEND SUMMARY_GL_LIST "OpenGL")
846	endif()
847	if(BUILD_GLES2)
848		list(APPEND SUMMARY_GL_LIST "OpenGL|ES 2")
849	endif()
850endif()
851if(NOT SUMMARY_GL_LIST)
852	set(SUMMARY_GL OFF)
853else()
854	string(REPLACE ";" ", " SUMMARY_GL "${SUMMARY_GL_LIST}")
855endif()
856if(USE_LIBZIP)
857	set(SUMMARY_ZIP libzip)
858elseif(USE_MINIZIP)
859	set(SUMMARY_ZIP "minizip (external)")
860elseif(USE_ZLIB)
861	set(SUMMARY_ZIP "minizip (included)")
862else()
863	set(SUMMARY_ZIP OFF)
864endif()
865
866if(NOT QUIET)
867	message(STATUS "Platforms:")
868	message(STATUS "	Game Boy Advance: ${M_CORE_GBA}")
869	message(STATUS "	Game Boy: ${M_CORE_GB}")
870	message(STATUS "Features:")
871	message(STATUS "	Debuggers: ${USE_DEBUGGERS}")
872	message(STATUS "	CLI debugger: ${USE_EDITLINE}")
873	message(STATUS "	GDB stub: ${USE_GDB_STUB}")
874	message(STATUS "	Video recording: ${USE_FFMPEG}")
875	message(STATUS "	GIF recording: ${USE_MAGICK}")
876	message(STATUS "	Screenshot/advanced savestate support: ${USE_PNG}")
877	message(STATUS "	ZIP support: ${SUMMARY_ZIP}")
878	message(STATUS "	7-Zip support: ${USE_LZMA}")
879	message(STATUS "	SQLite3 game database: ${USE_SQLITE3}")
880	message(STATUS "	OpenGL support: ${SUMMARY_GL}")
881	message(STATUS "Frontends:")
882	message(STATUS "	Qt: ${BUILD_QT}")
883	message(STATUS "	SDL (${SDL_VERSION}): ${BUILD_SDL}")
884	message(STATUS "	Profiling: ${BUILD_PERF}")
885	message(STATUS "	Test harness: ${BUILD_TEST}")
886	message(STATUS "	Test suite: ${BUILD_SUITE}")
887	message(STATUS "	Python bindings: ${BUILD_PYTHON}")
888	message(STATUS "	Examples: ${BUILD_EXAMPLE}")
889	message(STATUS "Cores:")
890	message(STATUS "	Libretro core: ${BUILD_LIBRETRO}")
891	if(APPLE)
892		message(STATUS "	OpenEmu core: ${BUILD_OPENEMU}")
893	endif()
894	message(STATUS "Libraries:")
895	message(STATUS "	Static: ${BUILD_STATIC}")
896	message(STATUS "	Shared: ${BUILD_SHARED}")
897endif()