1cmake_minimum_required(VERSION 2.6)
  2project(mGBA C)
  3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
  4if(NOT MSVC)
  5	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wno-missing-field-initializers -std=c99")
  6else()
  7	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_CRT_SECURE_NO_WARNINGS /wd4003 /wd4244 /wd4146")
  8endif()
  9set(USE_DEBUGGERS ON CACHE BOOL "Whether or not to enable the debugging infrastructure")
 10set(USE_EDITLINE ON CACHE BOOL "Whether or not to enable the CLI-mode debugger")
 11set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
 12set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
 13set(USE_ZLIB ON CACHE BOOL "Whether or not to enable zlib support")
 14set(USE_MINIZIP ON CACHE BOOL "Whether or not to enable external minizip support")
 15set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
 16set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable LIBZIP support")
 17set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
 18set(USE_SQLITE3 ON CACHE BOOL "Whether or not to enable SQLite3 support")
 19set(M_CORE_GBA ON CACHE BOOL "Build Game Boy Advance core")
 20set(M_CORE_GB ON CACHE BOOL "Build Game Boy core")
 21set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
 22set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
 23set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
 24set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
 25if(APPLE)
 26	set(BUILD_OPENEMU OFF CACHE BOOL "Build OpenEmu core")
 27endif()
 28set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
 29set(BUILD_TEST OFF CACHE BOOL "Build testing harness")
 30set(BUILD_SUITE OFF CACHE BOOL "Build test suite")
 31set(BUILD_EXAMPLE OFF CACHE BOOL "Build example frontends")
 32set(BUILD_PYTHON OFF CACHE BOOL "Build Python bindings")
 33set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
 34set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
 35set(SKIP_LIBRARY OFF CACHE BOOL "Skip building the library (useful for only building libretro or OpenEmu cores)")
 36set(BUILD_GL ON CACHE STRING "Build with OpenGL")
 37set(BUILD_GLES2 OFF CACHE STRING "Build with OpenGL|ES 2")
 38set(USE_EPOXY ON CACHE STRING "Build with libepoxy")
 39set(DISABLE_DEPS OFF CACHE BOOL "Build without dependencies")
 40file(GLOB ARM_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/*.c)
 41file(GLOB ARM_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/test/*.c)
 42file(GLOB LR35902_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/*.c)
 43file(GLOB LR35902_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/test/*.c)
 44file(GLOB GBA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/*.c)
 45file(GLOB GBA_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/test/*.c)
 46file(GLOB GB_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/*.c)
 47file(GLOB GB_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/test/*.c)
 48file(GLOB GBA_CHEATS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/cheats/*.c)
 49file(GLOB GBA_RR_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/rr/*.c)
 50file(GLOB CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/*.c)
 51file(GLOB CORE_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/test/*.c)
 52file(GLOB UTIL_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/*.[cSs])
 53file(GLOB UTIL_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/test/*.c)
 54file(GLOB GUI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/gui/*.c ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/gui/*.c)
 55file(GLOB GBA_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/renderers/*.c)
 56file(GLOB GBA_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/sio/lockstep.c)
 57file(GLOB GB_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/sio/lockstep.c)
 58file(GLOB GB_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/renderers/*.c)
 59file(GLOB THIRD_PARTY_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/inih/*.c)
 60set(CLI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/commandline.c)
 61set(CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-mem.c)
 62set(VFS_SRC)
 63source_group("ARM core" FILES ${ARM_SRC})
 64source_group("LR35902 core" FILES ${LR35902_SRC})
 65source_group("GBA board" FILES ${GBA_SRC} ${GBA_RENDERER_SRC} ${GBA_SIO_SRC})
 66source_group("GBA extra" FILES ${GBA_CHEATS_SRC} ${GBA_RR_SRC})
 67source_group("GB board" FILES ${GB_SRC} ${GB_SIO_SRC})
 68source_group("Utilities" FILES ${UTIL_SRC})
 69include_directories(BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/include ${CMAKE_CURRENT_SOURCE_DIR}/src)
 70
 71if(NOT CMAKE_BUILD_TYPE)
 72	set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
 73endif()
 74
 75include(GNUInstallDirs)
 76
 77set(LIBDIR "${CMAKE_INSTALL_LIBDIR}" CACHE PATH "Installed library directory")
 78mark_as_advanced(LIBDIR)
 79
 80if (BUILD_LIBRETRO)
 81	set(LIBRETRO_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (Libretro)")
 82	mark_as_advanced(LIBRETRO_LIBDIR)
 83endif()
 84
 85if (BUILD_OPENEMU)
 86	set(OE_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (OpenEmu)")
 87	mark_as_advanced(OE_LIBDIR)
 88endif()
 89
 90
 91set(CMAKE_INSTALL_RPATH "${LIBDIR}")
 92
 93if (NOT DEFINED MANDIR)
 94	set(MANDIR ${CMAKE_INSTALL_MANDIR})
 95endif()
 96
 97# Function definitions
 98include(FindPkgConfig)
 99function(find_feature FEATURE_NAME FEATURE_REQUIRES)
100	if (NOT ${FEATURE_NAME})
101		return()
102	endif()
103	if (DISABLE_DEPS)
104		set(${FEATURE_NAME} OFF PARENT_SCOPE)
105		return()
106	endif()
107	foreach(REQUIRE ${FEATURE_REQUIRES})
108		if(NOT ${REQUIRE}_FOUND)
109			find_package(${REQUIRE} QUIET)
110			if(NOT ${REQUIRE}_FOUND)
111				pkg_search_module(${REQUIRE} ${REQUIRE})
112				if (NOT ${REQUIRE}_FOUND)
113					message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
114					set(${FEATURE_NAME} OFF PARENT_SCOPE)
115					return()
116				endif()
117			endif()
118		endif()
119		string(TOUPPER ${REQUIRE} UREQUIRE)
120		set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
121		set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
122		set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
123		if (APPLE)
124			set(IS_FRAMEWORK OFF)
125			set(LIBS)
126			foreach(LIB IN LISTS ${REQUIRE}_LIBRARIES)
127				if(LIB STREQUAL "-framework")
128					set(IS_FRAMEWORK ON)
129				elseif(IS_FRAMEWORK)
130					list(APPEND LIBS "-framework ${LIB}")
131					set(IS_FRAMEWORK OFF)
132				else()
133					list(APPEND LIBS ${LIB})
134				endif()
135			endforeach()
136			set(${UREQUIRE}_LIBRARIES ${LIBS} PARENT_SCOPE)
137		else()
138			set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
139		endif()
140		set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
141		set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
142	endforeach()
143endfunction()
144
145# Version information
146add_custom_target(version-info ALL
147	COMMAND ${CMAKE_COMMAND}
148	-DBINARY_NAME=${BINARY_NAME}
149	-DCONFIG_FILE=${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in
150	-DOUT_FILE=${CMAKE_CURRENT_BINARY_DIR}/version.c
151	-P ${CMAKE_CURRENT_SOURCE_DIR}/version.cmake
152	WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
153
154include(${CMAKE_CURRENT_SOURCE_DIR}/version.cmake)
155configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in ${CMAKE_CURRENT_BINARY_DIR}/version.c)
156configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/flags.h.in ${CMAKE_CURRENT_BINARY_DIR}/flags.h)
157install(FILES ${CMAKE_CURRENT_BINARY_DIR}/flags.h DESTINATION include/mgba COMPONENT lib${BINARY_NAME})
158
159list(APPEND UTIL_SRC ${CMAKE_CURRENT_BINARY_DIR}/version.c)
160source_group("Generated sources" FILES ${CMAKE_CURRENT_BINARY_DIR}/version.c)
161
162# Advanced settings
163if(NOT 3DS)
164	# LTO appears to make 3DS binary slower
165	set(DEFAULT_LTO ON)
166else()
167	set(DEFAULT_LTO OFF)
168endif()
169
170set(BUILD_LTO ${DEFAULT_LTO} CACHE BOOL "Build with link-time optimization")
171set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
172set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
173set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
174mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
175set(PGO_PRE_FLAGS "-fprofile-generate=${PGO_DIR} -fprofile-arcs")
176set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
177
178if(BUILD_PGO AND NOT PGO_STAGE_2)
179	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
180	set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
181	set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
182elseif(BUILD_PGO AND PGO_STAGE_2)
183	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
184	set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
185	set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
186endif()
187
188# Platform support
189if(WIN32)
190	set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
191	add_definitions(-D_WIN32_WINNT=0x0600)
192	list(APPEND OS_LIB ws2_32 shlwapi)
193	list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/vfs-w32.c)
194	file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/*.c)
195	source_group("Windows-specific code" FILES ${OS_SRC})
196	if(MSVC)
197		add_definitions(-DNOMINMAX -DWIN32_LEAN_AND_MEAN)
198	endif()
199elseif(UNIX)
200	add_definitions(-DUSE_PTHREADS)
201
202	if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
203		add_definitions(-D_GNU_SOURCE)
204	endif()
205	if(NOT APPLE AND NOT HAIKU)
206		set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
207	endif()
208
209	list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
210	file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/posix/*.c)
211	source_group("POSIX-specific code" FILES ${OS_SRC})
212endif()
213
214if(APPLE)
215	add_definitions(-D_DARWIN_C_SOURCE)
216	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
217endif()
218
219if(NOT HAIKU AND NOT MSVC AND NOT PSP2)
220	set(M_LIBRARY m)
221endif()
222list(APPEND OS_LIB ${M_LIBRARY})
223
224if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
225	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
226	set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
227endif()
228
229if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
230	if(NOT BUILD_EGL)
231		add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
232	endif()
233endif()
234
235if(BUILD_RASPI)
236	set(BUILD_GL OFF CACHE BOOL "OpenGL not supported" FORCE)
237endif()
238
239if(BUILD_PANDORA)
240	add_definitions(-DBUILD_PANDORA)
241endif()
242
243if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
244	enable_language(ASM)
245endif()
246
247if(PSP2 OR WII)
248	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-format")
249endif()
250
251if(DEFINED 3DS OR DEFINED PSP2 OR DEFINED WII)
252	set(USE_DEBUGGERS OFF)
253	set(USE_SQLITE3 OFF)
254endif()
255
256if(NOT M_CORE_GBA)
257	set(USE_GDB_STUB OFF)
258endif()
259
260if(NOT USE_DEBUGGERS)
261	set(USE_EDITLINE OFF)
262	set(USE_GDB_STUB OFF)
263endif()
264
265if(WII)
266	add_definitions(-U__STRICT_ANSI__)
267endif()
268
269include(CheckFunctionExists)
270check_function_exists(strdup HAVE_STRDUP)
271check_function_exists(strndup HAVE_STRNDUP)
272check_function_exists(localtime_r HAVE_LOCALTIME_R)
273if(NOT CMAKE_SYSTEM_NAME STREQUAL "Generic")
274	check_function_exists(snprintf_l HAVE_SNPRINTF_L)
275	if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
276		# The strtof_l on Linux not actually exposed nor actually strtof_l
277		set(HAVE_STRTOF_L OFF)
278	else()
279		check_function_exists(strtof_l HAVE_STRTOF_L)
280	endif()
281	check_function_exists(newlocale HAVE_NEWLOCALE)
282	check_function_exists(freelocale HAVE_FREELOCALE)
283	check_function_exists(uselocale HAVE_USELOCALE)
284	check_function_exists(setlocale HAVE_SETLOCALE)
285else()
286	if(NOT DEFINED 3DS AND NOT DEFINED PSP2 AND NOT DEFINED WII)
287		set(DISABLE_DEPS ON CACHE BOOL "This platform cannot build with dependencies" FORCE)
288	endif()
289	set(DISABLE_FRONTENDS ON)
290	set(MINIMAL_CORE ON)
291endif()
292
293check_function_exists(chmod HAVE_CHMOD)
294check_function_exists(umask HAVE_UMASK)
295
296set(FUNCTION_DEFINES)
297
298if(HAVE_STRDUP)
299	list(APPEND FUNCTION_DEFINES HAVE_STRDUP)
300endif()
301
302if(HAVE_STRNDUP)
303	list(APPEND FUNCTION_DEFINES HAVE_STRNDUP)
304endif()
305
306if(HAVE_LOCALTIME_R)
307	list(APPEND FUNCTION_DEFINES HAVE_LOCALTIME_R)
308endif()
309
310if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE OR APPLE)
311	list(APPEND FUNCTION_DEFINES HAVE_LOCALE)
312	if (HAVE_STRTOF_L)
313		list(APPEND FUNCTION_DEFINES HAVE_STRTOF_L)
314	endif()
315	if (HAVE_SNPRINTF_L)
316		list(APPEND FUNCTION_DEFINES HAVE_SNPRINTF_L)
317	endif()
318endif()
319
320if(HAVE_SETLOCALE)
321	list(APPEND FUNCTION_DEFINES HAVE_SETLOCALE)
322endif()
323
324if(HAVE_CHMOD)
325	list(APPEND FUNCTION_DEFINES HAVE_CHMOD)
326endif()
327
328if(HAVE_UMASK)
329	list(APPEND FUNCTION_DEFINES HAVE_UMASK)
330endif()
331
332# Feature dependencies
333set(FEATURE_DEFINES)
334set(FEATURES)
335if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
336	set(LIBEDIT_LIBRARIES -ledit)
337	if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
338		list(APPEND LIBEDIT_LIBRARIES -ltermcap)
339	endif()
340else()
341	find_feature(USE_EDITLINE "libedit")
342endif()
343if(BUILD_GL)
344	find_package(OpenGL QUIET)
345	if(NOT OPENGL_FOUND)
346		set(BUILD_GL OFF CACHE BOOL "OpenGL not found" FORCE)
347	endif()
348endif()
349if(NOT BUILD_GL)
350	set(OPENGLE_LIBRARY "" CACHE PATH "" FORCE)
351endif()
352if(BUILD_GLES2 AND NOT BUILD_RASPI)
353	find_path(OPENGLES2_INCLUDE_DIR NAMES GLES2/gl2.h)
354	find_library(OPENGLES2_LIBRARY NAMES GLESv2 GLESv2_CM)
355	if(NOT OPENGLES2_INCLUDE_DIR OR NOT OPENGLES2_LIBRARY)
356		set(BUILD_GLES2 OFF CACHE BOOL "OpenGL|ES 2 not found" FORCE)
357	endif()
358endif()
359if(NOT BUILD_GLES2)
360	set(OPENGLES2_LIBRARY "" CACHE PATH "" FORCE)
361endif()
362set(WANT_ZLIB ${USE_ZLIB})
363set(WANT_PNG ${USE_PNG})
364set(WANT_LIBZIP ${USE_LIBZIP})
365set(WANT_SQLITE3 ${USE_SQLITE3})
366set(USE_CMOCKA ${BUILD_SUITE})
367
368find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
369find_feature(USE_ZLIB "ZLIB")
370find_feature(USE_MINIZIP "minizip")
371find_feature(USE_PNG "PNG")
372find_feature(USE_LIBZIP "libzip")
373find_feature(USE_MAGICK "MagickWand")
374find_feature(USE_EPOXY "epoxy")
375find_feature(USE_CMOCKA "cmocka")
376find_feature(USE_SQLITE3 "sqlite3")
377
378# Features
379set(DEBUGGER_SRC
380	${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/debugger.c
381	${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/parser.c
382	${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/cli-debugger.c)
383
384set(FEATURE_SRC)
385set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
386
387if(DISABLE_DEPS)
388	set(USE_GDB_STUB OFF)
389endif()
390
391if(USE_EDITLINE)
392	list(APPEND FEATURES EDITLINE)
393	include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
394	link_directories(${LIBEDIT_LIBRARY_DIRS})
395	set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
396	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
397	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/editline/cli-el-backend.c")
398else()
399	set(DEBUGGER_LIB "")
400endif()
401
402if(USE_GDB_STUB)
403	list(APPEND FEATURES GDB_STUB)
404	list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/gdb-stub.c)
405endif()
406source_group("Debugger" FILES ${DEBUGGER_SRC})
407
408if(USE_FFMPEG)
409	list(APPEND FEATURES FFMPEG)
410	pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
411	if(NOT LIBSWRESAMPLE_FOUND)
412		list(APPEND FEATURES LIBAV)
413	endif()
414	include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
415	link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
416	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/ffmpeg/ffmpeg-encoder.c")
417	string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
418	string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
419	string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
420	string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
421	string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
422	list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
423	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR}|libavcodec-extra-${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
424	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavformat${LIBAVFORMAT_VERSION_MAJOR}|libavformat-ffmpeg${LIBAVFORMAT_VERSION_MAJOR}")
425	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavresample${LIBAVRESAMPLE_VERSION_MAJOR}|libavresample-ffmpeg${LIBAVRESAMPLE_VERSION_MAJOR}")
426	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavutil${LIBAVUTIL_VERSION_MAJOR}|libavutil-ffmpeg${LIBAVUTIL_VERSION_MAJOR}")
427	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libswscale${LIBSWSCALE_VERSION_MAJOR}|libswscale-ffmpeg${LIBSWSCALE_VERSION_MAJOR}")
428	set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
429	if(APPLE)
430		set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
431		set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
432	endif()
433endif()
434
435list(APPEND THIRD_PARTY_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
436
437if(USE_MAGICK)
438	list(APPEND FEATURES MAGICK)
439	include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
440	link_directories(${MAGICKWAND_LIBRARY_DIRS})
441	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/imagemagick/imagemagick-gif-encoder.c")
442	list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
443	string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
444	string(REGEX MATCH "^[0-9]+" MAGICKWAND_VERSION_MAJOR ${MagickWand_VERSION})
445	if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
446		set(MAGICKWAND_DEB_VERSION "5")
447	elseif(${MagickWand_VERSION} EQUAL "6.9.7")
448		set(MAGICKWAND_DEB_VERSION "-6.q16-3")
449	else()
450		set(MAGICKWAND_DEB_VERSION "-6.q16-2")
451	endif()
452	list(APPEND FEATURE_DEFINES MAGICKWAND_VERSION_MAJOR=${MAGICKWAND_VERSION_MAJOR})
453
454	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
455endif()
456
457if(WANT_ZLIB AND NOT USE_ZLIB)
458	set(SKIP_INSTALL_ALL ON)
459	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib zlib)
460	set_property(TARGET zlibstatic PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/zlib;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib)
461	set_property(TARGET zlib PROPERTY EXCLUDE_FROM_ALL ON)
462	set_property(TARGET example PROPERTY EXCLUDE_FROM_ALL ON)
463	set_property(TARGET minigzip PROPERTY EXCLUDE_FROM_ALL ON)
464	set(ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
465	set(ZLIB_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
466	set(ZLIB_LIBRARY zlibstatic)
467	list(APPEND DEPENDENCY_LIB zlibstatic)
468	set(USE_ZLIB ON)
469endif()
470
471if(USE_ZLIB)
472	list(APPEND FEATURES ZLIB)
473	include_directories(AFTER ${ZLIB_INCLUDE_DIRS})
474	list(APPEND DEPENDENCY_LIB ${ZLIB_LIBRARIES})
475	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},zlib1g")
476endif()
477
478if(WANT_PNG AND USE_ZLIB AND NOT USE_PNG)
479	set(PNG_STATIC ON CACHE BOOL "" FORCE)
480	set(PNG_SHARED OFF CACHE BOOL "" FORCE)
481	set(PNG_TESTS OFF CACHE BOOL "" FORCE)
482	set(SKIP_INSTALL_ALL ON)
483	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng libpng)
484	set_property(TARGET png16_static PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/libpng;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng;${ZLIB_INCLUDE_DIRS})
485	set(PNG_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng ${CMAKE_CURRENT_BINARY_DIR}/libpng)
486	list(APPEND DEPENDENCY_LIB png16_static)
487	set(USE_PNG ON)
488endif()
489
490if(USE_PNG)
491	list(APPEND FEATURES PNG)
492	include_directories(AFTER ${PNG_INCLUDE_DIRS})
493	list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
494	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng12-0")
495endif()
496
497if(WANT_SQLITE3 AND NOT USE_SQLITE3)
498	list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/sqlite3.c)
499	include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/)
500	set(USE_SQLITE3 ON)
501endif()
502
503if(USE_LIBZIP)
504	include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
505	link_directories(${LIBZIP_LIBRARY_DIRS})
506	list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
507	list(APPEND FEATURES LIBZIP)
508	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
509	string(REGEX MATCH "^[0-9]+" LIBZIP_VERSION_MAJOR ${libzip_VERSION})
510	if (LIBZIP_VERSION_MAJOR LESS 1)
511		set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
512	elseif(LIBZIP_VERSION_MAJOR EQUAL 1)
513		set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip4")
514	else()
515		message(AUTHOR_WARNING Unknown version of libzip detected: ${libzip_VERSION})
516	endif()
517elseif(USE_MINIZIP)
518	include_directories(AFTER ${MINIZIP_INCLUDE_DIRS})
519	link_directories(${MINIZIP_LIBRARY_DIRS})
520	list(APPEND DEPENDENCY_LIB ${MINIZIP_LIBRARIES})
521	list(APPEND FEATURES MINIZIP)
522	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
523	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libminizip1")
524elseif(USE_ZLIB)
525	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c
526		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
527		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c)
528	set_source_files_properties(
529		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
530		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c
531		PROPERTIES COMPILE_FLAGS "-Wno-unused-parameter -Wno-implicit-function-declaration")
532endif()
533
534if (USE_LZMA)
535	include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/third-party/lzma)
536	add_definitions(-D_7ZIP_PPMD_SUPPPORT)
537	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-lzma.c)
538	set(LZMA_SRC
539		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
540		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
541		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
542		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
543		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
544		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
545		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zDec.c
546		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
547		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Delta.c
548		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
549		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
550		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra.c
551		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra86.c
552		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/BraIA64.c
553		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
554		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
555		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
556		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zFile.c
557		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
558	list(APPEND VFS_SRC ${LZMA_SRC})
559	list(APPEND FEATURES LZMA)
560endif()
561
562if(USE_EPOXY)
563	add_definitions(-DBUILD_GL -DBUILD_GLES2)
564	list(APPEND FEATURES EPOXY)
565	include_directories(AFTER ${EPOXY_INCLUDE_DIRS})
566	set(OPENGLES2_LIBRARY ${EPOXY_LIBRARIES})
567	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libepoxy0")
568endif()
569
570if(USE_SQLITE3)
571	list(APPEND FEATURES SQLITE3)
572	include_directories(AFTER ${SQLITE3_INCLUDE_DIRS})
573	list(APPEND DEPENDENCY_LIB ${SQLITE3_LIBRARIES})
574	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libsqlite3-0")
575	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/sqlite3/no-intro.c")
576endif()
577
578set(TEST_SRC ${CORE_TEST_SRC})
579if(M_CORE_GB)
580	add_definitions(-DM_CORE_GB)
581	list(APPEND CORE_SRC
582		${LR35902_SRC}
583		${GB_SRC}
584		${GB_RENDERER_SRC})
585	list(APPEND DEBUGGER_SRC
586		${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/cli-debugger.c
587		${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/debugger.c
588		${CMAKE_CURRENT_SOURCE_DIR}/src/gb/extra/cli.c)
589	list(APPEND TEST_SRC
590		${LR35902_TEST_SRC}
591		${GB_TEST_SRC})
592endif()
593
594if(M_CORE_GBA)
595	add_definitions(-DM_CORE_GBA)
596	list(APPEND CORE_SRC 
597		${ARM_SRC}
598		${GBA_SRC}
599		${GBA_CHEATS_SRC}
600		${GBA_RENDERER_SRC})
601	list(APPEND DEBUGGER_SRC
602		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c
603		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/debugger.c
604		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/memory-debugger.c
605		${CMAKE_CURRENT_SOURCE_DIR}/src/gba/extra/cli.c)
606	list(APPEND TEST_SRC
607		${ARM_TEST_SRC}
608		${GBA_TEST_SRC})
609	if(NOT M_CORE_GB)
610		list(APPEND CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/audio.c)
611	endif()
612endif()
613
614if(USE_DEBUGGERS)
615	list(APPEND FEATURE_SRC ${DEBUGGER_SRC})
616	list(APPEND FEATURES DEBUGGERS)
617endif()
618
619foreach(FEATURE IN LISTS FEATURES)
620	list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
621endforeach()
622
623source_group("Virtual files" FILES ${CORE_VFS_SRC} ${VFS_SRC})
624source_group("Extra features" FILES ${FEATURE_SRC})
625source_group("Third-party code" FILES ${THIRD_PARTY_SRC})
626
627# Platform binaries
628if(3DS)
629	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/3ds ${CMAKE_CURRENT_BINARY_DIR}/3ds)
630endif()
631
632if(WII)
633	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/wii ${CMAKE_CURRENT_BINARY_DIR}/wii)
634endif()
635
636if(PSP2)
637	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/psp2 ${CMAKE_CURRENT_BINARY_DIR}/psp2)
638endif()
639
640# Binaries
641list(APPEND CORE_SRC
642	${UTIL_SRC}
643	${CORE_VFS_SRC}
644	${OS_SRC}
645	${THIRD_PARTY_SRC})
646list(APPEND TEST_SRC ${UTIL_TEST_SRC})
647
648set(SRC ${CORE_SRC} ${VFS_SRC})
649if(NOT MINIMAL_CORE)
650	if(M_CORE_GBA)
651		list(APPEND SRC
652			${GBA_RR_SRC}
653			${GBA_EXTRA_SRC}
654			${GBA_SIO_SRC})
655	endif()
656	if(M_CORE_GB)
657		list(APPEND SRC
658			${GB_SIO_SRC})
659	endif()
660	list(APPEND SRC
661		${FEATURE_SRC}
662		${CLI_SRC})
663endif()
664
665if(NOT SKIP_LIBRARY)
666	if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
667		set(BUILD_SHARED ON)
668	endif()
669
670	if(BUILD_SHARED)
671		add_library(${BINARY_NAME} SHARED ${SRC} ${VFS_SRC})
672		if(BUILD_STATIC)
673			add_library(${BINARY_NAME}-static STATIC ${SRC})
674			set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
675			install(TARGETS ${BINARY_NAME}-static DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
676			add_dependencies(${BINARY_NAME}-static version-info)
677		endif()
678	else()
679		add_library(${BINARY_NAME} STATIC ${SRC})
680	endif()
681
682	add_dependencies(${BINARY_NAME} version-info)
683	set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
684
685	target_link_libraries(${BINARY_NAME} ${DEBUGGER_LIB} ${DEPENDENCY_LIB} ${OS_LIB})
686	install(TARGETS ${BINARY_NAME} LIBRARY DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME} NAMELINK_SKIP ARCHIVE DESTINATION ${LIBDIR} RUNTIME DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
687	if(UNIX AND NOT APPLE)
688		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-16.png DESTINATION share/icons/hicolor/16x16/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
689		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-24.png DESTINATION share/icons/hicolor/24x24/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
690		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-32.png DESTINATION share/icons/hicolor/32x32/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
691		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-48.png DESTINATION share/icons/hicolor/48x48/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
692		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-64.png DESTINATION share/icons/hicolor/64x64/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
693		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-96.png DESTINATION share/icons/hicolor/96x96/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
694		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-128.png DESTINATION share/icons/hicolor/128x128/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
695		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-256.png DESTINATION share/icons/hicolor/256x256/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
696		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-512.png DESTINATION share/icons/hicolor/512x512/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
697	endif()
698else()
699	set(BUILD_SHARED OFF)
700	set(BUILD_STATIC OFF)
701	find_library(${BINARY_NAME} ${BINARY_NAME})
702	if(NOT ${BINARY_NAME}_FOUND)
703		set(DISABLE_FRONTENDS ON)
704		set(BUILD_PERF OFF)
705		set(BUILD_TEST OFF)
706		set(BUILD_SUITE OFF)
707	endif()
708endif()
709
710if(BUILD_GL)
711	add_definitions(-DBUILD_GL)
712endif()
713
714if(BUILD_GLES2)
715	add_definitions(-DBUILD_GLES2)
716endif()
717
718if(DISABLE_FRONTENDS)
719	set(BUILD_SDL OFF)
720	set(BUILD_QT OFF)
721endif()
722
723if(BUILD_LIBRETRO)
724	file(GLOB RETRO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/libretro/*.c)
725	add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
726	set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5;DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=2")
727	target_link_libraries(${BINARY_NAME}_libretro ${OS_LIB})
728	install(TARGETS ${BINARY_NAME}_libretro LIBRARY DESTINATION ${LIBRETRO_LIBDIR} COMPONENT ${BINARY_NAME}_libretro NAMELINK_SKIP)
729endif()
730
731if(BUILD_OPENEMU)
732	find_library(FOUNDATION Foundation)
733	find_library(OPENEMUBASE OpenEmuBase)
734	file(GLOB OE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/*.m)
735	add_library(${BINARY_NAME}-openemu MODULE ${CORE_SRC} ${OE_SRC})
736	set_target_properties(${BINARY_NAME}-openemu PROPERTIES
737		MACOSX_BUNDLE_INFO_PLIST ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/Info.plist.in
738		BUNDLE TRUE
739		BUNDLE_EXTENSION oecoreplugin
740		OUTPUT_NAME ${PROJECT_NAME}
741		COMPILE_DEFINITIONS "DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=1")
742	target_link_libraries(${BINARY_NAME}-openemu ${OS_LIB} ${FOUNDATION} ${OPENEMUBASE})
743	install(TARGETS ${BINARY_NAME}-openemu LIBRARY DESTINATION ${OE_LIBDIR} COMPONENT ${BINARY_NAME}.oecoreplugin NAMELINK_SKIP)
744endif()
745
746if(BUILD_SDL)
747	add_definitions(-DBUILD_SDL)
748	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/sdl ${CMAKE_CURRENT_BINARY_DIR}/sdl)
749endif()
750
751if(BUILD_QT)
752	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/qt ${CMAKE_CURRENT_BINARY_DIR}/qt)
753endif()
754
755if(BUILD_PERF)
756	set(PERF_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/perf-main.c ${CLI_SRC})
757	if(UNIX AND NOT APPLE)
758		list(APPEND PERF_LIB rt)
759	endif()
760
761	add_executable(${BINARY_NAME}-perf ${PERF_SRC})
762	target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB} ${OS_LIB})
763	set_target_properties(${BINARY_NAME}-perf PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
764	install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
765	install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
766endif()
767
768if(BUILD_TEST)
769	add_executable(${BINARY_NAME}-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/fuzz-main.c)
770	target_link_libraries(${BINARY_NAME}-fuzz ${BINARY_NAME})
771	set_target_properties(${BINARY_NAME}-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
772	add_executable(tbl-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/tbl-fuzz-main.c)
773	target_link_libraries(tbl-fuzz ${BINARY_NAME})
774	set_target_properties(tbl-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
775	install(TARGETS ${BINARY_NAME}-fuzz tbl-fuzz DESTINATION bin COMPONENT ${BINARY_NAME}-test)
776endif()
777
778if(NOT USE_CMOCKA)
779	set(BUILD_SUITE OFF)
780endif()
781if(BUILD_SUITE)
782	enable_testing()
783	include_directories(AFTER ${CMOCKA_INCLUDE_DIRS})
784	link_directories(${CMOCKA_LIBRARY_DIRS})
785
786	add_executable(${BINARY_NAME}-suite ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/suite-main.c ${TEST_SRC})
787	target_link_libraries(${BINARY_NAME}-suite ${BINARY_NAME} ${PLATFORM_LIBRARY} cmocka)
788	set_target_properties(${BINARY_NAME}-suite PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
789	add_test(${BINARY_NAME}-suite ${BINARY_NAME}-suite)
790endif()
791
792if(BUILD_PYTHON)
793	enable_testing()
794	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/python ${CMAKE_CURRENT_BINARY_DIR}/python)
795endif()
796
797if(BUILD_EXAMPLE)
798	add_executable(${BINARY_NAME}-example-server ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/server.c)
799	target_link_libraries(${BINARY_NAME}-example-server ${BINARY_NAME})
800	set_target_properties(${BINARY_NAME}-example-server PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
801
802	if(BUILD_SDL)
803		add_executable(${BINARY_NAME}-example-client ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/client.c)
804		target_link_libraries(${BINARY_NAME}-example-client ${BINARY_NAME} ${SDL_LIBRARY} ${SDLMAIN_LIBRARY} ${OPENGL_LIBRARY} ${OPENGLES2_LIBRARY})
805		set_target_properties(${BINARY_NAME}-example-client PROPERTIES
806		                      COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}"
807		                      INCLUDE_DIRECTORIES "${SDL_INCLUDE_DIR};${CMAKE_CURRENT_SOURCE_DIR}/src;${CMAKE_CURRENT_SOURCE_DIR}/include")
808	endif()
809endif()
810
811# Packaging
812set(CPACK_PACKAGE_VERSION ${VERSION_STRING})
813set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
814set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
815set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
816set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
817set(CPACK_RESOURCE_FILE_README ${CMAKE_CURRENT_SOURCE_DIR}/README.md)
818
819set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
820set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
821set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
822set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README.md")
823set(CPACK_DEBIAN_PACKAGE_SECTION "games")
824
825SET(CPACK_DEB_COMPONENT_INSTALL ON)
826
827set(CPACK_STRIP_FILES ${BINARY_NAME})
828
829install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/README.md ${CMAKE_CURRENT_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
830
831include(CPack)
832
833# Summaries
834set(SUMMARY_GL_LIST)
835if(USE_EPOXY)
836	set(SUMMARY_GL_LIST "libepoxy")
837else()
838	if(BUILD_GL)
839		list(APPEND SUMMARY_GL_LIST "OpenGL")
840	endif()
841	if(BUILD_GLES2)
842		list(APPEND SUMMARY_GL_LIST "OpenGL|ES 2")
843	endif()
844endif()
845if(NOT SUMMARY_GL_LIST)
846	set(SUMMARY_GL OFF)
847else()
848	string(REPLACE ";" ", " SUMMARY_GL "${SUMMARY_GL_LIST}")
849endif()
850if(USE_LIBZIP)
851	set(SUMMARY_ZIP libzip)
852elseif(USE_MINIZIP)
853	set(SUMMARY_ZIP "minizip (external)")
854elseif(USE_ZLIB)
855	set(SUMMARY_ZIP "minizip (included)")
856else()
857	set(SUMMARY_ZIP OFF)
858endif()
859
860if(NOT QUIET)
861	message(STATUS "Platforms:")
862	message(STATUS "	Game Boy Advance: ${M_CORE_GBA}")
863	message(STATUS "	Game Boy: ${M_CORE_GB}")
864	message(STATUS "Features:")
865	message(STATUS "	Debuggers: ${USE_DEBUGGERS}")
866	message(STATUS "	CLI debugger: ${USE_EDITLINE}")
867	message(STATUS "	GDB stub: ${USE_GDB_STUB}")
868	message(STATUS "	Video recording: ${USE_FFMPEG}")
869	message(STATUS "	GIF recording: ${USE_MAGICK}")
870	message(STATUS "	Screenshot/advanced savestate support: ${USE_PNG}")
871	message(STATUS "	ZIP support: ${SUMMARY_ZIP}")
872	message(STATUS "	7-Zip support: ${USE_LZMA}")
873	message(STATUS "	SQLite3 game database: ${USE_SQLITE3}")
874	message(STATUS "	OpenGL support: ${SUMMARY_GL}")
875	message(STATUS "Frontends:")
876	message(STATUS "	Qt: ${BUILD_QT}")
877	message(STATUS "	SDL (${SDL_VERSION}): ${BUILD_SDL}")
878	message(STATUS "	Profiling: ${BUILD_PERF}")
879	message(STATUS "	Test harness: ${BUILD_TEST}")
880	message(STATUS "	Test suite: ${BUILD_SUITE}")
881	message(STATUS "	Python bindings: ${BUILD_PYTHON}")
882	message(STATUS "	Examples: ${BUILD_EXAMPLE}")
883	message(STATUS "Cores:")
884	message(STATUS "	Libretro core: ${BUILD_LIBRETRO}")
885	if(APPLE)
886		message(STATUS "	OpenEmu core: ${BUILD_OPENEMU}")
887	endif()
888	message(STATUS "Libraries:")
889	message(STATUS "	Static: ${BUILD_STATIC}")
890	message(STATUS "	Shared: ${BUILD_SHARED}")
891endif()