CMakeLists.txt (view raw)
1cmake_minimum_required(VERSION 2.8.11)
2project(mGBA)
3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
4if(NOT MSVC)
5 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wno-missing-field-initializers -std=c99")
6else()
7 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_CRT_SECURE_NO_WARNINGS /wd4003 /wd4244 /wd4146")
8endif()
9set(USE_DEBUGGERS ON CACHE BOOL "Whether or not to enable the debugging infrastructure")
10set(USE_EDITLINE ON CACHE BOOL "Whether or not to enable the CLI-mode debugger")
11set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
12set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
13set(USE_ZLIB ON CACHE BOOL "Whether or not to enable zlib support")
14set(USE_MINIZIP ON CACHE BOOL "Whether or not to enable external minizip support")
15set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
16set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable LIBZIP support")
17set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
18set(USE_SQLITE3 ON CACHE BOOL "Whether or not to enable SQLite3 support")
19set(M_CORE_GBA ON CACHE BOOL "Build Game Boy Advance core")
20set(M_CORE_GB ON CACHE BOOL "Build Game Boy core")
21set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
22set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
23set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
24set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
25if(APPLE)
26 set(BUILD_OPENEMU OFF CACHE BOOL "Build OpenEmu core")
27endif()
28set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
29set(BUILD_TEST OFF CACHE BOOL "Build testing harness")
30set(BUILD_SUITE OFF CACHE BOOL "Build test suite")
31set(BUILD_EXAMPLE OFF CACHE BOOL "Build example frontends")
32set(BUILD_PYTHON OFF CACHE BOOL "Build Python bindings")
33set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
34set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
35set(SKIP_LIBRARY OFF CACHE BOOL "Skip building the library (useful for only building libretro or OpenEmu cores)")
36set(BUILD_GL ON CACHE STRING "Build with OpenGL")
37set(BUILD_GLES2 OFF CACHE STRING "Build with OpenGL|ES 2")
38set(USE_EPOXY ON CACHE STRING "Build with libepoxy")
39set(DISABLE_DEPS OFF CACHE BOOL "Build without dependencies")
40file(GLOB ARM_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/*.c)
41file(GLOB ARM_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/test/*.c)
42file(GLOB LR35902_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/*.c)
43file(GLOB LR35902_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/test/*.c)
44file(GLOB GBA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/*.c)
45file(GLOB GBA_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/test/*.c)
46file(GLOB GB_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/*.c)
47file(GLOB GB_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/test/*.c)
48file(GLOB GBA_CHEATS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/cheats/*.c)
49file(GLOB GBA_RR_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/rr/*.c)
50file(GLOB CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/*.c)
51file(GLOB CORE_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/test/*.c)
52file(GLOB UTIL_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/*.[cSs])
53file(GLOB UTIL_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/test/*.c)
54file(GLOB GUI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/gui/*.c ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/gui/*.c)
55file(GLOB GBA_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/renderers/*.c)
56file(GLOB GBA_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/sio/lockstep.c)
57file(GLOB GBA_EXTRA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/extra/*.c)
58file(GLOB GB_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/sio/lockstep.c)
59file(GLOB GB_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/renderers/*.c)
60file(GLOB GB_EXTRA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/extra/*.c)
61file(GLOB THIRD_PARTY_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/inih/*.c)
62file(GLOB EXTRA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/*.c)
63set(CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-mem.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fifo.c)
64set(VFS_SRC)
65source_group("ARM core" FILES ${ARM_SRC})
66source_group("LR35902 core" FILES ${LR35902_SRC})
67source_group("GBA board" FILES ${GBA_SRC} ${GBA_RENDERER_SRC} ${GBA_SIO_SRC})
68source_group("GBA extra" FILES ${GBA_CHEATS_SRC} ${GBA_RR_SRC})
69source_group("GB board" FILES ${GB_SRC} ${GB_SIO_SRC})
70source_group("Utilities" FILES ${UTIL_SRC})
71include_directories(BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/include ${CMAKE_CURRENT_SOURCE_DIR}/src)
72
73if(NOT CMAKE_BUILD_TYPE)
74 set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
75endif()
76
77include(GNUInstallDirs)
78
79set(LIBDIR "${CMAKE_INSTALL_LIBDIR}" CACHE PATH "Installed library directory")
80mark_as_advanced(LIBDIR)
81
82if (BUILD_LIBRETRO)
83 set(LIBRETRO_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (Libretro)")
84 mark_as_advanced(LIBRETRO_LIBDIR)
85endif()
86
87if (BUILD_OPENEMU)
88 set(OE_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (OpenEmu)")
89 mark_as_advanced(OE_LIBDIR)
90endif()
91
92
93set(CMAKE_INSTALL_RPATH "${LIBDIR}")
94
95if (NOT DEFINED MANDIR)
96 set(MANDIR ${CMAKE_INSTALL_MANDIR})
97endif()
98
99# Function definitions
100include(FindPkgConfig)
101function(find_feature FEATURE_NAME FEATURE_REQUIRES)
102 if (NOT ${FEATURE_NAME})
103 return()
104 endif()
105 if (DISABLE_DEPS)
106 set(${FEATURE_NAME} OFF PARENT_SCOPE)
107 return()
108 endif()
109 foreach(REQUIRE ${FEATURE_REQUIRES})
110 if(NOT ${REQUIRE}_FOUND)
111 find_package(${REQUIRE} QUIET)
112 if(NOT ${REQUIRE}_FOUND)
113 pkg_search_module(${REQUIRE} ${REQUIRE})
114 if (NOT ${REQUIRE}_FOUND)
115 message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
116 set(${FEATURE_NAME} OFF PARENT_SCOPE)
117 return()
118 endif()
119 endif()
120 endif()
121 string(TOUPPER ${REQUIRE} UREQUIRE)
122 set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
123 set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
124 set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
125 set(${UREQUIRE}_VERSION_STRING ${${REQUIRE}_VERSION_STRING} PARENT_SCOPE)
126 if (APPLE)
127 set(IS_FRAMEWORK OFF)
128 set(LIBS)
129 foreach(LIB IN LISTS ${REQUIRE}_LIBRARIES)
130 if(LIB STREQUAL "-framework")
131 set(IS_FRAMEWORK ON)
132 elseif(IS_FRAMEWORK)
133 list(APPEND LIBS "-framework ${LIB}")
134 set(IS_FRAMEWORK OFF)
135 else()
136 list(APPEND LIBS ${LIB})
137 endif()
138 endforeach()
139 set(${UREQUIRE}_LIBRARIES ${LIBS} PARENT_SCOPE)
140 else()
141 set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
142 endif()
143 set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
144 set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
145 endforeach()
146endfunction()
147
148# Version information
149add_custom_target(version-info ALL
150 COMMAND ${CMAKE_COMMAND}
151 -DBINARY_NAME=${BINARY_NAME}
152 -DCONFIG_FILE=${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in
153 -DOUT_FILE=${CMAKE_CURRENT_BINARY_DIR}/version.c
154 -P ${CMAKE_CURRENT_SOURCE_DIR}/version.cmake
155 WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
156
157include(${CMAKE_CURRENT_SOURCE_DIR}/version.cmake)
158configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in ${CMAKE_CURRENT_BINARY_DIR}/version.c)
159
160list(APPEND UTIL_SRC ${CMAKE_CURRENT_BINARY_DIR}/version.c)
161source_group("Generated sources" FILES ${CMAKE_CURRENT_BINARY_DIR}/version.c)
162
163# Advanced settings
164if(NOT DEFINED 3DS)
165 # LTO appears to make 3DS binary slower
166 set(DEFAULT_LTO ON)
167else()
168 set(DEFAULT_LTO OFF)
169endif()
170
171set(BUILD_LTO ${DEFAULT_LTO} CACHE BOOL "Build with link-time optimization")
172set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
173set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
174set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
175mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
176set(PGO_PRE_FLAGS "-fprofile-generate=${PGO_DIR} -fprofile-arcs")
177set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
178
179if(BUILD_PGO AND NOT PGO_STAGE_2)
180 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
181 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
182 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
183elseif(BUILD_PGO AND PGO_STAGE_2)
184 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
185 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
186 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
187endif()
188
189# Platform support
190if(WIN32)
191 set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
192 add_definitions(-D_WIN32_WINNT=0x0600)
193 list(APPEND OS_LIB ws2_32 shlwapi)
194 list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/vfs-w32.c)
195 file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/*.c)
196 source_group("Windows-specific code" FILES ${OS_SRC})
197 if(MSVC)
198 add_definitions(-DNOMINMAX -DWIN32_LEAN_AND_MEAN)
199 set(CMAKE_WINDOWS_EXPORT_ALL_SYMBOLS TRUE)
200 endif()
201elseif(UNIX)
202 set(USE_PTHREADS ON)
203 add_definitions(-DUSE_PTHREADS)
204
205 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
206 add_definitions(-D_GNU_SOURCE)
207 endif()
208 if(NOT APPLE AND NOT HAIKU)
209 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
210 endif()
211
212 list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
213 file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/posix/*.c)
214 source_group("POSIX-specific code" FILES ${OS_SRC})
215endif()
216
217if(APPLE)
218 add_definitions(-D_DARWIN_C_SOURCE)
219 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
220endif()
221
222if(NOT HAIKU AND NOT MSVC AND NOT PSP2)
223 set(M_LIBRARY m)
224endif()
225list(APPEND OS_LIB ${M_LIBRARY})
226
227if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
228 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
229 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
230endif()
231
232if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
233 if(NOT BUILD_EGL)
234 add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
235 endif()
236endif()
237
238if(BUILD_RASPI)
239 set(BUILD_GL OFF CACHE BOOL "OpenGL not supported" FORCE)
240endif()
241
242if(BUILD_PANDORA)
243 add_definitions(-DBUILD_PANDORA)
244endif()
245
246if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
247 enable_language(ASM)
248endif()
249
250if(PSP2 OR WII)
251 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-format")
252endif()
253
254if(DEFINED 3DS OR DEFINED PSP2 OR DEFINED WII)
255 set(USE_DEBUGGERS OFF)
256 set(USE_SQLITE3 OFF)
257endif()
258
259if(NOT M_CORE_GBA)
260 set(USE_GDB_STUB OFF)
261endif()
262
263if(NOT USE_DEBUGGERS)
264 set(USE_EDITLINE OFF)
265 set(USE_GDB_STUB OFF)
266endif()
267
268if(WII)
269 add_definitions(-U__STRICT_ANSI__)
270endif()
271
272if(DEFINED 3DS)
273 add_definitions(-D_GNU_SOURCE)
274endif()
275
276include(CheckFunctionExists)
277check_function_exists(strdup HAVE_STRDUP)
278check_function_exists(strndup HAVE_STRNDUP)
279if(NOT DEFINED PSP2)
280 check_function_exists(localtime_r HAVE_LOCALTIME_R)
281endif()
282if(NOT CMAKE_SYSTEM_NAME STREQUAL "Generic")
283 check_function_exists(snprintf_l HAVE_SNPRINTF_L)
284 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
285 # The strtof_l on Linux not actually exposed nor actually strtof_l
286 set(HAVE_STRTOF_L OFF)
287 else()
288 check_function_exists(strtof_l HAVE_STRTOF_L)
289 endif()
290 check_function_exists(newlocale HAVE_NEWLOCALE)
291 check_function_exists(freelocale HAVE_FREELOCALE)
292 check_function_exists(uselocale HAVE_USELOCALE)
293 check_function_exists(setlocale HAVE_SETLOCALE)
294else()
295 if(DEFINED 3DS)
296 check_function_exists(snprintf_l HAVE_SNPRINTF_L)
297 check_function_exists(strtof_l HAVE_STRTOF_L)
298 check_function_exists(newlocale HAVE_NEWLOCALE)
299 check_function_exists(freelocale HAVE_FREELOCALE)
300 check_function_exists(uselocale HAVE_USELOCALE)
301 check_function_exists(setlocale HAVE_SETLOCALE)
302 endif()
303 if(NOT DEFINED 3DS AND NOT DEFINED PSP2 AND NOT DEFINED WII)
304 set(DISABLE_DEPS ON CACHE BOOL "This platform cannot build with dependencies" FORCE)
305 endif()
306 set(DISABLE_FRONTENDS ON)
307 set(MINIMAL_CORE ON)
308 set(ENABLE_EXTRA ON)
309endif()
310
311check_function_exists(chmod HAVE_CHMOD)
312check_function_exists(umask HAVE_UMASK)
313
314set(FUNCTION_DEFINES)
315
316if(HAVE_STRDUP)
317 list(APPEND FUNCTION_DEFINES HAVE_STRDUP)
318endif()
319
320if(HAVE_STRNDUP)
321 list(APPEND FUNCTION_DEFINES HAVE_STRNDUP)
322endif()
323
324if(HAVE_LOCALTIME_R)
325 list(APPEND FUNCTION_DEFINES HAVE_LOCALTIME_R)
326endif()
327
328if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE OR APPLE OR DEFINED 3DS)
329 list(APPEND FUNCTION_DEFINES HAVE_LOCALE)
330 if (HAVE_STRTOF_L)
331 list(APPEND FUNCTION_DEFINES HAVE_STRTOF_L)
332 endif()
333 if (HAVE_SNPRINTF_L)
334 list(APPEND FUNCTION_DEFINES HAVE_SNPRINTF_L)
335 endif()
336endif()
337
338if(HAVE_SETLOCALE)
339 list(APPEND FUNCTION_DEFINES HAVE_SETLOCALE)
340endif()
341
342if(HAVE_CHMOD)
343 list(APPEND FUNCTION_DEFINES HAVE_CHMOD)
344endif()
345
346if(HAVE_UMASK)
347 list(APPEND FUNCTION_DEFINES HAVE_UMASK)
348endif()
349
350# Feature dependencies
351set(FEATURE_DEFINES)
352set(FEATURES)
353if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
354 set(LIBEDIT_LIBRARIES -ledit)
355 if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
356 list(APPEND LIBEDIT_LIBRARIES -ltermcap)
357 endif()
358else()
359 find_feature(USE_EDITLINE "libedit")
360endif()
361if(BUILD_GL)
362 find_package(OpenGL QUIET)
363 if(NOT OPENGL_FOUND)
364 set(BUILD_GL OFF CACHE BOOL "OpenGL not found" FORCE)
365 endif()
366endif()
367if(NOT BUILD_GL)
368 set(OPENGLE_LIBRARY "" CACHE PATH "" FORCE)
369endif()
370if(BUILD_GLES2 AND NOT BUILD_RASPI)
371 find_path(OPENGLES2_INCLUDE_DIR NAMES GLES2/gl2.h)
372 find_library(OPENGLES2_LIBRARY NAMES GLESv2 GLESv2_CM)
373 if(NOT OPENGLES2_INCLUDE_DIR OR NOT OPENGLES2_LIBRARY)
374 set(BUILD_GLES2 OFF CACHE BOOL "OpenGL|ES 2 not found" FORCE)
375 endif()
376endif()
377if(NOT BUILD_GLES2)
378 set(OPENGLES2_LIBRARY "" CACHE PATH "" FORCE)
379endif()
380set(WANT_ZLIB ${USE_ZLIB})
381set(WANT_PNG ${USE_PNG})
382set(WANT_LIBZIP ${USE_LIBZIP})
383set(WANT_SQLITE3 ${USE_SQLITE3})
384set(USE_CMOCKA ${BUILD_SUITE})
385
386find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
387find_feature(USE_ZLIB "ZLIB")
388find_feature(USE_MINIZIP "minizip")
389find_feature(USE_PNG "PNG")
390find_feature(USE_LIBZIP "libzip")
391find_feature(USE_MAGICK "MagickWand")
392find_feature(USE_EPOXY "epoxy")
393find_feature(USE_CMOCKA "cmocka")
394find_feature(USE_SQLITE3 "sqlite3")
395
396# Features
397set(DEBUGGER_SRC
398 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/debugger.c
399 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/parser.c
400 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/symbols.c
401 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/cli-debugger.c)
402
403set(FEATURE_SRC)
404set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
405
406if(DISABLE_DEPS)
407 set(USE_GDB_STUB OFF)
408endif()
409
410if(USE_EDITLINE)
411 list(APPEND FEATURES EDITLINE)
412 include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
413 link_directories(${LIBEDIT_LIBRARY_DIRS})
414 set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
415 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
416 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/editline/cli-el-backend.c")
417else()
418 set(DEBUGGER_LIB "")
419endif()
420
421if(USE_GDB_STUB)
422 list(APPEND FEATURES GDB_STUB)
423 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/gdb-stub.c)
424endif()
425source_group("Debugger" FILES ${DEBUGGER_SRC})
426
427if(USE_FFMPEG)
428 list(APPEND FEATURES FFMPEG)
429 pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
430 if(NOT LIBSWRESAMPLE_FOUND)
431 list(APPEND FEATURES LIBAV)
432 endif()
433 include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
434 link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
435 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/ffmpeg/ffmpeg-encoder.c")
436 string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
437 string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
438 string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
439 string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
440 string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
441 list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
442 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR}|libavcodec-extra-${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
443 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavformat${LIBAVFORMAT_VERSION_MAJOR}|libavformat-ffmpeg${LIBAVFORMAT_VERSION_MAJOR}")
444 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavresample${LIBAVRESAMPLE_VERSION_MAJOR}|libavresample-ffmpeg${LIBAVRESAMPLE_VERSION_MAJOR}")
445 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavutil${LIBAVUTIL_VERSION_MAJOR}|libavutil-ffmpeg${LIBAVUTIL_VERSION_MAJOR}")
446 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libswscale${LIBSWSCALE_VERSION_MAJOR}|libswscale-ffmpeg${LIBSWSCALE_VERSION_MAJOR}")
447 set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
448 if(APPLE)
449 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
450 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
451 endif()
452endif()
453
454list(APPEND THIRD_PARTY_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
455
456if(USE_MAGICK)
457 list(APPEND FEATURES MAGICK)
458 include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
459 link_directories(${MAGICKWAND_LIBRARY_DIRS})
460 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/imagemagick/imagemagick-gif-encoder.c")
461 list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
462 string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
463 string(REGEX MATCH "^[0-9]+" MAGICKWAND_VERSION_MAJOR ${MagickWand_VERSION})
464 if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
465 set(MAGICKWAND_DEB_VERSION "5")
466 elseif(${MagickWand_VERSION} EQUAL "6.9.7")
467 set(MAGICKWAND_DEB_VERSION "-6.q16-3")
468 else()
469 set(MAGICKWAND_DEB_VERSION "-6.q16-2")
470 endif()
471 list(APPEND FEATURE_DEFINES MAGICKWAND_VERSION_MAJOR=${MAGICKWAND_VERSION_MAJOR})
472
473 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
474endif()
475
476if(WANT_ZLIB AND NOT USE_ZLIB)
477 set(SKIP_INSTALL_ALL ON)
478 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib zlib)
479 set_property(TARGET zlibstatic PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/zlib;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib)
480 set_property(TARGET zlib PROPERTY EXCLUDE_FROM_ALL ON)
481 set_property(TARGET example PROPERTY EXCLUDE_FROM_ALL ON)
482 set_property(TARGET minigzip PROPERTY EXCLUDE_FROM_ALL ON)
483 set(ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
484 set(ZLIB_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
485 set(ZLIB_LIBRARY zlibstatic)
486 list(APPEND DEPENDENCY_LIB zlibstatic)
487 set(USE_ZLIB ON)
488endif()
489
490if(USE_ZLIB)
491 list(APPEND FEATURES ZLIB)
492 include_directories(AFTER ${ZLIB_INCLUDE_DIRS})
493 list(APPEND DEPENDENCY_LIB ${ZLIB_LIBRARIES})
494 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},zlib1g")
495endif()
496
497if(WANT_PNG AND USE_ZLIB AND NOT USE_PNG)
498 set(PNG_STATIC ON CACHE BOOL "" FORCE)
499 set(PNG_SHARED OFF CACHE BOOL "" FORCE)
500 set(PNG_TESTS OFF CACHE BOOL "" FORCE)
501 set(SKIP_INSTALL_ALL ON)
502 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng libpng)
503 set_property(TARGET png16_static PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/libpng;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng;${ZLIB_INCLUDE_DIRS})
504 set(PNG_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng ${CMAKE_CURRENT_BINARY_DIR}/libpng)
505 list(APPEND DEPENDENCY_LIB png16_static)
506 set(USE_PNG ON)
507endif()
508
509if(USE_PNG)
510 list(APPEND FEATURES PNG)
511 include_directories(AFTER ${PNG_INCLUDE_DIRS})
512 list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
513 if(PNG_VERSION_STRING)
514 string(REGEX MATCH "^[0-9]+\\.[0-9]+" PNG_VERSION_PARTIAL ${PNG_VERSION_STRING})
515 if(${PNG_VERSION_PARTIAL} STREQUAL "1.6")
516 set(PNG_DEB_VERSION "16-16")
517 else()
518 set(PNG_DEB_VERSION "12-0")
519 endif()
520 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng${PNG_DEB_VERSION}")
521 endif()
522endif()
523
524if(WANT_SQLITE3 AND NOT USE_SQLITE3)
525 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/sqlite3.c)
526 include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/)
527 set(USE_SQLITE3 ON)
528endif()
529
530if(USE_LIBZIP)
531 include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
532 link_directories(${LIBZIP_LIBRARY_DIRS})
533 list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
534 list(APPEND FEATURES LIBZIP)
535 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
536 string(REGEX MATCH "^[0-9]+" LIBZIP_VERSION_MAJOR ${libzip_VERSION})
537 if (LIBZIP_VERSION_MAJOR LESS 1)
538 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
539 elseif(LIBZIP_VERSION_MAJOR EQUAL 1)
540 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip4")
541 else()
542 message(AUTHOR_WARNING Unknown version of libzip detected: ${libzip_VERSION})
543 endif()
544elseif(USE_MINIZIP)
545 include_directories(AFTER ${MINIZIP_INCLUDE_DIRS})
546 link_directories(${MINIZIP_LIBRARY_DIRS})
547 list(APPEND DEPENDENCY_LIB ${MINIZIP_LIBRARIES})
548 list(APPEND FEATURES MINIZIP)
549 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
550 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libminizip1")
551elseif(USE_ZLIB)
552 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c
553 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
554 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c)
555 if(NOT MSVC)
556 set_source_files_properties(
557 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
558 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c
559 PROPERTIES COMPILE_FLAGS "-Wno-unused-parameter -Wno-implicit-function-declaration")
560 endif()
561endif()
562
563if (USE_LZMA)
564 include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/third-party/lzma)
565 add_definitions(-D_7ZIP_PPMD_SUPPPORT)
566 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-lzma.c)
567 set(LZMA_SRC
568 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
569 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
570 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
571 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
572 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
573 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
574 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zDec.c
575 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
576 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Delta.c
577 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
578 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
579 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra.c
580 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra86.c
581 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/BraIA64.c
582 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
583 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
584 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
585 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zFile.c
586 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
587 list(APPEND VFS_SRC ${LZMA_SRC})
588 list(APPEND FEATURES LZMA)
589endif()
590
591if(USE_EPOXY)
592 add_definitions(-DBUILD_GL -DBUILD_GLES2)
593 list(APPEND FEATURES EPOXY)
594 include_directories(AFTER ${EPOXY_INCLUDE_DIRS})
595 set(OPENGLES2_LIBRARY ${EPOXY_LIBRARIES})
596 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libepoxy0")
597endif()
598
599if(USE_SQLITE3)
600 list(APPEND FEATURES SQLITE3)
601 include_directories(AFTER ${SQLITE3_INCLUDE_DIRS})
602 list(APPEND DEPENDENCY_LIB ${SQLITE3_LIBRARIES})
603 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libsqlite3-0")
604 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/sqlite3/no-intro.c")
605endif()
606
607set(TEST_SRC ${CORE_TEST_SRC})
608if(M_CORE_GB)
609 add_definitions(-DM_CORE_GB)
610 list(APPEND CORE_SRC
611 ${LR35902_SRC}
612 ${GB_SRC}
613 ${GB_RENDERER_SRC})
614 list(APPEND DEBUGGER_SRC
615 ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/cli-debugger.c
616 ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/debugger.c
617 ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/memory-debugger.c
618 ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/debugger/cli.c
619 ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/debugger/symbols.c)
620 list(APPEND TEST_SRC
621 ${LR35902_TEST_SRC}
622 ${GB_TEST_SRC})
623endif()
624
625if(M_CORE_GBA)
626 add_definitions(-DM_CORE_GBA)
627 list(APPEND CORE_SRC
628 ${ARM_SRC}
629 ${GBA_SRC}
630 ${GBA_CHEATS_SRC}
631 ${GBA_RENDERER_SRC})
632 list(APPEND DEBUGGER_SRC
633 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c
634 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/debugger.c
635 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/memory-debugger.c
636 ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/debugger/cli.c)
637 list(APPEND TEST_SRC
638 ${ARM_TEST_SRC}
639 ${GBA_TEST_SRC})
640 if(NOT M_CORE_GB)
641 list(APPEND CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/audio.c)
642 endif()
643endif()
644
645if(USE_DEBUGGERS)
646 list(APPEND FEATURE_SRC ${DEBUGGER_SRC})
647 list(APPEND FEATURES DEBUGGERS)
648endif()
649
650foreach(FEATURE IN LISTS FEATURES)
651 list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
652endforeach()
653
654source_group("Virtual files" FILES ${CORE_VFS_SRC} ${VFS_SRC})
655source_group("Extra features" FILES ${FEATURE_SRC})
656source_group("Third-party code" FILES ${THIRD_PARTY_SRC})
657
658# Platform binaries
659if(DEFINED 3DS)
660 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/3ds ${CMAKE_CURRENT_BINARY_DIR}/3ds)
661endif()
662
663if(DEFINED WII)
664 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/wii ${CMAKE_CURRENT_BINARY_DIR}/wii)
665endif()
666
667if(DEFINED PSP2)
668 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/psp2 ${CMAKE_CURRENT_BINARY_DIR}/psp2)
669endif()
670
671# Binaries
672list(APPEND CORE_SRC
673 ${UTIL_SRC}
674 ${CORE_VFS_SRC}
675 ${OS_SRC}
676 ${THIRD_PARTY_SRC})
677list(APPEND TEST_SRC ${UTIL_TEST_SRC})
678
679set(SRC ${CORE_SRC} ${VFS_SRC})
680if(NOT MINIMAL_CORE)
681 set(ENABLE_EXTRA ON)
682 if(M_CORE_GBA)
683 list(APPEND SRC
684 ${GBA_SIO_SRC})
685 endif()
686 if(M_CORE_GB)
687 list(APPEND SRC
688 ${GB_SIO_SRC})
689 endif()
690 list(APPEND SRC
691 ${FEATURE_SRC})
692endif()
693
694if(ENABLE_EXTRA)
695 if(M_CORE_GBA)
696 list(APPEND SRC
697 ${GBA_RR_SRC}
698 ${GBA_EXTRA_SRC})
699 endif()
700 if(M_CORE_GB)
701 list(APPEND SRC
702 ${GB_EXTRA_SRC})
703 endif()
704 list(APPEND SRC
705 ${EXTRA_SRC})
706endif()
707
708if(NOT SKIP_LIBRARY)
709 if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
710 set(BUILD_SHARED ON)
711 endif()
712
713 if(BUILD_SHARED)
714 add_library(${BINARY_NAME} SHARED ${SRC} ${VFS_SRC})
715 if(BUILD_STATIC)
716 add_library(${BINARY_NAME}-static STATIC ${SRC})
717 set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
718 install(TARGETS ${BINARY_NAME}-static DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
719 add_dependencies(${BINARY_NAME}-static version-info)
720 endif()
721 else()
722 add_library(${BINARY_NAME} STATIC ${SRC})
723 endif()
724
725 add_dependencies(${BINARY_NAME} version-info)
726 set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
727
728 target_link_libraries(${BINARY_NAME} ${DEBUGGER_LIB} ${DEPENDENCY_LIB} ${OS_LIB})
729 install(TARGETS ${BINARY_NAME} LIBRARY DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME} NAMELINK_SKIP ARCHIVE DESTINATION ${LIBDIR} RUNTIME DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
730 if(UNIX AND NOT APPLE AND NOT HAIKU)
731 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-16.png DESTINATION share/icons/hicolor/16x16/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
732 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-24.png DESTINATION share/icons/hicolor/24x24/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
733 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-32.png DESTINATION share/icons/hicolor/32x32/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
734 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-48.png DESTINATION share/icons/hicolor/48x48/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
735 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-64.png DESTINATION share/icons/hicolor/64x64/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
736 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-96.png DESTINATION share/icons/hicolor/96x96/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
737 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-128.png DESTINATION share/icons/hicolor/128x128/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
738 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-256.png DESTINATION share/icons/hicolor/256x256/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
739 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-512.png DESTINATION share/icons/hicolor/512x512/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
740 endif()
741else()
742 set(BUILD_SHARED OFF)
743 set(BUILD_STATIC OFF)
744 find_library(${BINARY_NAME} ${BINARY_NAME})
745 if(NOT ${BINARY_NAME}_FOUND)
746 set(DISABLE_FRONTENDS ON)
747 set(BUILD_PERF OFF)
748 set(BUILD_TEST OFF)
749 set(BUILD_SUITE OFF)
750 endif()
751endif()
752
753if(BUILD_GL)
754 add_definitions(-DBUILD_GL)
755endif()
756
757if(BUILD_GLES2)
758 add_definitions(-DBUILD_GLES2)
759endif()
760
761if(DISABLE_FRONTENDS)
762 set(BUILD_SDL OFF)
763 set(BUILD_QT OFF)
764endif()
765
766if(BUILD_LIBRETRO)
767 file(GLOB RETRO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/libretro/*.c)
768 add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
769 set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5;DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=2")
770 target_link_libraries(${BINARY_NAME}_libretro ${OS_LIB})
771 install(TARGETS ${BINARY_NAME}_libretro LIBRARY DESTINATION ${LIBRETRO_LIBDIR} COMPONENT ${BINARY_NAME}_libretro NAMELINK_SKIP)
772endif()
773
774if(BUILD_OPENEMU)
775 find_library(FOUNDATION Foundation)
776 find_library(OPENEMUBASE OpenEmuBase)
777 file(GLOB OE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/*.m)
778 add_library(${BINARY_NAME}-openemu MODULE ${CORE_SRC} ${OE_SRC})
779 set_target_properties(${BINARY_NAME}-openemu PROPERTIES
780 MACOSX_BUNDLE_INFO_PLIST ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/Info.plist.in
781 BUNDLE TRUE
782 BUNDLE_EXTENSION oecoreplugin
783 OUTPUT_NAME ${PROJECT_NAME}
784 COMPILE_DEFINITIONS "DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=1")
785 target_link_libraries(${BINARY_NAME}-openemu ${OS_LIB} ${FOUNDATION} ${OPENEMUBASE})
786 install(TARGETS ${BINARY_NAME}-openemu LIBRARY DESTINATION ${OE_LIBDIR} COMPONENT ${BINARY_NAME}.oecoreplugin NAMELINK_SKIP)
787endif()
788
789if(BUILD_SDL)
790 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/sdl ${CMAKE_CURRENT_BINARY_DIR}/sdl)
791 # The SDL platform CMakeLists could decide to disable SDL, so check again before adding the define.
792 if(BUILD_SDL)
793 add_definitions(-DBUILD_SDL)
794 endif()
795endif()
796
797if(BUILD_QT)
798 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/qt ${CMAKE_CURRENT_BINARY_DIR}/qt)
799endif()
800
801if(BUILD_PERF)
802 set(PERF_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/perf-main.c)
803 if(UNIX AND NOT APPLE)
804 list(APPEND PERF_LIB rt)
805 endif()
806
807 add_executable(${BINARY_NAME}-perf ${PERF_SRC})
808 target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB} ${OS_LIB})
809 set_target_properties(${BINARY_NAME}-perf PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
810 install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
811 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
812endif()
813
814if(BUILD_TEST)
815 add_executable(${BINARY_NAME}-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/fuzz-main.c)
816 target_link_libraries(${BINARY_NAME}-fuzz ${BINARY_NAME})
817 set_target_properties(${BINARY_NAME}-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
818 add_executable(tbl-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/tbl-fuzz-main.c)
819 target_link_libraries(tbl-fuzz ${BINARY_NAME})
820 set_target_properties(tbl-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
821 install(TARGETS ${BINARY_NAME}-fuzz tbl-fuzz DESTINATION bin COMPONENT ${BINARY_NAME}-test)
822endif()
823
824if(NOT USE_CMOCKA)
825 set(BUILD_SUITE OFF)
826endif()
827if(BUILD_SUITE)
828 enable_testing()
829 include_directories(AFTER ${CMOCKA_INCLUDE_DIRS})
830 link_directories(${CMOCKA_LIBRARY_DIRS})
831
832 add_executable(${BINARY_NAME}-suite ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/suite-main.c ${TEST_SRC})
833 target_link_libraries(${BINARY_NAME}-suite ${BINARY_NAME} ${PLATFORM_LIBRARY} cmocka)
834 set_target_properties(${BINARY_NAME}-suite PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
835 add_test(${BINARY_NAME}-suite ${BINARY_NAME}-suite)
836endif()
837
838if(BUILD_PYTHON)
839 enable_testing()
840 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/python ${CMAKE_CURRENT_BINARY_DIR}/python)
841endif()
842
843if(BUILD_EXAMPLE)
844 add_executable(${BINARY_NAME}-example-server ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/server.c)
845 target_link_libraries(${BINARY_NAME}-example-server ${BINARY_NAME})
846 set_target_properties(${BINARY_NAME}-example-server PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
847
848 if(BUILD_SDL)
849 add_executable(${BINARY_NAME}-example-client ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/client.c)
850 target_link_libraries(${BINARY_NAME}-example-client ${BINARY_NAME} ${SDL_LIBRARY} ${SDLMAIN_LIBRARY} ${OPENGL_LIBRARY} ${OPENGLES2_LIBRARY})
851 set_target_properties(${BINARY_NAME}-example-client PROPERTIES
852 COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}"
853 INCLUDE_DIRECTORIES "${SDL_INCLUDE_DIR};${CMAKE_CURRENT_SOURCE_DIR}/src;${CMAKE_CURRENT_SOURCE_DIR}/include")
854 endif()
855endif()
856
857configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/flags.h.in ${CMAKE_CURRENT_BINARY_DIR}/flags.h)
858install(FILES ${CMAKE_CURRENT_BINARY_DIR}/flags.h DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/mgba COMPONENT lib${BINARY_NAME})
859
860# Packaging
861set(CPACK_PACKAGE_VERSION ${VERSION_STRING})
862set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
863set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
864set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
865set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
866set(CPACK_RESOURCE_FILE_README ${CMAKE_CURRENT_SOURCE_DIR}/README.md)
867
868set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
869set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
870set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
871set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README.md")
872set(CPACK_DEBIAN_PACKAGE_SECTION "games")
873
874SET(CPACK_DEB_COMPONENT_INSTALL ON)
875
876set(CPACK_STRIP_FILES ${BINARY_NAME})
877
878install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/README.md ${CMAKE_CURRENT_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
879
880include(CPack)
881
882# Summaries
883set(SUMMARY_GL_LIST)
884if(USE_EPOXY)
885 set(SUMMARY_GL_LIST "libepoxy")
886else()
887 if(BUILD_GL)
888 list(APPEND SUMMARY_GL_LIST "OpenGL")
889 endif()
890 if(BUILD_GLES2)
891 list(APPEND SUMMARY_GL_LIST "OpenGL|ES 2")
892 endif()
893endif()
894if(NOT SUMMARY_GL_LIST)
895 set(SUMMARY_GL OFF)
896else()
897 string(REPLACE ";" ", " SUMMARY_GL "${SUMMARY_GL_LIST}")
898endif()
899if(USE_LIBZIP)
900 set(SUMMARY_ZIP libzip)
901elseif(USE_MINIZIP)
902 set(SUMMARY_ZIP "minizip (external)")
903elseif(USE_ZLIB)
904 set(SUMMARY_ZIP "minizip (included)")
905else()
906 set(SUMMARY_ZIP OFF)
907endif()
908
909if(NOT QUIET)
910 message(STATUS "Build type: ${CMAKE_BUILD_TYPE}")
911 message(STATUS "Platforms:")
912 message(STATUS " Game Boy Advance: ${M_CORE_GBA}")
913 message(STATUS " Game Boy: ${M_CORE_GB}")
914 message(STATUS "Features:")
915 message(STATUS " Debuggers: ${USE_DEBUGGERS}")
916 message(STATUS " CLI debugger: ${USE_EDITLINE}")
917 message(STATUS " GDB stub: ${USE_GDB_STUB}")
918 message(STATUS " Video recording: ${USE_FFMPEG}")
919 message(STATUS " GIF recording: ${USE_MAGICK}")
920 message(STATUS " Screenshot/advanced savestate support: ${USE_PNG}")
921 message(STATUS " ZIP support: ${SUMMARY_ZIP}")
922 message(STATUS " 7-Zip support: ${USE_LZMA}")
923 message(STATUS " SQLite3 game database: ${USE_SQLITE3}")
924 message(STATUS " OpenGL support: ${SUMMARY_GL}")
925 message(STATUS "Frontends:")
926 message(STATUS " Qt: ${BUILD_QT}")
927 message(STATUS " SDL (${SDL_VERSION}): ${BUILD_SDL}")
928 message(STATUS " Profiling: ${BUILD_PERF}")
929 message(STATUS " Test harness: ${BUILD_TEST}")
930 message(STATUS " Test suite: ${BUILD_SUITE}")
931 message(STATUS " Python bindings: ${BUILD_PYTHON}")
932 message(STATUS " Examples: ${BUILD_EXAMPLE}")
933 message(STATUS "Cores:")
934 message(STATUS " Libretro core: ${BUILD_LIBRETRO}")
935 if(APPLE)
936 message(STATUS " OpenEmu core: ${BUILD_OPENEMU}")
937 endif()
938 message(STATUS "Libraries:")
939 message(STATUS " Static: ${BUILD_STATIC}")
940 message(STATUS " Shared: ${BUILD_SHARED}")
941endif()