CMakeLists.txt (view raw)
1cmake_minimum_required(VERSION 2.6)
2project(mGBA C)
3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
4set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -std=gnu99")
5set(USE_CLI_DEBUGGER ON CACHE BOOL "Whether or not to enable the CLI-mode ARM debugger")
6set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
7set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
8set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
9set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable ZIP support")
10set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
11set(USE_BLIP ON CACHE BOOL "Whether or not to enable blip_buf support")
12set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
13set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
14set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
15set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
16set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
17set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
18set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
19file(GLOB ARM_SRC ${CMAKE_SOURCE_DIR}/src/arm/*.c)
20file(GLOB GBA_SRC ${CMAKE_SOURCE_DIR}/src/gba/*.c)
21file(GLOB GBA_RR_SRC ${CMAKE_SOURCE_DIR}/src/gba/rr/*.c)
22file(GLOB GBA_SV_SRC ${CMAKE_SOURCE_DIR}/src/gba/supervisor/*.c)
23file(GLOB UTIL_SRC ${CMAKE_SOURCE_DIR}/src/util/*.[cSs])
24file(GLOB VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/*.c)
25file(GLOB RENDERER_SRC ${CMAKE_SOURCE_DIR}/src/gba/renderers/video-software.c)
26file(GLOB THIRD_PARTY_SRC ${CMAKE_SOURCE_DIR}/src/third-party/inih/*.c)
27list(APPEND UTIL_SRC ${CMAKE_SOURCE_DIR}/src/platform/commandline.c)
28source_group("ARM core" FILES ${ARM_SRC})
29source_group("GBA board" FILES ${GBA_SRC} ${RENDERER_SRC})
30source_group("GBA supervisor" FILES ${GBA_SV_SRC} ${GBA_RR_SRC})
31source_group("Utilities" FILES ${UTIL_SRC} ${VFS_SRC}})
32include_directories(${CMAKE_SOURCE_DIR}/src/arm)
33include_directories(${CMAKE_SOURCE_DIR}/src)
34
35if(NOT CMAKE_BUILD_TYPE)
36 set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
37endif()
38
39set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
40
41include(GNUInstallDirs)
42
43# Function definitions
44include(FindPkgConfig)
45function(find_feature FEATURE_NAME FEATURE_REQUIRES)
46 if (NOT ${FEATURE_NAME})
47 return()
48 endif()
49 foreach(REQUIRE ${FEATURE_REQUIRES})
50 if(NOT ${REQUIRE}_FOUND)
51 find_package(${REQUIRE} QUIET)
52 if(NOT ${REQUIRE}_FOUND)
53 pkg_search_module(${REQUIRE} ${REQUIRE})
54 if (NOT ${REQUIRE}_FOUND)
55 message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
56 set(${FEATURE_NAME} OFF PARENT_SCOPE)
57 return()
58 endif()
59 endif()
60 endif()
61 string(TOUPPER ${REQUIRE} UREQUIRE)
62 set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
63 set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
64 set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
65 set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
66 set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
67 set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
68 endforeach()
69endfunction()
70
71# Version information
72set(LIB_VERSION_MAJOR 0)
73set(LIB_VERSION_MINOR 2)
74set(LIB_VERSION_PATCH 0)
75set(LIB_VERSION_ABI 0.2)
76set(LIB_VERSION_STRING ${LIB_VERSION_MAJOR}.${LIB_VERSION_MINOR}.${LIB_VERSION_PATCH})
77
78# Advanced settings
79set(BUILD_LTO ON CACHE BOOL "Build with link-time optimization")
80set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
81set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
82set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
83mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
84set(PGO_PRE_FLAGS "-pg -fprofile-generate=${PGO_DIR} -fprofile-arcs")
85set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
86
87if(BUILD_PGO AND NOT PGO_STAGE_2)
88 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
89 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
90 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
91elseif(BUILD_PGO AND PGO_STAGE_2)
92 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
93 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
94 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
95endif()
96
97add_definitions(-DBINARY_NAME="${BINARY_NAME}" -DPROJECT_NAME="${PROJECT_NAME}" -DPROJECT_VERSION="${LIB_VERSION_STRING}")
98
99# Feature dependencies
100set(FEATURES)
101if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
102 set(LIBEDIT_LIBRARIES -ledit)
103 if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
104 list(APPEND LIBEDIT_LIBRARIES -ltermcap)
105 endif()
106else()
107 find_feature(USE_CLI_DEBUGGER "libedit")
108endif()
109find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
110find_feature(USE_PNG "ZLIB;PNG")
111find_feature(USE_LIBZIP "libzip")
112find_feature(USE_MAGICK "MagickWand")
113
114# Platform support
115if(WIN32)
116 set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
117 add_definitions(-D_WIN32_WINNT=0x0600)
118 list(APPEND OS_LIB ws2_32)
119 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/windows/*.c)
120 source_group("Windows-specific code" FILES ${OS_SRC})
121else()
122 add_definitions(-DUSE_PTHREADS)
123 if(NOT APPLE)
124 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
125 endif()
126 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/posix/*.c)
127 source_group("POSIX-specific code" FILES ${OS_SRC})
128endif()
129
130if(APPLE)
131 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
132endif()
133
134if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
135 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
136 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
137endif()
138
139if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
140 if(NOT BUILD_EGL)
141 add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
142 endif()
143endif()
144
145if(BUILD_PANDORA)
146 add_definitions(-DBUILD_PANDORA)
147endif()
148
149if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
150 enable_language(ASM)
151endif()
152
153include(CheckFunctionExists)
154check_function_exists(strndup HAVE_STRNDUP)
155check_function_exists(snprintf_l HAVE_SNPRINTF_L)
156if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
157 # The strtof_l on Linux not actually exposed nor actually strtof_l
158 set(HAVE_STRTOF_L OFF)
159else()
160 check_function_exists(strtof_l HAVE_STRTOF_L)
161endif()
162check_function_exists(newlocale HAVE_NEWLOCALE)
163check_function_exists(freelocale HAVE_FREELOCALE)
164check_function_exists(uselocale HAVE_USELOCALE)
165
166if(HAVE_STRNDUP)
167 add_definitions(-DHAVE_STRNDUP)
168endif()
169
170if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE)
171 add_definitions(-DHAVE_LOCALE)
172 if (HAVE_STRTOF_L)
173 add_definitions(-DHAVE_STRTOF_L)
174 endif()
175 if (HAVE_SNPRINTF_L)
176 add_definitions(-DHAVE_SNPRINTF_L)
177 endif()
178endif()
179
180
181# Features
182set(DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/debugger.c ${CMAKE_SOURCE_DIR}/src/debugger/memory-debugger.c)
183set(FEATURE_SRC)
184set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
185
186if(USE_CLI_DEBUGGER)
187 list(APPEND FEATURES CLI_DEBUGGER)
188 list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/debugger/cli-debugger.c)
189 list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/debugger/parser.c)
190 list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/gba/supervisor/cli.c)
191 include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
192 link_directories(${LIBEDIT_LIBRARY_DIRS})
193 set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
194 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
195else()
196 set(DEBUGGER_LIB "")
197endif()
198
199if(USE_GDB_STUB)
200 list(APPEND FEATURES GDB_STUB)
201 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/gdb-stub.c)
202endif()
203source_group("ARM debugger" FILES ${DEBUGGER_SRC})
204
205if(USE_FFMPEG)
206 list(APPEND FEATURES FFMPEG)
207 pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
208 if(NOT LIBSWRESAMPLE_FOUND)
209 list(APPEND FEATURES LIBAV)
210 endif()
211 include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
212 link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
213 list(APPEND FEATURE_SRC "${CMAKE_SOURCE_DIR}/src/platform/ffmpeg/ffmpeg-encoder.c")
214 string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
215 string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
216 string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
217 string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
218 string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
219 list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
220 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR},libavformat${LIBAVFORMAT_VERSION_MAJOR},libavresample${LIBAVRESAMPLE_VERSION_MAJOR},libavutil${LIBAVUTIL_VERSION_MAJOR},libswscale${LIBSWSCALE_VERSION_MAJOR}")
221 set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra")
222endif()
223
224if(USE_BLIP)
225 list(APPEND THIRD_PARTY_SRC "${CMAKE_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
226 add_definitions(-DRESAMPLE_LIBRARY=RESAMPLE_BLIP_BUF)
227else()
228 add_definitions(-DRESAMPLE_LIBRARY=RESAMPLE_NN)
229endif()
230
231if(USE_MAGICK)
232 list(APPEND FEATURES MAGICK)
233 include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
234 link_directories(${MAGICKWAND_LIBRARY_DIRS})
235 list(APPEND FEATURE_SRC "${CMAKE_SOURCE_DIR}/src/platform/imagemagick/imagemagick-gif-encoder.c")
236 list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
237 string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
238 if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
239 set(MAGICKWAND_DEB_VERSION "5")
240 else()
241 set(MAGICKWAND_DEB_VERSION "-6.q16-2")
242 endif()
243 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
244endif()
245
246if(USE_PNG)
247 list(APPEND FEATURES PNG)
248 include_directories(AFTER ${PNG_INCLUDE_DIRS})
249 list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
250 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng12-0,zlib1g")
251endif()
252
253if(USE_LIBZIP)
254 include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
255 link_directories(${LIBZIP_LIBRARY_DIRS})
256 list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
257 list(APPEND FEATURES LIBZIP)
258 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
259endif()
260
261if (USE_LZMA)
262 include_directories(AFTER ${CMAKE_SOURCE_DIR}/third-party/lzma)
263 add_definitions(-D_7ZIP_PPMD_SUPPPORT)
264 set(LZMA_SRC
265 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
266 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
267 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
268 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
269 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
270 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
271 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zDec.c
272 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
273 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
274 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
275 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bra.c
276 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bra86.c
277 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
278 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
279 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
280 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zFile.c
281 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
282 list(APPEND FEATURE_SRC ${LZMA_SRC})
283 list(APPEND FEATURES LZMA)
284endif()
285
286set(FEATURE_DEFINES)
287foreach(FEATURE IN LISTS FEATURES)
288 list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
289endforeach()
290
291# Binaries
292set(CORE_SRC
293 ${ARM_SRC}
294 ${GBA_SRC}
295 ${GBA_RR_SRC}
296 ${GBA_SV_SRC}
297 ${DEBUGGER_SRC}
298 ${RENDERER_SRC}
299 ${UTIL_SRC}
300 ${VFS_SRC}
301 ${OS_SRC}
302 ${THIRD_PARTY_SRC})
303
304set(SRC
305 ${CORE_SRC}
306 ${FEATURE_SRC})
307
308if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
309 set(BUILD_SHARED ON)
310endif()
311
312if(BUILD_SHARED)
313 add_library(${BINARY_NAME} SHARED ${SRC})
314 if(BUILD_STATIC)
315 add_library(${BINARY_NAME}-static STATIC ${SRC})
316 set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${FEATURE_DEFINES}")
317 install(TARGETS ${BINARY_NAME}-static DESTINATION lib COMPONENT lib${BINARY_NAME})
318 endif()
319else()
320 add_library(${BINARY_NAME} STATIC ${SRC})
321endif()
322
323target_link_libraries(${BINARY_NAME} m ${DEBUGGER_LIB} ${OS_LIB} ${DEPENDENCY_LIB})
324install(TARGETS ${BINARY_NAME} DESTINATION lib COMPONENT lib${BINARY_NAME})
325set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${FEATURE_DEFINES}")
326
327if(BUILD_LIBRETRO)
328 file(GLOB RETRO_SRC ${CMAKE_SOURCE_DIR}/src/platform/libretro/*.c)
329 add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
330 set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5")
331 target_link_libraries(${BINARY_NAME}_libretro m ${OS_LIB})
332endif()
333
334if(BUILD_SDL)
335 add_definitions(-DBUILD_SDL)
336 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/sdl ${CMAKE_BINARY_DIR}/sdl)
337endif()
338
339if(BUILD_QT)
340 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/qt ${CMAKE_BINARY_DIR}/qt)
341endif()
342
343if(BUILD_PERF)
344 set(PERF_SRC ${CMAKE_SOURCE_DIR}/src/platform/perf-main.c)
345 if(UNIX AND NOT APPLE)
346 list(APPEND PERF_LIB rt)
347 endif()
348
349 add_executable(${BINARY_NAME}-perf ${PERF_SRC})
350 target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB})
351 install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
352 install(FILES ${CMAKE_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
353endif()
354
355# Packaging
356set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
357set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
358set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
359set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_SOURCE_DIR}/LICENSE)
360set(CPACK_RESOURCE_FILE_README ${CMAKE_SOURCE_DIR}/README.md)
361
362set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
363set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
364set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
365set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_SOURCE_DIR}/README.md")
366set(CPACK_DEBIAN_PACKAGE_SECTION "games")
367
368SET(CPACK_DEB_COMPONENT_INSTALL ON)
369
370set(CPACK_STRIP_FILES ${BINARY_NAME})
371
372install(FILES ${CMAKE_SOURCE_DIR}/README.md ${CMAKE_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
373
374include(CPack)
375
376# Summaries
377message(STATUS "Feature summary:")
378message(STATUS " CLI debugger: ${USE_CLI_DEBUGGER}")
379message(STATUS " GDB stub: ${USE_GDB_STUB}")
380message(STATUS " Video recording: ${USE_FFMPEG}")
381message(STATUS " GIF recording: ${USE_MAGICK}")
382message(STATUS " Screenshot/advanced savestate support: ${USE_PNG}")
383message(STATUS " ZIP support: ${USE_LIBZIP}")
384message(STATUS " 7-Zip support: ${USE_LZMA}")
385message(STATUS " Better audio resampling: ${USE_BLIP}")
386message(STATUS "Frontend summary:")
387message(STATUS " Qt: ${BUILD_QT}")
388message(STATUS " SDL (${SDL_VERSION}): ${BUILD_SDL}")
389message(STATUS " Libretro core: ${BUILD_LIBRETRO}")
390message(STATUS " Profiling: ${BUILD_PERF}")
391message(STATUS "Library summary:")
392message(STATUS " Static: ${BUILD_STATIC}")
393message(STATUS " Shared: ${BUILD_SHARED}")