1cmake_minimum_required(VERSION 2.6)
  2project(mGBA C)
  3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
  4if(NOT MSVC)
  5	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wno-missing-field-initializers -std=c99")
  6else()
  7	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_CRT_SECURE_NO_WARNINGS /wd4003 /wd4244 /wd4146")
  8endif()
  9set(USE_DEBUGGERS ON CACHE BOOL "Whether or not to enable the debugging infrastructure")
 10set(USE_EDITLINE ON CACHE BOOL "Whether or not to enable the CLI-mode debugger")
 11set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
 12set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
 13set(USE_ZLIB ON CACHE BOOL "Whether or not to enable zlib support")
 14set(USE_MINIZIP ON CACHE BOOL "Whether or not to enable external minizip support")
 15set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
 16set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable LIBZIP support")
 17set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
 18set(USE_SQLITE3 ON CACHE BOOL "Whether or not to enable SQLite3 support")
 19set(M_CORE_GBA ON CACHE BOOL "Build Game Boy Advance core")
 20set(M_CORE_GB ON CACHE BOOL "Build Game Boy core")
 21set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
 22set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
 23set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
 24set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
 25if(APPLE)
 26	set(BUILD_OPENEMU OFF CACHE BOOL "Build OpenEmu core")
 27endif()
 28set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
 29set(BUILD_TEST OFF CACHE BOOL "Build testing harness")
 30set(BUILD_SUITE OFF CACHE BOOL "Build test suite")
 31set(BUILD_EXAMPLE OFF CACHE BOOL "Build example frontends")
 32set(BUILD_PYTHON OFF CACHE BOOL "Build Python bindings")
 33set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
 34set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
 35set(SKIP_LIBRARY OFF CACHE BOOL "Skip building the library (useful for only building libretro or OpenEmu cores)")
 36set(BUILD_GL ON CACHE STRING "Build with OpenGL")
 37set(BUILD_GLES2 OFF CACHE STRING "Build with OpenGL|ES 2")
 38set(USE_EPOXY ON CACHE STRING "Build with libepoxy")
 39set(DISABLE_DEPS OFF CACHE BOOL "Build without dependencies")
 40file(GLOB ARM_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/*.c)
 41file(GLOB ARM_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/test/*.c)
 42file(GLOB LR35902_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/*.c)
 43file(GLOB LR35902_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/test/*.c)
 44file(GLOB GBA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/*.c)
 45file(GLOB GBA_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/test/*.c)
 46file(GLOB GB_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/*.c)
 47file(GLOB GB_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/test/*.c)
 48file(GLOB GBA_CHEATS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/cheats/*.c)
 49file(GLOB GBA_RR_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/rr/*.c)
 50file(GLOB CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/*.c)
 51file(GLOB CORE_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/test/*.c)
 52file(GLOB UTIL_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/*.[cSs])
 53file(GLOB UTIL_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/test/*.c)
 54file(GLOB GUI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/gui/*.c ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/gui/*.c)
 55file(GLOB GBA_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/renderers/*.c)
 56file(GLOB GBA_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/sio/lockstep.c)
 57file(GLOB GB_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/sio/lockstep.c)
 58file(GLOB GB_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/renderers/*.c)
 59file(GLOB THIRD_PARTY_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/inih/*.c)
 60set(CLI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/commandline.c)
 61set(CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-mem.c)
 62set(VFS_SRC)
 63source_group("ARM core" FILES ${ARM_SRC})
 64source_group("LR35902 core" FILES ${LR35902_SRC})
 65source_group("GBA board" FILES ${GBA_SRC} ${GBA_RENDERER_SRC} ${GBA_SIO_SRC})
 66source_group("GBA extra" FILES ${GBA_CHEATS_SRC} ${GBA_RR_SRC})
 67source_group("GB board" FILES ${GB_SRC} ${GB_SIO_SRC})
 68source_group("Utilities" FILES ${UTIL_SRC})
 69include_directories(BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/include ${CMAKE_CURRENT_SOURCE_DIR}/src)
 70
 71if(NOT CMAKE_BUILD_TYPE)
 72	set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
 73endif()
 74
 75include(GNUInstallDirs)
 76
 77set(LIBDIR "${CMAKE_INSTALL_LIBDIR}" CACHE PATH "Installed library directory")
 78mark_as_advanced(LIBDIR)
 79
 80if (BUILD_LIBRETRO)
 81	set(LIBRETRO_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (Libretro)")
 82	mark_as_advanced(LIBRETRO_LIBDIR)
 83endif()
 84
 85if (BUILD_OPENEMU)
 86	set(OE_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (OpenEmu)")
 87	mark_as_advanced(OE_LIBDIR)
 88endif()
 89
 90
 91set(CMAKE_INSTALL_RPATH "${LIBDIR}")
 92
 93if (NOT DEFINED MANDIR)
 94	set(MANDIR ${CMAKE_INSTALL_MANDIR})
 95endif()
 96
 97# Function definitions
 98include(FindPkgConfig)
 99function(find_feature FEATURE_NAME FEATURE_REQUIRES)
100	if (NOT ${FEATURE_NAME})
101		return()
102	endif()
103	if (DISABLE_DEPS)
104		set(${FEATURE_NAME} OFF PARENT_SCOPE)
105		return()
106	endif()
107	foreach(REQUIRE ${FEATURE_REQUIRES})
108		if(NOT ${REQUIRE}_FOUND)
109			find_package(${REQUIRE} QUIET)
110			if(NOT ${REQUIRE}_FOUND)
111				pkg_search_module(${REQUIRE} ${REQUIRE})
112				if (NOT ${REQUIRE}_FOUND)
113					message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
114					set(${FEATURE_NAME} OFF PARENT_SCOPE)
115					return()
116				endif()
117			endif()
118		endif()
119		string(TOUPPER ${REQUIRE} UREQUIRE)
120		set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
121		set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
122		set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
123		if (APPLE)
124			set(IS_FRAMEWORK OFF)
125			set(LIBS)
126			foreach(LIB IN LISTS ${REQUIRE}_LIBRARIES)
127				if(LIB STREQUAL "-framework")
128					set(IS_FRAMEWORK ON)
129				elseif(IS_FRAMEWORK)
130					list(APPEND LIBS "-framework ${LIB}")
131					set(IS_FRAMEWORK OFF)
132				else()
133					list(APPEND LIBS ${LIB})
134				endif()
135			endforeach()
136			set(${UREQUIRE}_LIBRARIES ${LIBS} PARENT_SCOPE)
137		else()
138			set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
139		endif()
140		set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
141		set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
142	endforeach()
143endfunction()
144
145# Version information
146add_custom_target(version-info ALL
147	COMMAND ${CMAKE_COMMAND}
148	-DBINARY_NAME=${BINARY_NAME}
149	-DCONFIG_FILE=${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in
150	-DOUT_FILE=${CMAKE_CURRENT_BINARY_DIR}/version.c
151	-P ${CMAKE_CURRENT_SOURCE_DIR}/version.cmake
152	WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
153
154include(${CMAKE_CURRENT_SOURCE_DIR}/version.cmake)
155configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in ${CMAKE_CURRENT_BINARY_DIR}/version.c)
156configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/flags.h.in ${CMAKE_CURRENT_BINARY_DIR}/flags.h)
157install(FILES ${CMAKE_CURRENT_BINARY_DIR}/flags.h DESTINATION include/mgba COMPONENT lib${BINARY_NAME})
158
159list(APPEND UTIL_SRC ${CMAKE_CURRENT_BINARY_DIR}/version.c)
160source_group("Generated sources" FILES ${CMAKE_CURRENT_BINARY_DIR}/version.c)
161
162# Advanced settings
163set(BUILD_LTO ON CACHE BOOL "Build with link-time optimization")
164set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
165set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
166set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
167mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
168set(PGO_PRE_FLAGS "-fprofile-generate=${PGO_DIR} -fprofile-arcs")
169set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
170
171if(BUILD_PGO AND NOT PGO_STAGE_2)
172	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
173	set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
174	set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
175elseif(BUILD_PGO AND PGO_STAGE_2)
176	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
177	set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
178	set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
179endif()
180
181# Platform support
182if(WIN32)
183	set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
184	add_definitions(-D_WIN32_WINNT=0x0600)
185	list(APPEND OS_LIB ws2_32 shlwapi)
186	list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/vfs-w32.c)
187	file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/*.c)
188	source_group("Windows-specific code" FILES ${OS_SRC})
189	if(MSVC)
190		add_definitions(-DNOMINMAX -DWIN32_LEAN_AND_MEAN)
191	endif()
192elseif(UNIX)
193	add_definitions(-DUSE_PTHREADS)
194
195	if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
196		add_definitions(-D_GNU_SOURCE)
197	endif()
198	if(NOT APPLE AND NOT HAIKU)
199		set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
200	endif()
201
202	list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
203	file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/posix/*.c)
204	source_group("POSIX-specific code" FILES ${OS_SRC})
205endif()
206
207if(APPLE)
208	add_definitions(-D_DARWIN_C_SOURCE)
209	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
210endif()
211
212if(NOT HAIKU AND NOT MSVC AND NOT PSP2)
213	set(M_LIBRARY m)
214endif()
215list(APPEND OS_LIB ${M_LIBRARY})
216
217if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
218	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
219	set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
220endif()
221
222if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
223	if(NOT BUILD_EGL)
224		add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
225	endif()
226endif()
227
228if(BUILD_RASPI)
229	set(BUILD_GL OFF CACHE BOOL "OpenGL not supported" FORCE)
230endif()
231
232if(BUILD_PANDORA)
233	add_definitions(-DBUILD_PANDORA)
234endif()
235
236if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
237	enable_language(ASM)
238endif()
239
240if(PSP2 OR WII)
241	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-format")
242endif()
243
244if(DEFINED 3DS OR DEFINED PSP2 OR DEFINED WII)
245	set(USE_DEBUGGERS OFF)
246endif()
247
248if(NOT M_CORE_GBA)
249	set(USE_GDB_STUB OFF)
250endif()
251
252if(NOT USE_DEBUGGERS)
253	set(USE_EDITLINE OFF)
254	set(USE_GDB_STUB OFF)
255endif()
256
257if(WII)
258	add_definitions(-U__STRICT_ANSI__)
259endif()
260
261include(CheckFunctionExists)
262check_function_exists(strdup HAVE_STRDUP)
263check_function_exists(strndup HAVE_STRNDUP)
264check_function_exists(localtime_r HAVE_LOCALTIME_R)
265if(NOT CMAKE_SYSTEM_NAME STREQUAL "Generic")
266	check_function_exists(snprintf_l HAVE_SNPRINTF_L)
267	if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
268		# The strtof_l on Linux not actually exposed nor actually strtof_l
269		set(HAVE_STRTOF_L OFF)
270	else()
271		check_function_exists(strtof_l HAVE_STRTOF_L)
272	endif()
273	check_function_exists(newlocale HAVE_NEWLOCALE)
274	check_function_exists(freelocale HAVE_FREELOCALE)
275	check_function_exists(uselocale HAVE_USELOCALE)
276	check_function_exists(setlocale HAVE_SETLOCALE)
277else()
278	if(NOT DEFINED 3DS AND NOT DEFINED PSP2 AND NOT DEFINED WII)
279		set(DISABLE_DEPS ON CACHE BOOL "This platform cannot build with dependencies" FORCE)
280	endif()
281	set(DISABLE_FRONTENDS ON)
282	set(MINIMAL_CORE ON)
283endif()
284
285check_function_exists(chmod HAVE_CHMOD)
286check_function_exists(umask HAVE_UMASK)
287
288set(FUNCTION_DEFINES)
289
290if(HAVE_STRDUP)
291	list(APPEND FUNCTION_DEFINES HAVE_STRDUP)
292endif()
293
294if(HAVE_STRNDUP)
295	list(APPEND FUNCTION_DEFINES HAVE_STRNDUP)
296endif()
297
298if(HAVE_LOCALTIME_R)
299	list(APPEND FUNCTION_DEFINES HAVE_LOCALTIME_R)
300endif()
301
302if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE OR APPLE)
303	list(APPEND FUNCTION_DEFINES HAVE_LOCALE)
304	if (HAVE_STRTOF_L)
305		list(APPEND FUNCTION_DEFINES HAVE_STRTOF_L)
306	endif()
307	if (HAVE_SNPRINTF_L)
308		list(APPEND FUNCTION_DEFINES HAVE_SNPRINTF_L)
309	endif()
310endif()
311
312if(HAVE_SETLOCALE)
313	list(APPEND FUNCTION_DEFINES HAVE_SETLOCALE)
314endif()
315
316if(HAVE_CHMOD)
317	list(APPEND FUNCTION_DEFINES HAVE_CHMOD)
318endif()
319
320if(HAVE_UMASK)
321	list(APPEND FUNCTION_DEFINES HAVE_UMASK)
322endif()
323
324# Feature dependencies
325set(FEATURES)
326if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
327	set(LIBEDIT_LIBRARIES -ledit)
328	if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
329		list(APPEND LIBEDIT_LIBRARIES -ltermcap)
330	endif()
331else()
332	find_feature(USE_EDITLINE "libedit")
333endif()
334if(BUILD_GL)
335	find_package(OpenGL QUIET)
336	if(NOT OPENGL_FOUND)
337		set(BUILD_GL OFF CACHE BOOL "OpenGL not found" FORCE)
338	endif()
339endif()
340if(NOT BUILD_GL)
341	set(OPENGLE_LIBRARY "" CACHE PATH "" FORCE)
342endif()
343if(BUILD_GLES2 AND NOT BUILD_RASPI)
344	find_path(OPENGLES2_INCLUDE_DIR NAMES GLES2/gl2.h)
345	find_library(OPENGLES2_LIBRARY NAMES GLESv2 GLESv2_CM)
346	if(NOT OPENGLES2_INCLUDE_DIR OR NOT OPENGLES2_LIBRARY)
347		set(BUILD_GLES2 OFF CACHE BOOL "OpenGL|ES 2 not found" FORCE)
348	endif()
349endif()
350if(NOT BUILD_GLES2)
351	set(OPENGLES2_LIBRARY "" CACHE PATH "" FORCE)
352endif()
353set(WANT_ZLIB ${USE_ZLIB})
354set(WANT_PNG ${USE_PNG})
355set(WANT_LIBZIP ${USE_LIBZIP})
356set(USE_CMOCKA ${BUILD_SUITE})
357
358find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
359find_feature(USE_ZLIB "ZLIB")
360find_feature(USE_MINIZIP "minizip")
361find_feature(USE_PNG "PNG")
362find_feature(USE_LIBZIP "libzip")
363find_feature(USE_MAGICK "MagickWand")
364find_feature(USE_EPOXY "epoxy")
365find_feature(USE_CMOCKA "cmocka")
366find_feature(USE_SQLITE3 "sqlite3")
367
368# Features
369set(DEBUGGER_SRC
370	${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/debugger.c
371	${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/parser.c
372	${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/cli-debugger.c)
373
374set(FEATURE_SRC)
375set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
376
377if(DISABLE_DEPS)
378	set(USE_GDB_STUB OFF)
379endif()
380
381if(USE_EDITLINE)
382	list(APPEND FEATURES EDITLINE)
383	include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
384	link_directories(${LIBEDIT_LIBRARY_DIRS})
385	set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
386	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
387	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/editline/cli-el-backend.c")
388else()
389	set(DEBUGGER_LIB "")
390endif()
391
392if(USE_GDB_STUB)
393	list(APPEND FEATURES GDB_STUB)
394	list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/gdb-stub.c)
395endif()
396source_group("Debugger" FILES ${DEBUGGER_SRC})
397
398if(USE_FFMPEG)
399	list(APPEND FEATURES FFMPEG)
400	pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
401	if(NOT LIBSWRESAMPLE_FOUND)
402		list(APPEND FEATURES LIBAV)
403	endif()
404	include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
405	link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
406	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/ffmpeg/ffmpeg-encoder.c")
407	string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
408	string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
409	string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
410	string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
411	string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
412	list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
413	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR}|libavcodec-extra-${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
414	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavformat${LIBAVFORMAT_VERSION_MAJOR}|libavformat-ffmpeg${LIBAVFORMAT_VERSION_MAJOR}")
415	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavresample${LIBAVRESAMPLE_VERSION_MAJOR}|libavresample-ffmpeg${LIBAVRESAMPLE_VERSION_MAJOR}")
416	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavutil${LIBAVUTIL_VERSION_MAJOR}|libavutil-ffmpeg${LIBAVUTIL_VERSION_MAJOR}")
417	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libswscale${LIBSWSCALE_VERSION_MAJOR}|libswscale-ffmpeg${LIBSWSCALE_VERSION_MAJOR}")
418	set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
419	if(APPLE)
420		set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
421		set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
422	endif()
423endif()
424
425list(APPEND THIRD_PARTY_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
426
427if(USE_MAGICK)
428	list(APPEND FEATURES MAGICK)
429	include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
430	link_directories(${MAGICKWAND_LIBRARY_DIRS})
431	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/imagemagick/imagemagick-gif-encoder.c")
432	list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
433	string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
434	if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
435		set(MAGICKWAND_DEB_VERSION "5")
436	else()
437		set(MAGICKWAND_DEB_VERSION "-6.q16-2")
438	endif()
439	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
440endif()
441
442if(WANT_ZLIB AND NOT USE_ZLIB)
443	set(SKIP_INSTALL_ALL ON)
444	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib zlib)
445	set_property(TARGET zlibstatic PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/zlib;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib)
446	set_property(TARGET zlib PROPERTY EXCLUDE_FROM_ALL ON)
447	set_property(TARGET example PROPERTY EXCLUDE_FROM_ALL ON)
448	set_property(TARGET minigzip PROPERTY EXCLUDE_FROM_ALL ON)
449	set(ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
450	set(ZLIB_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
451	set(ZLIB_LIBRARY zlibstatic)
452	list(APPEND DEPENDENCY_LIB zlibstatic)
453	set(USE_ZLIB ON)
454endif()
455
456if(USE_ZLIB)
457	list(APPEND FEATURES ZLIB)
458	include_directories(AFTER ${ZLIB_INCLUDE_DIRS})
459	list(APPEND DEPENDENCY_LIB ${ZLIB_LIBRARIES})
460	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},zlib1g")
461endif()
462
463if(WANT_PNG AND USE_ZLIB AND NOT USE_PNG)
464	set(PNG_STATIC ON CACHE BOOL "" FORCE)
465	set(PNG_SHARED OFF CACHE BOOL "" FORCE)
466	set(PNG_TESTS OFF CACHE BOOL "" FORCE)
467	set(SKIP_INSTALL_ALL ON)
468	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng libpng)
469	set_property(TARGET png16_static PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/libpng;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng;${ZLIB_INCLUDE_DIRS})
470	set(PNG_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng ${CMAKE_CURRENT_BINARY_DIR}/libpng)
471	list(APPEND DEPENDENCY_LIB png16_static)
472	set(USE_PNG ON)
473endif()
474
475if(USE_PNG)
476	list(APPEND FEATURES PNG)
477	include_directories(AFTER ${PNG_INCLUDE_DIRS})
478	list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
479	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng12-0")
480endif()
481
482if(USE_LIBZIP)
483	include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
484	link_directories(${LIBZIP_LIBRARY_DIRS})
485	list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
486	list(APPEND FEATURES LIBZIP)
487	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
488	string(REGEX MATCH "^[0-9]+" LIBZIP_VERSION_MAJOR ${libzip_VERSION})
489	if (LIBZIP_VERSION_MAJOR LESS 1)
490		set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
491	elseif(LIBZIP_VERSION_MAJOR EQUAL 1)
492		set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip4")
493	else()
494		message(AUTHOR_WARNING Unknown version of libzip detected: ${libzip_VERSION})
495	endif()
496elseif(USE_MINIZIP)
497	include_directories(AFTER ${MINIZIP_INCLUDE_DIRS})
498	link_directories(${MINIZIP_LIBRARY_DIRS})
499	list(APPEND DEPENDENCY_LIB ${MINIZIP_LIBRARIES})
500	list(APPEND FEATURES MINIZIP)
501	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
502	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libminizip1")
503elseif(USE_ZLIB)
504	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c
505		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
506		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c)
507	set_source_files_properties(
508		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
509		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c
510		PROPERTIES COMPILE_FLAGS "-Wno-unused-parameter -Wno-implicit-function-declaration")
511endif()
512
513if (USE_LZMA)
514	include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/third-party/lzma)
515	add_definitions(-D_7ZIP_PPMD_SUPPPORT)
516	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-lzma.c)
517	set(LZMA_SRC
518		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
519		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
520		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
521		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
522		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
523		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
524		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zDec.c
525		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
526		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Delta.c
527		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
528		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
529		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra.c
530		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra86.c
531		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/BraIA64.c
532		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
533		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
534		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
535		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zFile.c
536		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
537	list(APPEND VFS_SRC ${LZMA_SRC})
538	list(APPEND FEATURES LZMA)
539endif()
540
541if(USE_EPOXY)
542	add_definitions(-DBUILD_GL -DBUILD_GLES2)
543	list(APPEND FEATURES EPOXY)
544	include_directories(AFTER ${EPOXY_INCLUDE_DIRS})
545	set(OPENGLES2_LIBRARY ${EPOXY_LIBRARIES})
546	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libepoxy0")
547endif()
548
549if(USE_SQLITE3)
550	list(APPEND FEATURES SQLITE3)
551	include_directories(AFTER ${SQLITE3_INCLUDE_DIRS})
552	list(APPEND DEPENDENCY_LIB ${SQLITE3_LIBRARIES})
553	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libsqlite3-0")
554	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/sqlite3/no-intro.c")
555endif()
556
557set(TEST_SRC ${CORE_TEST_SRC})
558if(M_CORE_GB)
559	add_definitions(-DM_CORE_GB)
560	list(APPEND CORE_SRC
561		${LR35902_SRC}
562		${GB_SRC}
563		${GB_RENDERER_SRC})
564	list(APPEND DEBUGGER_SRC
565		${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/cli-debugger.c
566		${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/debugger.c
567		${CMAKE_CURRENT_SOURCE_DIR}/src/gb/extra/cli.c)
568	list(APPEND TEST_SRC
569		${LR35902_TEST_SRC}
570		${GB_TEST_SRC})
571endif()
572
573if(M_CORE_GBA)
574	add_definitions(-DM_CORE_GBA)
575	list(APPEND CORE_SRC 
576		${ARM_SRC}
577		${GBA_SRC}
578		${GBA_CHEATS_SRC}
579		${GBA_RENDERER_SRC})
580	list(APPEND DEBUGGER_SRC
581		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c
582		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/debugger.c
583		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/memory-debugger.c
584		${CMAKE_CURRENT_SOURCE_DIR}/src/gba/extra/cli.c)
585	list(APPEND TEST_SRC
586		${ARM_TEST_SRC}
587		${GBA_TEST_SRC})
588	if(NOT M_CORE_GB)
589		list(APPEND CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/audio.c)
590	endif()
591endif()
592
593if(USE_DEBUGGERS)
594	list(APPEND FEATURE_SRC ${DEBUGGER_SRC})
595	list(APPEND FEATURES DEBUGGERS)
596endif()
597
598set(FEATURE_DEFINES)
599foreach(FEATURE IN LISTS FEATURES)
600	list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
601endforeach()
602
603source_group("Virtual files" FILES ${CORE_VFS_SRC} ${VFS_SRC})
604source_group("Extra features" FILES ${FEATURE_SRC})
605source_group("Third-party code" FILES ${THIRD_PARTY_SRC})
606
607# Platform binaries
608if(3DS)
609	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/3ds ${CMAKE_CURRENT_BINARY_DIR}/3ds)
610endif()
611
612if(WII)
613	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/wii ${CMAKE_CURRENT_BINARY_DIR}/wii)
614endif()
615
616if(PSP2)
617	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/psp2 ${CMAKE_CURRENT_BINARY_DIR}/psp2)
618endif()
619
620# Binaries
621list(APPEND CORE_SRC
622	${UTIL_SRC}
623	${CORE_VFS_SRC}
624	${OS_SRC}
625	${THIRD_PARTY_SRC})
626list(APPEND TEST_SRC ${UTIL_TEST_SRC})
627
628set(SRC ${CORE_SRC} ${VFS_SRC})
629if(NOT MINIMAL_CORE)
630	if(M_CORE_GBA)
631		list(APPEND SRC
632			${GBA_RR_SRC}
633			${GBA_EXTRA_SRC}
634			${GBA_SIO_SRC})
635	endif()
636	if(M_CORE_GB)
637		list(APPEND SRC
638			${GB_SIO_SRC})
639	endif()
640	list(APPEND SRC
641		${FEATURE_SRC}
642		${CLI_SRC})
643endif()
644
645if(NOT SKIP_LIBRARY)
646	if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
647		set(BUILD_SHARED ON)
648	endif()
649
650	if(BUILD_SHARED)
651		add_library(${BINARY_NAME} SHARED ${SRC} ${VFS_SRC})
652		if(BUILD_STATIC)
653			add_library(${BINARY_NAME}-static STATIC ${SRC})
654			set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
655			install(TARGETS ${BINARY_NAME}-static DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
656			add_dependencies(${BINARY_NAME}-static version-info)
657		endif()
658	else()
659		add_library(${BINARY_NAME} STATIC ${SRC})
660	endif()
661
662	add_dependencies(${BINARY_NAME} version-info)
663	set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
664
665	target_link_libraries(${BINARY_NAME} ${DEBUGGER_LIB} ${DEPENDENCY_LIB} ${OS_LIB})
666	install(TARGETS ${BINARY_NAME} LIBRARY DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME} NAMELINK_SKIP ARCHIVE DESTINATION ${LIBDIR} RUNTIME DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
667	if(UNIX AND NOT APPLE)
668		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-16.png DESTINATION share/icons/hicolor/16x16/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
669		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-24.png DESTINATION share/icons/hicolor/24x24/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
670		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-32.png DESTINATION share/icons/hicolor/32x32/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
671		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-48.png DESTINATION share/icons/hicolor/48x48/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
672		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-64.png DESTINATION share/icons/hicolor/64x64/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
673		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-96.png DESTINATION share/icons/hicolor/96x96/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
674		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-128.png DESTINATION share/icons/hicolor/128x128/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
675		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-256.png DESTINATION share/icons/hicolor/256x256/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
676		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-512.png DESTINATION share/icons/hicolor/512x512/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
677	endif()
678else()
679	set(BUILD_SHARED OFF)
680	set(BUILD_STATIC OFF)
681	find_library(${BINARY_NAME} ${BINARY_NAME})
682	if(NOT ${BINARY_NAME}_FOUND)
683		set(DISABLE_FRONTENDS ON)
684		set(BUILD_PERF OFF)
685		set(BUILD_TEST OFF)
686		set(BUILD_SUITE OFF)
687	endif()
688endif()
689
690if(BUILD_GL)
691	add_definitions(-DBUILD_GL)
692endif()
693
694if(BUILD_GLES2)
695	add_definitions(-DBUILD_GLES2)
696endif()
697
698if(DISABLE_FRONTENDS)
699	set(BUILD_SDL OFF)
700	set(BUILD_QT OFF)
701endif()
702
703if(BUILD_LIBRETRO)
704	file(GLOB RETRO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/libretro/*.c)
705	add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
706	set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5;DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=2")
707	target_link_libraries(${BINARY_NAME}_libretro ${OS_LIB})
708	install(TARGETS ${BINARY_NAME}_libretro LIBRARY DESTINATION ${LIBRETRO_LIBDIR} COMPONENT ${BINARY_NAME}_libretro NAMELINK_SKIP)
709endif()
710
711if(BUILD_OPENEMU)
712	find_library(FOUNDATION Foundation)
713	find_library(OPENEMUBASE OpenEmuBase)
714	file(GLOB OE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/*.m)
715	add_library(${BINARY_NAME}-openemu MODULE ${CORE_SRC} ${OE_SRC})
716	set_target_properties(${BINARY_NAME}-openemu PROPERTIES
717		MACOSX_BUNDLE_INFO_PLIST ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/Info.plist.in
718		BUNDLE TRUE
719		BUNDLE_EXTENSION oecoreplugin
720		OUTPUT_NAME ${PROJECT_NAME}
721		COMPILE_DEFINITIONS "DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=1")
722	target_link_libraries(${BINARY_NAME}-openemu ${OS_LIB} ${FOUNDATION} ${OPENEMUBASE})
723	install(TARGETS ${BINARY_NAME}-openemu LIBRARY DESTINATION ${OE_LIBDIR} COMPONENT ${BINARY_NAME}.oecoreplugin NAMELINK_SKIP)
724endif()
725
726if(BUILD_SDL)
727	add_definitions(-DBUILD_SDL)
728	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/sdl ${CMAKE_CURRENT_BINARY_DIR}/sdl)
729endif()
730
731if(BUILD_QT)
732	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/qt ${CMAKE_CURRENT_BINARY_DIR}/qt)
733endif()
734
735if(BUILD_PERF)
736	set(PERF_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/perf-main.c ${CLI_SRC})
737	if(UNIX AND NOT APPLE)
738		list(APPEND PERF_LIB rt)
739	endif()
740
741	add_executable(${BINARY_NAME}-perf ${PERF_SRC})
742	target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB} ${OS_LIB})
743	set_target_properties(${BINARY_NAME}-perf PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
744	install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
745	install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
746endif()
747
748if(BUILD_TEST)
749	add_executable(${BINARY_NAME}-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/fuzz-main.c)
750	target_link_libraries(${BINARY_NAME}-fuzz ${BINARY_NAME})
751	set_target_properties(${BINARY_NAME}-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
752	add_executable(tbl-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/tbl-fuzz-main.c)
753	target_link_libraries(tbl-fuzz ${BINARY_NAME})
754	set_target_properties(tbl-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
755	install(TARGETS ${BINARY_NAME}-fuzz tbl-fuzz DESTINATION bin COMPONENT ${BINARY_NAME}-test)
756endif()
757
758if(NOT USE_CMOCKA)
759	set(BUILD_SUITE OFF)
760endif()
761if(BUILD_SUITE)
762	enable_testing()
763	include_directories(AFTER ${CMOCKA_INCLUDE_DIRS})
764	link_directories(${CMOCKA_LIBRARY_DIRS})
765
766	add_executable(${BINARY_NAME}-suite ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/suite-main.c ${TEST_SRC})
767	target_link_libraries(${BINARY_NAME}-suite ${BINARY_NAME} ${PLATFORM_LIBRARY} cmocka)
768	set_target_properties(${BINARY_NAME}-suite PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
769	add_test(${BINARY_NAME}-suite ${BINARY_NAME}-suite)
770endif()
771
772if(BUILD_PYTHON)
773	enable_testing()
774	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/python ${CMAKE_CURRENT_BINARY_DIR}/python)
775endif()
776
777if(BUILD_EXAMPLE)
778	add_executable(${BINARY_NAME}-example-server ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/server.c)
779	target_link_libraries(${BINARY_NAME}-example-server ${BINARY_NAME})
780	set_target_properties(${BINARY_NAME}-example-server PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
781
782	if(BUILD_SDL)
783		add_executable(${BINARY_NAME}-example-client ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/client.c)
784		target_link_libraries(${BINARY_NAME}-example-client ${BINARY_NAME} ${SDL_LIBRARY} ${SDLMAIN_LIBRARY} ${OPENGL_LIBRARY} ${OPENGLES2_LIBRARY})
785		set_target_properties(${BINARY_NAME}-example-client PROPERTIES
786		                      COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}"
787		                      INCLUDE_DIRECTORIES "${SDL_INCLUDE_DIR};${CMAKE_CURRENT_SOURCE_DIR}/src;${CMAKE_CURRENT_SOURCE_DIR}/include")
788	endif()
789endif()
790
791# Packaging
792set(CPACK_PACKAGE_VERSION ${VERSION_STRING})
793set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
794set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
795set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
796set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
797set(CPACK_RESOURCE_FILE_README ${CMAKE_CURRENT_SOURCE_DIR}/README.md)
798
799set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
800set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
801set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
802set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README.md")
803set(CPACK_DEBIAN_PACKAGE_SECTION "games")
804
805SET(CPACK_DEB_COMPONENT_INSTALL ON)
806
807set(CPACK_STRIP_FILES ${BINARY_NAME})
808
809install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/README.md ${CMAKE_CURRENT_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
810
811include(CPack)
812
813# Summaries
814set(SUMMARY_GL_LIST)
815if(USE_EPOXY)
816	set(SUMMARY_GL_LIST "libepoxy")
817else()
818	if(BUILD_GL)
819		list(APPEND SUMMARY_GL_LIST "OpenGL")
820	endif()
821	if(BUILD_GLES2)
822		list(APPEND SUMMARY_GL_LIST "OpenGL|ES 2")
823	endif()
824endif()
825if(NOT SUMMARY_GL_LIST)
826	set(SUMMARY_GL OFF)
827else()
828	string(REPLACE ";" ", " SUMMARY_GL "${SUMMARY_GL_LIST}")
829endif()
830if(USE_LIBZIP)
831	set(SUMMARY_ZIP libzip)
832elseif(USE_MINIZIP)
833	set(SUMMARY_ZIP "minizip (external)")
834elseif(USE_ZLIB)
835	set(SUMMARY_ZIP "minizip (included)")
836else()
837	set(SUMMARY_ZIP OFF)
838endif()
839
840if(NOT QUIET)
841	message(STATUS "Platforms:")
842	message(STATUS "	Game Boy Advance: ${M_CORE_GBA}")
843	message(STATUS "	Game Boy: ${M_CORE_GB}")
844	message(STATUS "Features:")
845	message(STATUS "	Debuggers: ${USE_DEBUGGERS}")
846	message(STATUS "	CLI debugger: ${USE_EDITLINE}")
847	message(STATUS "	GDB stub: ${USE_GDB_STUB}")
848	message(STATUS "	Video recording: ${USE_FFMPEG}")
849	message(STATUS "	GIF recording: ${USE_MAGICK}")
850	message(STATUS "	Screenshot/advanced savestate support: ${USE_PNG}")
851	message(STATUS "	ZIP support: ${SUMMARY_ZIP}")
852	message(STATUS "	7-Zip support: ${USE_LZMA}")
853	message(STATUS "	SQLite3 game database: ${USE_SQLITE3}")
854	message(STATUS "	OpenGL support: ${SUMMARY_GL}")
855	message(STATUS "Frontends:")
856	message(STATUS "	Qt: ${BUILD_QT}")
857	message(STATUS "	SDL (${SDL_VERSION}): ${BUILD_SDL}")
858	message(STATUS "	Profiling: ${BUILD_PERF}")
859	message(STATUS "	Test harness: ${BUILD_TEST}")
860	message(STATUS "	Test suite: ${BUILD_SUITE}")
861	message(STATUS "	Python bindings: ${BUILD_PYTHON}")
862	message(STATUS "	Examples: ${BUILD_EXAMPLE}")
863	message(STATUS "Cores:")
864	message(STATUS "	Libretro core: ${BUILD_LIBRETRO}")
865	if(APPLE)
866		message(STATUS "	OpenEmu core: ${BUILD_OPENEMU}")
867	endif()
868	message(STATUS "Libraries:")
869	message(STATUS "	Static: ${BUILD_STATIC}")
870	message(STATUS "	Shared: ${BUILD_SHARED}")
871endif()