1cmake_minimum_required(VERSION 2.6)
  2project(mGBA)
  3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
  4set(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -g -Wall -Wextra -std=gnu99")
  5set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -O3 -Wall -Wextra -std=gnu99")
  6set(USE_CLI_DEBUGGER ON CACHE BOOL "Whether or not to enable the CLI-mode ARM debugger")
  7set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
  8set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
  9set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
 10set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable ZIP support")
 11set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
 12set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
 13file(GLOB ARM_SRC ${CMAKE_SOURCE_DIR}/src/arm/*.c)
 14file(GLOB GBA_SRC ${CMAKE_SOURCE_DIR}/src/gba/*.c)
 15file(GLOB UTIL_SRC ${CMAKE_SOURCE_DIR}/src/util/*.[cS])
 16file(GLOB VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/*.c)
 17file(GLOB RENDERER_SRC ${CMAKE_SOURCE_DIR}/src/gba/renderers/video-software.c)
 18list(APPEND UTIL_SRC ${CMAKE_SOURCE_DIR}/src/platform/commandline.c)
 19source_group("ARM core" FILES ${ARM_SRC})
 20source_group("GBA board" FILES ${GBA_SRC} ${RENDERER_SRC})
 21source_group("Utilities" FILES ${UTIL_SRC} ${VFS_SRC}})
 22include_directories(${CMAKE_SOURCE_DIR}/src/arm)
 23include_directories(${CMAKE_SOURCE_DIR}/src/gba)
 24include_directories(${CMAKE_SOURCE_DIR}/src)
 25
 26# Function definitions
 27include(FindPkgConfig)
 28function(find_feature FEATURE_NAME FEATURE_REQUIRES)
 29	if (NOT ${FEATURE_NAME})
 30		return()
 31	endif()
 32	foreach(REQUIRE ${FEATURE_REQUIRES})
 33		find_package(${REQUIRE} QUIET)
 34		pkg_search_module(${REQUIRE} ${REQUIRE})
 35		if (NOT ${REQUIRE}_FOUND)
 36			message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
 37			set(${FEATURE_NAME} OFF PARENT_SCOPE)
 38			return()
 39		endif()
 40		string(TOUPPER ${REQUIRE} UREQUIRE)
 41		set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
 42		set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
 43		set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
 44		set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
 45		set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
 46		set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
 47	endforeach()
 48endfunction()
 49
 50# Version information
 51set(LIB_VERSION_MAJOR 0)
 52set(LIB_VERSION_MINOR 1)
 53set(LIB_VERSION_PATCH 0)
 54set(LIB_VERSION_ABI 0.1)
 55set(LIB_VERSION_STRING ${LIB_VERSION_MAJOR}.${LIB_VERSION_MINOR}.${LIB_VERSION_PATCH})
 56
 57# Advanced settings
 58set(BUILD_PGO CACHE BOOL "Build with profiling-guided optimization")
 59set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
 60set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
 61mark_as_advanced(BUILD_PGO PGO_STAGE_2 PGO_DIR)
 62set(PGO_PRE_FLAGS "-pg -fprofile-generate=${PGO_DIR}")
 63set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR}")
 64
 65if(BUILD_PGO AND NOT PGO_STAGE_2)
 66	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
 67	set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
 68	set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
 69elseif(BUILD_PGO AND PGO_STAGE_2)
 70	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
 71	set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
 72	set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
 73endif()
 74
 75add_definitions(-DBINARY_NAME="${BINARY_NAME}" -DPROJECT_NAME="${PROJECT_NAME}")
 76
 77# Feature dependencies
 78find_feature(USE_CLI_DEBUGGER "libedit")
 79find_feature(USE_FFMPEG "libavcodec;libavformat;libavutil")
 80find_feature(USE_PNG "PNG;ZLIB")
 81find_feature(USE_LIBZIP "libzip")
 82
 83# Platform support
 84if(WIN32)
 85	add_definitions(-D_WIN32_WINNT=0x0600)
 86	list(APPEND OS_LIB Ws2_32)
 87	file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/windows/*.c)
 88	source_group("Windows-specific code" FILES ${OS_SRC})
 89else()
 90	add_definitions(-DUSE_PTHREADS)
 91	list(APPEND OS_LIB pthread)
 92	file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/posix/*.c)
 93	source_group("POSIX-specific code" FILES ${OS_SRC})
 94endif()
 95
 96if(BUILD_BBB OR BUILD_RASPI)
 97	enable_language(ASM)
 98	if(NOT BUILD_EGL)
 99		add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
100	endif()
101endif()
102
103# Features
104set(DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/debugger.c ${CMAKE_SOURCE_DIR}/src/debugger/memory-debugger.c)
105
106if(USE_CLI_DEBUGGER)
107	add_definitions(-DUSE_CLI_DEBUGGER)
108	list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/cli-debugger.c)
109	list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/parser.c)
110	include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
111	link_directories(${LIBEDIT_LIBRARY_DIRS})
112	set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
113else()
114	set(DEBUGGER_LIB "")
115endif()
116
117if(USE_GDB_STUB)
118	add_definitions(-DUSE_GDB_STUB)
119	list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/gdb-stub.c)
120endif()
121source_group("ARM debugger" FILES ${DEBUGGER_SRC})
122
123if(USE_FFMPEG)
124	add_definitions(-DUSE_FFMPEG)
125	include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS})
126	link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS})
127	list(APPEND UTIL_SRC "${CMAKE_SOURCE_DIR}/src/platform/ffmpeg/ffmpeg-encoder.c")
128	list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVUTIL_LIBRARIES})
129endif()
130
131if(USE_PNG)
132	add_definitions(-DUSE_PNG)
133	include_directories(AFTER ${PNG_INCLUDE_DIRS})
134	list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
135endif()
136
137if(USE_LIBZIP)
138	include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
139	link_directories(${LIBZIP_LIBRARY_DIRS})
140	list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
141	add_definitions(-DENABLE_LIBZIP)
142endif()
143
144# Binaries
145add_library(${BINARY_NAME} SHARED ${ARM_SRC} ${GBA_SRC} ${DEBUGGER_SRC} ${RENDERER_SRC} ${UTIL_SRC} ${VFS_SRC} ${OS_SRC})
146target_link_libraries(${BINARY_NAME} m ${DEBUGGER_LIB} ${OS_LIB} ${DEPENDENCY_LIB})
147install(TARGETS ${BINARY_NAME} DESTINATION lib)
148set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI})
149
150if(BUILD_SDL)
151	add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/sdl ${CMAKE_BINARY_DIR}/sdl)
152endif()
153
154if(BUILD_PERF)
155	set(PERF_SRC ${CMAKE_SOURCE_DIR}/src/platform/perf-main.c)
156	if(UNIX AND NOT APPLE)
157		list(APPEND PERF_LIB rt)
158	endif()
159
160	add_executable(${BINARY_NAME}-perf ${PERF_SRC})
161	target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB})
162	install(TARGETS ${BINARY_NAME}-perf DESTINATION bin)
163endif()
164
165# Summaries
166message(STATUS "Feature summary:")
167message(STATUS "	CLI debugger: ${USE_CLI_DEBUGGER}")
168message(STATUS "	GDB stub: ${USE_GDB_STUB}")
169message(STATUS "	Video recording: ${USE_FFMPEG}")
170message(STATUS "	Screenshot/advanced savestate support: ${USE_PNG}")
171message(STATUS "	ZIP support: ${USE_LIBZIP}")
172message(STATUS "Frontend summary:")
173message(STATUS "	SDL (${SDL_VERSION}): ${BUILD_SDL}")
174message(STATUS "	Profiling: ${BUILD_PERF}")