CMakeLists.txt (view raw)
1cmake_minimum_required(VERSION 2.6)
2project(mGBA C)
3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
4set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -std=gnu99")
5set(USE_CLI_DEBUGGER ON CACHE BOOL "Whether or not to enable the CLI-mode ARM debugger")
6set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
7set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
8set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
9set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable ZIP support")
10set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
11set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
12set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
13set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
14file(GLOB ARM_SRC ${CMAKE_SOURCE_DIR}/src/arm/*.c)
15file(GLOB GBA_SRC ${CMAKE_SOURCE_DIR}/src/gba/*.c)
16file(GLOB UTIL_SRC ${CMAKE_SOURCE_DIR}/src/util/*.[cS])
17file(GLOB VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/*.c)
18file(GLOB RENDERER_SRC ${CMAKE_SOURCE_DIR}/src/gba/renderers/video-software.c)
19file(GLOB THIRD_PARTY_SRC ${CMAKE_SOURCE_DIR}/src/third-party/inih/*.c)
20list(APPEND UTIL_SRC ${CMAKE_SOURCE_DIR}/src/platform/commandline.c)
21source_group("ARM core" FILES ${ARM_SRC})
22source_group("GBA board" FILES ${GBA_SRC} ${RENDERER_SRC})
23source_group("Utilities" FILES ${UTIL_SRC} ${VFS_SRC}})
24include_directories(${CMAKE_SOURCE_DIR}/src/arm)
25include_directories(${CMAKE_SOURCE_DIR}/src/gba)
26include_directories(${CMAKE_SOURCE_DIR}/src)
27
28include(GNUInstallDirs)
29
30# Function definitions
31include(FindPkgConfig)
32function(find_feature FEATURE_NAME FEATURE_REQUIRES)
33 if (NOT ${FEATURE_NAME})
34 return()
35 endif()
36 foreach(REQUIRE ${FEATURE_REQUIRES})
37 if(NOT ${REQUIRE}_FOUND)
38 find_package(${REQUIRE} QUIET)
39 if(NOT ${REQUIRE}_FOUND)
40 pkg_search_module(${REQUIRE} ${REQUIRE})
41 if (NOT ${REQUIRE}_FOUND)
42 message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
43 set(${FEATURE_NAME} OFF PARENT_SCOPE)
44 return()
45 endif()
46 endif()
47 endif()
48 string(TOUPPER ${REQUIRE} UREQUIRE)
49 set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
50 set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
51 set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
52 set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
53 set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
54 set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
55 endforeach()
56endfunction()
57
58# Version information
59set(LIB_VERSION_MAJOR 0)
60set(LIB_VERSION_MINOR 1)
61set(LIB_VERSION_PATCH 0)
62set(LIB_VERSION_ABI 0.1)
63set(LIB_VERSION_STRING ${LIB_VERSION_MAJOR}.${LIB_VERSION_MINOR}.${LIB_VERSION_PATCH})
64
65# Advanced settings
66set(BUILD_PGO CACHE BOOL "Build with profiling-guided optimization")
67set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
68set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
69mark_as_advanced(BUILD_PGO PGO_STAGE_2 PGO_DIR)
70set(PGO_PRE_FLAGS "-pg -fprofile-generate=${PGO_DIR} -fprofile-arcs")
71set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
72
73if(BUILD_PGO AND NOT PGO_STAGE_2)
74 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
75 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
76 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
77elseif(BUILD_PGO AND PGO_STAGE_2)
78 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
79 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
80 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
81endif()
82
83add_definitions(-DBINARY_NAME="${BINARY_NAME}" -DPROJECT_NAME="${PROJECT_NAME}" -DPROJECT_VERSION="${LIB_VERSION_STRING}")
84
85# Feature dependencies
86find_feature(USE_CLI_DEBUGGER "libedit")
87find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
88find_feature(USE_PNG "ZLIB;PNG")
89find_feature(USE_LIBZIP "libzip")
90find_feature(USE_MAGICK "MagickWand")
91
92include(CheckFunctionExists)
93check_function_exists(strndup HAVE_STRNDUP)
94
95if(HAVE_STRNDUP)
96 add_definitions(-DHAVE_STRNDUP)
97endif()
98
99# Platform support
100if(WIN32)
101 add_definitions(-D_WIN32_WINNT=0x0600)
102 list(APPEND OS_LIB ws2_32)
103 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/windows/*.c)
104 source_group("Windows-specific code" FILES ${OS_SRC})
105else()
106 add_definitions(-DUSE_PTHREADS)
107 list(APPEND OS_LIB pthread)
108 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/posix/*.c)
109 source_group("POSIX-specific code" FILES ${OS_SRC})
110endif()
111
112if(BUILD_BBB OR BUILD_RASPI)
113 enable_language(ASM)
114 if(NOT BUILD_EGL)
115 add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
116 endif()
117endif()
118
119# Features
120set(DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/debugger.c ${CMAKE_SOURCE_DIR}/src/debugger/memory-debugger.c)
121
122if(USE_CLI_DEBUGGER)
123 add_definitions(-DUSE_CLI_DEBUGGER)
124 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/cli-debugger.c)
125 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/parser.c)
126 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/gba/gba-cli.c)
127 include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
128 link_directories(${LIBEDIT_LIBRARY_DIRS})
129 set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
130else()
131 set(DEBUGGER_LIB "")
132endif()
133
134if(USE_GDB_STUB)
135 add_definitions(-DUSE_GDB_STUB)
136 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/gdb-stub.c)
137endif()
138source_group("ARM debugger" FILES ${DEBUGGER_SRC})
139
140if(USE_FFMPEG)
141 add_definitions(-DUSE_FFMPEG)
142 include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
143 link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
144 list(APPEND UTIL_SRC "${CMAKE_SOURCE_DIR}/src/platform/ffmpeg/ffmpeg-encoder.c")
145 list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
146endif()
147
148if(USE_MAGICK)
149 add_definitions(-DUSE_MAGICK)
150 include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
151 link_directories(${MAGICKWAND_LIBRARY_DIRS})
152 list(APPEND UTIL_SRC "${CMAKE_SOURCE_DIR}/src/platform/imagemagick/imagemagick-gif-encoder.c")
153 list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
154endif()
155
156if(USE_PNG)
157 add_definitions(-DUSE_PNG)
158 include_directories(AFTER ${PNG_INCLUDE_DIRS})
159 list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
160endif()
161
162if(USE_LIBZIP)
163 include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
164 link_directories(${LIBZIP_LIBRARY_DIRS})
165 list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
166 add_definitions(-DENABLE_LIBZIP)
167endif()
168
169# Binaries
170add_library(${BINARY_NAME} SHARED
171 ${ARM_SRC}
172 ${GBA_SRC}
173 ${DEBUGGER_SRC}
174 ${RENDERER_SRC}
175 ${UTIL_SRC}
176 ${VFS_SRC}
177 ${OS_SRC}
178 ${THIRD_PARTY_SRC})
179target_link_libraries(${BINARY_NAME} m ${DEBUGGER_LIB} ${OS_LIB} ${DEPENDENCY_LIB})
180install(TARGETS ${BINARY_NAME} DESTINATION lib)
181set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI})
182
183if(BUILD_SDL)
184 add_definitions(-DBUILD_SDL)
185 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/sdl ${CMAKE_BINARY_DIR}/sdl)
186endif()
187
188if(BUILD_QT)
189 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/qt ${CMAKE_BINARY_DIR}/qt)
190endif()
191
192if(BUILD_PERF)
193 set(PERF_SRC ${CMAKE_SOURCE_DIR}/src/platform/perf-main.c)
194 if(UNIX AND NOT APPLE)
195 list(APPEND PERF_LIB rt)
196 endif()
197
198 add_executable(${BINARY_NAME}-perf ${PERF_SRC})
199 target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB})
200 install(TARGETS ${BINARY_NAME}-perf DESTINATION bin)
201 install(FILES ${CMAKE_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}")
202endif()
203
204# Summaries
205message(STATUS "Feature summary:")
206message(STATUS " CLI debugger: ${USE_CLI_DEBUGGER}")
207message(STATUS " GDB stub: ${USE_GDB_STUB}")
208message(STATUS " Video recording: ${USE_FFMPEG}")
209message(STATUS " GIF recording: ${USE_MAGICK}")
210message(STATUS " Screenshot/advanced savestate support: ${USE_PNG}")
211message(STATUS " ZIP support: ${USE_LIBZIP}")
212message(STATUS "Frontend summary:")
213message(STATUS " Qt: ${BUILD_QT}")
214message(STATUS " SDL (${SDL_VERSION}): ${BUILD_SDL}")
215message(STATUS " Profiling: ${BUILD_PERF}")