CMakeLists.txt (view raw)
1cmake_minimum_required(VERSION 2.6)
2project(mGBA C)
3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
4if(NOT MSVC)
5 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -std=c99")
6else()
7 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_CRT_SECURE_NO_WARNINGS /wd4003 /wd4244 /wd4146")
8endif()
9set(USE_CLI_DEBUGGER ON CACHE BOOL "Whether or not to enable the CLI-mode ARM debugger")
10set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
11set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
12set(USE_ZLIB ON CACHE BOOL "Whether or not to enable zlib support")
13set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
14set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable LIBZIP support")
15set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
16set(USE_BLIP ON CACHE BOOL "Whether or not to enable blip_buf support")
17set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
18set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
19set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
20set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
21if(APPLE)
22 set(BUILD_OPENEMU OFF CACHE BOOL "Build OpenEmu core")
23endif()
24set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
25set(BUILD_TEST OFF CACHE BOOL "Build testing harness")
26set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
27set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
28set(SKIP_LIBRARY OFF CACHE BOOL "Skip building the library (useful for only building libretro or OpenEmu cores)")
29set(BUILD_GL ON CACHE STRING "Build with OpenGL")
30set(BUILD_GLES2 OFF CACHE STRING "Build with OpenGL|ES 2")
31set(USE_EPOXY ON CACHE STRING "Build with libepoxy")
32set(DISABLE_DEPS OFF CACHE BOOL "Build without dependencies")
33file(GLOB ARM_SRC ${CMAKE_SOURCE_DIR}/src/arm/*.c)
34file(GLOB GBA_SRC ${CMAKE_SOURCE_DIR}/src/gba/*.c)
35file(GLOB GBA_CHEATS_SRC ${CMAKE_SOURCE_DIR}/src/gba/cheats/*.c)
36file(GLOB GBA_RR_SRC ${CMAKE_SOURCE_DIR}/src/gba/rr/*.c)
37file(GLOB GBA_SV_SRC ${CMAKE_SOURCE_DIR}/src/gba/supervisor/*.c)
38file(GLOB GBA_CTX_SRC ${CMAKE_SOURCE_DIR}/src/gba/context/*.c)
39file(GLOB UTIL_SRC ${CMAKE_SOURCE_DIR}/src/util/*.[cSs])
40file(GLOB GUI_SRC ${CMAKE_SOURCE_DIR}/src/util/gui/*.c ${CMAKE_SOURCE_DIR}/src/gba/gui/*.c)
41file(GLOB RENDERER_SRC ${CMAKE_SOURCE_DIR}/src/gba/renderers/*.c)
42file(GLOB SIO_SRC ${CMAKE_SOURCE_DIR}/src/gba/sio/lockstep.c)
43file(GLOB THIRD_PARTY_SRC ${CMAKE_SOURCE_DIR}/src/third-party/inih/*.c)
44list(APPEND GBA_SV_SRC ${CMAKE_SOURCE_DIR}/src/platform/commandline.c)
45set(CORE_VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-mem.c)
46set(VFS_SRC)
47source_group("ARM core" FILES ${ARM_SRC})
48source_group("GBA board" FILES ${GBA_SRC} ${RENDERER_SRC} ${SIO_SRC})
49source_group("GBA extra" FILES ${GBA_CHEATS_SRC} ${GBA_CTX_SRC} ${GBA_SV_SRC} ${GBA_RR_SRC})
50source_group("Utilities" FILES ${UTIL_SRC})
51include_directories(${CMAKE_SOURCE_DIR}/src/arm)
52include_directories(${CMAKE_SOURCE_DIR}/src)
53
54if(NOT CMAKE_BUILD_TYPE)
55 set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
56endif()
57
58set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${LIBDIR}")
59
60include(GNUInstallDirs)
61
62if (NOT DEFINED LIBDIR)
63 set(LIBDIR "lib")
64endif()
65
66if (NOT DEFINED MANDIR)
67 set(MANDIR ${CMAKE_INSTALL_MANDIR})
68endif()
69
70# Function definitions
71include(FindPkgConfig)
72function(find_feature FEATURE_NAME FEATURE_REQUIRES)
73 if (NOT ${FEATURE_NAME})
74 return()
75 endif()
76 if (DISABLE_DEPS)
77 set(${FEATURE_NAME} OFF PARENT_SCOPE)
78 return()
79 endif()
80 foreach(REQUIRE ${FEATURE_REQUIRES})
81 if(NOT ${REQUIRE}_FOUND)
82 find_package(${REQUIRE} QUIET)
83 if(NOT ${REQUIRE}_FOUND)
84 pkg_search_module(${REQUIRE} ${REQUIRE})
85 if (NOT ${REQUIRE}_FOUND)
86 message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
87 set(${FEATURE_NAME} OFF PARENT_SCOPE)
88 return()
89 endif()
90 endif()
91 endif()
92 string(TOUPPER ${REQUIRE} UREQUIRE)
93 set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
94 set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
95 set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
96 set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
97 set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
98 set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
99 endforeach()
100endfunction()
101
102# Version information
103add_custom_target(version-info ALL ${CMAKE_COMMAND} -E touch ${CMAKE_SOURCE_DIR}/src/util/version.c.in
104 COMMAND ${CMAKE_COMMAND}
105 -DBINARY_NAME=${BINARY_NAME}
106 -DCONFIG_FILE=${CMAKE_SOURCE_DIR}/src/util/version.c.in
107 -DOUT_FILE=${CMAKE_CURRENT_BINARY_DIR}/version.c
108 -P ${CMAKE_SOURCE_DIR}/version.cmake
109 WORKING_DIRECTORY ${CMAKE_BINARY_DIR})
110
111include(${CMAKE_SOURCE_DIR}/version.cmake)
112configure_file(${CMAKE_SOURCE_DIR}/src/util/version.c.in ${CMAKE_CURRENT_BINARY_DIR}/version.c)
113list(APPEND UTIL_SRC ${CMAKE_BINARY_DIR}/version.c)
114source_group("Generated sources" FILES ${CMAKE_BINARY_DIR}/version.c)
115
116# Advanced settings
117set(BUILD_LTO ON CACHE BOOL "Build with link-time optimization")
118set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
119set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
120set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
121mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
122set(PGO_PRE_FLAGS "-fprofile-generate=${PGO_DIR} -fprofile-arcs")
123set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
124
125if(BUILD_PGO AND NOT PGO_STAGE_2)
126 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
127 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
128 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
129elseif(BUILD_PGO AND PGO_STAGE_2)
130 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
131 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
132 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
133endif()
134
135# Platform support
136if(WIN32)
137 set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
138 add_definitions(-D_WIN32_WINNT=0x0600)
139 list(APPEND OS_LIB ws2_32 shlwapi)
140 list(APPEND CORE_VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
141 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/windows/*.c)
142 source_group("Windows-specific code" FILES ${OS_SRC})
143elseif(UNIX)
144 add_definitions(-DUSE_PTHREADS)
145
146 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
147 add_definitions(-D_GNU_SOURCE)
148 endif()
149 if(NOT APPLE AND NOT HAIKU)
150 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
151 endif()
152
153 list(APPEND CORE_VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
154 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/posix/*.c)
155 source_group("POSIX-specific code" FILES ${OS_SRC})
156endif()
157
158if(APPLE)
159 add_definitions(-D_DARWIN_C_SOURCE)
160 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
161endif()
162
163if(NOT HAIKU AND NOT MSVC AND NOT PSP2)
164 set(M_LIBRARY m)
165endif()
166list(APPEND OS_LIB ${M_LIBRARY})
167
168if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
169 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
170 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
171 set_source_files_properties(${CMAKE_SOURCE_DIR}/src/arm/isa-arm.c ${CMAKE_SOURCE_DIR}/src/arm/isa-thumb.c PROPERTIES COMPILE_FLAGS -fno-lto)
172endif()
173
174if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
175 if(NOT BUILD_EGL)
176 add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
177 endif()
178endif()
179
180if(BUILD_RASPI)
181 set(BUILD_GL OFF CACHE BOOL "OpenGL not supported" FORCE)
182endif()
183
184if(BUILD_PANDORA)
185 add_definitions(-DBUILD_PANDORA)
186endif()
187
188if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
189 enable_language(ASM)
190endif()
191
192if(PSP2 OR WII)
193 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-format")
194endif()
195
196if(DEFINED 3DS OR DEFINED PSP2 OR DEFINED WII)
197 set(USE_GDB_STUB OFF)
198endif()
199
200if(WII)
201 add_definitions(-U__STRICT_ANSI__)
202endif()
203
204include(CheckFunctionExists)
205check_function_exists(strdup HAVE_STRDUP)
206check_function_exists(strndup HAVE_STRNDUP)
207check_function_exists(localtime_r HAVE_LOCALTIME_R)
208if(NOT CMAKE_SYSTEM_NAME STREQUAL "Generic")
209 check_function_exists(snprintf_l HAVE_SNPRINTF_L)
210 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
211 # The strtof_l on Linux not actually exposed nor actually strtof_l
212 set(HAVE_STRTOF_L OFF)
213 else()
214 check_function_exists(strtof_l HAVE_STRTOF_L)
215 endif()
216 check_function_exists(newlocale HAVE_NEWLOCALE)
217 check_function_exists(freelocale HAVE_FREELOCALE)
218 check_function_exists(uselocale HAVE_USELOCALE)
219 check_function_exists(setlocale HAVE_SETLOCALE)
220else()
221 if(NOT DEFINED 3DS AND NOT DEFINED PSP2 AND NOT DEFINED WII)
222 set(DISABLE_DEPS ON CACHE BOOL "This platform cannot build with dependencies" FORCE)
223 endif()
224 set(DISABLE_FRONTENDS ON)
225 set(MINIMAL_CORE ON)
226endif()
227
228check_function_exists(chmod HAVE_CHMOD)
229check_function_exists(umask HAVE_UMASK)
230
231set(FUNCTION_DEFINES)
232
233if(HAVE_STRDUP)
234 list(APPEND FUNCTION_DEFINES HAVE_STRDUP)
235endif()
236
237if(HAVE_STRNDUP)
238 list(APPEND FUNCTION_DEFINES HAVE_STRNDUP)
239endif()
240
241if(HAVE_LOCALTIME_R)
242 list(APPEND FUNCTION_DEFINES HAVE_LOCALTIME_R)
243endif()
244
245if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE)
246 list(APPEND FUNCTION_DEFINES HAVE_LOCALE)
247 if (HAVE_STRTOF_L)
248 list(APPEND FUNCTION_DEFINES HAVE_STRTOF_L)
249 endif()
250 if (HAVE_SNPRINTF_L)
251 list(APPEND FUNCTION_DEFINES HAVE_SNPRINTF_L)
252 endif()
253endif()
254
255if(HAVE_SETLOCALE)
256 list(APPEND FUNCTION_DEFINES HAVE_SETLOCALE)
257endif()
258
259if(HAVE_CHMOD)
260 list(APPEND FUNCTION_DEFINES HAVE_CHMOD)
261endif()
262
263if(HAVE_UMASK)
264 list(APPEND FUNCTION_DEFINES HAVE_UMASK)
265endif()
266
267# Feature dependencies
268set(FEATURES)
269if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
270 set(LIBEDIT_LIBRARIES -ledit)
271 if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
272 list(APPEND LIBEDIT_LIBRARIES -ltermcap)
273 endif()
274else()
275 find_feature(USE_CLI_DEBUGGER "libedit")
276endif()
277if(BUILD_GL)
278 find_package(OpenGL QUIET)
279 if(NOT OPENGL_FOUND)
280 set(BUILD_GL OFF CACHE BOOL "OpenGL not found" FORCE)
281 endif()
282endif()
283if(NOT BUILD_GL)
284 set(OPENGLE_LIBRARY "" CACHE PATH "" FORCE)
285endif()
286if(BUILD_GLES2 AND NOT BUILD_RASPI)
287 find_path(OPENGLES2_INCLUDE_DIR NAMES GLES2/gl2.h)
288 find_library(OPENGLES2_LIBRARY NAMES GLESv2 GLESv2_CM)
289 if(NOT OPENGLES2_INCLUDE_DIR OR NOT OPENGLES2_LIBRARY)
290 set(BUILD_GLES2 OFF CACHE BOOL "OpenGL|ES 2 not found" FORCE)
291 endif()
292endif()
293if(NOT BUILD_GLES2)
294 set(OPENGLES2_LIBRARY "" CACHE PATH "" FORCE)
295endif()
296set(WANT_ZLIB ${USE_ZLIB})
297set(WANT_PNG ${USE_PNG})
298set(WANT_LIBZIP ${USE_LIBZIP})
299
300find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
301find_feature(USE_ZLIB "ZLIB")
302find_feature(USE_PNG "PNG")
303find_feature(USE_LIBZIP "libzip")
304find_feature(USE_MAGICK "MagickWand")
305find_feature(USE_EPOXY "epoxy")
306
307# Features
308set(DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/debugger.c ${CMAKE_SOURCE_DIR}/src/debugger/memory-debugger.c)
309set(FEATURE_SRC)
310set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
311
312if(DISABLE_DEPS)
313 set(USE_GDB_STUB OFF)
314endif()
315
316if(USE_CLI_DEBUGGER)
317 list(APPEND FEATURES CLI_DEBUGGER)
318 list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/debugger/cli-debugger.c)
319 list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/debugger/parser.c)
320 list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/gba/supervisor/cli.c)
321 include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
322 link_directories(${LIBEDIT_LIBRARY_DIRS})
323 set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
324 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
325else()
326 set(DEBUGGER_LIB "")
327endif()
328
329if(USE_GDB_STUB)
330 list(APPEND FEATURES GDB_STUB)
331 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/gdb-stub.c)
332endif()
333source_group("ARM debugger" FILES ${DEBUGGER_SRC})
334
335if(USE_FFMPEG)
336 list(APPEND FEATURES FFMPEG)
337 pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
338 if(NOT LIBSWRESAMPLE_FOUND)
339 list(APPEND FEATURES LIBAV)
340 endif()
341 include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
342 link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
343 list(APPEND FEATURE_SRC "${CMAKE_SOURCE_DIR}/src/platform/ffmpeg/ffmpeg-encoder.c")
344 string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
345 string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
346 string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
347 string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
348 string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
349 list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
350 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR}|libavcodec-extra-${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
351 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavformat${LIBAVFORMAT_VERSION_MAJOR}|libavformat-ffmpeg${LIBAVFORMAT_VERSION_MAJOR}")
352 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavresample${LIBAVRESAMPLE_VERSION_MAJOR}|libavresample-ffmpeg${LIBAVRESAMPLE_VERSION_MAJOR}")
353 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavutil${LIBAVUTIL_VERSION_MAJOR}|libavutil-ffmpeg${LIBAVUTIL_VERSION_MAJOR}")
354 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libswscale${LIBSWSCALE_VERSION_MAJOR}|libswscale-ffmpeg${LIBSWSCALE_VERSION_MAJOR}")
355 set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
356 if(APPLE)
357 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
358 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
359 endif()
360endif()
361
362if(USE_BLIP)
363 list(APPEND THIRD_PARTY_SRC "${CMAKE_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
364 add_definitions(-DRESAMPLE_LIBRARY=RESAMPLE_BLIP_BUF)
365else()
366 add_definitions(-DRESAMPLE_LIBRARY=RESAMPLE_NN)
367endif()
368
369if(USE_MAGICK)
370 list(APPEND FEATURES MAGICK)
371 include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
372 link_directories(${MAGICKWAND_LIBRARY_DIRS})
373 list(APPEND FEATURE_SRC "${CMAKE_SOURCE_DIR}/src/platform/imagemagick/imagemagick-gif-encoder.c")
374 list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
375 string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
376 if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
377 set(MAGICKWAND_DEB_VERSION "5")
378 else()
379 set(MAGICKWAND_DEB_VERSION "-6.q16-2")
380 endif()
381 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
382endif()
383
384if(WANT_ZLIB AND NOT USE_ZLIB)
385 set(SKIP_INSTALL_ALL ON)
386 add_subdirectory(${CMAKE_SOURCE_DIR}/src/third-party/zlib zlib)
387 set_property(TARGET zlibstatic PROPERTY INCLUDE_DIRECTORIES ${CMAKE_BINARY_DIR}/zlib;${CMAKE_SOURCE_DIR}/src/third-party/zlib)
388 set_property(TARGET zlib PROPERTY EXCLUDE_FROM_ALL ON)
389 set_property(TARGET example PROPERTY EXCLUDE_FROM_ALL ON)
390 set_property(TARGET minigzip PROPERTY EXCLUDE_FROM_ALL ON)
391 set(ZLIB_INCLUDE_DIRS ${CMAKE_SOURCE_DIR}/src/third-party/zlib ${CMAKE_BINARY_DIR}/zlib)
392 set(ZLIB_INCLUDE_DIR ${CMAKE_SOURCE_DIR}/src/third-party/zlib ${CMAKE_BINARY_DIR}/zlib)
393 set(ZLIB_LIBRARY zlibstatic)
394 list(APPEND DEPENDENCY_LIB zlibstatic)
395 set(USE_ZLIB ON)
396endif()
397
398if(USE_ZLIB)
399 list(APPEND FEATURES ZLIB)
400 include_directories(AFTER ${ZLIB_INCLUDE_DIRS})
401 list(APPEND DEPENDENCY_LIB ${ZLIB_LIBRARIES})
402 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},zlib1g")
403endif()
404
405if(WANT_PNG AND USE_ZLIB AND NOT USE_PNG)
406 set(PNG_STATIC ON CACHE BOOL "" FORCE)
407 set(PNG_SHARED OFF CACHE BOOL "" FORCE)
408 set(PNG_TESTS OFF CACHE BOOL "" FORCE)
409 set(SKIP_INSTALL_ALL ON)
410 add_subdirectory(${CMAKE_SOURCE_DIR}/src/third-party/libpng libpng)
411 set_property(TARGET png16_static PROPERTY INCLUDE_DIRECTORIES ${CMAKE_BINARY_DIR}/libpng;${CMAKE_SOURCE_DIR}/src/third-party/libpng;${ZLIB_INCLUDE_DIRS})
412 set(PNG_INCLUDE_DIRS ${CMAKE_SOURCE_DIR}/src/third-party/libpng ${CMAKE_BINARY_DIR}/libpng)
413 list(APPEND DEPENDENCY_LIB png16_static)
414 set(USE_PNG ON)
415endif()
416
417if(USE_PNG)
418 list(APPEND FEATURES PNG)
419 include_directories(AFTER ${PNG_INCLUDE_DIRS})
420 list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
421 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng12-0")
422endif()
423
424if(USE_LIBZIP)
425 include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
426 link_directories(${LIBZIP_LIBRARY_DIRS})
427 list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
428 list(APPEND FEATURES LIBZIP)
429 list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
430 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
431elseif(USE_ZLIB)
432 list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-zip.c
433 ${CMAKE_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
434 ${CMAKE_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c)
435endif()
436
437if (USE_LZMA)
438 include_directories(AFTER ${CMAKE_SOURCE_DIR}/third-party/lzma)
439 add_definitions(-D_7ZIP_PPMD_SUPPPORT)
440 list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-lzma.c)
441 set(LZMA_SRC
442 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
443 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
444 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
445 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
446 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
447 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
448 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zDec.c
449 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
450 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Delta.c
451 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
452 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
453 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bra.c
454 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bra86.c
455 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/BraIA64.c
456 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
457 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
458 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
459 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zFile.c
460 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
461 list(APPEND VFS_SRC ${LZMA_SRC})
462 list(APPEND FEATURES LZMA)
463endif()
464
465if(USE_EPOXY)
466 add_definitions(-DBUILD_GL -DBUILD_GLES2)
467 list(APPEND FEATURES EPOXY)
468 include_directories(AFTER ${EPOXY_INCLUDE_DIRS})
469 set(OPENGLES2_LIBRARY ${EPOXY_LIBRARIES})
470 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libepoxy0")
471endif()
472
473
474set(FEATURE_DEFINES)
475foreach(FEATURE IN LISTS FEATURES)
476 list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
477endforeach()
478
479source_group("Virtual files" FILES ${CORE_VFS_SRC} ${VFS_SRC})
480source_group("Extra features" FILES ${FEATURE_SRC})
481source_group("Third-party code" FILES ${THIRD_PARTY_SRC})
482
483# Platform binaries
484if(3DS)
485 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/3ds ${CMAKE_BINARY_DIR}/3ds)
486endif()
487
488if(WII)
489 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/wii ${CMAKE_BINARY_DIR}/wii)
490endif()
491
492if(PSP2)
493 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/psp2 ${CMAKE_BINARY_DIR}/psp2)
494endif()
495
496# Binaries
497set(CORE_SRC
498 ${ARM_SRC}
499 ${GBA_SRC}
500 ${GBA_CHEATS_SRC}
501 ${GBA_CTX_SRC}
502 ${DEBUGGER_SRC}
503 ${RENDERER_SRC}
504 ${UTIL_SRC}
505 ${CORE_VFS_SRC}
506 ${OS_SRC}
507 ${THIRD_PARTY_SRC})
508
509if(NOT MINIMAL_CORE)
510 set(SRC
511 ${CORE_SRC}
512 ${GBA_RR_SRC}
513 ${GBA_SV_SRC}
514 ${SIO_SRC}
515 ${FEATURE_SRC}
516 ${VFS_SRC})
517else()
518 set(SRC ${CORE_SRC} ${VFS_SRC})
519endif()
520
521if(NOT SKIP_LIBRARY)
522 if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
523 set(BUILD_SHARED ON)
524 endif()
525
526 if(BUILD_SHARED)
527 add_library(${BINARY_NAME} SHARED ${SRC} ${VFS_SRC})
528 if(BUILD_STATIC)
529 add_library(${BINARY_NAME}-static STATIC ${SRC})
530 set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
531 install(TARGETS ${BINARY_NAME}-static DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
532 add_dependencies(${BINARY_NAME}-static version-info)
533 endif()
534 else()
535 add_library(${BINARY_NAME} STATIC ${SRC})
536 endif()
537
538 add_dependencies(${BINARY_NAME} version-info)
539 set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
540
541 target_link_libraries(${BINARY_NAME} ${DEBUGGER_LIB} ${DEPENDENCY_LIB} ${OS_LIB})
542 install(TARGETS ${BINARY_NAME} LIBRARY DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME} NAMELINK_SKIP ARCHIVE DESTINATION ${LIBDIR} RUNTIME DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
543 if(UNIX AND NOT APPLE)
544 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-16.png DESTINATION share/icons/hicolor/16x16/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
545 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-24.png DESTINATION share/icons/hicolor/24x24/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
546 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-32.png DESTINATION share/icons/hicolor/32x32/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
547 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-48.png DESTINATION share/icons/hicolor/48x48/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
548 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-64.png DESTINATION share/icons/hicolor/64x64/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
549 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-96.png DESTINATION share/icons/hicolor/96x96/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
550 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-128.png DESTINATION share/icons/hicolor/128x128/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
551 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-256.png DESTINATION share/icons/hicolor/256x256/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
552 install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-512.png DESTINATION share/icons/hicolor/512x512/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
553 endif()
554else()
555 set(BUILD_SHARED OFF)
556 set(BUILD_STATIC OFF)
557 find_library(${BINARY_NAME} ${BINARY_NAME})
558 if(NOT ${BINARY_NAME}_FOUND)
559 set(DISABLE_FRONTENDS ON)
560 set(BUILD_PERF OFF)
561 set(BUILD_TEST OFF)
562 endif()
563endif()
564
565if(BUILD_GL)
566 add_definitions(-DBUILD_GL)
567endif()
568
569if(BUILD_GLES2)
570 add_definitions(-DBUILD_GLES2)
571endif()
572
573if(DISABLE_FRONTENDS)
574 set(BUILD_SDL OFF)
575 set(BUILD_QT OFF)
576endif()
577
578if(BUILD_LIBRETRO)
579 file(GLOB RETRO_SRC ${CMAKE_SOURCE_DIR}/src/platform/libretro/*.c)
580 add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
581 set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5;DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=2")
582 target_link_libraries(${BINARY_NAME}_libretro ${OS_LIB})
583 install(TARGETS ${BINARY_NAME}_libretro LIBRARY DESTINATION ${LIBDIR} COMPONENT ${BINARY_NAME}_libretro NAMELINK_SKIP)
584endif()
585
586if(BUILD_OPENEMU)
587 find_library(FOUNDATION Foundation)
588 find_library(OPENEMUBASE OpenEmuBase)
589 file(GLOB OE_SRC ${CMAKE_SOURCE_DIR}/src/platform/openemu/*.m)
590 add_library(${BINARY_NAME}-openemu MODULE ${CORE_SRC} ${OE_SRC})
591 set_target_properties(${BINARY_NAME}-openemu PROPERTIES
592 MACOSX_BUNDLE_INFO_PLIST ${CMAKE_SOURCE_DIR}/src/platform/openemu/Info.plist.in
593 BUNDLE TRUE
594 BUNDLE_EXTENSION oecoreplugin
595 OUTPUT_NAME ${PROJECT_NAME}
596 COMPILE_DEFINITIONS "DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=1")
597 target_link_libraries(${BINARY_NAME}-openemu ${OS_LIB} ${FOUNDATION} ${OPENEMUBASE})
598 install(TARGETS ${BINARY_NAME}-openemu LIBRARY DESTINATION ${LIBDIR} COMPONENT ${BINARY_NAME}.oecoreplugin NAMELINK_SKIP)
599endif()
600
601if(BUILD_SDL)
602 add_definitions(-DBUILD_SDL)
603 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/sdl ${CMAKE_BINARY_DIR}/sdl)
604endif()
605
606if(BUILD_QT)
607 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/qt ${CMAKE_BINARY_DIR}/qt)
608endif()
609
610if(BUILD_PERF)
611 set(PERF_SRC ${CMAKE_SOURCE_DIR}/src/platform/test/perf-main.c)
612 if(UNIX AND NOT APPLE)
613 list(APPEND PERF_LIB rt)
614 endif()
615
616 add_executable(${BINARY_NAME}-perf ${PERF_SRC})
617 target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB})
618 set_target_properties(${BINARY_NAME}-perf PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
619 install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
620 install(FILES ${CMAKE_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
621endif()
622
623if(BUILD_TEST)
624 add_executable(${BINARY_NAME}-fuzz ${CMAKE_SOURCE_DIR}/src/platform/test/fuzz-main.c)
625 target_link_libraries(${BINARY_NAME}-fuzz ${BINARY_NAME})
626 set_target_properties(${BINARY_NAME}-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
627 install(TARGETS ${BINARY_NAME}-fuzz DESTINATION bin COMPONENT ${BINARY_NAME}-test)
628endif()
629
630# Packaging
631set(CPACK_PACKAGE_VERSION ${VERSION_STRING})
632set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
633set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
634set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
635set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_SOURCE_DIR}/LICENSE)
636set(CPACK_RESOURCE_FILE_README ${CMAKE_SOURCE_DIR}/README.md)
637
638set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
639set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
640set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
641set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_SOURCE_DIR}/README.md")
642set(CPACK_DEBIAN_PACKAGE_SECTION "games")
643
644SET(CPACK_DEB_COMPONENT_INSTALL ON)
645
646set(CPACK_STRIP_FILES ${BINARY_NAME})
647
648install(FILES ${CMAKE_SOURCE_DIR}/README.md ${CMAKE_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
649
650include(CPack)
651
652# Summaries
653set(SUMMARY_GL_LIST)
654if(USE_EPOXY)
655 set(SUMMARY_GL_LIST "libepoxy")
656else()
657 if(BUILD_GL)
658 list(APPEND SUMMARY_GL_LIST "OpenGL")
659 endif()
660 if(BUILD_GLES2)
661 list(APPEND SUMMARY_GL_LIST "OpenGL|ES 2")
662 endif()
663endif()
664if(NOT SUMMARY_GL_LIST)
665 set(SUMMARY_GL OFF)
666else()
667 string(REPLACE ";" ", " SUMMARY_GL "${SUMMARY_GL_LIST}")
668endif()
669if(USE_LIBZIP)
670 set(SUMMARY_ZIP libzip)
671elseif(USE_ZLIB)
672 set(SUMMARY_ZIP minizip)
673else()
674 set(SUMMARY_ZIP OFF)
675endif()
676
677message(STATUS "Features:")
678message(STATUS " CLI debugger: ${USE_CLI_DEBUGGER}")
679message(STATUS " GDB stub: ${USE_GDB_STUB}")
680message(STATUS " Video recording: ${USE_FFMPEG}")
681message(STATUS " GIF recording: ${USE_MAGICK}")
682message(STATUS " Screenshot/advanced savestate support: ${USE_PNG}")
683message(STATUS " ZIP support: ${SUMMARY_ZIP}")
684message(STATUS " 7-Zip support: ${USE_LZMA}")
685message(STATUS " Better audio resampling: ${USE_BLIP}")
686message(STATUS " OpenGL support: ${SUMMARY_GL}")
687message(STATUS "Frontends:")
688message(STATUS " Qt: ${BUILD_QT}")
689message(STATUS " SDL (${SDL_VERSION}): ${BUILD_SDL}")
690message(STATUS " Profiling: ${BUILD_PERF}")
691message(STATUS " Test harness: ${BUILD_TEST}")
692message(STATUS "Cores:")
693message(STATUS " Libretro core: ${BUILD_LIBRETRO}")
694if(APPLE)
695 message(STATUS " OpenEmu core: ${BUILD_OPENEMU}")
696endif()
697message(STATUS "Libraries:")
698message(STATUS " Static: ${BUILD_STATIC}")
699message(STATUS " Shared: ${BUILD_SHARED}")