CMakeLists.txt (view raw)
1cmake_minimum_required(VERSION 3.1)
2if(POLICY CMP0025)
3 cmake_policy(SET CMP0025 NEW)
4endif()
5project(mGBA)
6set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
7if(NOT MSVC)
8 set(GCC_STD "c99")
9 if(SWITCH)
10 set(GCC_STD "gnu11")
11 elseif(CMAKE_C_COMPILER_ID STREQUAL "GNU" AND CMAKE_COMPILER_VERSION VERSION_LESS "4.3")
12 set(GCC_STD "gnu99")
13 endif()
14 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wno-missing-field-initializers -std=${GCC_STD}")
15else()
16 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_CRT_SECURE_NO_WARNINGS /wd4003 /wd4244 /wd4146")
17endif()
18set(USE_DEBUGGERS ON CACHE BOOL "Whether or not to enable the debugging infrastructure")
19if (NOT WIN32)
20 set(USE_EDITLINE ON CACHE BOOL "Whether or not to enable the CLI-mode debugger")
21endif()
22set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
23set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
24set(USE_ZLIB ON CACHE BOOL "Whether or not to enable zlib support")
25set(USE_MINIZIP ON CACHE BOOL "Whether or not to enable external minizip support")
26set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
27set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable LIBZIP support")
28set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
29set(USE_SQLITE3 ON CACHE BOOL "Whether or not to enable SQLite3 support")
30set(USE_ELF ON CACHE BOOL "Whether or not to enable ELF support")
31set(M_CORE_GBA ON CACHE BOOL "Build Game Boy Advance core")
32set(M_CORE_GB ON CACHE BOOL "Build Game Boy core")
33set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
34set(ENABLE_SCRIPTING ON CACHE BOOL "Whether or not to enable scripting support")
35set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
36set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
37set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
38if(APPLE)
39 set(BUILD_OPENEMU OFF CACHE BOOL "Build OpenEmu core")
40endif()
41set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
42set(BUILD_TEST OFF CACHE BOOL "Build testing harness")
43set(BUILD_SUITE OFF CACHE BOOL "Build test suite")
44set(BUILD_EXAMPLE OFF CACHE BOOL "Build example frontends")
45set(BUILD_PYTHON OFF CACHE BOOL "Build Python bindings")
46set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
47set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
48set(SKIP_LIBRARY OFF CACHE BOOL "Skip building the library (useful for only building libretro or OpenEmu cores)")
49set(BUILD_GL ON CACHE BOOL "Build with OpenGL")
50set(BUILD_GLES2 OFF CACHE BOOL "Build with OpenGL|ES 2")
51set(BUILD_GLES3 OFF CACHE BOOL "Build with OpenGL|ES 3")
52set(USE_EPOXY ON CACHE STRING "Build with libepoxy")
53set(DISABLE_DEPS OFF CACHE BOOL "Build without dependencies")
54set(DISTBUILD OFF CACHE BOOL "Build distribution packages")
55if(WIN32)
56 set(WIN32_UNIX_PATHS OFF CACHE BOOL "Use Unix-like paths")
57 mark_as_advanced(WIN32_UNIX_PATHS)
58endif()
59file(GLOB ARM_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/*.c)
60file(GLOB ARM_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/test/*.c)
61file(GLOB LR35902_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/*.c)
62file(GLOB LR35902_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/test/*.c)
63file(GLOB GBA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/*.c)
64file(GLOB GBA_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/test/*.c)
65file(GLOB GB_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/*.c)
66file(GLOB GB_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/test/*.c)
67file(GLOB GBA_CHEATS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/cheats/*.c)
68file(GLOB GBA_RR_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/rr/*.c)
69file(GLOB CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/*.c)
70file(GLOB CORE_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/test/*.c)
71file(GLOB UTIL_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/*.c)
72file(GLOB UTIL_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/test/*.c)
73file(GLOB GUI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/gui/*.c ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/gui/*.c)
74file(GLOB GBA_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/renderers/*.c)
75file(GLOB GBA_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/sio/*.c)
76file(GLOB GBA_EXTRA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/extra/*.c)
77file(GLOB GB_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/sio/*.c)
78file(GLOB GB_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/renderers/*.c)
79file(GLOB GB_EXTRA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/extra/*.c)
80file(GLOB THIRD_PARTY_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/inih/*.c)
81file(GLOB EXTRA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/*.c)
82set(CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-mem.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fifo.c)
83set(VFS_SRC)
84source_group("ARM core" FILES ${ARM_SRC})
85source_group("LR35902 core" FILES ${LR35902_SRC})
86source_group("GBA board" FILES ${GBA_SRC} ${GBA_RENDERER_SRC} ${GBA_SIO_SRC})
87source_group("GBA extra" FILES ${GBA_CHEATS_SRC} ${GBA_RR_SRC})
88source_group("GB board" FILES ${GB_SRC} ${GB_SIO_SRC})
89source_group("Utilities" FILES ${UTIL_SRC})
90include_directories(BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/include ${CMAKE_CURRENT_SOURCE_DIR}/src)
91
92if(NOT CMAKE_BUILD_TYPE)
93 set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
94endif()
95
96if(UNIX OR WIN32_UNIX_PATHS)
97 include(GNUInstallDirs)
98else()
99 set(CMAKE_INSTALL_LIBDIR ".")
100 set(CMAKE_INSTALL_BINDIR ".")
101 set(CMAKE_INSTALL_DATADIR ".")
102 set(CMAKE_INSTALL_DOCDIR ".")
103 set(CMAKE_INSTALL_INCLUDEDIR "include")
104endif()
105
106set(LIBDIR "${CMAKE_INSTALL_LIBDIR}" CACHE PATH "Installed library directory")
107mark_as_advanced(LIBDIR)
108
109if (BUILD_LIBRETRO)
110 set(LIBRETRO_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (Libretro)")
111 mark_as_advanced(LIBRETRO_LIBDIR)
112endif()
113
114if (BUILD_OPENEMU)
115 set(OE_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (OpenEmu)")
116 mark_as_advanced(OE_LIBDIR)
117endif()
118
119if (DISTBUILD)
120 set(EXTRA_LICENSES "" CACHE FILEPATH "Extra licenses to include in distribution packaages")
121 mark_as_advanced(EXTRA_LICENSES)
122endif()
123mark_as_advanced(DISTBUILD)
124
125set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${LIBDIR}")
126
127if (NOT DEFINED MANDIR)
128 set(MANDIR ${CMAKE_INSTALL_MANDIR})
129endif()
130
131# Function definitions
132include(FindPkgConfig)
133function(find_feature FEATURE_NAME FEATURE_REQUIRES)
134 if (NOT ${FEATURE_NAME})
135 return()
136 endif()
137 if (DISABLE_DEPS)
138 set(${FEATURE_NAME} OFF PARENT_SCOPE)
139 return()
140 endif()
141 foreach(REQUIRE ${FEATURE_REQUIRES})
142 if(NOT ${REQUIRE}_FOUND)
143 find_package(${REQUIRE} QUIET)
144 if(NOT ${REQUIRE}_FOUND)
145 pkg_search_module(${REQUIRE} ${REQUIRE})
146 if (NOT ${REQUIRE}_FOUND)
147 message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
148 set(${FEATURE_NAME} OFF PARENT_SCOPE)
149 return()
150 endif()
151 endif()
152 endif()
153 string(TOUPPER ${REQUIRE} UREQUIRE)
154 set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
155 set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
156 set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
157 set(${UREQUIRE}_VERSION_STRING ${${REQUIRE}_VERSION_STRING} PARENT_SCOPE)
158 if (APPLE)
159 set(IS_FRAMEWORK OFF)
160 set(LIBS)
161 foreach(LIB IN LISTS ${REQUIRE}_LIBRARIES)
162 if(LIB STREQUAL "-framework")
163 set(IS_FRAMEWORK ON)
164 elseif(IS_FRAMEWORK)
165 list(APPEND LIBS "-framework ${LIB}")
166 set(IS_FRAMEWORK OFF)
167 else()
168 list(APPEND LIBS ${LIB})
169 endif()
170 endforeach()
171 set(${UREQUIRE}_LIBRARIES ${LIBS} PARENT_SCOPE)
172 else()
173 set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
174 endif()
175 set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
176 set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
177 endforeach()
178endfunction()
179
180# Version information
181add_custom_target(version-info ALL
182 COMMAND ${CMAKE_COMMAND}
183 -DBINARY_NAME=${BINARY_NAME}
184 -DCONFIG_FILE=${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in
185 -DOUT_FILE=${CMAKE_CURRENT_BINARY_DIR}/version.c
186 -P ${CMAKE_CURRENT_SOURCE_DIR}/version.cmake
187 WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
188
189include(${CMAKE_CURRENT_SOURCE_DIR}/version.cmake)
190configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in ${CMAKE_CURRENT_BINARY_DIR}/version.c)
191
192list(APPEND UTIL_SRC ${CMAKE_CURRENT_BINARY_DIR}/version.c)
193source_group("Generated sources" FILES ${CMAKE_CURRENT_BINARY_DIR}/version.c)
194
195# Advanced settings
196if(NOT DEFINED 3DS AND NOT (CMAKE_C_COMPILER_ID STREQUAL "GNU" AND CMAKE_COMPILER_VERSION VERSION_LESS "4.5"))
197 # LTO appears to make 3DS binary slower
198 set(DEFAULT_LTO ON)
199else()
200 set(DEFAULT_LTO OFF)
201endif()
202
203set(BUILD_LTO ${DEFAULT_LTO} CACHE BOOL "Build with link-time optimization")
204set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
205set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
206set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
207mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
208set(PGO_PRE_FLAGS "-fprofile-generate=${PGO_DIR} -fprofile-arcs")
209set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
210
211if(BUILD_PGO AND NOT PGO_STAGE_2)
212 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
213 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
214 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
215elseif(BUILD_PGO AND PGO_STAGE_2)
216 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
217 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
218 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
219endif()
220
221# Platform support
222if(WIN32)
223 set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
224 add_definitions(-D_WIN32_WINNT=0x0600)
225 list(APPEND OS_LIB ws2_32 shlwapi)
226 list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/vfs-w32.c)
227 file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/*.c)
228 source_group("Windows-specific code" FILES ${OS_SRC})
229 if(MSVC)
230 add_definitions(-DNOMINMAX -DWIN32_LEAN_AND_MEAN)
231 set(CMAKE_WINDOWS_EXPORT_ALL_SYMBOLS TRUE)
232 endif()
233elseif(UNIX)
234 set(USE_PTHREADS ON)
235 add_definitions(-DUSE_PTHREADS)
236
237 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
238 add_definitions(-D_GNU_SOURCE)
239 endif()
240 if(NOT APPLE AND NOT HAIKU)
241 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
242 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -pthread")
243 endif()
244
245 list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
246 file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/posix/*.c)
247 source_group("POSIX-specific code" FILES ${OS_SRC})
248endif()
249
250if(APPLE)
251 add_definitions(-D_DARWIN_C_SOURCE)
252 if(CMAKE_SYSTEM_VERSION VERSION_GREATER "10.5.8")
253 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
254 endif()
255endif()
256
257if(NOT HAIKU AND NOT MSVC AND NOT PSP2)
258 set(M_LIBRARY m)
259endif()
260list(APPEND OS_LIB ${M_LIBRARY})
261
262if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
263 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
264 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
265endif()
266
267if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
268 if(NOT BUILD_EGL)
269 add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
270 endif()
271endif()
272
273if(BUILD_RASPI)
274 set(BUILD_GL OFF CACHE BOOL "OpenGL not supported" FORCE)
275endif()
276
277if(BUILD_PANDORA)
278 add_definitions(-DBUILD_PANDORA)
279endif()
280
281if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
282 enable_language(ASM)
283endif()
284
285if(PSP2 OR WII)
286 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-format")
287endif()
288
289if(DEFINED 3DS OR DEFINED PSP2 OR DEFINED WII OR DEFINED SWITCH)
290 set(IS_EMBEDDED ON)
291 set(USE_DEBUGGERS OFF)
292 set(USE_SQLITE3 OFF)
293endif()
294
295if(DEFINED 3DS)
296 add_definitions(-DFIXED_ROM_BUFFER)
297endif()
298
299if(DEFINED SWITCH)
300 set(BUILD_GLES3 ON CACHE BOOL "Build with OpenGL|ES 3" FORCE)
301endif()
302
303if(NOT M_CORE_GBA)
304 set(USE_GDB_STUB OFF)
305endif()
306
307if(NOT USE_DEBUGGERS)
308 set(USE_EDITLINE OFF)
309 set(USE_GDB_STUB OFF)
310endif()
311
312if(WII)
313 add_definitions(-U__STRICT_ANSI__)
314endif()
315
316if(DEFINED 3DS)
317 add_definitions(-D_GNU_SOURCE)
318endif()
319
320include(CheckFunctionExists)
321include(CheckIncludeFiles)
322check_function_exists(strdup HAVE_STRDUP)
323check_function_exists(strndup HAVE_STRNDUP)
324if(NOT DEFINED PSP2)
325 check_function_exists(localtime_r HAVE_LOCALTIME_R)
326endif()
327check_include_files("xlocale.h" HAVE_XLOCALE)
328if(NOT CMAKE_SYSTEM_NAME STREQUAL "Generic")
329 check_function_exists(snprintf_l HAVE_SNPRINTF_L)
330 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
331 # The strtof_l on Linux not actually exposed nor actually strtof_l
332 set(HAVE_STRTOF_L OFF)
333 else()
334 check_function_exists(strtof_l HAVE_STRTOF_L)
335 endif()
336 check_function_exists(newlocale HAVE_NEWLOCALE)
337 check_function_exists(freelocale HAVE_FREELOCALE)
338 check_function_exists(uselocale HAVE_USELOCALE)
339 check_function_exists(setlocale HAVE_SETLOCALE)
340else()
341 if(DEFINED 3DS OR DEFINED WII OR DEFINED SWITCH)
342 set(CMAKE_REQUIRED_FLAGS -Wl,--require-defined,snprintf_l)
343 check_function_exists(snprintf_l HAVE_SNPRINTF_L)
344 set(CMAKE_REQUIRED_FLAGS -Wl,--require-defined,strtof_l)
345 check_function_exists(strtof_l HAVE_STRTOF_L)
346 set(CMAKE_REQUIRED_FLAGS -Wl,--require-defined,newlocale)
347 check_function_exists(newlocale HAVE_NEWLOCALE)
348 set(CMAKE_REQUIRED_FLAGS -Wl,--require-defined,freelocale)
349 check_function_exists(freelocale HAVE_FREELOCALE)
350 set(CMAKE_REQUIRED_FLAGS -Wl,--require-defined,uselocale)
351 check_function_exists(uselocale HAVE_USELOCALE)
352 set(CMAKE_REQUIRED_FLAGS -Wl,--require-defined,setlocale)
353 check_function_exists(setlocale HAVE_SETLOCALE)
354 unset(CMAKE_REQUIRED_FLAGS)
355 endif()
356 if(NOT IS_EMBEDDED)
357 set(DISABLE_DEPS ON CACHE BOOL "This platform cannot build with dependencies" FORCE)
358 endif()
359 set(BUILD_STATIC ON CACHE BOOL "" FORCE)
360 set(BUILD_SHARED OFF CACHE BOOL "" FORCE)
361 set(DISABLE_FRONTENDS ON)
362 set(MINIMAL_CORE ON)
363 set(ENABLE_EXTRA ON)
364endif()
365
366check_function_exists(chmod HAVE_CHMOD)
367check_function_exists(umask HAVE_UMASK)
368
369set(FUNCTION_DEFINES)
370
371if(HAVE_STRDUP)
372 list(APPEND FUNCTION_DEFINES HAVE_STRDUP)
373endif()
374
375if(HAVE_STRNDUP)
376 list(APPEND FUNCTION_DEFINES HAVE_STRNDUP)
377endif()
378
379if(HAVE_LOCALTIME_R)
380 list(APPEND FUNCTION_DEFINES HAVE_LOCALTIME_R)
381endif()
382
383if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE OR APPLE)
384 list(APPEND FUNCTION_DEFINES HAVE_LOCALE)
385 if (HAVE_SNPRINTF_L)
386 list(APPEND FUNCTION_DEFINES HAVE_SNPRINTF_L)
387 endif()
388endif()
389
390if(HAVE_SETLOCALE)
391 list(APPEND FUNCTION_DEFINES HAVE_SETLOCALE)
392endif()
393
394if (HAVE_STRTOF_L)
395 list(APPEND FUNCTION_DEFINES HAVE_STRTOF_L)
396endif()
397
398if(HAVE_XLOCALE)
399 list(APPEND FUNCTION_DEFINES HAVE_XLOCALE)
400endif()
401
402if(HAVE_CHMOD)
403 list(APPEND FUNCTION_DEFINES HAVE_CHMOD)
404endif()
405
406if(HAVE_UMASK)
407 list(APPEND FUNCTION_DEFINES HAVE_UMASK)
408endif()
409
410# Feature dependencies
411set(FEATURE_DEFINES)
412set(FEATURE_FLAGS)
413set(FEATURES)
414set(ENABLES)
415if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
416 set(LIBEDIT_LIBRARIES -ledit)
417 if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
418 list(APPEND LIBEDIT_LIBRARIES -ltermcap)
419 endif()
420else()
421 find_feature(USE_EDITLINE "libedit")
422endif()
423if(BUILD_GL)
424 find_package(OpenGL QUIET)
425 if(NOT OPENGL_FOUND)
426 set(BUILD_GL OFF CACHE BOOL "OpenGL not found" FORCE)
427 endif()
428endif()
429if(NOT BUILD_GL)
430 set(OPENGLE_LIBRARY "" CACHE PATH "" FORCE)
431endif()
432if(BUILD_GLES2 AND NOT BUILD_RASPI)
433 find_path(OPENGLES2_INCLUDE_DIR NAMES GLES2/gl2.h)
434 find_library(OPENGLES2_LIBRARY NAMES GLESv2 GLESv2_CM)
435 if(NOT OPENGLES2_INCLUDE_DIR OR NOT OPENGLES2_LIBRARY)
436 set(BUILD_GLES2 OFF CACHE BOOL "OpenGL|ES 2 not found" FORCE)
437 endif()
438endif()
439if(NOT BUILD_GLES2)
440 set(OPENGLES2_LIBRARY "" CACHE PATH "" FORCE)
441endif()
442if(BUILD_GLES3)
443 find_path(OPENGLES3_INCLUDE_DIR NAMES GLES3/gl3.h)
444 find_library(OPENGLES3_LIBRARY NAMES GLESv3 GLESv2)
445 if(NOT OPENGLES3_INCLUDE_DIR OR NOT OPENGLES3_LIBRARY)
446 set(BUILD_GLES3 OFF CACHE BOOL "OpenGL|ES 3 not found" FORCE)
447 endif()
448endif()
449set(WANT_ZLIB ${USE_ZLIB})
450set(WANT_PNG ${USE_PNG})
451set(WANT_LIBZIP ${USE_LIBZIP})
452set(WANT_SQLITE3 ${USE_SQLITE3})
453set(USE_CMOCKA ${BUILD_SUITE})
454
455find_feature(USE_FFMPEG "libavcodec;libavformat;libavutil;libswscale")
456find_feature(USE_ZLIB "ZLIB")
457find_feature(USE_MINIZIP "minizip")
458find_feature(USE_PNG "PNG")
459find_feature(USE_LIBZIP "libzip")
460find_feature(USE_MAGICK "MagickWand")
461find_feature(USE_EPOXY "epoxy")
462find_feature(USE_CMOCKA "cmocka")
463find_feature(USE_SQLITE3 "sqlite3")
464find_feature(USE_ELF "libelf")
465find_feature(ENABLE_PYTHON "PythonLibs")
466
467if(USE_FFMPEG)
468 set(USE_LIBAVRESAMPLE ON)
469 set(USE_LIBSWRESAMPLE ON)
470 find_feature(USE_LIBAVRESAMPLE "libavresample")
471 find_feature(USE_LIBSWRESAMPLE "libswresample")
472endif()
473
474# Features
475set(DEBUGGER_SRC
476 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/debugger.c
477 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/parser.c
478 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/symbols.c
479 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/cli-debugger.c)
480
481file(GLOB DEBUGGER_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/test/*.c)
482
483set(FEATURE_SRC)
484set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
485
486if(DISABLE_DEPS)
487 set(USE_GDB_STUB OFF)
488endif()
489
490if(USE_EDITLINE)
491 list(APPEND FEATURES EDITLINE)
492 include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
493 link_directories(${LIBEDIT_LIBRARY_DIRS})
494 set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
495 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
496 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/editline/cli-el-backend.c")
497else()
498 set(DEBUGGER_LIB "")
499endif()
500
501if(USE_GDB_STUB)
502 list(APPEND FEATURES GDB_STUB)
503 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/gdb-stub.c)
504endif()
505source_group("Debugger" FILES ${DEBUGGER_SRC})
506
507if(USE_FFMPEG)
508 list(APPEND FEATURES FFMPEG)
509 if(USE_LIBSWRESAMPLE)
510 list(APPEND FEATURES LIBSWRESAMPLE)
511 else()
512 list(APPEND FEATURES LIBAVRESAMPLE)
513 list(APPEND FEATURES LIBAV)
514 endif()
515 include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWRESAMPLE_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
516 link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWRESAMPLE_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
517 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/ffmpeg/ffmpeg-encoder.c")
518 string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
519 string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
520 string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
521 string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
522 list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES} ${LIBSWRESAMPLE_LIBRARIES})
523 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR}|libavcodec-extra-${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
524 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavformat${LIBAVFORMAT_VERSION_MAJOR}|libavformat-ffmpeg${LIBAVFORMAT_VERSION_MAJOR}")
525 if(USE_LIBSWRESAMPLE)
526 string(REGEX MATCH "^[0-9]+" LIBSWRESAMPLE_VERSION_MAJOR ${libswresample_VERSION})
527 math(EXPR LIBSWRESAMPLE_VERSION_DEBIAN "${LIBSWRESAMPLE_VERSION_MAJOR} - 1")
528 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libswresample${LIBSWRESAMPLE_VERSION_DEBIAN}|libswresample-ffmpeg${LIBSWRESAMPLE_VERSION_DEBIAN}")
529 else()
530 string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
531 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavresample${LIBAVRESAMPLE_VERSION_MAJOR}|libavresample-ffmpeg${LIBAVRESAMPLE_VERSION_MAJOR}")
532 endif()
533 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavutil${LIBAVUTIL_VERSION_MAJOR}|libavutil-ffmpeg${LIBAVUTIL_VERSION_MAJOR}")
534 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libswscale${LIBSWSCALE_VERSION_MAJOR}|libswscale-ffmpeg${LIBSWSCALE_VERSION_MAJOR}")
535 set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
536 if(APPLE)
537 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
538 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
539 endif()
540endif()
541
542list(APPEND THIRD_PARTY_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
543
544if(USE_MAGICK)
545 list(APPEND FEATURES MAGICK)
546 include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
547 link_directories(${MAGICKWAND_LIBRARY_DIRS})
548 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/imagemagick/imagemagick-gif-encoder.c")
549 list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
550 string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
551 string(REGEX MATCH "^[0-9]+" MAGICKWAND_VERSION_MAJOR ${MagickWand_VERSION})
552 if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
553 set(MAGICKWAND_DEB_VERSION "5")
554 elseif(${MagickWand_VERSION} EQUAL "6.9.7")
555 set(MAGICKWAND_DEB_VERSION "-6.q16-3")
556 else()
557 set(MAGICKWAND_DEB_VERSION "-6.q16-2")
558 endif()
559 list(APPEND FEATURE_DEFINES MAGICKWAND_VERSION_MAJOR=${MAGICKWAND_VERSION_MAJOR})
560 list(APPEND FEATURE_FLAGS ${MAGICKWAND_CFLAGS_OTHER})
561
562 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
563endif()
564
565if(WANT_ZLIB AND NOT USE_ZLIB)
566 set(SKIP_INSTALL_ALL ON)
567 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib zlib)
568 set_property(TARGET zlibstatic PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/zlib;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib)
569 set_property(TARGET zlib PROPERTY EXCLUDE_FROM_ALL ON)
570 set_property(TARGET example PROPERTY EXCLUDE_FROM_ALL ON)
571 set_property(TARGET minigzip PROPERTY EXCLUDE_FROM_ALL ON)
572 set(ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
573 set(ZLIB_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
574 set(ZLIB_LIBRARY zlibstatic)
575 list(APPEND DEPENDENCY_LIB zlibstatic)
576 set(USE_ZLIB ON)
577endif()
578
579if(USE_ZLIB)
580 list(APPEND FEATURES ZLIB)
581 include_directories(AFTER ${ZLIB_INCLUDE_DIRS})
582 list(APPEND DEPENDENCY_LIB ${ZLIB_LIBRARIES})
583 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},zlib1g")
584 set(HAVE_CRC32 ON)
585 list(APPEND OS_LIB ${ZLIB_LIBRARIES})
586else()
587 # zlib pulls in crc32
588 check_function_exists(crc32 HAVE_CRC32)
589endif()
590
591if(HAVE_CRC32)
592 list(APPEND FUNCTION_DEFINES HAVE_CRC32)
593endif()
594
595if(WANT_PNG AND USE_ZLIB AND NOT USE_PNG)
596 set(PNG_STATIC ON CACHE BOOL "" FORCE)
597 set(PNG_SHARED OFF CACHE BOOL "" FORCE)
598 set(PNG_TESTS OFF CACHE BOOL "" FORCE)
599 set(SKIP_INSTALL_ALL ON)
600 if (SWITCH)
601 set(PNG_ARM_NEON "off" CACHE STRING "" FORCE)
602 endif()
603 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng libpng)
604 set_property(TARGET png_static PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/libpng;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng;${ZLIB_INCLUDE_DIRS})
605 set(PNG_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng ${CMAKE_CURRENT_BINARY_DIR}/libpng)
606 list(APPEND DEPENDENCY_LIB png_static)
607 set(USE_PNG ON)
608endif()
609
610if(USE_PNG)
611 list(APPEND FEATURES PNG)
612 include_directories(AFTER ${PNG_INCLUDE_DIRS})
613 list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
614 if(PNG_VERSION_STRING)
615 string(REGEX MATCH "^[0-9]+\\.[0-9]+" PNG_VERSION_PARTIAL ${PNG_VERSION_STRING})
616 if(${PNG_VERSION_PARTIAL} STREQUAL "1.6")
617 set(PNG_DEB_VERSION "16-16")
618 else()
619 set(PNG_DEB_VERSION "12-0")
620 endif()
621 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng${PNG_DEB_VERSION}")
622 endif()
623endif()
624
625if(WANT_SQLITE3 AND NOT USE_SQLITE3)
626 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/sqlite3.c)
627 include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/)
628 set(USE_SQLITE3 ON)
629endif()
630
631if(USE_LIBZIP)
632 include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
633 link_directories(${LIBZIP_LIBRARY_DIRS})
634 list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
635 list(APPEND FEATURES LIBZIP)
636 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
637 string(REGEX MATCH "^[0-9]+" LIBZIP_VERSION_MAJOR ${libzip_VERSION})
638 if (LIBZIP_VERSION_MAJOR LESS 1)
639 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
640 elseif(LIBZIP_VERSION_MAJOR EQUAL 1)
641 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip4")
642 else()
643 message(AUTHOR_WARNING Unknown version of libzip detected: ${libzip_VERSION})
644 endif()
645elseif(USE_MINIZIP)
646 include_directories(AFTER ${MINIZIP_INCLUDE_DIRS})
647 link_directories(${MINIZIP_LIBRARY_DIRS})
648 list(APPEND DEPENDENCY_LIB ${MINIZIP_LIBRARIES})
649 list(APPEND FEATURES MINIZIP)
650 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
651 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libminizip1")
652elseif(USE_ZLIB)
653 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c
654 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
655 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c)
656 if(NOT MSVC)
657 set_source_files_properties(
658 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
659 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c
660 PROPERTIES COMPILE_FLAGS "-Wno-unused-parameter -Wno-implicit-function-declaration")
661 endif()
662endif()
663
664if (USE_LZMA)
665 include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma)
666 add_definitions(-D_7ZIP_PPMD_SUPPPORT)
667 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-lzma.c)
668 set(LZMA_SRC
669 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
670 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
671 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
672 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
673 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
674 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
675 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zDec.c
676 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
677 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Delta.c
678 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
679 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
680 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra.c
681 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra86.c
682 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/BraIA64.c
683 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
684 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
685 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
686 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zFile.c
687 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
688 list(APPEND VFS_SRC ${LZMA_SRC})
689 list(APPEND FEATURES LZMA)
690endif()
691
692if(USE_EPOXY)
693 add_definitions(-DBUILD_GL -DBUILD_GLES2)
694 list(APPEND FEATURES EPOXY)
695 include_directories(AFTER ${EPOXY_INCLUDE_DIRS})
696 set(OPENGLES2_LIBRARY ${EPOXY_LIBRARIES})
697 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libepoxy0")
698endif()
699
700if(USE_SQLITE3)
701 list(APPEND FEATURES SQLITE3)
702 include_directories(AFTER ${SQLITE3_INCLUDE_DIRS})
703 list(APPEND DEPENDENCY_LIB ${SQLITE3_LIBRARIES})
704 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libsqlite3-0")
705 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/sqlite3/no-intro.c")
706endif()
707
708if(USE_ELF)
709 list(APPEND FEATURES ELF)
710 include_directories(AFTER ${LIBELF_INCLUDE_DIRS})
711 list(APPEND DEPENDENCY_LIB ${LIBELF_LIBRARIES})
712 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libelf1")
713endif()
714
715if(ENABLE_SCRIPTING)
716 list(APPEND ENABLES SCRIPTING)
717
718 if(BUILD_PYTHON)
719 find_package(PythonLibs ${USE_PYTHON_VERSION})
720 list(APPEND DEPENDENCY_LIB ${PYTHON_LIBRARIES})
721 include_directories(AFTER ${PYTHON_INCLUDE_DIRS})
722 list(APPEND ENABLES PYTHON)
723 endif()
724endif()
725
726set(TEST_SRC ${CORE_TEST_SRC})
727if(M_CORE_GB)
728 add_definitions(-DM_CORE_GB)
729 list(APPEND CORE_SRC
730 ${LR35902_SRC}
731 ${GB_SRC}
732 ${GB_RENDERER_SRC})
733 list(APPEND DEBUGGER_SRC
734 ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/cli-debugger.c
735 ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/debugger.c
736 ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/memory-debugger.c
737 ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/debugger/cli.c
738 ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/debugger/symbols.c)
739 list(APPEND TEST_SRC
740 ${LR35902_TEST_SRC}
741 ${GB_TEST_SRC})
742endif()
743
744if(M_CORE_GBA)
745 add_definitions(-DM_CORE_GBA)
746 list(APPEND CORE_SRC
747 ${ARM_SRC}
748 ${GBA_SRC}
749 ${GBA_CHEATS_SRC}
750 ${GBA_RENDERER_SRC})
751 list(APPEND DEBUGGER_SRC
752 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c
753 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/debugger.c
754 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/memory-debugger.c
755 ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/debugger/cli.c)
756 list(APPEND TEST_SRC
757 ${ARM_TEST_SRC}
758 ${GBA_TEST_SRC})
759 if(NOT M_CORE_GB)
760 list(APPEND CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/audio.c)
761 endif()
762endif()
763
764if(USE_DEBUGGERS)
765 list(APPEND FEATURE_SRC ${DEBUGGER_SRC})
766 list(APPEND TEST_SRC ${DEBUGGER_TEST_SRC})
767 list(APPEND FEATURES DEBUGGERS)
768endif()
769
770foreach(FEATURE IN LISTS FEATURES)
771 list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
772endforeach()
773
774foreach(ENABLE IN LISTS ENABLES)
775 list(APPEND FEATURE_DEFINES "ENABLE_${ENABLE}")
776endforeach()
777
778source_group("Virtual files" FILES ${CORE_VFS_SRC} ${VFS_SRC})
779source_group("Extra features" FILES ${FEATURE_SRC})
780source_group("Third-party code" FILES ${THIRD_PARTY_SRC})
781
782# Platform binaries
783if(DEFINED 3DS)
784 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/3ds ${CMAKE_CURRENT_BINARY_DIR}/3ds)
785endif()
786
787if(DEFINED WII)
788 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/wii ${CMAKE_CURRENT_BINARY_DIR}/wii)
789endif()
790
791if(DEFINED PSP2)
792 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/psp2 ${CMAKE_CURRENT_BINARY_DIR}/psp2)
793endif()
794
795if(DEFINED SWITCH)
796 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/switch ${CMAKE_CURRENT_BINARY_DIR}/switch)
797endif()
798
799# Binaries
800list(APPEND CORE_SRC
801 ${UTIL_SRC}
802 ${CORE_VFS_SRC}
803 ${OS_SRC}
804 ${THIRD_PARTY_SRC})
805list(APPEND TEST_SRC ${UTIL_TEST_SRC})
806
807set(SRC ${CORE_SRC} ${VFS_SRC})
808if(NOT MINIMAL_CORE)
809 set(ENABLE_EXTRA ON)
810 if(M_CORE_GBA)
811 list(APPEND SRC
812 ${GBA_SIO_SRC})
813 endif()
814 if(M_CORE_GB)
815 list(APPEND SRC
816 ${GB_SIO_SRC})
817 endif()
818 list(APPEND SRC
819 ${FEATURE_SRC})
820endif()
821
822if(ENABLE_EXTRA)
823 if(M_CORE_GBA)
824 list(APPEND SRC
825 ${GBA_RR_SRC}
826 ${GBA_EXTRA_SRC})
827 endif()
828 if(M_CORE_GB)
829 list(APPEND SRC
830 ${GB_EXTRA_SRC})
831 endif()
832 list(APPEND SRC
833 ${EXTRA_SRC})
834endif()
835
836if(NOT SKIP_LIBRARY)
837 if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
838 set(BUILD_SHARED ON)
839 endif()
840
841 if(BUILD_SHARED)
842 add_library(${BINARY_NAME} SHARED ${SRC} ${VFS_SRC})
843 if(BUILD_STATIC)
844 add_library(${BINARY_NAME}-static STATIC ${SRC})
845 set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}" COMPILE_OPTIONS "${FEATURE_FLAGS}")
846 install(TARGETS ${BINARY_NAME}-static DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
847 add_dependencies(${BINARY_NAME}-static version-info)
848 endif()
849 else()
850 add_library(${BINARY_NAME} STATIC ${SRC})
851 endif()
852
853 add_dependencies(${BINARY_NAME} version-info)
854 set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}" COMPILE_OPTIONS "${FEATURE_FLAGS}")
855
856 target_link_libraries(${BINARY_NAME} ${DEBUGGER_LIB} ${DEPENDENCY_LIB} ${OS_LIB})
857 install(TARGETS ${BINARY_NAME} LIBRARY DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME} NAMELINK_SKIP ARCHIVE DESTINATION ${LIBDIR} RUNTIME DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
858 if(UNIX AND NOT APPLE AND NOT HAIKU)
859 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-16.png DESTINATION share/icons/hicolor/16x16/apps RENAME mgba.png COMPONENT ${BINARY_NAME})
860 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-24.png DESTINATION share/icons/hicolor/24x24/apps RENAME mgba.png COMPONENT ${BINARY_NAME})
861 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-32.png DESTINATION share/icons/hicolor/32x32/apps RENAME mgba.png COMPONENT ${BINARY_NAME})
862 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-48.png DESTINATION share/icons/hicolor/48x48/apps RENAME mgba.png COMPONENT ${BINARY_NAME})
863 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-64.png DESTINATION share/icons/hicolor/64x64/apps RENAME mgba.png COMPONENT ${BINARY_NAME})
864 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-96.png DESTINATION share/icons/hicolor/96x96/apps RENAME mgba.png COMPONENT ${BINARY_NAME})
865 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-128.png DESTINATION share/icons/hicolor/128x128/apps RENAME mgba.png COMPONENT ${BINARY_NAME})
866 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-256.png DESTINATION share/icons/hicolor/256x256/apps RENAME mgba.png COMPONENT ${BINARY_NAME})
867 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-512.png DESTINATION share/icons/hicolor/512x512/apps RENAME mgba.png COMPONENT ${BINARY_NAME})
868 endif()
869else()
870 set(BUILD_SHARED OFF)
871 set(BUILD_STATIC OFF)
872 find_library(${BINARY_NAME} ${BINARY_NAME})
873 if(NOT ${BINARY_NAME}_FOUND)
874 set(DISABLE_FRONTENDS ON)
875 set(BUILD_PERF OFF)
876 set(BUILD_TEST OFF)
877 set(BUILD_SUITE OFF)
878 endif()
879endif()
880
881if(BUILD_GL)
882 add_definitions(-DBUILD_GL)
883endif()
884
885if(BUILD_GLES2)
886 add_definitions(-DBUILD_GLES2)
887endif()
888
889if(BUILD_GLES3)
890 add_definitions(-DBUILD_GLES3)
891endif()
892
893if(DISABLE_FRONTENDS)
894 set(BUILD_SDL OFF)
895 set(BUILD_QT OFF)
896endif()
897
898if(BUILD_PYTHON)
899 enable_testing()
900 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/python ${CMAKE_CURRENT_BINARY_DIR}/python)
901endif()
902
903if(BUILD_LIBRETRO)
904 file(GLOB RETRO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/libretro/*.c)
905 add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
906 set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5;DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=2")
907 target_link_libraries(${BINARY_NAME}_libretro ${OS_LIB})
908 install(TARGETS ${BINARY_NAME}_libretro LIBRARY DESTINATION ${LIBRETRO_LIBDIR} COMPONENT ${BINARY_NAME}_libretro NAMELINK_SKIP)
909endif()
910
911if(BUILD_OPENEMU)
912 find_library(FOUNDATION Foundation)
913 find_library(OPENEMUBASE OpenEmuBase)
914 file(GLOB OE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/*.m)
915 add_library(${BINARY_NAME}-openemu MODULE ${CORE_SRC} ${OS_SRC})
916 set_target_properties(${BINARY_NAME}-openemu PROPERTIES
917 MACOSX_BUNDLE_INFO_PLIST ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/Info.plist.in
918 BUNDLE TRUE
919 BUNDLE_EXTENSION oecoreplugin
920 OUTPUT_NAME ${PROJECT_NAME}
921 COMPILE_DEFINITIONS "DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=1")
922 target_link_libraries(${BINARY_NAME}-openemu ${OS_LIB} ${FOUNDATION} ${OPENEMUBASE})
923 install(TARGETS ${BINARY_NAME}-openemu LIBRARY DESTINATION ${OE_LIBDIR} COMPONENT ${BINARY_NAME}.oecoreplugin NAMELINK_SKIP)
924endif()
925
926if(BUILD_SDL)
927 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/sdl ${CMAKE_CURRENT_BINARY_DIR}/sdl)
928endif()
929
930if(BUILD_QT)
931 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/qt ${CMAKE_CURRENT_BINARY_DIR}/qt)
932endif()
933
934if(BUILD_PERF)
935 set(PERF_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/perf-main.c)
936 if(UNIX AND NOT APPLE)
937 list(APPEND PERF_LIB rt)
938 endif()
939
940 add_executable(${BINARY_NAME}-perf ${PERF_SRC})
941 target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB} ${OS_LIB})
942 set_target_properties(${BINARY_NAME}-perf PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
943 install(TARGETS ${BINARY_NAME}-perf DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT ${BINARY_NAME}-perf)
944 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/tools/perf.py DESTINATION "${LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
945endif()
946
947if(BUILD_TEST)
948 add_executable(${BINARY_NAME}-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/fuzz-main.c)
949 target_link_libraries(${BINARY_NAME}-fuzz ${BINARY_NAME})
950 set_target_properties(${BINARY_NAME}-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
951 add_executable(tbl-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/tbl-fuzz-main.c)
952 target_link_libraries(tbl-fuzz ${BINARY_NAME})
953 set_target_properties(tbl-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
954 install(TARGETS ${BINARY_NAME}-fuzz tbl-fuzz DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT ${BINARY_NAME}-test)
955endif()
956
957if(NOT USE_CMOCKA)
958 set(BUILD_SUITE OFF)
959endif()
960if(BUILD_SUITE)
961 enable_testing()
962 include_directories(AFTER ${CMOCKA_INCLUDE_DIRS})
963 link_directories(${CMOCKA_LIBRARY_DIRS})
964
965 foreach(TEST IN LISTS TEST_SRC)
966 string(REPLACE "${CMAKE_SOURCE_DIR}/src/" "" TEST_NAME "${TEST}")
967 string(REPLACE "/" "-" TEST_NAME "${TEST_NAME}")
968 string(REPLACE "-test" "" TEST_NAME "${TEST_NAME}")
969 string(REPLACE ".c" "" TEST_NAME "${TEST_NAME}")
970 add_executable(test-${TEST_NAME} ${TEST})
971 target_link_libraries(test-${TEST_NAME} ${BINARY_NAME} ${PLATFORM_LIBRARY} cmocka)
972 set_target_properties(test-${TEST_NAME} PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
973 add_test(${TEST_NAME} test-${TEST_NAME})
974 endforeach()
975endif()
976
977if(BUILD_EXAMPLE)
978 add_executable(${BINARY_NAME}-example-server ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/server.c)
979 target_link_libraries(${BINARY_NAME}-example-server ${BINARY_NAME})
980 set_target_properties(${BINARY_NAME}-example-server PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
981
982 if(SDL_FOUND)
983 add_executable(${BINARY_NAME}-example-client ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/client.c)
984 target_link_libraries(${BINARY_NAME}-example-client ${BINARY_NAME} ${SDL_LIBRARY} ${SDLMAIN_LIBRARY} ${OPENGL_LIBRARY} ${OPENGLES2_LIBRARY})
985 set_target_properties(${BINARY_NAME}-example-client PROPERTIES
986 COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}"
987 INCLUDE_DIRECTORIES "${SDL_INCLUDE_DIR};${CMAKE_CURRENT_SOURCE_DIR}/src;${CMAKE_CURRENT_SOURCE_DIR}/include")
988 endif()
989endif()
990
991configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/flags.h.in ${CMAKE_CURRENT_BINARY_DIR}/flags.h)
992install(FILES ${CMAKE_CURRENT_BINARY_DIR}/flags.h DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/mgba COMPONENT lib${BINARY_NAME})
993
994# Packaging
995install(DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/res/licenses DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT ${BINARY_NAME})
996if(EXTRA_LICENSES)
997 install(FILES ${EXTRA_LICENSES} DESTINATION ${CMAKE_INSTALL_DOCDIR}/licenses COMPONENT ${BINARY_NAME})
998endif()
999
1000file(GLOB READMES ${CMAKE_CURRENT_SOURCE_DIR}/README*.md)
1001
1002find_program(DOS2UNIX NAMES dos2unix)
1003find_program(MARKDOWN NAMES markdown kramdown pandoc)
1004
1005if(UNIX OR NOT DOS2UNIX)
1006 if(UNIX OR NOT MARKDOWN)
1007 install(FILES ${READMES} DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT ${BINARY_NAME})
1008 endif()
1009 install(FILES "${CMAKE_CURRENT_SOURCE_DIR}/CHANGES" "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE" DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT ${BINARY_NAME})
1010else()
1011 add_custom_command(OUTPUT CHANGES.txt COMMAND ${DOS2UNIX} -n "${CMAKE_CURRENT_SOURCE_DIR}/CHANGES" "${CMAKE_CURRENT_BINARY_DIR}/CHANGES.txt" MAIN_DEPENDENCY "${CMAKE_CURRENT_SOURCE_DIR}/CHANGES")
1012 add_custom_command(OUTPUT LICENSE.txt COMMAND ${DOS2UNIX} -n "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE" "${CMAKE_CURRENT_BINARY_DIR}/LICENSE.txt" MAIN_DEPENDENCY "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE")
1013 add_custom_target(CHANGES ALL DEPENDS CHANGES.txt)
1014 add_custom_target(LICENSE ALL DEPENDS LICENSE.txt)
1015 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/CHANGES.txt ${CMAKE_CURRENT_BINARY_DIR}/LICENSE.txt DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT ${BINARY_NAME})
1016endif()
1017
1018if(MARKDOWN)
1019 foreach(README ${READMES})
1020 get_filename_component(README_BASE "${README}" NAME_WE)
1021 add_custom_command(OUTPUT ${README_BASE}.html COMMAND ${MARKDOWN} "${README}" > ${README_BASE}.html MAIN_DEPENDENCY "${README}")
1022 add_custom_target(${README_BASE} ALL DEPENDS ${README_BASE}.html)
1023 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${README_BASE}.html DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT ${BINARY_NAME})
1024 endforeach()
1025endif()
1026
1027set(CPACK_PACKAGE_VERSION ${VERSION_STRING})
1028set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
1029set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
1030set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
1031set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
1032set(CPACK_RESOURCE_FILE_README ${CMAKE_CURRENT_SOURCE_DIR}/README.md)
1033
1034set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
1035set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
1036set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
1037set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README.md")
1038set(CPACK_DEBIAN_PACKAGE_SECTION "games")
1039
1040SET(CPACK_DEB_COMPONENT_INSTALL ON)
1041
1042set(CPACK_STRIP_FILES ON)
1043
1044if(DISTBUILD)
1045 set(CPACK_ARCHIVE_COMPONENT_INSTALL ON)
1046 if(WIN32 OR APPLE)
1047 set(CPACK_COMPONENTS_ALL ${BINARY_NAME} ${BINARY_NAME}-qt ${BINARY_NAME}-sdl ${BINARY_NAME}-perf)
1048 set(CPACK_COMPONENTS_GROUPING ALL_COMPONENTS_IN_ONE)
1049 elseif(3DS)
1050 set(CPACK_COMPONENTS_ALL ${BINARY_NAME} ${BINARY_NAME}-3ds ${BINARY_NAME}-perf)
1051 elseif(WII)
1052 set(CPACK_COMPONENTS_ALL ${BINARY_NAME} ${BINARY_NAME}-wii)
1053 elseif(PSP2)
1054 set(CPACK_COMPONENTS_ALL ${BINARY_NAME} ${BINARY_NAME}-psp2)
1055 elseif(SWITCH)
1056 set(CPACK_COMPONENTS_ALL ${BINARY_NAME} ${BINARY_NAME}-switch)
1057 endif()
1058endif()
1059
1060include(CPack)
1061
1062cpack_add_component_group(base)
1063cpack_add_component(${BINARY_NAME} GROUP base)
1064
1065cpack_add_component_group(dev PARENT_GROUP base)
1066if(BUILD_SHARED)
1067 cpack_add_component(lib${BINARY_NAME} GROUP base)
1068 if(BUILD_STATIC)
1069 cpack_add_component(lib${BINARY_NAME}-static GROUP dev)
1070 endif()
1071elseif(BUILD_STATIC)
1072 cpack_add_component(lib${BINARY_NAME} GROUP dev)
1073endif()
1074
1075if(3DS)
1076 cpack_add_component(${BINARY_NAME}-3ds GROUP base)
1077elseif(PSP2)
1078 cpack_add_component(${BINARY_NAME}-psp2 GROUP base)
1079elseif(WII)
1080 cpack_add_component(${BINARY_NAME}-wii GROUP base)
1081elseif(SWITCH)
1082 cpack_add_component(${BINARY_NAME}-switch GROUP base)
1083endif()
1084
1085if(BUILD_QT)
1086 cpack_add_component_group(qt PARENT_GROUP base)
1087 cpack_add_component(${BINARY_NAME}-qt GROUP qt)
1088endif()
1089
1090if(SDL_FOUND)
1091 cpack_add_component_group(sdl PARENT_GROUP base)
1092 cpack_add_component(${BINARY_NAME}-sdl GROUP sdl)
1093endif()
1094
1095cpack_add_component_group(test PARENT_GROUP dev)
1096cpack_add_component(${BINARY_NAME}-perf GROUP test)
1097cpack_add_component(${BINARY_NAME}-fuzz GROUP test)
1098cpack_add_component(tbl-fuzz GROUP test)
1099
1100# Summaries
1101set(SUMMARY_GL_LIST)
1102if(USE_EPOXY)
1103 set(SUMMARY_GL_LIST "libepoxy")
1104else()
1105 if(BUILD_GL)
1106 list(APPEND SUMMARY_GL_LIST "OpenGL")
1107 endif()
1108 if(BUILD_GLES2)
1109 list(APPEND SUMMARY_GL_LIST "OpenGL|ES 2")
1110 endif()
1111 if(BUILD_GLES3)
1112 list(APPEND SUMMARY_GL_LIST "OpenGL|ES 3")
1113 endif()
1114endif()
1115if(NOT SUMMARY_GL_LIST)
1116 set(SUMMARY_GL OFF)
1117else()
1118 string(REPLACE ";" ", " SUMMARY_GL "${SUMMARY_GL_LIST}")
1119endif()
1120if(USE_LIBZIP)
1121 set(SUMMARY_ZIP libzip)
1122elseif(USE_MINIZIP)
1123 set(SUMMARY_ZIP "minizip (external)")
1124elseif(USE_ZLIB)
1125 set(SUMMARY_ZIP "minizip (included)")
1126else()
1127 set(SUMMARY_ZIP OFF)
1128endif()
1129
1130if(NOT QUIET)
1131 message(STATUS "Build type: ${CMAKE_BUILD_TYPE}")
1132 message(STATUS "Platforms:")
1133 message(STATUS " Game Boy Advance: ${M_CORE_GBA}")
1134 message(STATUS " Game Boy: ${M_CORE_GB}")
1135 message(STATUS "Features:")
1136 message(STATUS " Debuggers: ${USE_DEBUGGERS}")
1137 if(NOT WIN32)
1138 message(STATUS " CLI debugger: ${USE_EDITLINE}")
1139 endif()
1140 message(STATUS " GDB stub: ${USE_GDB_STUB}")
1141 message(STATUS " Video recording: ${USE_FFMPEG}")
1142 message(STATUS " GIF recording: ${USE_MAGICK}")
1143 message(STATUS " Screenshot/advanced savestate support: ${USE_PNG}")
1144 message(STATUS " ZIP support: ${SUMMARY_ZIP}")
1145 message(STATUS " 7-Zip support: ${USE_LZMA}")
1146 message(STATUS " SQLite3 game database: ${USE_SQLITE3}")
1147 message(STATUS " ELF loading support: ${USE_ELF}")
1148 message(STATUS " OpenGL support: ${SUMMARY_GL}")
1149 message(STATUS "Frontends:")
1150 message(STATUS " Qt: ${BUILD_QT}")
1151 message(STATUS " SDL (${SDL_VERSION}): ${BUILD_SDL}")
1152 message(STATUS " Profiling: ${BUILD_PERF}")
1153 message(STATUS " Test harness: ${BUILD_TEST}")
1154 message(STATUS " Test suite: ${BUILD_SUITE}")
1155 message(STATUS " Python bindings: ${BUILD_PYTHON}")
1156 message(STATUS " Examples: ${BUILD_EXAMPLE}")
1157 message(STATUS "Cores:")
1158 message(STATUS " Libretro core: ${BUILD_LIBRETRO}")
1159 if(APPLE)
1160 message(STATUS " OpenEmu core: ${BUILD_OPENEMU}")
1161 endif()
1162 message(STATUS "Libraries:")
1163 message(STATUS " Static: ${BUILD_STATIC}")
1164 message(STATUS " Shared: ${BUILD_SHARED}")
1165endif()