CMakeLists.txt (view raw)
1cmake_minimum_required(VERSION 2.6)
2project(mGBA C)
3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
4if(NOT MSVC)
5 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wno-missing-field-initializers -std=c99")
6else()
7 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_CRT_SECURE_NO_WARNINGS /wd4003 /wd4244 /wd4146")
8endif()
9set(USE_DEBUGGERS ON CACHE BOOL "Whether or not to enable the debugging infrastructure")
10set(USE_EDITLINE ON CACHE BOOL "Whether or not to enable the CLI-mode debugger")
11set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
12set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
13set(USE_ZLIB ON CACHE BOOL "Whether or not to enable zlib support")
14set(USE_MINIZIP ON CACHE BOOL "Whether or not to enable external minizip support")
15set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
16set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable LIBZIP support")
17set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
18set(M_CORE_GBA ON CACHE BOOL "Build Game Boy Advance core")
19set(M_CORE_GB ON CACHE BOOL "Build Game Boy core")
20set(M_CORE_DS ON CACHE BOOL "Build DS core")
21set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
22set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
23set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
24set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
25if(APPLE)
26 set(BUILD_OPENEMU OFF CACHE BOOL "Build OpenEmu core")
27endif()
28set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
29set(BUILD_TEST OFF CACHE BOOL "Build testing harness")
30set(BUILD_SUITE OFF CACHE BOOL "Build test suite")
31set(BUILD_EXAMPLE OFF CACHE BOOL "Build example frontends")
32set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
33set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
34set(SKIP_LIBRARY OFF CACHE BOOL "Skip building the library (useful for only building libretro or OpenEmu cores)")
35set(BUILD_GL ON CACHE STRING "Build with OpenGL")
36set(BUILD_GLES2 OFF CACHE STRING "Build with OpenGL|ES 2")
37set(USE_EPOXY ON CACHE STRING "Build with libepoxy")
38set(DISABLE_DEPS OFF CACHE BOOL "Build without dependencies")
39file(GLOB ARM_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/*.c)
40file(GLOB ARM_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/test/*.c)
41file(GLOB LR35902_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/*.c)
42file(GLOB LR35902_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/test/*.c)
43file(GLOB GBA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/*.c)
44file(GLOB GBA_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/test/*.c)
45file(GLOB GB_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/*.c)
46file(GLOB GB_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/test/*.c)
47file(GLOB DS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/ds/*.c)
48file(GLOB GBA_CHEATS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/cheats/*.c)
49file(GLOB GBA_RR_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/rr/*.c)
50file(GLOB CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/*.c)
51file(GLOB CORE_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/test/*.c)
52file(GLOB UTIL_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/*.[cSs])
53file(GLOB UTIL_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/test/*.c)
54file(GLOB GUI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/gui/*.c ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/gui/*.c)
55file(GLOB GBA_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/renderers/*.c)
56file(GLOB SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/sio/lockstep.c)
57file(GLOB GB_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/renderers/*.c)
58file(GLOB THIRD_PARTY_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/inih/*.c)
59set(CLI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/commandline.c)
60set(CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-mem.c)
61set(VFS_SRC)
62source_group("ARM core" FILES ${ARM_SRC})
63source_group("LR35902 core" FILES ${LR35902_SRC})
64source_group("GBA board" FILES ${GBA_SRC} ${GBA_RENDERER_SRC} ${SIO_SRC})
65source_group("GBA extra" FILES ${GBA_CHEATS_SRC} ${GBA_RR_SRC})
66source_group("GB board" FILES ${GB_SRC})
67source_group("DS board" FILES ${DS_SRC})
68source_group("Utilities" FILES ${UTIL_SRC})
69include_directories(BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/src)
70
71if(NOT CMAKE_BUILD_TYPE)
72 set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
73endif()
74
75include(GNUInstallDirs)
76
77set(LIBDIR "${CMAKE_INSTALL_LIBDIR}" CACHE PATH "Installed library directory")
78mark_as_advanced(LIBDIR)
79
80if (BUILD_LIBRETRO)
81 set(LIBRETRO_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (Libretro)")
82 mark_as_advanced(LIBRETRO_LIBDIR)
83endif()
84
85if (BUILD_OPENEMU)
86 set(OE_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (OpenEmu)")
87 mark_as_advanced(OE_LIBDIR)
88endif()
89
90
91set(CMAKE_INSTALL_RPATH "${LIBDIR}")
92
93if (NOT DEFINED MANDIR)
94 set(MANDIR ${CMAKE_INSTALL_MANDIR})
95endif()
96
97# Function definitions
98include(FindPkgConfig)
99function(find_feature FEATURE_NAME FEATURE_REQUIRES)
100 if (NOT ${FEATURE_NAME})
101 return()
102 endif()
103 if (DISABLE_DEPS)
104 set(${FEATURE_NAME} OFF PARENT_SCOPE)
105 return()
106 endif()
107 foreach(REQUIRE ${FEATURE_REQUIRES})
108 if(NOT ${REQUIRE}_FOUND)
109 find_package(${REQUIRE} QUIET)
110 if(NOT ${REQUIRE}_FOUND)
111 pkg_search_module(${REQUIRE} ${REQUIRE})
112 if (NOT ${REQUIRE}_FOUND)
113 message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
114 set(${FEATURE_NAME} OFF PARENT_SCOPE)
115 return()
116 endif()
117 endif()
118 endif()
119 string(TOUPPER ${REQUIRE} UREQUIRE)
120 set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
121 set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
122 set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
123 if (APPLE)
124 set(IS_FRAMEWORK OFF)
125 set(LIBS)
126 foreach(LIB IN LISTS ${REQUIRE}_LIBRARIES)
127 if(LIB STREQUAL "-framework")
128 set(IS_FRAMEWORK ON)
129 elseif(IS_FRAMEWORK)
130 list(APPEND LIBS "-framework ${LIB}")
131 set(IS_FRAMEWORK OFF)
132 else()
133 list(APPEND LIBS ${LIB})
134 endif()
135 endforeach()
136 set(${UREQUIRE}_LIBRARIES ${LIBS} PARENT_SCOPE)
137 else()
138 set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
139 endif()
140 set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
141 set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
142 endforeach()
143endfunction()
144
145# Version information
146add_custom_target(version-info ALL
147 COMMAND ${CMAKE_COMMAND}
148 -DBINARY_NAME=${BINARY_NAME}
149 -DCONFIG_FILE=${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in
150 -DOUT_FILE=${CMAKE_CURRENT_BINARY_DIR}/version.c
151 -P ${CMAKE_CURRENT_SOURCE_DIR}/version.cmake
152 WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
153
154include(${CMAKE_CURRENT_SOURCE_DIR}/version.cmake)
155configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in ${CMAKE_CURRENT_BINARY_DIR}/version.c)
156list(APPEND UTIL_SRC ${CMAKE_CURRENT_BINARY_DIR}/version.c)
157source_group("Generated sources" FILES ${CMAKE_CURRENT_BINARY_DIR}/version.c)
158
159# Advanced settings
160set(BUILD_LTO ON CACHE BOOL "Build with link-time optimization")
161set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
162set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
163set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
164mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
165set(PGO_PRE_FLAGS "-fprofile-generate=${PGO_DIR} -fprofile-arcs")
166set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
167
168if(BUILD_PGO AND NOT PGO_STAGE_2)
169 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
170 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
171 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
172elseif(BUILD_PGO AND PGO_STAGE_2)
173 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
174 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
175 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
176endif()
177
178# Platform support
179if(WIN32)
180 set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
181 add_definitions(-D_WIN32_WINNT=0x0600)
182 list(APPEND OS_LIB ws2_32 shlwapi)
183 list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/vfs-w32.c)
184 file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/*.c)
185 source_group("Windows-specific code" FILES ${OS_SRC})
186 if(MSVC)
187 add_definitions(-DNOMINMAX -DWIN32_LEAN_AND_MEAN)
188 endif()
189elseif(UNIX)
190 add_definitions(-DUSE_PTHREADS)
191
192 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
193 add_definitions(-D_GNU_SOURCE)
194 endif()
195 if(NOT APPLE AND NOT HAIKU)
196 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
197 endif()
198
199 list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
200 file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/posix/*.c)
201 source_group("POSIX-specific code" FILES ${OS_SRC})
202endif()
203
204if(APPLE)
205 add_definitions(-D_DARWIN_C_SOURCE)
206 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
207endif()
208
209if(NOT HAIKU AND NOT MSVC AND NOT PSP2)
210 set(M_LIBRARY m)
211endif()
212list(APPEND OS_LIB ${M_LIBRARY})
213
214if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
215 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
216 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
217endif()
218
219if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
220 if(NOT BUILD_EGL)
221 add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
222 endif()
223endif()
224
225if(BUILD_RASPI)
226 set(BUILD_GL OFF CACHE BOOL "OpenGL not supported" FORCE)
227endif()
228
229if(BUILD_PANDORA)
230 add_definitions(-DBUILD_PANDORA)
231endif()
232
233if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
234 enable_language(ASM)
235endif()
236
237if(PSP2 OR WII)
238 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-format")
239endif()
240
241if(DEFINED 3DS OR DEFINED PSP2 OR DEFINED WII)
242 set(USE_DEBUGGERS OFF)
243endif()
244
245if(NOT M_CORE_GBA)
246 set(USE_GDB_STUB OFF)
247endif()
248
249if(NOT USE_DEBUGGERS)
250 set(USE_EDITLINE OFF)
251 set(USE_GDB_STUB OFF)
252endif()
253
254if(WII)
255 add_definitions(-U__STRICT_ANSI__)
256endif()
257
258include(CheckFunctionExists)
259check_function_exists(strdup HAVE_STRDUP)
260check_function_exists(strndup HAVE_STRNDUP)
261check_function_exists(localtime_r HAVE_LOCALTIME_R)
262if(NOT CMAKE_SYSTEM_NAME STREQUAL "Generic")
263 check_function_exists(snprintf_l HAVE_SNPRINTF_L)
264 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
265 # The strtof_l on Linux not actually exposed nor actually strtof_l
266 set(HAVE_STRTOF_L OFF)
267 else()
268 check_function_exists(strtof_l HAVE_STRTOF_L)
269 endif()
270 check_function_exists(newlocale HAVE_NEWLOCALE)
271 check_function_exists(freelocale HAVE_FREELOCALE)
272 check_function_exists(uselocale HAVE_USELOCALE)
273 check_function_exists(setlocale HAVE_SETLOCALE)
274else()
275 if(NOT DEFINED 3DS AND NOT DEFINED PSP2 AND NOT DEFINED WII)
276 set(DISABLE_DEPS ON CACHE BOOL "This platform cannot build with dependencies" FORCE)
277 endif()
278 set(DISABLE_FRONTENDS ON)
279 set(MINIMAL_CORE ON)
280endif()
281
282check_function_exists(chmod HAVE_CHMOD)
283check_function_exists(umask HAVE_UMASK)
284
285set(FUNCTION_DEFINES)
286
287if(HAVE_STRDUP)
288 list(APPEND FUNCTION_DEFINES HAVE_STRDUP)
289endif()
290
291if(HAVE_STRNDUP)
292 list(APPEND FUNCTION_DEFINES HAVE_STRNDUP)
293endif()
294
295if(HAVE_LOCALTIME_R)
296 list(APPEND FUNCTION_DEFINES HAVE_LOCALTIME_R)
297endif()
298
299if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE OR APPLE)
300 list(APPEND FUNCTION_DEFINES HAVE_LOCALE)
301 if (HAVE_STRTOF_L)
302 list(APPEND FUNCTION_DEFINES HAVE_STRTOF_L)
303 endif()
304 if (HAVE_SNPRINTF_L)
305 list(APPEND FUNCTION_DEFINES HAVE_SNPRINTF_L)
306 endif()
307endif()
308
309if(HAVE_SETLOCALE)
310 list(APPEND FUNCTION_DEFINES HAVE_SETLOCALE)
311endif()
312
313if(HAVE_CHMOD)
314 list(APPEND FUNCTION_DEFINES HAVE_CHMOD)
315endif()
316
317if(HAVE_UMASK)
318 list(APPEND FUNCTION_DEFINES HAVE_UMASK)
319endif()
320
321# Feature dependencies
322set(FEATURES)
323if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
324 set(LIBEDIT_LIBRARIES -ledit)
325 if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
326 list(APPEND LIBEDIT_LIBRARIES -ltermcap)
327 endif()
328else()
329 find_feature(USE_EDITLINE "libedit")
330endif()
331if(BUILD_GL)
332 find_package(OpenGL QUIET)
333 if(NOT OPENGL_FOUND)
334 set(BUILD_GL OFF CACHE BOOL "OpenGL not found" FORCE)
335 endif()
336endif()
337if(NOT BUILD_GL)
338 set(OPENGLE_LIBRARY "" CACHE PATH "" FORCE)
339endif()
340if(BUILD_GLES2 AND NOT BUILD_RASPI)
341 find_path(OPENGLES2_INCLUDE_DIR NAMES GLES2/gl2.h)
342 find_library(OPENGLES2_LIBRARY NAMES GLESv2 GLESv2_CM)
343 if(NOT OPENGLES2_INCLUDE_DIR OR NOT OPENGLES2_LIBRARY)
344 set(BUILD_GLES2 OFF CACHE BOOL "OpenGL|ES 2 not found" FORCE)
345 endif()
346endif()
347if(NOT BUILD_GLES2)
348 set(OPENGLES2_LIBRARY "" CACHE PATH "" FORCE)
349endif()
350set(WANT_ZLIB ${USE_ZLIB})
351set(WANT_PNG ${USE_PNG})
352set(WANT_LIBZIP ${USE_LIBZIP})
353set(USE_CMOCKA ${BUILD_SUITE})
354
355find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
356find_feature(USE_ZLIB "ZLIB")
357find_feature(USE_MINIZIP "minizip")
358find_feature(USE_PNG "PNG")
359find_feature(USE_LIBZIP "libzip")
360find_feature(USE_MAGICK "MagickWand")
361find_feature(USE_EPOXY "epoxy")
362find_feature(USE_CMOCKA "cmocka")
363
364# Features
365set(DEBUGGER_SRC
366 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/debugger.c
367 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/parser.c
368 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/cli-debugger.c)
369
370set(FEATURE_SRC)
371set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
372
373if(DISABLE_DEPS)
374 set(USE_GDB_STUB OFF)
375endif()
376
377if(USE_EDITLINE)
378 list(APPEND FEATURES EDITLINE)
379 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/cli-debugger.c)
380 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/parser.c)
381 if(M_CORE_GBA)
382 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c)
383 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/extra/cli.c)
384 endif()
385 if(M_CORE_GB)
386 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/cli-debugger.c)
387 endif()
388 if(M_CORE_DS)
389 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c)
390 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/ds/extra/cli.c)
391 endif()
392 include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
393 link_directories(${LIBEDIT_LIBRARY_DIRS})
394 set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
395 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
396 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/editline/cli-el-backend.c")
397else()
398 set(DEBUGGER_LIB "")
399endif()
400
401if(USE_GDB_STUB)
402 list(APPEND FEATURES GDB_STUB)
403 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/gdb-stub.c)
404endif()
405source_group("Debugger" FILES ${DEBUGGER_SRC})
406
407if(USE_FFMPEG)
408 list(APPEND FEATURES FFMPEG)
409 pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
410 if(NOT LIBSWRESAMPLE_FOUND)
411 list(APPEND FEATURES LIBAV)
412 endif()
413 include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
414 link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
415 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/ffmpeg/ffmpeg-encoder.c")
416 string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
417 string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
418 string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
419 string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
420 string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
421 list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
422 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR}|libavcodec-extra-${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
423 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavformat${LIBAVFORMAT_VERSION_MAJOR}|libavformat-ffmpeg${LIBAVFORMAT_VERSION_MAJOR}")
424 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavresample${LIBAVRESAMPLE_VERSION_MAJOR}|libavresample-ffmpeg${LIBAVRESAMPLE_VERSION_MAJOR}")
425 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavutil${LIBAVUTIL_VERSION_MAJOR}|libavutil-ffmpeg${LIBAVUTIL_VERSION_MAJOR}")
426 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libswscale${LIBSWSCALE_VERSION_MAJOR}|libswscale-ffmpeg${LIBSWSCALE_VERSION_MAJOR}")
427 set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
428 if(APPLE)
429 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
430 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
431 endif()
432endif()
433
434list(APPEND THIRD_PARTY_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
435
436if(USE_MAGICK)
437 list(APPEND FEATURES MAGICK)
438 include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
439 link_directories(${MAGICKWAND_LIBRARY_DIRS})
440 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/imagemagick/imagemagick-gif-encoder.c")
441 list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
442 string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
443 if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
444 set(MAGICKWAND_DEB_VERSION "5")
445 else()
446 set(MAGICKWAND_DEB_VERSION "-6.q16-2")
447 endif()
448 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
449endif()
450
451if(WANT_ZLIB AND NOT USE_ZLIB)
452 set(SKIP_INSTALL_ALL ON)
453 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib zlib)
454 set_property(TARGET zlibstatic PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/zlib;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib)
455 set_property(TARGET zlib PROPERTY EXCLUDE_FROM_ALL ON)
456 set_property(TARGET example PROPERTY EXCLUDE_FROM_ALL ON)
457 set_property(TARGET minigzip PROPERTY EXCLUDE_FROM_ALL ON)
458 set(ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
459 set(ZLIB_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
460 set(ZLIB_LIBRARY zlibstatic)
461 list(APPEND DEPENDENCY_LIB zlibstatic)
462 set(USE_ZLIB ON)
463endif()
464
465if(USE_ZLIB)
466 list(APPEND FEATURES ZLIB)
467 include_directories(AFTER ${ZLIB_INCLUDE_DIRS})
468 list(APPEND DEPENDENCY_LIB ${ZLIB_LIBRARIES})
469 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},zlib1g")
470endif()
471
472if(WANT_PNG AND USE_ZLIB AND NOT USE_PNG)
473 set(PNG_STATIC ON CACHE BOOL "" FORCE)
474 set(PNG_SHARED OFF CACHE BOOL "" FORCE)
475 set(PNG_TESTS OFF CACHE BOOL "" FORCE)
476 set(SKIP_INSTALL_ALL ON)
477 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng libpng)
478 set_property(TARGET png16_static PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/libpng;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng;${ZLIB_INCLUDE_DIRS})
479 set(PNG_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng ${CMAKE_CURRENT_BINARY_DIR}/libpng)
480 list(APPEND DEPENDENCY_LIB png16_static)
481 set(USE_PNG ON)
482endif()
483
484if(USE_PNG)
485 list(APPEND FEATURES PNG)
486 include_directories(AFTER ${PNG_INCLUDE_DIRS})
487 list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
488 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng12-0")
489endif()
490
491if(USE_LIBZIP)
492 include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
493 link_directories(${LIBZIP_LIBRARY_DIRS})
494 list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
495 list(APPEND FEATURES LIBZIP)
496 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
497 string(REGEX MATCH "^[0-9]+" LIBZIP_VERSION_MAJOR ${libzip_VERSION})
498 if (LIBZIP_VERSION_MAJOR LESS 1)
499 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
500 elseif(LIBZIP_VERSION_MAJOR EQUAL 1)
501 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip4")
502 else()
503 message(AUTHOR_WARNING Unknown version of libzip detected: ${libzip_VERSION})
504 endif()
505elseif(USE_MINIZIP)
506 include_directories(AFTER ${MINIZIP_INCLUDE_DIRS})
507 link_directories(${MINIZIP_LIBRARY_DIRS})
508 list(APPEND DEPENDENCY_LIB ${MINIZIP_LIBRARIES})
509 list(APPEND FEATURES MINIZIP)
510 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
511 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libminizip1")
512elseif(USE_ZLIB)
513 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c
514 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
515 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c)
516 set_source_files_properties(
517 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
518 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c
519 PROPERTIES COMPILE_FLAGS "-Wno-unused-parameter -Wno-implicit-function-declaration")
520endif()
521
522if (USE_LZMA)
523 include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/third-party/lzma)
524 add_definitions(-D_7ZIP_PPMD_SUPPPORT)
525 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-lzma.c)
526 set(LZMA_SRC
527 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
528 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
529 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
530 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
531 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
532 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
533 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zDec.c
534 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
535 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Delta.c
536 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
537 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
538 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra.c
539 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra86.c
540 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/BraIA64.c
541 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
542 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
543 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
544 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zFile.c
545 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
546 list(APPEND VFS_SRC ${LZMA_SRC})
547 list(APPEND FEATURES LZMA)
548endif()
549
550if(USE_EPOXY)
551 add_definitions(-DBUILD_GL -DBUILD_GLES2)
552 list(APPEND FEATURES EPOXY)
553 include_directories(AFTER ${EPOXY_INCLUDE_DIRS})
554 set(OPENGLES2_LIBRARY ${EPOXY_LIBRARIES})
555 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libepoxy0")
556endif()
557
558set(TEST_SRC ${CORE_TEST_SRC})
559if(M_CORE_GB)
560 add_definitions(-DM_CORE_GB)
561 list(APPEND CORE_SRC
562 ${LR35902_SRC}
563 ${GB_SRC}
564 ${GB_RENDERER_SRC})
565 list(APPEND DEBUGGER_SRC
566 ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/cli-debugger.c
567 ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/debugger.c
568 ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/extra/cli.c)
569 list(APPEND TEST_SRC
570 ${LR35902_TEST_SRC}
571 ${GB_TEST_SRC})
572endif()
573
574if(M_CORE_GBA)
575 add_definitions(-DM_CORE_GBA)
576 list(APPEND CORE_SRC
577 ${ARM_SRC}
578 ${GBA_SRC}
579 ${GBA_CHEATS_SRC}
580 ${GBA_RENDERER_SRC})
581 list(APPEND DEBUGGER_SRC
582 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c
583 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/debugger.c
584 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/memory-debugger.c
585 ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/extra/cli.c)
586 list(APPEND TEST_SRC
587 ${ARM_TEST_SRC}
588 ${GBA_TEST_SRC})
589 if(NOT M_CORE_GB)
590 list(APPEND CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/audio.c)
591 endif()
592endif()
593
594if(USE_DEBUGGERS)
595 list(APPEND FEATURE_SRC ${DEBUGGER_SRC})
596 list(APPEND FEATURES DEBUGGERS)
597endif()
598
599set(FEATURE_DEFINES)
600foreach(FEATURE IN LISTS FEATURES)
601 list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
602endforeach()
603
604if(M_CORE_DS)
605 add_definitions(-DM_CORE_DS)
606 list(APPEND CORE_SRC
607 ${ARM_SRC}
608 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/debugger.c
609 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/memory-debugger.c
610 ${DS_SRC})
611endif()
612
613source_group("Virtual files" FILES ${CORE_VFS_SRC} ${VFS_SRC})
614source_group("Extra features" FILES ${FEATURE_SRC})
615source_group("Third-party code" FILES ${THIRD_PARTY_SRC})
616
617# Platform binaries
618if(3DS)
619 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/3ds ${CMAKE_CURRENT_BINARY_DIR}/3ds)
620endif()
621
622if(WII)
623 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/wii ${CMAKE_CURRENT_BINARY_DIR}/wii)
624endif()
625
626if(PSP2)
627 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/psp2 ${CMAKE_CURRENT_BINARY_DIR}/psp2)
628endif()
629
630# Binaries
631list(APPEND CORE_SRC
632 ${UTIL_SRC}
633 ${CORE_VFS_SRC}
634 ${OS_SRC}
635 ${THIRD_PARTY_SRC})
636list(APPEND TEST_SRC ${UTIL_TEST_SRC})
637
638set(SRC ${CORE_SRC} ${VFS_SRC})
639if(NOT MINIMAL_CORE)
640 if(M_CORE_GBA)
641 list(APPEND SRC
642 ${GBA_RR_SRC}
643 ${GBA_EXTRA_SRC}
644 ${SIO_SRC})
645 endif()
646 list(APPEND SRC
647 ${FEATURE_SRC}
648 ${CLI_SRC})
649endif()
650
651if(NOT SKIP_LIBRARY)
652 if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
653 set(BUILD_SHARED ON)
654 endif()
655
656 if(BUILD_SHARED)
657 add_library(${BINARY_NAME} SHARED ${SRC} ${VFS_SRC})
658 if(BUILD_STATIC)
659 add_library(${BINARY_NAME}-static STATIC ${SRC})
660 set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
661 install(TARGETS ${BINARY_NAME}-static DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
662 add_dependencies(${BINARY_NAME}-static version-info)
663 endif()
664 else()
665 add_library(${BINARY_NAME} STATIC ${SRC})
666 endif()
667
668 add_dependencies(${BINARY_NAME} version-info)
669 set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
670
671 target_link_libraries(${BINARY_NAME} ${DEBUGGER_LIB} ${DEPENDENCY_LIB} ${OS_LIB})
672 install(TARGETS ${BINARY_NAME} LIBRARY DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME} NAMELINK_SKIP ARCHIVE DESTINATION ${LIBDIR} RUNTIME DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
673 if(UNIX AND NOT APPLE)
674 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-16.png DESTINATION share/icons/hicolor/16x16/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
675 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-24.png DESTINATION share/icons/hicolor/24x24/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
676 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-32.png DESTINATION share/icons/hicolor/32x32/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
677 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-48.png DESTINATION share/icons/hicolor/48x48/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
678 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-64.png DESTINATION share/icons/hicolor/64x64/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
679 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-96.png DESTINATION share/icons/hicolor/96x96/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
680 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-128.png DESTINATION share/icons/hicolor/128x128/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
681 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-256.png DESTINATION share/icons/hicolor/256x256/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
682 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-512.png DESTINATION share/icons/hicolor/512x512/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
683 endif()
684else()
685 set(BUILD_SHARED OFF)
686 set(BUILD_STATIC OFF)
687 find_library(${BINARY_NAME} ${BINARY_NAME})
688 if(NOT ${BINARY_NAME}_FOUND)
689 set(DISABLE_FRONTENDS ON)
690 set(BUILD_PERF OFF)
691 set(BUILD_TEST OFF)
692 set(BUILD_SUITE OFF)
693 endif()
694endif()
695
696if(BUILD_GL)
697 add_definitions(-DBUILD_GL)
698endif()
699
700if(BUILD_GLES2)
701 add_definitions(-DBUILD_GLES2)
702endif()
703
704if(DISABLE_FRONTENDS)
705 set(BUILD_SDL OFF)
706 set(BUILD_QT OFF)
707endif()
708
709if(BUILD_LIBRETRO)
710 file(GLOB RETRO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/libretro/*.c)
711 add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
712 set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5;DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=2")
713 target_link_libraries(${BINARY_NAME}_libretro ${OS_LIB})
714 install(TARGETS ${BINARY_NAME}_libretro LIBRARY DESTINATION ${LIBRETRO_LIBDIR} COMPONENT ${BINARY_NAME}_libretro NAMELINK_SKIP)
715endif()
716
717if(BUILD_OPENEMU)
718 find_library(FOUNDATION Foundation)
719 find_library(OPENEMUBASE OpenEmuBase)
720 file(GLOB OE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/*.m)
721 add_library(${BINARY_NAME}-openemu MODULE ${CORE_SRC} ${OE_SRC})
722 set_target_properties(${BINARY_NAME}-openemu PROPERTIES
723 MACOSX_BUNDLE_INFO_PLIST ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/Info.plist.in
724 BUNDLE TRUE
725 BUNDLE_EXTENSION oecoreplugin
726 OUTPUT_NAME ${PROJECT_NAME}
727 COMPILE_DEFINITIONS "DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=1")
728 target_link_libraries(${BINARY_NAME}-openemu ${OS_LIB} ${FOUNDATION} ${OPENEMUBASE})
729 install(TARGETS ${BINARY_NAME}-openemu LIBRARY DESTINATION ${OE_LIBDIR} COMPONENT ${BINARY_NAME}.oecoreplugin NAMELINK_SKIP)
730endif()
731
732if(BUILD_SDL)
733 add_definitions(-DBUILD_SDL)
734 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/sdl ${CMAKE_CURRENT_BINARY_DIR}/sdl)
735endif()
736
737if(BUILD_QT)
738 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/qt ${CMAKE_CURRENT_BINARY_DIR}/qt)
739endif()
740
741if(BUILD_PERF)
742 set(PERF_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/perf-main.c ${CLI_SRC})
743 if(UNIX AND NOT APPLE)
744 list(APPEND PERF_LIB rt)
745 endif()
746
747 add_executable(${BINARY_NAME}-perf ${PERF_SRC})
748 target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB} ${OS_LIB})
749 set_target_properties(${BINARY_NAME}-perf PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
750 install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
751 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
752endif()
753
754if(BUILD_TEST)
755 add_executable(${BINARY_NAME}-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/fuzz-main.c)
756 target_link_libraries(${BINARY_NAME}-fuzz ${BINARY_NAME})
757 set_target_properties(${BINARY_NAME}-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
758 add_executable(tbl-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/tbl-fuzz-main.c)
759 target_link_libraries(tbl-fuzz ${BINARY_NAME})
760 set_target_properties(tbl-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
761 install(TARGETS ${BINARY_NAME}-fuzz tbl-fuzz DESTINATION bin COMPONENT ${BINARY_NAME}-test)
762endif()
763
764if(NOT USE_CMOCKA)
765 set(BUILD_SUITE OFF)
766endif()
767if(BUILD_SUITE)
768 enable_testing()
769 include_directories(AFTER ${CMOCKA_INCLUDE_DIRS})
770 link_directories(${CMOCKA_LIBRARY_DIRS})
771
772 add_executable(${BINARY_NAME}-suite ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/suite-main.c ${TEST_SRC})
773 target_link_libraries(${BINARY_NAME}-suite ${BINARY_NAME} ${PLATFORM_LIBRARY} cmocka)
774 set_target_properties(${BINARY_NAME}-suite PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
775 add_test(${BINARY_NAME}-suite ${BINARY_NAME}-suite)
776endif()
777
778if(BUILD_EXAMPLE)
779 add_executable(${BINARY_NAME}-example-server ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/server.c)
780 target_link_libraries(${BINARY_NAME}-example-server ${BINARY_NAME})
781 set_target_properties(${BINARY_NAME}-example-server PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
782
783 if(BUILD_SDL)
784 add_executable(${BINARY_NAME}-example-client ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/client.c)
785 target_link_libraries(${BINARY_NAME}-example-client ${BINARY_NAME} ${SDL_LIBRARY} ${SDLMAIN_LIBRARY} ${OPENGL_LIBRARY} ${OPENGLES2_LIBRARY})
786 set_target_properties(${BINARY_NAME}-example-client PROPERTIES
787 COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}"
788 INCLUDE_DIRECTORIES "${SDL_INCLUDE_DIR};${CMAKE_CURRENT_SOURCE_DIR}/src")
789 endif()
790endif()
791
792# Packaging
793set(CPACK_PACKAGE_VERSION ${VERSION_STRING})
794set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
795set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
796set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
797set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
798set(CPACK_RESOURCE_FILE_README ${CMAKE_CURRENT_SOURCE_DIR}/README.md)
799
800set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
801set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
802set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
803set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README.md")
804set(CPACK_DEBIAN_PACKAGE_SECTION "games")
805
806SET(CPACK_DEB_COMPONENT_INSTALL ON)
807
808set(CPACK_STRIP_FILES ${BINARY_NAME})
809
810install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/README.md ${CMAKE_CURRENT_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
811
812include(CPack)
813
814# Summaries
815set(SUMMARY_GL_LIST)
816if(USE_EPOXY)
817 set(SUMMARY_GL_LIST "libepoxy")
818else()
819 if(BUILD_GL)
820 list(APPEND SUMMARY_GL_LIST "OpenGL")
821 endif()
822 if(BUILD_GLES2)
823 list(APPEND SUMMARY_GL_LIST "OpenGL|ES 2")
824 endif()
825endif()
826if(NOT SUMMARY_GL_LIST)
827 set(SUMMARY_GL OFF)
828else()
829 string(REPLACE ";" ", " SUMMARY_GL "${SUMMARY_GL_LIST}")
830endif()
831if(USE_LIBZIP)
832 set(SUMMARY_ZIP libzip)
833elseif(USE_MINIZIP)
834 set(SUMMARY_ZIP "minizip (external)")
835elseif(USE_ZLIB)
836 set(SUMMARY_ZIP "minizip (included)")
837else()
838 set(SUMMARY_ZIP OFF)
839endif()
840
841if(NOT QUIET)
842 message(STATUS "Platforms:")
843 message(STATUS " Game Boy Advance: ${M_CORE_GBA}")
844 message(STATUS " Game Boy: ${M_CORE_GB}")
845 message(STATUS " DS: ${M_CORE_DS}")
846 message(STATUS "Features:")
847 message(STATUS " Debuggers: ${USE_DEBUGGERS}")
848 message(STATUS " CLI debugger: ${USE_EDITLINE}")
849 message(STATUS " GDB stub: ${USE_GDB_STUB}")
850 message(STATUS " Video recording: ${USE_FFMPEG}")
851 message(STATUS " GIF recording: ${USE_MAGICK}")
852 message(STATUS " Screenshot/advanced savestate support: ${USE_PNG}")
853 message(STATUS " ZIP support: ${SUMMARY_ZIP}")
854 message(STATUS " 7-Zip support: ${USE_LZMA}")
855 message(STATUS " OpenGL support: ${SUMMARY_GL}")
856 message(STATUS "Frontends:")
857 message(STATUS " Qt: ${BUILD_QT}")
858 message(STATUS " SDL (${SDL_VERSION}): ${BUILD_SDL}")
859 message(STATUS " Profiling: ${BUILD_PERF}")
860 message(STATUS " Test harness: ${BUILD_TEST}")
861 message(STATUS " Test suite: ${BUILD_SUITE}")
862 message(STATUS " Examples: ${BUILD_EXAMPLE}")
863 message(STATUS "Cores:")
864 message(STATUS " Libretro core: ${BUILD_LIBRETRO}")
865 if(APPLE)
866 message(STATUS " OpenEmu core: ${BUILD_OPENEMU}")
867 endif()
868 message(STATUS "Libraries:")
869 message(STATUS " Static: ${BUILD_STATIC}")
870 message(STATUS " Shared: ${BUILD_SHARED}")
871endif()