1cmake_minimum_required(VERSION 2.8.11)
  2enable_language(CXX)
  3
  4set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++11")
  5
  6if(APPLE)
  7	set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mmacosx-version-min=10.7")
  8	if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
  9		set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -stdlib=libc++")
 10	endif()
 11endif()
 12
 13set(PLATFORM_SRC)
 14set(QT_STATIC OFF)
 15
 16if(BUILD_SDL)
 17	if(NOT SDL_FOUND AND NOT SDL2_FOUND)
 18		find_package(SDL 1.2 REQUIRED)
 19	endif()
 20	if(SDL2_FOUND)
 21		link_directories(${SDL2_LIBDIR})
 22	endif()
 23	list(APPEND PLATFORM_LIBRARY ${SDL_LIBRARY} ${SDLMAIN_LIBRARY})
 24	list(APPEND PLATFORM_SRC ${PLATFORM_SRC} ${CMAKE_SOURCE_DIR}/src/platform/sdl/sdl-events.c ${CMAKE_SOURCE_DIR}/src/platform/sdl/sdl-audio.c)
 25	include_directories(${SDL_INCLUDE_DIR} ${CMAKE_SOURCE_DIR}/src/platform/sdl)
 26endif()
 27
 28set(CMAKE_AUTOMOC ON)
 29set(CMAKE_INCLUDE_CURRENT_DIR ON)
 30
 31find_package(Qt5Multimedia)
 32find_package(Qt5OpenGL)
 33find_package(Qt5Widgets)
 34
 35if(NOT Qt5OpenGL_FOUND OR NOT Qt5Widgets_FOUND OR NOT OPENGL_FOUND)
 36	message(WARNING "Cannot find Qt modules")
 37	set(BUILD_QT OFF PARENT_SCOPE)
 38	return()
 39endif()
 40
 41list(APPEND PLATFORM_SRC ${PLATFORM_SRC} ${CMAKE_SOURCE_DIR}/src/platform/opengl/gl.c)
 42
 43get_target_property(QT_TYPE Qt5::Core TYPE)
 44if(QT_TYPE STREQUAL STATIC_LIBRARY)
 45	set(QT_STATIC ON)
 46	add_definitions(-DQT_STATIC)
 47endif()
 48
 49set(SOURCE_FILES
 50	AudioProcessor.cpp
 51	CheatsModel.cpp
 52	CheatsView.cpp
 53	ConfigController.cpp
 54	Display.cpp
 55	DisplayGL.cpp
 56	DisplayQt.cpp
 57	GBAApp.cpp
 58	GBAKeyEditor.cpp
 59	GIFView.cpp
 60	GameController.cpp
 61	GamepadAxisEvent.cpp
 62	GamepadButtonEvent.cpp
 63	InputController.cpp
 64	InputProfile.cpp
 65	KeyEditor.cpp
 66	LoadSaveState.cpp
 67	LogController.cpp
 68	LogView.cpp
 69	MemoryModel.cpp
 70	MemoryView.cpp
 71	MessagePainter.cpp
 72	MultiplayerController.cpp
 73	OverrideView.cpp
 74	PaletteView.cpp
 75	SavestateButton.cpp
 76	SensorView.cpp
 77	SettingsView.cpp
 78	ShortcutController.cpp
 79	ShortcutView.cpp
 80	Swatch.cpp
 81	Window.cpp
 82	VFileDevice.cpp
 83	VideoView.cpp)
 84
 85qt5_wrap_ui(UI_FILES
 86	CheatsView.ui
 87	GIFView.ui
 88	LoadSaveState.ui
 89	LogView.ui
 90	MemoryView.ui
 91	OverrideView.ui
 92	PaletteView.ui
 93	SensorView.ui
 94	SettingsView.ui
 95	ShortcutView.ui
 96	VideoView.ui)
 97
 98set(QT_LIBRARIES)
 99set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libqt5widgets5,libqt5opengl5")
100
101set(AUDIO_SRC)
102if(BUILD_SDL)
103	list(APPEND AUDIO_SRC AudioProcessorSDL.cpp)
104endif()
105
106if(Qt5Multimedia_FOUND)
107	list(APPEND AUDIO_SRC
108		AudioProcessorQt.cpp
109		AudioDevice.cpp)
110	if (WIN32 AND QT_STATIC)
111		list(APPEND QT_LIBRARIES qtaudio_windows strmiids winmm)
112	endif()
113	list(APPEND QT_LIBRARIES Qt5::Multimedia)
114	add_definitions(-DBUILD_QT_MULTIMEDIA)
115	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libqt5multimedia5")
116endif()
117
118if(NOT AUDIO_SRC)
119	message(WARNING "No supported audio modules found")
120	set(BUILD_QT OFF PARENT_SCOPE)
121	return()
122endif()
123
124if(USE_GDB_STUB)
125	list(APPEND PLATFORM_SRC GDBController.cpp GDBWindow.cpp)
126endif()
127set(MACOSX_BUNDLE_ICON_FILE mgba.icns)
128set(MACOSX_BUNDLE_BUNDLE_VERSION ${LIB_VERSION_STRING})
129set(MACOSX_BUNDLE_BUNDLE_NAME ${PROJECT_NAME})
130set(MACOSX_BUNDLE_GUI_IDENTIFIER com.endrift.${BINARY_NAME}-qt)
131set_source_files_properties(${CMAKE_SOURCE_DIR}/res/mgba.icns PROPERTIES MACOSX_PACKAGE_LOCATION Resources)
132
133qt5_add_resources(RESOURCES resources.qrc)
134if(WIN32)
135	configure_file(${CMAKE_SOURCE_DIR}/res/mgba.rc.in ${CMAKE_BINARY_DIR}/res/mgba.rc)
136	list(APPEND RESOURCES ${CMAKE_BINARY_DIR}/res/mgba.rc)
137	if(QT_STATIC)
138		list(APPEND QT_LIBRARIES qwindows imm32)
139	endif()
140endif()
141add_executable(${BINARY_NAME}-qt WIN32 MACOSX_BUNDLE main.cpp ${CMAKE_SOURCE_DIR}/res/mgba.icns ${SOURCE_FILES} ${PLATFORM_SRC} ${UI_FILES} ${AUDIO_SRC} ${RESOURCES})
142set_target_properties(${BINARY_NAME}-qt PROPERTIES MACOSX_BUNDLE_INFO_PLIST ${CMAKE_SOURCE_DIR}/res/info.plist.in COMPILE_DEFINITIONS "${FEATURE_DEFINES}")
143
144list(APPEND QT_LIBRARIES Qt5::Widgets Qt5::OpenGL)
145target_link_libraries(${BINARY_NAME}-qt ${PLATFORM_LIBRARY} ${OPENGL_LIBRARY} ${BINARY_NAME} ${QT_LIBRARIES})
146set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS}" PARENT_SCOPE)
147
148install(TARGETS ${BINARY_NAME}-qt
149	RUNTIME DESTINATION bin COMPONENT ${BINARY_NAME}-qt
150	BUNDLE DESTINATION Applications COMPONENT ${BINARY_NAME}-qt)
151if(UNIX AND NOT APPLE)
152	find_program(DESKTOP_FILE_INSTALL desktop-file-install)
153	if(DESKTOP_FILE_INSTALL)
154		install(CODE "execute_process(COMMAND ${DESKTOP_FILE_INSTALL} \"${CMAKE_SOURCE_DIR}/res/mgba-qt.desktop\" --dir \"$ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/share/applications/\")")
155	endif()
156endif()
157if(APPLE OR WIN32)
158	set_target_properties(${BINARY_NAME}-qt PROPERTIES OUTPUT_NAME ${PROJECT_NAME})
159endif()
160if(APPLE)
161	set(DEPLOY_OPTIONS -p platforms/libqcocoa.dylib,audio/libqtaudio_coreaudio.dylib)
162	if(NOT CMAKE_INSTALL_NAME_TOOL EQUAL "install_name_tool")
163		set(DEPLOY_OPTIONS ${DEPLOY_OPTIONS} -I ${CMAKE_INSTALL_NAME_TOOL})
164	endif()
165	if(DEFINED CMAKE_OTOOL AND NOT CMAKE_OTOOL EQUAL "otool")
166		set(DEPLOY_OPTIONS ${DEPLOY_OPTIONS} -O ${CMAKE_OTOOL})
167	endif()
168	if(DEFINED CROSS_ROOT)
169		set(DEPLOY_OPTIONS ${DEPLOY_OPTIONS} -R ${CROSS_ROOT})
170	endif()
171	add_custom_command(TARGET ${BINARY_NAME}-qt POST_BUILD COMMAND ${CMAKE_SOURCE_DIR}/tools/deploy-mac.py ${DEPLOY_OPTIONS} ${PROJECT_NAME}.app)
172endif()