1cmake_minimum_required(VERSION 2.8.11)
  2enable_language(CXX)
  3
  4set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++11")
  5
  6if(APPLE)
  7	set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mmacosx-version-min=10.7")
  8	if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
  9		set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -stdlib=libc++")
 10	endif()
 11endif()
 12
 13set(PLATFORM_SRC)
 14set(QT_STATIC OFF)
 15
 16if(BUILD_SDL)
 17	if(NOT SDL_FOUND AND NOT SDL2_FOUND)
 18		find_package(SDL 1.2 REQUIRED)
 19	endif()
 20	if(SDL2_FOUND)
 21		link_directories(${SDL2_LIBDIR})
 22	endif()
 23	list(APPEND PLATFORM_LIBRARY ${SDL_LIBRARY} ${SDLMAIN_LIBRARY})
 24	list(APPEND PLATFORM_SRC ${PLATFORM_SRC} ${CMAKE_SOURCE_DIR}/src/platform/sdl/sdl-events.c ${CMAKE_SOURCE_DIR}/src/platform/sdl/sdl-audio.c)
 25	include_directories(${SDL_INCLUDE_DIR} ${CMAKE_SOURCE_DIR}/src/platform/sdl)
 26endif()
 27
 28set(CMAKE_AUTOMOC ON)
 29set(CMAKE_INCLUDE_CURRENT_DIR ON)
 30
 31if(NOT WIN32 OR NOT BUILD_SDL)
 32	find_package(Qt5Multimedia)
 33endif()
 34find_package(Qt5OpenGL)
 35find_package(Qt5Widgets)
 36
 37if(NOT BUILD_GL AND NOT BUILD_GLES2)
 38	message(WARNING "OpenGL is required to build the Qt port")
 39	set(BUILD_QT OFF PARENT_SCOPE)
 40	return()
 41endif()
 42
 43if(NOT Qt5OpenGL_FOUND OR NOT Qt5Widgets_FOUND)
 44	message(WARNING "Cannot find Qt modules")
 45	set(BUILD_QT OFF PARENT_SCOPE)
 46	return()
 47endif()
 48
 49if(BUILD_GL)
 50	list(APPEND PLATFORM_SRC ${CMAKE_SOURCE_DIR}/src/platform/opengl/gl.c)
 51	if(NOT WIN32 OR USE_EPOXY)
 52		list(APPEND PLATFORM_SRC ${CMAKE_SOURCE_DIR}/src/platform/opengl/gles2.c)
 53	endif()
 54endif()
 55
 56if(BUILD_GLES2)
 57	list(APPEND PLATFORM_SRC ${CMAKE_SOURCE_DIR}/src/platform/opengl/gles2.c)
 58endif()
 59
 60get_target_property(QT_TYPE Qt5::Core TYPE)
 61if(QT_TYPE STREQUAL STATIC_LIBRARY)
 62	set(QT_STATIC ON)
 63	list(APPEND QT_DEFINES QT_STATIC)
 64endif()
 65
 66set(SOURCE_FILES
 67	AboutScreen.cpp
 68	AudioProcessor.cpp
 69	CheatsModel.cpp
 70	CheatsView.cpp
 71	ConfigController.cpp
 72	Display.cpp
 73	DisplayGL.cpp
 74	DisplayQt.cpp
 75	GBAApp.cpp
 76	GBAKeyEditor.cpp
 77	GIFView.cpp
 78	GameController.cpp
 79	GamepadAxisEvent.cpp
 80	GamepadButtonEvent.cpp
 81	IOViewer.cpp
 82	InputController.cpp
 83	InputProfile.cpp
 84	KeyEditor.cpp
 85	LoadSaveState.cpp
 86	LogController.cpp
 87	LogView.cpp
 88	MemoryModel.cpp
 89	MemoryView.cpp
 90	MessagePainter.cpp
 91	MultiplayerController.cpp
 92	OverrideView.cpp
 93	PaletteView.cpp
 94	SavestateButton.cpp
 95	SensorView.cpp
 96	SettingsView.cpp
 97	ShaderSelector.cpp
 98	ShortcutController.cpp
 99	ShortcutView.cpp
100	Swatch.cpp
101	Window.cpp
102	VFileDevice.cpp
103	VideoView.cpp)
104
105qt5_wrap_ui(UI_FILES
106	AboutScreen.ui
107	CheatsView.ui
108	GIFView.ui
109	IOViewer.ui
110	LoadSaveState.ui
111	LogView.ui
112	MemoryView.ui
113	OverrideView.ui
114	PaletteView.ui
115	SensorView.ui
116	SettingsView.ui
117	ShaderSelector.ui
118	ShortcutView.ui
119	VideoView.ui)
120
121set(QT_LIBRARIES)
122set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libqt5widgets5,libqt5opengl5")
123
124set(AUDIO_SRC)
125if(BUILD_SDL)
126	list(APPEND AUDIO_SRC AudioProcessorSDL.cpp)
127endif()
128
129set(QT_DEFINES)
130if(Qt5Multimedia_FOUND)
131	list(APPEND AUDIO_SRC
132		AudioProcessorQt.cpp
133		AudioDevice.cpp)
134	if (WIN32 AND QT_STATIC)
135		list(APPEND QT_LIBRARIES qtaudio_windows strmiids winmm)
136	endif()
137	list(APPEND QT_LIBRARIES Qt5::Multimedia)
138	list(APPEND QT_DEFINES BUILD_QT_MULTIMEDIA)
139	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libqt5multimedia5")
140endif()
141
142if(NOT AUDIO_SRC)
143	message(WARNING "No supported audio modules found")
144	set(BUILD_QT OFF PARENT_SCOPE)
145	return()
146endif()
147
148if(USE_GDB_STUB)
149	list(APPEND PLATFORM_SRC GDBController.cpp GDBWindow.cpp)
150endif()
151set(MACOSX_BUNDLE_ICON_FILE mgba.icns)
152set(MACOSX_BUNDLE_BUNDLE_VERSION ${LIB_VERSION_STRING})
153set(MACOSX_BUNDLE_BUNDLE_NAME ${PROJECT_NAME})
154set(MACOSX_BUNDLE_GUI_IDENTIFIER com.endrift.${BINARY_NAME}-qt)
155set_source_files_properties(${CMAKE_SOURCE_DIR}/res/mgba.icns PROPERTIES MACOSX_PACKAGE_LOCATION Resources)
156
157qt5_add_resources(RESOURCES resources.qrc)
158if(WIN32)
159	configure_file(${CMAKE_SOURCE_DIR}/res/mgba.rc.in ${CMAKE_BINARY_DIR}/res/mgba.rc)
160	list(APPEND RESOURCES ${CMAKE_BINARY_DIR}/res/mgba.rc)
161	if(QT_STATIC)
162		list(APPEND QT_LIBRARIES qwindows imm32)
163	endif()
164endif()
165if(APPLE)
166	set(SHADER_DIR Applications/${PROJECT_NAME}.app/Contents/Resources)
167else()
168	set(SHADER_DIR ${CMAKE_INSTALL_DATADIR}/${BINARY_NAME})
169endif()
170install(DIRECTORY ${CMAKE_SOURCE_DIR}/res/shaders DESTINATION ${SHADER_DIR} COMPONENT ${BINARY_NAME}-qt)
171if(NOT WIN32 AND NOT APPLE)
172	list(APPEND QT_DEFINES QT_SHADER_DIR="${SHADER_DIR}/shaders")
173endif()
174
175add_executable(${BINARY_NAME}-qt WIN32 MACOSX_BUNDLE main.cpp ${CMAKE_SOURCE_DIR}/res/mgba.icns ${SOURCE_FILES} ${PLATFORM_SRC} ${UI_FILES} ${AUDIO_SRC} ${RESOURCES})
176set_target_properties(${BINARY_NAME}-qt PROPERTIES MACOSX_BUNDLE_INFO_PLIST ${CMAKE_SOURCE_DIR}/res/info.plist.in COMPILE_DEFINITIONS "${FEATURE_DEFINES};${FUNCTION_DEFINES};${OS_DEFINES};${QT_DEFINES}")
177
178list(APPEND QT_LIBRARIES Qt5::Widgets Qt5::OpenGL)
179target_link_libraries(${BINARY_NAME}-qt ${PLATFORM_LIBRARY} ${BINARY_NAME} ${QT_LIBRARIES} ${OPENGL_LIBRARY} ${OPENGLES2_LIBRARY})
180set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS}" PARENT_SCOPE)
181
182install(TARGETS ${BINARY_NAME}-qt
183	RUNTIME DESTINATION bin COMPONENT ${BINARY_NAME}-qt
184	BUNDLE DESTINATION Applications COMPONENT ${BINARY_NAME}-qt)
185if(UNIX AND NOT APPLE)
186	find_program(DESKTOP_FILE_INSTALL desktop-file-install)
187	if(DESKTOP_FILE_INSTALL)
188		install(CODE "execute_process(COMMAND ${DESKTOP_FILE_INSTALL} \"${CMAKE_SOURCE_DIR}/res/mgba-qt.desktop\" --dir \"\$ENV{DESTDIR}\${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_DATADIR}/applications/\")")
189	endif()
190endif()
191if(UNIX)
192	install(FILES ${CMAKE_SOURCE_DIR}/doc/mgba-qt.6 DESTINATION ${MANDIR}/man6 COMPONENT ${BINARY_NAME}-qt)
193endif()
194if(APPLE OR WIN32)
195	set_target_properties(${BINARY_NAME}-qt PROPERTIES OUTPUT_NAME ${PROJECT_NAME})
196endif()
197if(APPLE)
198	set(DEPLOY_OPTIONS -p platforms/libqcocoa.dylib,audio/libqtaudio_coreaudio.dylib)
199	if(NOT CMAKE_INSTALL_NAME_TOOL EQUAL "install_name_tool")
200		set(DEPLOY_OPTIONS ${DEPLOY_OPTIONS} -I ${CMAKE_INSTALL_NAME_TOOL})
201	endif()
202	if(DEFINED CMAKE_OTOOL AND NOT CMAKE_OTOOL EQUAL "otool")
203		set(DEPLOY_OPTIONS ${DEPLOY_OPTIONS} -O ${CMAKE_OTOOL})
204	endif()
205	if(DEFINED CROSS_ROOT)
206		set(DEPLOY_OPTIONS ${DEPLOY_OPTIONS} -R ${CROSS_ROOT})
207	endif()
208	add_custom_command(TARGET ${BINARY_NAME}-qt POST_BUILD COMMAND ${CMAKE_SOURCE_DIR}/tools/deploy-mac.py ${DEPLOY_OPTIONS} ${PROJECT_NAME}.app)
209endif()