1set(USE_VFS_3DS ON CACHE BOOL "Use 3DS-specific file support")
  2mark_as_advanced(USE_VFS_3DS)
  3
  4find_program(3DSLINK 3dslink)
  5find_program(3DSXTOOL 3dsxtool)
  6find_program(BANNERTOOL bannertool)
  7find_program(MAKEROM makerom)
  8find_program(PICASSO picasso)
  9find_program(RAW2C raw2c)
 10find_program(STRIP ${cross_prefix}strip)
 11
 12set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-format" PARENT_SCOPE)
 13set(OS_DEFINES COLOR_16_BIT COLOR_5_6_5 IOAPI_NO_64)
 14
 15include_directories(${CMAKE_CURRENT_BINARY_DIR})
 16list(APPEND OS_LIB citro3d ctru)
 17file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/3ds-*.c ${CMAKE_CURRENT_SOURCE_DIR}/ctru-heap.c ${CMAKE_CURRENT_SOURCE_DIR}/socket.c)
 18set(OS_SRC ${OS_SRC} PARENT_SCOPE)
 19set(OS_LIB ${OS_LIB} PARENT_SCOPE)
 20source_group("3DS-specific code" FILES ${OS_SRC})
 21
 22if(USE_VFS_3DS)
 23	list(APPEND OS_DEFINES USE_VFS_3DS)
 24else()
 25	list(APPEND OS_DEFINES USE_VFS_FILE)
 26	list(APPEND CORE_VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-file.c ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
 27endif()
 28set(CORE_VFS_SRC ${CORE_VFS_SRC} PARENT_SCOPE)
 29set(OS_DEFINES ${OS_DEFINES} PARENT_SCOPE)
 30
 31list(APPEND GUI_SRC
 32	${CMAKE_CURRENT_BINARY_DIR}/icons.c
 33	${CMAKE_CURRENT_BINARY_DIR}/uishader.c
 34	${CMAKE_CURRENT_BINARY_DIR}/uishader.h
 35	${CMAKE_CURRENT_BINARY_DIR}/uishader.shbin.h
 36
 37	${CMAKE_CURRENT_SOURCE_DIR}/gui-font.c
 38	${CMAKE_CURRENT_SOURCE_DIR}/ctr-gpu.c
 39	${CMAKE_CURRENT_SOURCE_DIR}/ctr-gpu.h)
 40
 41set_source_files_properties(
 42	${CMAKE_CURRENT_BINARY_DIR}/icons.c
 43	${CMAKE_CURRENT_BINARY_DIR}/uishader.c
 44	${CMAKE_CURRENT_BINARY_DIR}/uishader.h
 45	${CMAKE_CURRENT_BINARY_DIR}/uishader.shbin.h
 46	PROPERTIES GENERATED ON)
 47
 48add_executable(${BINARY_NAME}.elf ${GUI_SRC} main.c)
 49set_target_properties(${BINARY_NAME}.elf PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
 50target_link_libraries(${BINARY_NAME}.elf ${BINARY_NAME} ${M_LIBRARY} ${OS_LIB})
 51
 52add_custom_command(OUTPUT ${BINARY_NAME}.smdh
 53                   COMMAND ${BANNERTOOL} makesmdh -s "${PROJECT_NAME}" -l "${SUMMARY}" -p "endrift" -i ${CMAKE_SOURCE_DIR}/res/mgba-48.png -o ${BINARY_NAME}.smdh
 54                   DEPENDS ${CMAKE_SOURCE_DIR}/res/mgba-48.png)
 55
 56add_custom_command(OUTPUT ${BINARY_NAME}.bnr
 57                   COMMAND ${BANNERTOOL} makebanner -ci ${CMAKE_CURRENT_SOURCE_DIR}/banner.cgfx -a ${CMAKE_CURRENT_SOURCE_DIR}/bios.wav -o ${BINARY_NAME}.bnr
 58                   DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/banner.cgfx ${CMAKE_CURRENT_SOURCE_DIR}/bios.wav)
 59
 60add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/icons.c
 61                   COMMAND ${RAW2C} ${CMAKE_SOURCE_DIR}/src/platform/3ds/icons.raw
 62                   DEPENDS ${CMAKE_SOURCE_DIR}/src/platform/3ds/icons.raw)
 63
 64add_custom_command(
 65	OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/uishader.shbin ${CMAKE_CURRENT_BINARY_DIR}/uishader.shbin.h
 66	DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/uishader.v.pica ${CMAKE_CURRENT_SOURCE_DIR}/uishader.g.pica
 67	COMMAND ${PICASSO}
 68		-o ${CMAKE_CURRENT_BINARY_DIR}/uishader.shbin
 69		-h ${CMAKE_CURRENT_BINARY_DIR}/uishader.shbin.h
 70		${CMAKE_CURRENT_SOURCE_DIR}/uishader.v.pica
 71		${CMAKE_CURRENT_SOURCE_DIR}/uishader.g.pica
 72	COMMENT "picasso uishader.shbin")
 73
 74add_custom_command(
 75	OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/uishader.c ${CMAKE_CURRENT_BINARY_DIR}/uishader.h
 76	MAIN_DEPENDENCY ${CMAKE_CURRENT_BINARY_DIR}/uishader.shbin
 77	COMMAND ${RAW2C} ${CMAKE_CURRENT_BINARY_DIR}/uishader.shbin
 78	WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
 79	COMMENT "raw2c uishader.shbin")
 80
 81add_custom_command(OUTPUT ${BINARY_NAME}.3dsx
 82                   COMMAND ${3DSXTOOL} ${BINARY_NAME}.elf ${BINARY_NAME}.3dsx --smdh=${BINARY_NAME}.smdh
 83                   DEPENDS ${BINARY_NAME}.elf ${BINARY_NAME}.smdh)
 84add_custom_target(${BINARY_NAME}.3dsx ALL DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${BINARY_NAME}.3dsx)
 85
 86add_custom_command(OUTPUT ${BINARY_NAME}.cia
 87                   COMMAND ${STRIP} -o ${BINARY_NAME}-stripped.elf ${BINARY_NAME}.elf
 88                   COMMAND ${MAKEROM} -f cia -o ${BINARY_NAME}.cia -rsf cia.rsf -target t -exefslogo -elf ${BINARY_NAME}-stripped.elf -icon ${BINARY_NAME}.smdh -banner ${BINARY_NAME}.bnr -major ${LIB_VERSION_MAJOR} -minor ${LIB_VERSION_MINOR} -micro ${LIB_VERSION_PATCH}
 89                   DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/cia.rsf ${BINARY_NAME}.elf ${BINARY_NAME}.smdh ${BINARY_NAME}.bnr)
 90add_custom_target(${BINARY_NAME}.cia ALL DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${BINARY_NAME}.cia)
 91
 92add_custom_target(run ${3DSLINK} ${CMAKE_CURRENT_BINARY_DIR}/${BINARY_NAME}.3dsx
 93                  DEPENDS ${BINARY_NAME}.3dsx)
 94
 95add_custom_target(install-cia stat -f '0 00000001 %016Xz' '${CMAKE_CURRENT_BINARY_DIR}/${BINARY_NAME}.cia' | xxd -r | cat -- - '${CMAKE_CURRENT_BINARY_DIR}/${BINARY_NAME}.cia' | nc $ENV{N3DS_IP} 5000
 96                  DEPENDS ${BINARY_NAME}.cia)
 97
 98if(BUILD_PERF)
 99	add_custom_target(${BINARY_NAME}-perf.3dsx ALL
100	                  ${3DSXTOOL} ../${BINARY_NAME}-perf ${BINARY_NAME}-perf.3dsx --smdh=${BINARY_NAME}.smdh
101	                  DEPENDS ${BINARY_NAME}-perf ${BINARY_NAME}.smdh)
102	install(FILES
103		    ${CMAKE_CURRENT_BINARY_DIR}/${BINARY_NAME}-perf.3dsx
104		    DESTINATION . COMPONENT ${BINARY_NAME}-3ds)
105endif()
106
107configure_file(${CMAKE_CURRENT_SOURCE_DIR}/cia.rsf.in ${CMAKE_CURRENT_BINARY_DIR}/cia.rsf)
108install(FILES
109	    ${CMAKE_CURRENT_BINARY_DIR}/${BINARY_NAME}.3dsx
110	    ${CMAKE_CURRENT_BINARY_DIR}/${BINARY_NAME}.smdh
111	    ${CMAKE_CURRENT_BINARY_DIR}/${BINARY_NAME}.cia
112	    DESTINATION . COMPONENT ${BINARY_NAME}-3ds)