CMakeLists.txt (view raw)
1cmake_minimum_required(VERSION 2.6)
2project(mGBA C)
3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
4if(NOT MSVC)
5 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wno-missing-field-initializers -std=c99")
6else()
7 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_CRT_SECURE_NO_WARNINGS /wd4003 /wd4244 /wd4146")
8endif()
9set(USE_DEBUGGERS ON CACHE BOOL "Whether or not to enable the debugging infrastructure")
10set(USE_EDITLINE ON CACHE BOOL "Whether or not to enable the CLI-mode debugger")
11set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
12set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
13set(USE_ZLIB ON CACHE BOOL "Whether or not to enable zlib support")
14set(USE_MINIZIP ON CACHE BOOL "Whether or not to enable external minizip support")
15set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
16set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable LIBZIP support")
17set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
18set(USE_SQLITE3 ON CACHE BOOL "Whether or not to enable SQLite3 support")
19set(M_CORE_GBA ON CACHE BOOL "Build Game Boy Advance core")
20set(M_CORE_GB ON CACHE BOOL "Build Game Boy core")
21set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
22set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
23set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
24set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
25if(APPLE)
26 set(BUILD_OPENEMU OFF CACHE BOOL "Build OpenEmu core")
27endif()
28set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
29set(BUILD_TEST OFF CACHE BOOL "Build testing harness")
30set(BUILD_SUITE OFF CACHE BOOL "Build test suite")
31set(BUILD_EXAMPLE OFF CACHE BOOL "Build example frontends")
32set(BUILD_PYTHON OFF CACHE BOOL "Build Python bindings")
33set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
34set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
35set(SKIP_LIBRARY OFF CACHE BOOL "Skip building the library (useful for only building libretro or OpenEmu cores)")
36set(BUILD_GL ON CACHE STRING "Build with OpenGL")
37set(BUILD_GLES2 OFF CACHE STRING "Build with OpenGL|ES 2")
38set(USE_EPOXY ON CACHE STRING "Build with libepoxy")
39set(DISABLE_DEPS OFF CACHE BOOL "Build without dependencies")
40file(GLOB ARM_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/*.c)
41file(GLOB ARM_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/test/*.c)
42file(GLOB LR35902_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/*.c)
43file(GLOB LR35902_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/test/*.c)
44file(GLOB GBA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/*.c)
45file(GLOB GBA_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/test/*.c)
46file(GLOB GB_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/*.c)
47file(GLOB GB_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/test/*.c)
48file(GLOB GBA_CHEATS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/cheats/*.c)
49file(GLOB GBA_RR_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/rr/*.c)
50file(GLOB CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/*.c)
51file(GLOB CORE_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/test/*.c)
52file(GLOB UTIL_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/*.[cSs])
53file(GLOB UTIL_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/test/*.c)
54file(GLOB GUI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/gui/*.c ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/gui/*.c)
55file(GLOB GBA_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/renderers/*.c)
56file(GLOB GBA_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/sio/lockstep.c)
57file(GLOB GB_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/sio/lockstep.c)
58file(GLOB GB_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/renderers/*.c)
59file(GLOB THIRD_PARTY_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/inih/*.c)
60set(CLI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/commandline.c)
61set(CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-mem.c)
62set(VFS_SRC)
63source_group("ARM core" FILES ${ARM_SRC})
64source_group("LR35902 core" FILES ${LR35902_SRC})
65source_group("GBA board" FILES ${GBA_SRC} ${GBA_RENDERER_SRC} ${GBA_SIO_SRC})
66source_group("GBA extra" FILES ${GBA_CHEATS_SRC} ${GBA_RR_SRC})
67source_group("GB board" FILES ${GB_SRC} ${GB_SIO_SRC})
68source_group("Utilities" FILES ${UTIL_SRC})
69include_directories(BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/include ${CMAKE_CURRENT_SOURCE_DIR}/src)
70
71if(NOT CMAKE_BUILD_TYPE)
72 set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
73endif()
74
75include(GNUInstallDirs)
76
77set(LIBDIR "${CMAKE_INSTALL_LIBDIR}" CACHE PATH "Installed library directory")
78mark_as_advanced(LIBDIR)
79
80if (BUILD_LIBRETRO)
81 set(LIBRETRO_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (Libretro)")
82 mark_as_advanced(LIBRETRO_LIBDIR)
83endif()
84
85if (BUILD_OPENEMU)
86 set(OE_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (OpenEmu)")
87 mark_as_advanced(OE_LIBDIR)
88endif()
89
90
91set(CMAKE_INSTALL_RPATH "${LIBDIR}")
92
93if (NOT DEFINED MANDIR)
94 set(MANDIR ${CMAKE_INSTALL_MANDIR})
95endif()
96
97# Function definitions
98include(FindPkgConfig)
99function(find_feature FEATURE_NAME FEATURE_REQUIRES)
100 if (NOT ${FEATURE_NAME})
101 return()
102 endif()
103 if (DISABLE_DEPS)
104 set(${FEATURE_NAME} OFF PARENT_SCOPE)
105 return()
106 endif()
107 foreach(REQUIRE ${FEATURE_REQUIRES})
108 if(NOT ${REQUIRE}_FOUND)
109 find_package(${REQUIRE} QUIET)
110 if(NOT ${REQUIRE}_FOUND)
111 pkg_search_module(${REQUIRE} ${REQUIRE})
112 if (NOT ${REQUIRE}_FOUND)
113 message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
114 set(${FEATURE_NAME} OFF PARENT_SCOPE)
115 return()
116 endif()
117 endif()
118 endif()
119 string(TOUPPER ${REQUIRE} UREQUIRE)
120 set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
121 set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
122 set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
123 if (APPLE)
124 set(IS_FRAMEWORK OFF)
125 set(LIBS)
126 foreach(LIB IN LISTS ${REQUIRE}_LIBRARIES)
127 if(LIB STREQUAL "-framework")
128 set(IS_FRAMEWORK ON)
129 elseif(IS_FRAMEWORK)
130 list(APPEND LIBS "-framework ${LIB}")
131 set(IS_FRAMEWORK OFF)
132 else()
133 list(APPEND LIBS ${LIB})
134 endif()
135 endforeach()
136 set(${UREQUIRE}_LIBRARIES ${LIBS} PARENT_SCOPE)
137 else()
138 set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
139 endif()
140 set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
141 set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
142 endforeach()
143endfunction()
144
145# Version information
146add_custom_target(version-info ALL
147 COMMAND ${CMAKE_COMMAND}
148 -DBINARY_NAME=${BINARY_NAME}
149 -DCONFIG_FILE=${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in
150 -DOUT_FILE=${CMAKE_CURRENT_BINARY_DIR}/version.c
151 -P ${CMAKE_CURRENT_SOURCE_DIR}/version.cmake
152 WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
153
154include(${CMAKE_CURRENT_SOURCE_DIR}/version.cmake)
155configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in ${CMAKE_CURRENT_BINARY_DIR}/version.c)
156configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/flags.h.in ${CMAKE_CURRENT_BINARY_DIR}/flags.h)
157install(FILES ${CMAKE_CURRENT_BINARY_DIR}/flags.h DESTINATION include/mgba COMPONENT lib${BINARY_NAME})
158
159list(APPEND UTIL_SRC ${CMAKE_CURRENT_BINARY_DIR}/version.c)
160source_group("Generated sources" FILES ${CMAKE_CURRENT_BINARY_DIR}/version.c)
161
162# Advanced settings
163if(NOT DEFINED 3DS)
164 # LTO appears to make 3DS binary slower
165 set(DEFAULT_LTO ON)
166else()
167 set(DEFAULT_LTO OFF)
168endif()
169
170set(BUILD_LTO ${DEFAULT_LTO} CACHE BOOL "Build with link-time optimization")
171set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
172set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
173set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
174mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
175set(PGO_PRE_FLAGS "-fprofile-generate=${PGO_DIR} -fprofile-arcs")
176set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
177
178if(BUILD_PGO AND NOT PGO_STAGE_2)
179 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
180 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
181 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
182elseif(BUILD_PGO AND PGO_STAGE_2)
183 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
184 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
185 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
186endif()
187
188# Platform support
189if(WIN32)
190 set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
191 add_definitions(-D_WIN32_WINNT=0x0600)
192 list(APPEND OS_LIB ws2_32 shlwapi)
193 list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/vfs-w32.c)
194 file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/*.c)
195 source_group("Windows-specific code" FILES ${OS_SRC})
196 if(MSVC)
197 add_definitions(-DNOMINMAX -DWIN32_LEAN_AND_MEAN)
198 set(CMAKE_WINDOWS_EXPORT_ALL_SYMBOLS TRUE)
199 endif()
200elseif(UNIX)
201 add_definitions(-DUSE_PTHREADS)
202
203 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
204 add_definitions(-D_GNU_SOURCE)
205 endif()
206 if(NOT APPLE AND NOT HAIKU)
207 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
208 endif()
209
210 list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
211 file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/posix/*.c)
212 source_group("POSIX-specific code" FILES ${OS_SRC})
213endif()
214
215if(APPLE)
216 add_definitions(-D_DARWIN_C_SOURCE)
217 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
218endif()
219
220if(NOT HAIKU AND NOT MSVC AND NOT PSP2)
221 set(M_LIBRARY m)
222endif()
223list(APPEND OS_LIB ${M_LIBRARY})
224
225if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
226 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
227 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
228endif()
229
230if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
231 if(NOT BUILD_EGL)
232 add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
233 endif()
234endif()
235
236if(BUILD_RASPI)
237 set(BUILD_GL OFF CACHE BOOL "OpenGL not supported" FORCE)
238endif()
239
240if(BUILD_PANDORA)
241 add_definitions(-DBUILD_PANDORA)
242endif()
243
244if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
245 enable_language(ASM)
246endif()
247
248if(PSP2 OR WII)
249 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-format")
250endif()
251
252if(DEFINED 3DS OR DEFINED PSP2 OR DEFINED WII)
253 set(USE_DEBUGGERS OFF)
254 set(USE_SQLITE3 OFF)
255endif()
256
257if(NOT M_CORE_GBA)
258 set(USE_GDB_STUB OFF)
259endif()
260
261if(NOT USE_DEBUGGERS)
262 set(USE_EDITLINE OFF)
263 set(USE_GDB_STUB OFF)
264endif()
265
266if(WII)
267 add_definitions(-U__STRICT_ANSI__)
268endif()
269
270if(DEFINED 3DS)
271 add_definitions(-D_GNU_SOURCE)
272endif()
273
274include(CheckFunctionExists)
275check_function_exists(strdup HAVE_STRDUP)
276check_function_exists(strndup HAVE_STRNDUP)
277check_function_exists(localtime_r HAVE_LOCALTIME_R)
278if(NOT CMAKE_SYSTEM_NAME STREQUAL "Generic")
279 check_function_exists(snprintf_l HAVE_SNPRINTF_L)
280 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
281 # The strtof_l on Linux not actually exposed nor actually strtof_l
282 set(HAVE_STRTOF_L OFF)
283 else()
284 check_function_exists(strtof_l HAVE_STRTOF_L)
285 endif()
286 check_function_exists(newlocale HAVE_NEWLOCALE)
287 check_function_exists(freelocale HAVE_FREELOCALE)
288 check_function_exists(uselocale HAVE_USELOCALE)
289 check_function_exists(setlocale HAVE_SETLOCALE)
290else()
291 if(DEFINED 3DS)
292 check_function_exists(snprintf_l HAVE_SNPRINTF_L)
293 check_function_exists(strtof_l HAVE_STRTOF_L)
294 check_function_exists(newlocale HAVE_NEWLOCALE)
295 check_function_exists(freelocale HAVE_FREELOCALE)
296 check_function_exists(uselocale HAVE_USELOCALE)
297 check_function_exists(setlocale HAVE_SETLOCALE)
298 endif()
299 if(NOT DEFINED 3DS AND NOT DEFINED PSP2 AND NOT DEFINED WII)
300 set(DISABLE_DEPS ON CACHE BOOL "This platform cannot build with dependencies" FORCE)
301 endif()
302 set(DISABLE_FRONTENDS ON)
303 set(MINIMAL_CORE ON)
304endif()
305
306check_function_exists(chmod HAVE_CHMOD)
307check_function_exists(umask HAVE_UMASK)
308
309set(FUNCTION_DEFINES)
310
311if(HAVE_STRDUP)
312 list(APPEND FUNCTION_DEFINES HAVE_STRDUP)
313endif()
314
315if(HAVE_STRNDUP)
316 list(APPEND FUNCTION_DEFINES HAVE_STRNDUP)
317endif()
318
319if(HAVE_LOCALTIME_R)
320 list(APPEND FUNCTION_DEFINES HAVE_LOCALTIME_R)
321endif()
322
323if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE OR APPLE OR DEFINED 3DS)
324 list(APPEND FUNCTION_DEFINES HAVE_LOCALE)
325 if (HAVE_STRTOF_L)
326 list(APPEND FUNCTION_DEFINES HAVE_STRTOF_L)
327 endif()
328 if (HAVE_SNPRINTF_L)
329 list(APPEND FUNCTION_DEFINES HAVE_SNPRINTF_L)
330 endif()
331endif()
332
333if(HAVE_SETLOCALE)
334 list(APPEND FUNCTION_DEFINES HAVE_SETLOCALE)
335endif()
336
337if(HAVE_CHMOD)
338 list(APPEND FUNCTION_DEFINES HAVE_CHMOD)
339endif()
340
341if(HAVE_UMASK)
342 list(APPEND FUNCTION_DEFINES HAVE_UMASK)
343endif()
344
345# Feature dependencies
346set(FEATURE_DEFINES)
347set(FEATURES)
348if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
349 set(LIBEDIT_LIBRARIES -ledit)
350 if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
351 list(APPEND LIBEDIT_LIBRARIES -ltermcap)
352 endif()
353else()
354 find_feature(USE_EDITLINE "libedit")
355endif()
356if(BUILD_GL)
357 find_package(OpenGL QUIET)
358 if(NOT OPENGL_FOUND)
359 set(BUILD_GL OFF CACHE BOOL "OpenGL not found" FORCE)
360 endif()
361endif()
362if(NOT BUILD_GL)
363 set(OPENGLE_LIBRARY "" CACHE PATH "" FORCE)
364endif()
365if(BUILD_GLES2 AND NOT BUILD_RASPI)
366 find_path(OPENGLES2_INCLUDE_DIR NAMES GLES2/gl2.h)
367 find_library(OPENGLES2_LIBRARY NAMES GLESv2 GLESv2_CM)
368 if(NOT OPENGLES2_INCLUDE_DIR OR NOT OPENGLES2_LIBRARY)
369 set(BUILD_GLES2 OFF CACHE BOOL "OpenGL|ES 2 not found" FORCE)
370 endif()
371endif()
372if(NOT BUILD_GLES2)
373 set(OPENGLES2_LIBRARY "" CACHE PATH "" FORCE)
374endif()
375set(WANT_ZLIB ${USE_ZLIB})
376set(WANT_PNG ${USE_PNG})
377set(WANT_LIBZIP ${USE_LIBZIP})
378set(WANT_SQLITE3 ${USE_SQLITE3})
379set(USE_CMOCKA ${BUILD_SUITE})
380
381find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
382find_feature(USE_ZLIB "ZLIB")
383find_feature(USE_MINIZIP "minizip")
384find_feature(USE_PNG "PNG")
385find_feature(USE_LIBZIP "libzip")
386find_feature(USE_MAGICK "MagickWand")
387find_feature(USE_EPOXY "epoxy")
388find_feature(USE_CMOCKA "cmocka")
389find_feature(USE_SQLITE3 "sqlite3")
390
391# Features
392set(DEBUGGER_SRC
393 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/debugger.c
394 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/parser.c
395 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/cli-debugger.c)
396
397set(FEATURE_SRC)
398set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
399
400if(DISABLE_DEPS)
401 set(USE_GDB_STUB OFF)
402endif()
403
404if(USE_EDITLINE)
405 list(APPEND FEATURES EDITLINE)
406 include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
407 link_directories(${LIBEDIT_LIBRARY_DIRS})
408 set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
409 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
410 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/editline/cli-el-backend.c")
411else()
412 set(DEBUGGER_LIB "")
413endif()
414
415if(USE_GDB_STUB)
416 list(APPEND FEATURES GDB_STUB)
417 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/gdb-stub.c)
418endif()
419source_group("Debugger" FILES ${DEBUGGER_SRC})
420
421if(USE_FFMPEG)
422 list(APPEND FEATURES FFMPEG)
423 pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
424 if(NOT LIBSWRESAMPLE_FOUND)
425 list(APPEND FEATURES LIBAV)
426 endif()
427 include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
428 link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
429 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/ffmpeg/ffmpeg-encoder.c")
430 string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
431 string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
432 string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
433 string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
434 string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
435 list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
436 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR}|libavcodec-extra-${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
437 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavformat${LIBAVFORMAT_VERSION_MAJOR}|libavformat-ffmpeg${LIBAVFORMAT_VERSION_MAJOR}")
438 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavresample${LIBAVRESAMPLE_VERSION_MAJOR}|libavresample-ffmpeg${LIBAVRESAMPLE_VERSION_MAJOR}")
439 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavutil${LIBAVUTIL_VERSION_MAJOR}|libavutil-ffmpeg${LIBAVUTIL_VERSION_MAJOR}")
440 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libswscale${LIBSWSCALE_VERSION_MAJOR}|libswscale-ffmpeg${LIBSWSCALE_VERSION_MAJOR}")
441 set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
442 if(APPLE)
443 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
444 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
445 endif()
446endif()
447
448list(APPEND THIRD_PARTY_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
449
450if(USE_MAGICK)
451 list(APPEND FEATURES MAGICK)
452 include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
453 link_directories(${MAGICKWAND_LIBRARY_DIRS})
454 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/imagemagick/imagemagick-gif-encoder.c")
455 list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
456 string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
457 string(REGEX MATCH "^[0-9]+" MAGICKWAND_VERSION_MAJOR ${MagickWand_VERSION})
458 if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
459 set(MAGICKWAND_DEB_VERSION "5")
460 elseif(${MagickWand_VERSION} EQUAL "6.9.7")
461 set(MAGICKWAND_DEB_VERSION "-6.q16-3")
462 else()
463 set(MAGICKWAND_DEB_VERSION "-6.q16-2")
464 endif()
465 list(APPEND FEATURE_DEFINES MAGICKWAND_VERSION_MAJOR=${MAGICKWAND_VERSION_MAJOR})
466
467 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
468endif()
469
470if(WANT_ZLIB AND NOT USE_ZLIB)
471 set(SKIP_INSTALL_ALL ON)
472 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib zlib)
473 set_property(TARGET zlibstatic PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/zlib;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib)
474 set_property(TARGET zlib PROPERTY EXCLUDE_FROM_ALL ON)
475 set_property(TARGET example PROPERTY EXCLUDE_FROM_ALL ON)
476 set_property(TARGET minigzip PROPERTY EXCLUDE_FROM_ALL ON)
477 set(ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
478 set(ZLIB_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
479 set(ZLIB_LIBRARY zlibstatic)
480 list(APPEND DEPENDENCY_LIB zlibstatic)
481 set(USE_ZLIB ON)
482endif()
483
484if(USE_ZLIB)
485 list(APPEND FEATURES ZLIB)
486 include_directories(AFTER ${ZLIB_INCLUDE_DIRS})
487 list(APPEND DEPENDENCY_LIB ${ZLIB_LIBRARIES})
488 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},zlib1g")
489endif()
490
491if(WANT_PNG AND USE_ZLIB AND NOT USE_PNG)
492 set(PNG_STATIC ON CACHE BOOL "" FORCE)
493 set(PNG_SHARED OFF CACHE BOOL "" FORCE)
494 set(PNG_TESTS OFF CACHE BOOL "" FORCE)
495 set(SKIP_INSTALL_ALL ON)
496 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng libpng)
497 set_property(TARGET png16_static PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/libpng;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng;${ZLIB_INCLUDE_DIRS})
498 set(PNG_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng ${CMAKE_CURRENT_BINARY_DIR}/libpng)
499 list(APPEND DEPENDENCY_LIB png16_static)
500 set(USE_PNG ON)
501endif()
502
503if(USE_PNG)
504 list(APPEND FEATURES PNG)
505 include_directories(AFTER ${PNG_INCLUDE_DIRS})
506 list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
507 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng12-0")
508endif()
509
510if(WANT_SQLITE3 AND NOT USE_SQLITE3)
511 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/sqlite3.c)
512 include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/)
513 set(USE_SQLITE3 ON)
514endif()
515
516if(USE_LIBZIP)
517 include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
518 link_directories(${LIBZIP_LIBRARY_DIRS})
519 list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
520 list(APPEND FEATURES LIBZIP)
521 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
522 string(REGEX MATCH "^[0-9]+" LIBZIP_VERSION_MAJOR ${libzip_VERSION})
523 if (LIBZIP_VERSION_MAJOR LESS 1)
524 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
525 elseif(LIBZIP_VERSION_MAJOR EQUAL 1)
526 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip4")
527 else()
528 message(AUTHOR_WARNING Unknown version of libzip detected: ${libzip_VERSION})
529 endif()
530elseif(USE_MINIZIP)
531 include_directories(AFTER ${MINIZIP_INCLUDE_DIRS})
532 link_directories(${MINIZIP_LIBRARY_DIRS})
533 list(APPEND DEPENDENCY_LIB ${MINIZIP_LIBRARIES})
534 list(APPEND FEATURES MINIZIP)
535 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
536 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libminizip1")
537elseif(USE_ZLIB)
538 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c
539 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
540 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c)
541 if(NOT MSVC)
542 set_source_files_properties(
543 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
544 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c
545 PROPERTIES COMPILE_FLAGS "-Wno-unused-parameter -Wno-implicit-function-declaration")
546 endif()
547endif()
548
549if (USE_LZMA)
550 include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/third-party/lzma)
551 add_definitions(-D_7ZIP_PPMD_SUPPPORT)
552 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-lzma.c)
553 set(LZMA_SRC
554 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
555 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
556 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
557 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
558 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
559 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
560 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zDec.c
561 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
562 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Delta.c
563 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
564 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
565 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra.c
566 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra86.c
567 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/BraIA64.c
568 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
569 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
570 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
571 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zFile.c
572 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
573 list(APPEND VFS_SRC ${LZMA_SRC})
574 list(APPEND FEATURES LZMA)
575endif()
576
577if(USE_EPOXY)
578 add_definitions(-DBUILD_GL -DBUILD_GLES2)
579 list(APPEND FEATURES EPOXY)
580 include_directories(AFTER ${EPOXY_INCLUDE_DIRS})
581 set(OPENGLES2_LIBRARY ${EPOXY_LIBRARIES})
582 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libepoxy0")
583endif()
584
585if(USE_SQLITE3)
586 list(APPEND FEATURES SQLITE3)
587 include_directories(AFTER ${SQLITE3_INCLUDE_DIRS})
588 list(APPEND DEPENDENCY_LIB ${SQLITE3_LIBRARIES})
589 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libsqlite3-0")
590 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/sqlite3/no-intro.c")
591endif()
592
593set(TEST_SRC ${CORE_TEST_SRC})
594if(M_CORE_GB)
595 add_definitions(-DM_CORE_GB)
596 list(APPEND CORE_SRC
597 ${LR35902_SRC}
598 ${GB_SRC}
599 ${GB_RENDERER_SRC})
600 list(APPEND DEBUGGER_SRC
601 ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/cli-debugger.c
602 ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/debugger.c
603 ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/extra/cli.c)
604 list(APPEND TEST_SRC
605 ${LR35902_TEST_SRC}
606 ${GB_TEST_SRC})
607endif()
608
609if(M_CORE_GBA)
610 add_definitions(-DM_CORE_GBA)
611 list(APPEND CORE_SRC
612 ${ARM_SRC}
613 ${GBA_SRC}
614 ${GBA_CHEATS_SRC}
615 ${GBA_RENDERER_SRC})
616 list(APPEND DEBUGGER_SRC
617 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c
618 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/debugger.c
619 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/memory-debugger.c
620 ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/extra/cli.c)
621 list(APPEND TEST_SRC
622 ${ARM_TEST_SRC}
623 ${GBA_TEST_SRC})
624 if(NOT M_CORE_GB)
625 list(APPEND CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/audio.c)
626 endif()
627endif()
628
629if(USE_DEBUGGERS)
630 list(APPEND FEATURE_SRC ${DEBUGGER_SRC})
631 list(APPEND FEATURES DEBUGGERS)
632endif()
633
634foreach(FEATURE IN LISTS FEATURES)
635 list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
636endforeach()
637
638source_group("Virtual files" FILES ${CORE_VFS_SRC} ${VFS_SRC})
639source_group("Extra features" FILES ${FEATURE_SRC})
640source_group("Third-party code" FILES ${THIRD_PARTY_SRC})
641
642# Platform binaries
643if(DEFINED 3DS)
644 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/3ds ${CMAKE_CURRENT_BINARY_DIR}/3ds)
645endif()
646
647if(DEFINED WII)
648 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/wii ${CMAKE_CURRENT_BINARY_DIR}/wii)
649endif()
650
651if(DEFINED PSP2)
652 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/psp2 ${CMAKE_CURRENT_BINARY_DIR}/psp2)
653endif()
654
655# Binaries
656list(APPEND CORE_SRC
657 ${UTIL_SRC}
658 ${CORE_VFS_SRC}
659 ${OS_SRC}
660 ${THIRD_PARTY_SRC})
661list(APPEND TEST_SRC ${UTIL_TEST_SRC})
662
663set(SRC ${CORE_SRC} ${VFS_SRC})
664if(NOT MINIMAL_CORE)
665 if(M_CORE_GBA)
666 list(APPEND SRC
667 ${GBA_RR_SRC}
668 ${GBA_EXTRA_SRC}
669 ${GBA_SIO_SRC})
670 endif()
671 if(M_CORE_GB)
672 list(APPEND SRC
673 ${GB_SIO_SRC})
674 endif()
675 list(APPEND SRC
676 ${FEATURE_SRC}
677 ${CLI_SRC})
678endif()
679
680if(NOT SKIP_LIBRARY)
681 if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
682 set(BUILD_SHARED ON)
683 endif()
684
685 if(BUILD_SHARED)
686 add_library(${BINARY_NAME} SHARED ${SRC} ${VFS_SRC})
687 if(BUILD_STATIC)
688 add_library(${BINARY_NAME}-static STATIC ${SRC})
689 set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
690 install(TARGETS ${BINARY_NAME}-static DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
691 add_dependencies(${BINARY_NAME}-static version-info)
692 endif()
693 else()
694 add_library(${BINARY_NAME} STATIC ${SRC})
695 endif()
696
697 add_dependencies(${BINARY_NAME} version-info)
698 set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
699
700 target_link_libraries(${BINARY_NAME} ${DEBUGGER_LIB} ${DEPENDENCY_LIB} ${OS_LIB})
701 install(TARGETS ${BINARY_NAME} LIBRARY DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME} NAMELINK_SKIP ARCHIVE DESTINATION ${LIBDIR} RUNTIME DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
702 if(UNIX AND NOT APPLE)
703 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-16.png DESTINATION share/icons/hicolor/16x16/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
704 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-24.png DESTINATION share/icons/hicolor/24x24/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
705 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-32.png DESTINATION share/icons/hicolor/32x32/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
706 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-48.png DESTINATION share/icons/hicolor/48x48/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
707 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-64.png DESTINATION share/icons/hicolor/64x64/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
708 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-96.png DESTINATION share/icons/hicolor/96x96/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
709 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-128.png DESTINATION share/icons/hicolor/128x128/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
710 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-256.png DESTINATION share/icons/hicolor/256x256/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
711 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-512.png DESTINATION share/icons/hicolor/512x512/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
712 endif()
713else()
714 set(BUILD_SHARED OFF)
715 set(BUILD_STATIC OFF)
716 find_library(${BINARY_NAME} ${BINARY_NAME})
717 if(NOT ${BINARY_NAME}_FOUND)
718 set(DISABLE_FRONTENDS ON)
719 set(BUILD_PERF OFF)
720 set(BUILD_TEST OFF)
721 set(BUILD_SUITE OFF)
722 endif()
723endif()
724
725if(BUILD_GL)
726 add_definitions(-DBUILD_GL)
727endif()
728
729if(BUILD_GLES2)
730 add_definitions(-DBUILD_GLES2)
731endif()
732
733if(DISABLE_FRONTENDS)
734 set(BUILD_SDL OFF)
735 set(BUILD_QT OFF)
736endif()
737
738if(BUILD_LIBRETRO)
739 file(GLOB RETRO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/libretro/*.c)
740 add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
741 set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5;DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=2")
742 target_link_libraries(${BINARY_NAME}_libretro ${OS_LIB})
743 install(TARGETS ${BINARY_NAME}_libretro LIBRARY DESTINATION ${LIBRETRO_LIBDIR} COMPONENT ${BINARY_NAME}_libretro NAMELINK_SKIP)
744endif()
745
746if(BUILD_OPENEMU)
747 find_library(FOUNDATION Foundation)
748 find_library(OPENEMUBASE OpenEmuBase)
749 file(GLOB OE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/*.m)
750 add_library(${BINARY_NAME}-openemu MODULE ${CORE_SRC} ${OE_SRC})
751 set_target_properties(${BINARY_NAME}-openemu PROPERTIES
752 MACOSX_BUNDLE_INFO_PLIST ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/Info.plist.in
753 BUNDLE TRUE
754 BUNDLE_EXTENSION oecoreplugin
755 OUTPUT_NAME ${PROJECT_NAME}
756 COMPILE_DEFINITIONS "DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=1")
757 target_link_libraries(${BINARY_NAME}-openemu ${OS_LIB} ${FOUNDATION} ${OPENEMUBASE})
758 install(TARGETS ${BINARY_NAME}-openemu LIBRARY DESTINATION ${OE_LIBDIR} COMPONENT ${BINARY_NAME}.oecoreplugin NAMELINK_SKIP)
759endif()
760
761if(BUILD_SDL)
762 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/sdl ${CMAKE_CURRENT_BINARY_DIR}/sdl)
763 # The SDL platform CMakeLists could decide to disable SDL, so check again before adding the define.
764 if(BUILD_SDL)
765 add_definitions(-DBUILD_SDL)
766 endif()
767endif()
768
769if(BUILD_QT)
770 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/qt ${CMAKE_CURRENT_BINARY_DIR}/qt)
771endif()
772
773if(BUILD_PERF)
774 set(PERF_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/perf-main.c ${CLI_SRC})
775 if(UNIX AND NOT APPLE)
776 list(APPEND PERF_LIB rt)
777 endif()
778
779 add_executable(${BINARY_NAME}-perf ${PERF_SRC})
780 target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB} ${OS_LIB})
781 set_target_properties(${BINARY_NAME}-perf PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
782 install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
783 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
784endif()
785
786if(BUILD_TEST)
787 add_executable(${BINARY_NAME}-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/fuzz-main.c)
788 target_link_libraries(${BINARY_NAME}-fuzz ${BINARY_NAME})
789 set_target_properties(${BINARY_NAME}-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
790 add_executable(tbl-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/tbl-fuzz-main.c)
791 target_link_libraries(tbl-fuzz ${BINARY_NAME})
792 set_target_properties(tbl-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
793 install(TARGETS ${BINARY_NAME}-fuzz tbl-fuzz DESTINATION bin COMPONENT ${BINARY_NAME}-test)
794endif()
795
796if(NOT USE_CMOCKA)
797 set(BUILD_SUITE OFF)
798endif()
799if(BUILD_SUITE)
800 enable_testing()
801 include_directories(AFTER ${CMOCKA_INCLUDE_DIRS})
802 link_directories(${CMOCKA_LIBRARY_DIRS})
803
804 add_executable(${BINARY_NAME}-suite ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/suite-main.c ${TEST_SRC})
805 target_link_libraries(${BINARY_NAME}-suite ${BINARY_NAME} ${PLATFORM_LIBRARY} cmocka)
806 set_target_properties(${BINARY_NAME}-suite PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
807 add_test(${BINARY_NAME}-suite ${BINARY_NAME}-suite)
808endif()
809
810if(BUILD_PYTHON)
811 enable_testing()
812 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/python ${CMAKE_CURRENT_BINARY_DIR}/python)
813endif()
814
815if(BUILD_EXAMPLE)
816 add_executable(${BINARY_NAME}-example-server ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/server.c)
817 target_link_libraries(${BINARY_NAME}-example-server ${BINARY_NAME})
818 set_target_properties(${BINARY_NAME}-example-server PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
819
820 if(BUILD_SDL)
821 add_executable(${BINARY_NAME}-example-client ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/client.c)
822 target_link_libraries(${BINARY_NAME}-example-client ${BINARY_NAME} ${SDL_LIBRARY} ${SDLMAIN_LIBRARY} ${OPENGL_LIBRARY} ${OPENGLES2_LIBRARY})
823 set_target_properties(${BINARY_NAME}-example-client PROPERTIES
824 COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}"
825 INCLUDE_DIRECTORIES "${SDL_INCLUDE_DIR};${CMAKE_CURRENT_SOURCE_DIR}/src;${CMAKE_CURRENT_SOURCE_DIR}/include")
826 endif()
827endif()
828
829# Packaging
830set(CPACK_PACKAGE_VERSION ${VERSION_STRING})
831set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
832set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
833set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
834set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
835set(CPACK_RESOURCE_FILE_README ${CMAKE_CURRENT_SOURCE_DIR}/README.md)
836
837set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
838set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
839set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
840set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README.md")
841set(CPACK_DEBIAN_PACKAGE_SECTION "games")
842
843SET(CPACK_DEB_COMPONENT_INSTALL ON)
844
845set(CPACK_STRIP_FILES ${BINARY_NAME})
846
847install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/README.md ${CMAKE_CURRENT_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
848
849include(CPack)
850
851# Summaries
852set(SUMMARY_GL_LIST)
853if(USE_EPOXY)
854 set(SUMMARY_GL_LIST "libepoxy")
855else()
856 if(BUILD_GL)
857 list(APPEND SUMMARY_GL_LIST "OpenGL")
858 endif()
859 if(BUILD_GLES2)
860 list(APPEND SUMMARY_GL_LIST "OpenGL|ES 2")
861 endif()
862endif()
863if(NOT SUMMARY_GL_LIST)
864 set(SUMMARY_GL OFF)
865else()
866 string(REPLACE ";" ", " SUMMARY_GL "${SUMMARY_GL_LIST}")
867endif()
868if(USE_LIBZIP)
869 set(SUMMARY_ZIP libzip)
870elseif(USE_MINIZIP)
871 set(SUMMARY_ZIP "minizip (external)")
872elseif(USE_ZLIB)
873 set(SUMMARY_ZIP "minizip (included)")
874else()
875 set(SUMMARY_ZIP OFF)
876endif()
877
878if(NOT QUIET)
879 message(STATUS "Platforms:")
880 message(STATUS " Game Boy Advance: ${M_CORE_GBA}")
881 message(STATUS " Game Boy: ${M_CORE_GB}")
882 message(STATUS "Features:")
883 message(STATUS " Debuggers: ${USE_DEBUGGERS}")
884 message(STATUS " CLI debugger: ${USE_EDITLINE}")
885 message(STATUS " GDB stub: ${USE_GDB_STUB}")
886 message(STATUS " Video recording: ${USE_FFMPEG}")
887 message(STATUS " GIF recording: ${USE_MAGICK}")
888 message(STATUS " Screenshot/advanced savestate support: ${USE_PNG}")
889 message(STATUS " ZIP support: ${SUMMARY_ZIP}")
890 message(STATUS " 7-Zip support: ${USE_LZMA}")
891 message(STATUS " SQLite3 game database: ${USE_SQLITE3}")
892 message(STATUS " OpenGL support: ${SUMMARY_GL}")
893 message(STATUS "Frontends:")
894 message(STATUS " Qt: ${BUILD_QT}")
895 message(STATUS " SDL (${SDL_VERSION}): ${BUILD_SDL}")
896 message(STATUS " Profiling: ${BUILD_PERF}")
897 message(STATUS " Test harness: ${BUILD_TEST}")
898 message(STATUS " Test suite: ${BUILD_SUITE}")
899 message(STATUS " Python bindings: ${BUILD_PYTHON}")
900 message(STATUS " Examples: ${BUILD_EXAMPLE}")
901 message(STATUS "Cores:")
902 message(STATUS " Libretro core: ${BUILD_LIBRETRO}")
903 if(APPLE)
904 message(STATUS " OpenEmu core: ${BUILD_OPENEMU}")
905 endif()
906 message(STATUS "Libraries:")
907 message(STATUS " Static: ${BUILD_STATIC}")
908 message(STATUS " Shared: ${BUILD_SHARED}")
909endif()