CMakeLists.txt (view raw)
1cmake_minimum_required(VERSION 2.6)
2project(mGBA C)
3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
4set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -std=gnu99")
5set(USE_CLI_DEBUGGER ON CACHE BOOL "Whether or not to enable the CLI-mode ARM debugger")
6set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
7set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
8set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
9set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable ZIP support")
10set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
11set(USE_BLIP ON CACHE BOOL "Whether or not to enable blip_buf support")
12set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
13set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
14set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
15set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
16set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
17set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
18file(GLOB ARM_SRC ${CMAKE_SOURCE_DIR}/src/arm/*.c)
19file(GLOB GBA_SRC ${CMAKE_SOURCE_DIR}/src/gba/*.c)
20file(GLOB GBA_RR_SRC ${CMAKE_SOURCE_DIR}/src/gba/rr/*.c)
21file(GLOB GBA_SV_SRC ${CMAKE_SOURCE_DIR}/src/gba/supervisor/*.c)
22file(GLOB UTIL_SRC ${CMAKE_SOURCE_DIR}/src/util/*.[cSs])
23file(GLOB VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/*.c)
24file(GLOB RENDERER_SRC ${CMAKE_SOURCE_DIR}/src/gba/renderers/video-software.c)
25file(GLOB THIRD_PARTY_SRC ${CMAKE_SOURCE_DIR}/src/third-party/inih/*.c)
26list(APPEND UTIL_SRC ${CMAKE_SOURCE_DIR}/src/platform/commandline.c)
27source_group("ARM core" FILES ${ARM_SRC})
28source_group("GBA board" FILES ${GBA_SRC} ${RENDERER_SRC})
29source_group("GBA supervisor" FILES ${GBA_SV_SRC} ${GBA_RR_SRC})
30source_group("Utilities" FILES ${UTIL_SRC} ${VFS_SRC}})
31include_directories(${CMAKE_SOURCE_DIR}/src/arm)
32include_directories(${CMAKE_SOURCE_DIR}/src)
33
34if(NOT CMAKE_BUILD_TYPE)
35 set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
36endif()
37
38set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
39
40include(GNUInstallDirs)
41
42# Function definitions
43include(FindPkgConfig)
44function(find_feature FEATURE_NAME FEATURE_REQUIRES)
45 if (NOT ${FEATURE_NAME})
46 return()
47 endif()
48 foreach(REQUIRE ${FEATURE_REQUIRES})
49 if(NOT ${REQUIRE}_FOUND)
50 find_package(${REQUIRE} QUIET)
51 if(NOT ${REQUIRE}_FOUND)
52 pkg_search_module(${REQUIRE} ${REQUIRE})
53 if (NOT ${REQUIRE}_FOUND)
54 message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
55 set(${FEATURE_NAME} OFF PARENT_SCOPE)
56 return()
57 endif()
58 endif()
59 endif()
60 string(TOUPPER ${REQUIRE} UREQUIRE)
61 set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
62 set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
63 set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
64 set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
65 set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
66 set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
67 endforeach()
68endfunction()
69
70# Version information
71set(LIB_VERSION_MAJOR 0)
72set(LIB_VERSION_MINOR 2)
73set(LIB_VERSION_PATCH 0)
74set(LIB_VERSION_ABI 0.2)
75set(LIB_VERSION_STRING ${LIB_VERSION_MAJOR}.${LIB_VERSION_MINOR}.${LIB_VERSION_PATCH})
76
77# Advanced settings
78set(BUILD_PGO CACHE BOOL "Build with profiling-guided optimization")
79set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
80set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
81mark_as_advanced(BUILD_PGO PGO_STAGE_2 PGO_DIR)
82set(PGO_PRE_FLAGS "-pg -fprofile-generate=${PGO_DIR} -fprofile-arcs")
83set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
84
85if(BUILD_PGO AND NOT PGO_STAGE_2)
86 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
87 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
88 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
89elseif(BUILD_PGO AND PGO_STAGE_2)
90 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
91 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
92 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
93endif()
94
95add_definitions(-DBINARY_NAME="${BINARY_NAME}" -DPROJECT_NAME="${PROJECT_NAME}" -DPROJECT_VERSION="${LIB_VERSION_STRING}")
96
97# Feature dependencies
98if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
99 set(LIBEDIT_LIBRARIES -ledit)
100else()
101 find_feature(USE_CLI_DEBUGGER "libedit")
102endif()
103find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
104find_feature(USE_PNG "ZLIB;PNG")
105find_feature(USE_LIBZIP "libzip")
106find_feature(USE_MAGICK "MagickWand")
107
108# Platform support
109if(WIN32)
110 add_definitions(-D_WIN32_WINNT=0x0600)
111 list(APPEND OS_LIB ws2_32)
112 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/windows/*.c)
113 source_group("Windows-specific code" FILES ${OS_SRC})
114else()
115 add_definitions(-DUSE_PTHREADS)
116 if(NOT APPLE)
117 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
118 endif()
119 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/posix/*.c)
120 source_group("POSIX-specific code" FILES ${OS_SRC})
121endif()
122
123if(APPLE)
124 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
125endif()
126
127if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU")
128 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
129 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
130endif()
131
132if(BUILD_BBB OR BUILD_RASPI)
133 enable_language(ASM)
134 if(NOT BUILD_EGL)
135 add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
136 endif()
137endif()
138
139include(CheckFunctionExists)
140check_function_exists(strndup HAVE_STRNDUP)
141check_function_exists(snprintf_l HAVE_SNPRINTF_L)
142if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
143 # The strtof_l on Linux not actually exposed nor actually strtof_l
144 set(HAVE_STRTOF_L OFF)
145else()
146 check_function_exists(strtof_l HAVE_STRTOF_L)
147endif()
148check_function_exists(newlocale HAVE_NEWLOCALE)
149check_function_exists(freelocale HAVE_FREELOCALE)
150check_function_exists(uselocale HAVE_USELOCALE)
151
152if(HAVE_STRNDUP)
153 add_definitions(-DHAVE_STRNDUP)
154endif()
155
156if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE)
157 add_definitions(-DHAVE_LOCALE)
158 if (HAVE_STRTOF_L)
159 add_definitions(-DHAVE_STRTOF_L)
160 endif()
161 if (HAVE_SNPRINTF_L)
162 add_definitions(-DHAVE_SNPRINTF_L)
163 endif()
164endif()
165
166
167# Features
168set(DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/debugger.c ${CMAKE_SOURCE_DIR}/src/debugger/memory-debugger.c)
169set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
170
171if(USE_CLI_DEBUGGER)
172 add_definitions(-DUSE_CLI_DEBUGGER)
173 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/cli-debugger.c)
174 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/parser.c)
175 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/gba/supervisor/cli.c)
176 include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
177 link_directories(${LIBEDIT_LIBRARY_DIRS})
178 set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
179 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
180else()
181 set(DEBUGGER_LIB "")
182endif()
183
184if(USE_GDB_STUB)
185 add_definitions(-DUSE_GDB_STUB)
186 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/gdb-stub.c)
187endif()
188source_group("ARM debugger" FILES ${DEBUGGER_SRC})
189
190if(USE_FFMPEG)
191 add_definitions(-DUSE_FFMPEG)
192 pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
193 if(NOT LIBSWRESAMPLE_FOUND)
194 add_definitions(-DUSE_LIBAV)
195 endif()
196 include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
197 link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
198 list(APPEND UTIL_SRC "${CMAKE_SOURCE_DIR}/src/platform/ffmpeg/ffmpeg-encoder.c")
199 string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
200 string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
201 string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
202 string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
203 string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
204 list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
205 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR},libavformat${LIBAVFORMAT_VERSION_MAJOR},libavresample${LIBAVRESAMPLE_VERSION_MAJOR},libavutil${LIBAVUTIL_VERSION_MAJOR},libswscale${LIBSWSCALE_VERSION_MAJOR}")
206 set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra")
207endif()
208
209if(USE_BLIP)
210 list(APPEND UTIL_SRC "${CMAKE_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
211 add_definitions(-DRESAMPLE_LIBRARY=RESAMPLE_BLIP_BUF)
212else()
213 add_definitions(-DRESAMPLE_LIBRARY=RESAMPLE_NN)
214endif()
215
216if(USE_MAGICK)
217 add_definitions(-DUSE_MAGICK)
218 include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
219 link_directories(${MAGICKWAND_LIBRARY_DIRS})
220 list(APPEND UTIL_SRC "${CMAKE_SOURCE_DIR}/src/platform/imagemagick/imagemagick-gif-encoder.c")
221 list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
222 string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
223 if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
224 set(MAGICKWAND_DEB_VERSION "5")
225 else()
226 set(MAGICKWAND_DEB_VERSION "-6.q16-2")
227 endif()
228 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
229endif()
230
231if(USE_PNG)
232 add_definitions(-DUSE_PNG)
233 include_directories(AFTER ${PNG_INCLUDE_DIRS})
234 list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
235 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng12-0,zlib1g")
236endif()
237
238if(USE_LIBZIP)
239 include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
240 link_directories(${LIBZIP_LIBRARY_DIRS})
241 list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
242 add_definitions(-DENABLE_LIBZIP)
243 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
244endif()
245
246if (USE_LZMA)
247 include_directories(AFTER ${CMAKE_SOURCE_DIR}/third-party/lzma)
248 add_definitions(-D_7ZIP_PPMD_SUPPPORT)
249 set(LZMA_SRC
250 ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-lzma.c
251 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
252 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
253 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
254 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
255 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
256 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
257 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zDec.c
258 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
259 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
260 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
261 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bra.c
262 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bra86.c
263 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
264 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
265 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
266 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zFile.c
267 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
268 list(APPEND UTIL_SRC ${LZMA_SRC})
269 add_definitions(-DENABLE_LZMA)
270endif()
271
272# Binaries
273set(SRC
274 ${ARM_SRC}
275 ${GBA_SRC}
276 ${GBA_RR_SRC}
277 ${GBA_SV_SRC}
278 ${DEBUGGER_SRC}
279 ${RENDERER_SRC}
280 ${UTIL_SRC}
281 ${VFS_SRC}
282 ${OS_SRC}
283 ${THIRD_PARTY_SRC})
284
285if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
286 set(BUILD_SHARED ON)
287endif()
288
289if(BUILD_SHARED)
290 add_library(${BINARY_NAME} SHARED ${SRC})
291 if(BUILD_STATIC)
292 add_library(${BINARY_NAME}-static STATIC ${SRC})
293 install(TARGETS ${BINARY_NAME}-static DESTINATION lib COMPONENT lib${BINARY_NAME})
294 endif()
295else()
296 add_library(${BINARY_NAME} STATIC ${SRC})
297endif()
298
299target_link_libraries(${BINARY_NAME} m ${DEBUGGER_LIB} ${OS_LIB} ${DEPENDENCY_LIB})
300install(TARGETS ${BINARY_NAME} DESTINATION lib COMPONENT lib${BINARY_NAME})
301set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI})
302
303if(BUILD_SDL)
304 add_definitions(-DBUILD_SDL)
305 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/sdl ${CMAKE_BINARY_DIR}/sdl)
306endif()
307
308if(BUILD_QT)
309 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/qt ${CMAKE_BINARY_DIR}/qt)
310endif()
311
312if(BUILD_PERF)
313 set(PERF_SRC ${CMAKE_SOURCE_DIR}/src/platform/perf-main.c)
314 if(UNIX AND NOT APPLE)
315 list(APPEND PERF_LIB rt)
316 endif()
317
318 add_executable(${BINARY_NAME}-perf ${PERF_SRC})
319 target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB})
320 install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
321 install(FILES ${CMAKE_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
322endif()
323
324# Packaging
325set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
326set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
327set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
328set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_SOURCE_DIR}/LICENSE)
329set(CPACK_RESOURCE_FILE_README ${CMAKE_SOURCE_DIR}/README.md)
330
331set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
332set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
333set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
334set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_SOURCE_DIR}/README.md")
335set(CPACK_DEBIAN_PACKAGE_SECTION "games")
336
337SET(CPACK_DEB_COMPONENT_INSTALL ON)
338
339set(CPACK_STRIP_FILES ${BINARY_NAME})
340
341install(FILES ${CMAKE_SOURCE_DIR}/README.md ${CMAKE_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
342
343include(CPack)
344
345# Summaries
346message(STATUS "Feature summary:")
347message(STATUS " CLI debugger: ${USE_CLI_DEBUGGER}")
348message(STATUS " GDB stub: ${USE_GDB_STUB}")
349message(STATUS " Video recording: ${USE_FFMPEG}")
350message(STATUS " GIF recording: ${USE_MAGICK}")
351message(STATUS " Screenshot/advanced savestate support: ${USE_PNG}")
352message(STATUS " ZIP support: ${USE_LIBZIP}")
353message(STATUS " 7-Zip support: ${USE_LZMA}")
354message(STATUS " Better audio resampling: ${USE_BLIP}")
355message(STATUS "Frontend summary:")
356message(STATUS " Qt: ${BUILD_QT}")
357message(STATUS " SDL (${SDL_VERSION}): ${BUILD_SDL}")
358message(STATUS " Profiling: ${BUILD_PERF}")
359message(STATUS "Library summary:")
360message(STATUS " Static: ${BUILD_STATIC}")
361message(STATUS " Shared: ${BUILD_SHARED}")