CMakeLists.txt (view raw)
1cmake_minimum_required(VERSION 2.6)
2project(mGBA C)
3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
4set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -std=gnu99")
5set(USE_CLI_DEBUGGER ON CACHE BOOL "Whether or not to enable the CLI-mode ARM debugger")
6set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
7set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
8set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
9set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable ZIP support")
10set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
11set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
12set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
13set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
14file(GLOB ARM_SRC ${CMAKE_SOURCE_DIR}/src/arm/*.c)
15file(GLOB GBA_SRC ${CMAKE_SOURCE_DIR}/src/gba/*.c)
16file(GLOB UTIL_SRC ${CMAKE_SOURCE_DIR}/src/util/*.[cSs])
17file(GLOB VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/*.c)
18file(GLOB RENDERER_SRC ${CMAKE_SOURCE_DIR}/src/gba/renderers/video-software.c)
19file(GLOB THIRD_PARTY_SRC ${CMAKE_SOURCE_DIR}/src/third-party/inih/*.c)
20list(APPEND UTIL_SRC ${CMAKE_SOURCE_DIR}/src/platform/commandline.c)
21source_group("ARM core" FILES ${ARM_SRC})
22source_group("GBA board" FILES ${GBA_SRC} ${RENDERER_SRC})
23source_group("Utilities" FILES ${UTIL_SRC} ${VFS_SRC}})
24include_directories(${CMAKE_SOURCE_DIR}/src/arm)
25include_directories(${CMAKE_SOURCE_DIR}/src/gba)
26include_directories(${CMAKE_SOURCE_DIR}/src)
27
28if(NOT CMAKE_BUILD_TYPE)
29 set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)")
30endif()
31
32include(GNUInstallDirs)
33
34# Function definitions
35include(FindPkgConfig)
36function(find_feature FEATURE_NAME FEATURE_REQUIRES)
37 if (NOT ${FEATURE_NAME})
38 return()
39 endif()
40 foreach(REQUIRE ${FEATURE_REQUIRES})
41 if(NOT ${REQUIRE}_FOUND)
42 find_package(${REQUIRE} QUIET)
43 if(NOT ${REQUIRE}_FOUND)
44 pkg_search_module(${REQUIRE} ${REQUIRE})
45 if (NOT ${REQUIRE}_FOUND)
46 message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
47 set(${FEATURE_NAME} OFF PARENT_SCOPE)
48 return()
49 endif()
50 endif()
51 endif()
52 string(TOUPPER ${REQUIRE} UREQUIRE)
53 set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
54 set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
55 set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
56 set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
57 set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
58 set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
59 endforeach()
60endfunction()
61
62# Version information
63set(LIB_VERSION_MAJOR 0)
64set(LIB_VERSION_MINOR 1)
65set(LIB_VERSION_PATCH 0)
66set(LIB_VERSION_ABI 0.1)
67set(LIB_VERSION_STRING ${LIB_VERSION_MAJOR}.${LIB_VERSION_MINOR}.${LIB_VERSION_PATCH})
68
69# Advanced settings
70set(BUILD_PGO CACHE BOOL "Build with profiling-guided optimization")
71set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
72set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
73mark_as_advanced(BUILD_PGO PGO_STAGE_2 PGO_DIR)
74set(PGO_PRE_FLAGS "-pg -fprofile-generate=${PGO_DIR} -fprofile-arcs")
75set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
76
77if(BUILD_PGO AND NOT PGO_STAGE_2)
78 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
79 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
80 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
81elseif(BUILD_PGO AND PGO_STAGE_2)
82 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
83 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
84 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
85endif()
86
87add_definitions(-DBINARY_NAME="${BINARY_NAME}" -DPROJECT_NAME="${PROJECT_NAME}" -DPROJECT_VERSION="${LIB_VERSION_STRING}")
88
89# Feature dependencies
90find_feature(USE_CLI_DEBUGGER "libedit")
91find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
92find_feature(USE_PNG "ZLIB;PNG")
93find_feature(USE_LIBZIP "libzip")
94find_feature(USE_MAGICK "MagickWand")
95
96include(CheckFunctionExists)
97check_function_exists(strndup HAVE_STRNDUP)
98
99if(HAVE_STRNDUP)
100 add_definitions(-DHAVE_STRNDUP)
101endif()
102
103# Platform support
104set(BINARY_TYPE SHARED)
105if(WIN32)
106 add_definitions(-D_WIN32_WINNT=0x0600)
107 list(APPEND OS_LIB ws2_32)
108 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/windows/*.c)
109 source_group("Windows-specific code" FILES ${OS_SRC})
110elseif(UNIX)
111 add_definitions(-DUSE_PTHREADS)
112 list(APPEND OS_LIB pthread)
113 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/posix/*.c)
114 source_group("POSIX-specific code" FILES ${OS_SRC})
115elseif(3DS)
116 enable_language(ASM)
117 add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
118 list(APPEND OS_LIB ctru)
119 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/3ds/3ds-*.c)
120 source_group("3DS-specific code" FILES ${OS_SRC})
121 set(BINARY_TYPE STATIC)
122endif()
123
124if(APPLE)
125 set(CMAKE_OSX_DEPLOYMENT_TARGET "10.7")
126 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -stdlib=libc++")
127endif()
128
129if(BUILD_BBB OR BUILD_RASPI)
130 enable_language(ASM)
131 if(NOT BUILD_EGL)
132 add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
133 endif()
134endif()
135
136# Features
137set(DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/debugger.c ${CMAKE_SOURCE_DIR}/src/debugger/memory-debugger.c)
138
139if(USE_CLI_DEBUGGER)
140 add_definitions(-DUSE_CLI_DEBUGGER)
141 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/cli-debugger.c)
142 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/parser.c)
143 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/gba/gba-cli.c)
144 include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
145 link_directories(${LIBEDIT_LIBRARY_DIRS})
146 set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
147else()
148 set(DEBUGGER_LIB "")
149endif()
150
151if(USE_GDB_STUB)
152 add_definitions(-DUSE_GDB_STUB)
153 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/gdb-stub.c)
154endif()
155source_group("ARM debugger" FILES ${DEBUGGER_SRC})
156
157if(USE_FFMPEG)
158 add_definitions(-DUSE_FFMPEG)
159 include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
160 link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
161 list(APPEND UTIL_SRC "${CMAKE_SOURCE_DIR}/src/platform/ffmpeg/ffmpeg-encoder.c")
162 list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
163endif()
164
165if(USE_MAGICK)
166 add_definitions(-DUSE_MAGICK)
167 include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
168 link_directories(${MAGICKWAND_LIBRARY_DIRS})
169 list(APPEND UTIL_SRC "${CMAKE_SOURCE_DIR}/src/platform/imagemagick/imagemagick-gif-encoder.c")
170 list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
171endif()
172
173if(USE_PNG)
174 add_definitions(-DUSE_PNG)
175 include_directories(AFTER ${PNG_INCLUDE_DIRS})
176 list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
177endif()
178
179if(USE_LIBZIP)
180 include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
181 link_directories(${LIBZIP_LIBRARY_DIRS})
182 list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
183 add_definitions(-DENABLE_LIBZIP)
184endif()
185
186# Binaries
187add_library(${BINARY_NAME} ${BINARY_TYPE}
188 ${ARM_SRC}
189 ${GBA_SRC}
190 ${DEBUGGER_SRC}
191 ${RENDERER_SRC}
192 ${UTIL_SRC}
193 ${VFS_SRC}
194 ${OS_SRC}
195 ${THIRD_PARTY_SRC})
196target_link_libraries(${BINARY_NAME} m ${DEBUGGER_LIB} ${OS_LIB} ${DEPENDENCY_LIB})
197install(TARGETS ${BINARY_NAME} DESTINATION lib)
198set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI})
199
200if(BUILD_SDL)
201 add_definitions(-DBUILD_SDL)
202 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/sdl ${CMAKE_BINARY_DIR}/sdl)
203endif()
204
205if(BUILD_QT)
206 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/qt ${CMAKE_BINARY_DIR}/qt)
207endif()
208
209if(BUILD_PERF)
210 set(PERF_SRC ${CMAKE_SOURCE_DIR}/src/platform/perf-main.c)
211 if(UNIX AND NOT APPLE)
212 list(APPEND PERF_LIB rt)
213 endif()
214
215 add_executable(${BINARY_NAME}-perf ${PERF_SRC})
216 target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB})
217 install(TARGETS ${BINARY_NAME}-perf DESTINATION bin)
218 install(FILES ${CMAKE_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}")
219endif()
220
221if(3DS)
222 add_executable(${BINARY_NAME}.elf ${CMAKE_SOURCE_DIR}/src/platform/3ds/main.c)
223 target_link_libraries(${BINARY_NAME}.elf ${BINARY_NAME} m ${OS_LIB})
224 add_custom_command(TARGET ${BINARY_NAME}.elf POST_BUILD COMMAND ${3DSXTOOL} ${BINARY_NAME}.elf ${BINARY_NAME}.3dsx)
225endif()
226
227# Packaging
228set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
229set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
230set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
231set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_SOURCE_DIR}/LICENSE)
232
233set(CPACK_STRIP_FILES ${BINARY_NAME})
234
235include(CPack)
236
237# Summaries
238message(STATUS "Feature summary:")
239message(STATUS " CLI debugger: ${USE_CLI_DEBUGGER}")
240message(STATUS " GDB stub: ${USE_GDB_STUB}")
241message(STATUS " Video recording: ${USE_FFMPEG}")
242message(STATUS " GIF recording: ${USE_MAGICK}")
243message(STATUS " Screenshot/advanced savestate support: ${USE_PNG}")
244message(STATUS " ZIP support: ${USE_LIBZIP}")
245message(STATUS "Frontend summary:")
246message(STATUS " Qt: ${BUILD_QT}")
247message(STATUS " SDL (${SDL_VERSION}): ${BUILD_SDL}")
248message(STATUS " Profiling: ${BUILD_PERF}")