CMakeLists.txt (view raw)
1cmake_minimum_required(VERSION 2.6)
2project(mGBA C)
3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
4set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -std=c99")
5set(USE_CLI_DEBUGGER ON CACHE BOOL "Whether or not to enable the CLI-mode ARM debugger")
6set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
7set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
8set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
9set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable ZIP support")
10set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
11set(USE_BLIP ON CACHE BOOL "Whether or not to enable blip_buf support")
12set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
13set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
14set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
15set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
16set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
17set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
18set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
19file(GLOB ARM_SRC ${CMAKE_SOURCE_DIR}/src/arm/*.c)
20file(GLOB GBA_SRC ${CMAKE_SOURCE_DIR}/src/gba/*.c)
21file(GLOB GBA_CHEATS_SRC ${CMAKE_SOURCE_DIR}/src/gba/cheats/*.c)
22file(GLOB GBA_RR_SRC ${CMAKE_SOURCE_DIR}/src/gba/rr/*.c)
23file(GLOB GBA_SV_SRC ${CMAKE_SOURCE_DIR}/src/gba/supervisor/*.c)
24file(GLOB UTIL_SRC ${CMAKE_SOURCE_DIR}/src/util/*.[cSs])
25file(GLOB RENDERER_SRC ${CMAKE_SOURCE_DIR}/src/gba/renderers/video-software.c)
26file(GLOB SIO_SRC ${CMAKE_SOURCE_DIR}/src/gba/sio/lockstep.c)
27file(GLOB THIRD_PARTY_SRC ${CMAKE_SOURCE_DIR}/src/third-party/inih/*.c)
28list(APPEND UTIL_SRC ${CMAKE_SOURCE_DIR}/src/platform/commandline.c)
29set(VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-mem.c)
30source_group("ARM core" FILES ${ARM_SRC})
31source_group("GBA board" FILES ${GBA_SRC} ${RENDERER_SRC} ${SIO_SRC})
32source_group("GBA supervisor" FILES ${GBA_CHEATS_SRC} ${GBA_SV_SRC} ${GBA_RR_SRC})
33source_group("Utilities" FILES ${UTIL_SRC})
34include_directories(${CMAKE_SOURCE_DIR}/src/arm)
35include_directories(${CMAKE_SOURCE_DIR}/src)
36
37if(NOT CMAKE_BUILD_TYPE)
38 set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
39endif()
40
41set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
42
43include(GNUInstallDirs)
44
45# Function definitions
46include(FindPkgConfig)
47function(find_feature FEATURE_NAME FEATURE_REQUIRES)
48 if (NOT ${FEATURE_NAME})
49 return()
50 endif()
51 foreach(REQUIRE ${FEATURE_REQUIRES})
52 if(NOT ${REQUIRE}_FOUND)
53 find_package(${REQUIRE} QUIET)
54 if(NOT ${REQUIRE}_FOUND)
55 pkg_search_module(${REQUIRE} ${REQUIRE})
56 if (NOT ${REQUIRE}_FOUND)
57 message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
58 set(${FEATURE_NAME} OFF PARENT_SCOPE)
59 return()
60 endif()
61 endif()
62 endif()
63 string(TOUPPER ${REQUIRE} UREQUIRE)
64 set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
65 set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
66 set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
67 set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
68 set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
69 set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
70 endforeach()
71endfunction()
72
73# Version information
74set(LIB_VERSION_MAJOR 0)
75set(LIB_VERSION_MINOR 3)
76set(LIB_VERSION_PATCH 0)
77set(LIB_VERSION_ABI 0.3)
78set(LIB_VERSION_STRING ${LIB_VERSION_MAJOR}.${LIB_VERSION_MINOR}.${LIB_VERSION_PATCH})
79
80# Advanced settings
81set(BUILD_LTO ON CACHE BOOL "Build with link-time optimization")
82set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
83set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
84set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
85mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
86set(PGO_PRE_FLAGS "-pg -fprofile-generate=${PGO_DIR} -fprofile-arcs")
87set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
88
89if(BUILD_PGO AND NOT PGO_STAGE_2)
90 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
91 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
92 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
93elseif(BUILD_PGO AND PGO_STAGE_2)
94 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
95 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
96 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
97endif()
98
99add_definitions(-DBINARY_NAME="${BINARY_NAME}" -DPROJECT_NAME="${PROJECT_NAME}" -DPROJECT_VERSION="${LIB_VERSION_STRING}")
100
101# Feature dependencies
102set(FEATURES)
103if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
104 set(LIBEDIT_LIBRARIES -ledit)
105 if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
106 list(APPEND LIBEDIT_LIBRARIES -ltermcap)
107 endif()
108else()
109 find_feature(USE_CLI_DEBUGGER "libedit")
110endif()
111find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
112find_feature(USE_PNG "ZLIB;PNG")
113find_feature(USE_LIBZIP "libzip")
114find_feature(USE_MAGICK "MagickWand")
115
116# Platform support
117if(WIN32)
118 set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
119 add_definitions(-D_WIN32_WINNT=0x0600)
120 list(APPEND OS_LIB ws2_32)
121 list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
122 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/windows/*.c)
123 source_group("Windows-specific code" FILES ${OS_SRC})
124else()
125 add_definitions(-DUSE_PTHREADS)
126
127 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
128 add_definitions(-D_BSD_SOURCE -D_POSIX_SOURCE -D_POSIX_C_SOURCE=200809L)
129 endif()
130 if(NOT APPLE)
131 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
132 endif()
133
134 list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
135 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/posix/*.c)
136 source_group("POSIX-specific code" FILES ${OS_SRC})
137endif()
138
139if(APPLE)
140 add_definitions(-D_DARWIN_C_SOURCE)
141 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
142endif()
143
144if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
145 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
146 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
147endif()
148
149if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
150 if(NOT BUILD_EGL)
151 add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
152 endif()
153endif()
154
155if(BUILD_PANDORA)
156 add_definitions(-DBUILD_PANDORA)
157endif()
158
159if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
160 enable_language(ASM)
161endif()
162
163include(CheckFunctionExists)
164check_function_exists(strndup HAVE_STRNDUP)
165check_function_exists(snprintf_l HAVE_SNPRINTF_L)
166if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
167 # The strtof_l on Linux not actually exposed nor actually strtof_l
168 set(HAVE_STRTOF_L OFF)
169else()
170 check_function_exists(strtof_l HAVE_STRTOF_L)
171endif()
172check_function_exists(newlocale HAVE_NEWLOCALE)
173check_function_exists(freelocale HAVE_FREELOCALE)
174check_function_exists(uselocale HAVE_USELOCALE)
175
176if(HAVE_STRNDUP)
177 add_definitions(-DHAVE_STRNDUP)
178endif()
179
180if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE)
181 add_definitions(-DHAVE_LOCALE)
182 if (HAVE_STRTOF_L)
183 add_definitions(-DHAVE_STRTOF_L)
184 endif()
185 if (HAVE_SNPRINTF_L)
186 add_definitions(-DHAVE_SNPRINTF_L)
187 endif()
188endif()
189
190
191# Features
192set(DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/debugger.c ${CMAKE_SOURCE_DIR}/src/debugger/memory-debugger.c)
193set(FEATURE_SRC)
194set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
195
196if(USE_CLI_DEBUGGER)
197 list(APPEND FEATURES CLI_DEBUGGER)
198 list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/debugger/cli-debugger.c)
199 list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/debugger/parser.c)
200 list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/gba/supervisor/cli.c)
201 include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
202 link_directories(${LIBEDIT_LIBRARY_DIRS})
203 set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
204 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
205else()
206 set(DEBUGGER_LIB "")
207endif()
208
209if(USE_GDB_STUB)
210 list(APPEND FEATURES GDB_STUB)
211 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/gdb-stub.c)
212endif()
213source_group("ARM debugger" FILES ${DEBUGGER_SRC})
214
215if(USE_FFMPEG)
216 list(APPEND FEATURES FFMPEG)
217 pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
218 if(NOT LIBSWRESAMPLE_FOUND)
219 list(APPEND FEATURES LIBAV)
220 endif()
221 include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
222 link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
223 list(APPEND FEATURE_SRC "${CMAKE_SOURCE_DIR}/src/platform/ffmpeg/ffmpeg-encoder.c")
224 string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
225 string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
226 string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
227 string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
228 string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
229 list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
230 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR},libavformat${LIBAVFORMAT_VERSION_MAJOR},libavresample${LIBAVRESAMPLE_VERSION_MAJOR},libavutil${LIBAVUTIL_VERSION_MAJOR},libswscale${LIBSWSCALE_VERSION_MAJOR}")
231 set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra")
232endif()
233
234if(USE_BLIP)
235 list(APPEND THIRD_PARTY_SRC "${CMAKE_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
236 add_definitions(-DRESAMPLE_LIBRARY=RESAMPLE_BLIP_BUF)
237else()
238 add_definitions(-DRESAMPLE_LIBRARY=RESAMPLE_NN)
239endif()
240
241if(USE_MAGICK)
242 list(APPEND FEATURES MAGICK)
243 include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
244 link_directories(${MAGICKWAND_LIBRARY_DIRS})
245 list(APPEND FEATURE_SRC "${CMAKE_SOURCE_DIR}/src/platform/imagemagick/imagemagick-gif-encoder.c")
246 list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
247 string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
248 if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
249 set(MAGICKWAND_DEB_VERSION "5")
250 else()
251 set(MAGICKWAND_DEB_VERSION "-6.q16-2")
252 endif()
253 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
254endif()
255
256if(USE_PNG)
257 list(APPEND FEATURES PNG)
258 include_directories(AFTER ${PNG_INCLUDE_DIRS})
259 list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
260 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng12-0,zlib1g")
261endif()
262
263if(USE_LIBZIP)
264 include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
265 link_directories(${LIBZIP_LIBRARY_DIRS})
266 list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
267 list(APPEND FEATURES LIBZIP)
268 list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
269 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
270endif()
271
272if (USE_LZMA)
273 include_directories(AFTER ${CMAKE_SOURCE_DIR}/third-party/lzma)
274 add_definitions(-D_7ZIP_PPMD_SUPPPORT)
275 list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-lzma.c)
276 set(LZMA_SRC
277 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
278 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
279 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
280 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
281 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
282 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
283 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zDec.c
284 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
285 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
286 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
287 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bra.c
288 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bra86.c
289 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
290 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
291 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
292 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zFile.c
293 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
294 list(APPEND FEATURE_SRC ${LZMA_SRC})
295 list(APPEND FEATURES LZMA)
296endif()
297
298set(FEATURE_DEFINES)
299foreach(FEATURE IN LISTS FEATURES)
300 list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
301endforeach()
302
303# Binaries
304set(CORE_SRC
305 ${ARM_SRC}
306 ${GBA_SRC}
307 ${GBA_CHEATS_SRC}
308 ${GBA_RR_SRC}
309 ${GBA_SV_SRC}
310 ${DEBUGGER_SRC}
311 ${RENDERER_SRC}
312 ${SIO_SRC}
313 ${UTIL_SRC}
314 ${VFS_SRC}
315 ${OS_SRC}
316 ${THIRD_PARTY_SRC})
317
318set(SRC
319 ${CORE_SRC}
320 ${FEATURE_SRC})
321
322if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
323 set(BUILD_SHARED ON)
324endif()
325
326if(BUILD_SHARED)
327 add_library(${BINARY_NAME} SHARED ${SRC})
328 if(BUILD_STATIC)
329 add_library(${BINARY_NAME}-static STATIC ${SRC})
330 set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${FEATURE_DEFINES}")
331 install(TARGETS ${BINARY_NAME}-static DESTINATION lib COMPONENT lib${BINARY_NAME})
332 endif()
333else()
334 add_library(${BINARY_NAME} STATIC ${SRC})
335endif()
336
337target_link_libraries(${BINARY_NAME} m ${DEBUGGER_LIB} ${OS_LIB} ${DEPENDENCY_LIB})
338install(TARGETS ${BINARY_NAME} DESTINATION lib COMPONENT lib${BINARY_NAME})
339set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${FEATURE_DEFINES}")
340
341if(BUILD_LIBRETRO)
342 file(GLOB RETRO_SRC ${CMAKE_SOURCE_DIR}/src/platform/libretro/*.c)
343 add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
344 set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5")
345 target_link_libraries(${BINARY_NAME}_libretro m ${OS_LIB})
346endif()
347
348if(BUILD_SDL)
349 add_definitions(-DBUILD_SDL)
350 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/sdl ${CMAKE_BINARY_DIR}/sdl)
351endif()
352
353if(BUILD_QT)
354 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/qt ${CMAKE_BINARY_DIR}/qt)
355endif()
356
357if(BUILD_PERF)
358 set(PERF_SRC ${CMAKE_SOURCE_DIR}/src/platform/perf-main.c)
359 if(UNIX AND NOT APPLE)
360 list(APPEND PERF_LIB rt)
361 endif()
362
363 add_executable(${BINARY_NAME}-perf ${PERF_SRC})
364 target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB})
365 install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
366 install(FILES ${CMAKE_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
367endif()
368
369# Packaging
370set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
371set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
372set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
373set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_SOURCE_DIR}/LICENSE)
374set(CPACK_RESOURCE_FILE_README ${CMAKE_SOURCE_DIR}/README.md)
375
376set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
377set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
378set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
379set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_SOURCE_DIR}/README.md")
380set(CPACK_DEBIAN_PACKAGE_SECTION "games")
381
382SET(CPACK_DEB_COMPONENT_INSTALL ON)
383
384set(CPACK_STRIP_FILES ${BINARY_NAME})
385
386install(FILES ${CMAKE_SOURCE_DIR}/README.md ${CMAKE_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
387
388include(CPack)
389
390# Summaries
391message(STATUS "Feature summary:")
392message(STATUS " CLI debugger: ${USE_CLI_DEBUGGER}")
393message(STATUS " GDB stub: ${USE_GDB_STUB}")
394message(STATUS " Video recording: ${USE_FFMPEG}")
395message(STATUS " GIF recording: ${USE_MAGICK}")
396message(STATUS " Screenshot/advanced savestate support: ${USE_PNG}")
397message(STATUS " ZIP support: ${USE_LIBZIP}")
398message(STATUS " 7-Zip support: ${USE_LZMA}")
399message(STATUS " Better audio resampling: ${USE_BLIP}")
400message(STATUS "Frontend summary:")
401message(STATUS " Qt: ${BUILD_QT}")
402message(STATUS " SDL (${SDL_VERSION}): ${BUILD_SDL}")
403message(STATUS " Libretro core: ${BUILD_LIBRETRO}")
404message(STATUS " Profiling: ${BUILD_PERF}")
405message(STATUS "Library summary:")
406message(STATUS " Static: ${BUILD_STATIC}")
407message(STATUS " Shared: ${BUILD_SHARED}")