1cmake_minimum_required(VERSION 2.6)
  2project(mGBA C)
  3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
  4set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -std=gnu99")
  5set(USE_CLI_DEBUGGER ON CACHE BOOL "Whether or not to enable the CLI-mode ARM debugger")
  6set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
  7set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
  8set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
  9set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable ZIP support")
 10set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
 11set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
 12file(GLOB ARM_SRC ${CMAKE_SOURCE_DIR}/src/arm/*.c)
 13file(GLOB GBA_SRC ${CMAKE_SOURCE_DIR}/src/gba/*.c)
 14file(GLOB UTIL_SRC ${CMAKE_SOURCE_DIR}/src/util/*.[cS])
 15file(GLOB VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/*.c)
 16file(GLOB RENDERER_SRC ${CMAKE_SOURCE_DIR}/src/gba/renderers/video-software.c)
 17list(APPEND UTIL_SRC ${CMAKE_SOURCE_DIR}/src/platform/commandline.c)
 18source_group("ARM core" FILES ${ARM_SRC})
 19source_group("GBA board" FILES ${GBA_SRC} ${RENDERER_SRC})
 20source_group("Utilities" FILES ${UTIL_SRC} ${VFS_SRC}})
 21include_directories(${CMAKE_SOURCE_DIR}/src/arm)
 22include_directories(${CMAKE_SOURCE_DIR}/src/gba)
 23include_directories(${CMAKE_SOURCE_DIR}/src)
 24
 25include(GNUInstallDirs)
 26
 27# Function definitions
 28include(FindPkgConfig)
 29function(find_feature FEATURE_NAME FEATURE_REQUIRES)
 30	if (NOT ${FEATURE_NAME})
 31		return()
 32	endif()
 33	foreach(REQUIRE ${FEATURE_REQUIRES})
 34		find_package(${REQUIRE} QUIET)
 35		pkg_search_module(${REQUIRE} ${REQUIRE})
 36		if (NOT ${REQUIRE}_FOUND)
 37			message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
 38			set(${FEATURE_NAME} OFF PARENT_SCOPE)
 39			return()
 40		endif()
 41		string(TOUPPER ${REQUIRE} UREQUIRE)
 42		set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
 43		set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
 44		set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
 45		set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
 46		set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
 47		set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
 48	endforeach()
 49endfunction()
 50
 51# Version information
 52set(LIB_VERSION_MAJOR 0)
 53set(LIB_VERSION_MINOR 1)
 54set(LIB_VERSION_PATCH 0)
 55set(LIB_VERSION_ABI 0.1)
 56set(LIB_VERSION_STRING ${LIB_VERSION_MAJOR}.${LIB_VERSION_MINOR}.${LIB_VERSION_PATCH})
 57
 58# Advanced settings
 59set(BUILD_PGO CACHE BOOL "Build with profiling-guided optimization")
 60set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
 61set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
 62mark_as_advanced(BUILD_PGO PGO_STAGE_2 PGO_DIR)
 63set(PGO_PRE_FLAGS "-pg -fprofile-generate=${PGO_DIR}")
 64set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR}")
 65
 66if(BUILD_PGO AND NOT PGO_STAGE_2)
 67	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
 68	set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
 69	set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
 70elseif(BUILD_PGO AND PGO_STAGE_2)
 71	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
 72	set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
 73	set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
 74endif()
 75
 76add_definitions(-DBINARY_NAME="${BINARY_NAME}" -DPROJECT_NAME="${PROJECT_NAME}" -DPROJECT_VERSION="${LIB_VERSION_STRING}")
 77
 78# Feature dependencies
 79find_feature(USE_CLI_DEBUGGER "libedit")
 80find_feature(USE_FFMPEG "libavcodec;libavformat;libavutil")
 81find_feature(USE_PNG "PNG;ZLIB")
 82find_feature(USE_LIBZIP "libzip")
 83
 84include(CheckFunctionExists)
 85check_function_exists(strndup HAVE_STRNDUP)
 86
 87if(HAVE_STRNDUP)
 88	add_definitions(-DHAVE_STRNDUP)
 89endif()
 90
 91# Platform support
 92if(WIN32)
 93	add_definitions(-D_WIN32_WINNT=0x0600)
 94	list(APPEND OS_LIB Ws2_32)
 95	file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/windows/*.c)
 96	source_group("Windows-specific code" FILES ${OS_SRC})
 97else()
 98	add_definitions(-DUSE_PTHREADS)
 99	list(APPEND OS_LIB pthread)
100	file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/posix/*.c)
101	source_group("POSIX-specific code" FILES ${OS_SRC})
102endif()
103
104if(BUILD_BBB OR BUILD_RASPI)
105	enable_language(ASM)
106	if(NOT BUILD_EGL)
107		add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
108	endif()
109endif()
110
111# Features
112set(DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/debugger.c ${CMAKE_SOURCE_DIR}/src/debugger/memory-debugger.c)
113
114if(USE_CLI_DEBUGGER)
115	add_definitions(-DUSE_CLI_DEBUGGER)
116	list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/cli-debugger.c)
117	list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/parser.c)
118	include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
119	link_directories(${LIBEDIT_LIBRARY_DIRS})
120	set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
121else()
122	set(DEBUGGER_LIB "")
123endif()
124
125if(USE_GDB_STUB)
126	add_definitions(-DUSE_GDB_STUB)
127	list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/gdb-stub.c)
128endif()
129source_group("ARM debugger" FILES ${DEBUGGER_SRC})
130
131if(USE_FFMPEG)
132	add_definitions(-DUSE_FFMPEG)
133	include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS})
134	link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS})
135	list(APPEND UTIL_SRC "${CMAKE_SOURCE_DIR}/src/platform/ffmpeg/ffmpeg-encoder.c")
136	list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVUTIL_LIBRARIES})
137endif()
138
139if(USE_PNG)
140	add_definitions(-DUSE_PNG)
141	include_directories(AFTER ${PNG_INCLUDE_DIRS})
142	list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
143endif()
144
145if(USE_LIBZIP)
146	include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
147	link_directories(${LIBZIP_LIBRARY_DIRS})
148	list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
149	add_definitions(-DENABLE_LIBZIP)
150endif()
151
152# Binaries
153add_library(${BINARY_NAME} SHARED ${ARM_SRC} ${GBA_SRC} ${DEBUGGER_SRC} ${RENDERER_SRC} ${UTIL_SRC} ${VFS_SRC} ${OS_SRC})
154target_link_libraries(${BINARY_NAME} m ${DEBUGGER_LIB} ${OS_LIB} ${DEPENDENCY_LIB})
155install(TARGETS ${BINARY_NAME} DESTINATION lib)
156set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI})
157
158if(BUILD_SDL)
159	add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/sdl ${CMAKE_BINARY_DIR}/sdl)
160endif()
161
162if(BUILD_PERF)
163	set(PERF_SRC ${CMAKE_SOURCE_DIR}/src/platform/perf-main.c)
164	if(UNIX AND NOT APPLE)
165		list(APPEND PERF_LIB rt)
166	endif()
167
168	add_executable(${BINARY_NAME}-perf ${PERF_SRC})
169	target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB})
170	install(TARGETS ${BINARY_NAME}-perf DESTINATION bin)
171	install(FILES ${CMAKE_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}")
172endif()
173
174# Summaries
175message(STATUS "Feature summary:")
176message(STATUS "	CLI debugger: ${USE_CLI_DEBUGGER}")
177message(STATUS "	GDB stub: ${USE_GDB_STUB}")
178message(STATUS "	Video recording: ${USE_FFMPEG}")
179message(STATUS "	Screenshot/advanced savestate support: ${USE_PNG}")
180message(STATUS "	ZIP support: ${USE_LIBZIP}")
181message(STATUS "Frontend summary:")
182message(STATUS "	SDL (${SDL_VERSION}): ${BUILD_SDL}")
183message(STATUS "	Profiling: ${BUILD_PERF}")