CMakeLists.txt (view raw)
1cmake_minimum_required(VERSION 2.6)
2project(mGBA C)
3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
4set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -std=c99")
5set(USE_CLI_DEBUGGER ON CACHE BOOL "Whether or not to enable the CLI-mode ARM debugger")
6set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
7set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
8set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
9set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable ZIP support")
10set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
11set(USE_BLIP ON CACHE BOOL "Whether or not to enable blip_buf support")
12set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
13set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
14set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
15set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
16set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
17set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
18set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
19file(GLOB ARM_SRC ${CMAKE_SOURCE_DIR}/src/arm/*.c)
20file(GLOB GBA_SRC ${CMAKE_SOURCE_DIR}/src/gba/*.c)
21file(GLOB GBA_RR_SRC ${CMAKE_SOURCE_DIR}/src/gba/rr/*.c)
22file(GLOB GBA_SV_SRC ${CMAKE_SOURCE_DIR}/src/gba/supervisor/*.c)
23file(GLOB UTIL_SRC ${CMAKE_SOURCE_DIR}/src/util/*.[cSs])
24file(GLOB VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/*.c)
25file(GLOB RENDERER_SRC ${CMAKE_SOURCE_DIR}/src/gba/renderers/video-software.c)
26file(GLOB SIO_SRC ${CMAKE_SOURCE_DIR}/src/gba/sio/lockstep.c)
27file(GLOB THIRD_PARTY_SRC ${CMAKE_SOURCE_DIR}/src/third-party/inih/*.c)
28list(APPEND UTIL_SRC ${CMAKE_SOURCE_DIR}/src/platform/commandline.c)
29source_group("ARM core" FILES ${ARM_SRC})
30source_group("GBA board" FILES ${GBA_SRC} ${RENDERER_SRC} ${SIO_SRC})
31source_group("GBA supervisor" FILES ${GBA_SV_SRC} ${GBA_RR_SRC})
32source_group("Utilities" FILES ${UTIL_SRC} ${VFS_SRC}})
33include_directories(${CMAKE_SOURCE_DIR}/src/arm)
34include_directories(${CMAKE_SOURCE_DIR}/src)
35
36if(NOT CMAKE_BUILD_TYPE)
37 set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
38endif()
39
40set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
41
42include(GNUInstallDirs)
43
44# Function definitions
45include(FindPkgConfig)
46function(find_feature FEATURE_NAME FEATURE_REQUIRES)
47 if (NOT ${FEATURE_NAME})
48 return()
49 endif()
50 foreach(REQUIRE ${FEATURE_REQUIRES})
51 if(NOT ${REQUIRE}_FOUND)
52 find_package(${REQUIRE} QUIET)
53 if(NOT ${REQUIRE}_FOUND)
54 pkg_search_module(${REQUIRE} ${REQUIRE})
55 if (NOT ${REQUIRE}_FOUND)
56 message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
57 set(${FEATURE_NAME} OFF PARENT_SCOPE)
58 return()
59 endif()
60 endif()
61 endif()
62 string(TOUPPER ${REQUIRE} UREQUIRE)
63 set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
64 set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
65 set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
66 set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
67 set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
68 set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
69 endforeach()
70endfunction()
71
72# Version information
73set(LIB_VERSION_MAJOR 0)
74set(LIB_VERSION_MINOR 2)
75set(LIB_VERSION_PATCH 0)
76set(LIB_VERSION_ABI 0.2)
77set(LIB_VERSION_STRING ${LIB_VERSION_MAJOR}.${LIB_VERSION_MINOR}.${LIB_VERSION_PATCH})
78
79# Advanced settings
80set(BUILD_LTO ON CACHE BOOL "Build with link-time optimization")
81set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
82set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
83set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
84mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
85set(PGO_PRE_FLAGS "-pg -fprofile-generate=${PGO_DIR} -fprofile-arcs")
86set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
87
88if(BUILD_PGO AND NOT PGO_STAGE_2)
89 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
90 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
91 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
92elseif(BUILD_PGO AND PGO_STAGE_2)
93 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
94 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
95 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
96endif()
97
98add_definitions(-DBINARY_NAME="${BINARY_NAME}" -DPROJECT_NAME="${PROJECT_NAME}" -DPROJECT_VERSION="${LIB_VERSION_STRING}")
99
100# Feature dependencies
101set(FEATURES)
102if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
103 set(LIBEDIT_LIBRARIES -ledit)
104 if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
105 list(APPEND LIBEDIT_LIBRARIES -ltermcap)
106 endif()
107else()
108 find_feature(USE_CLI_DEBUGGER "libedit")
109endif()
110find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
111find_feature(USE_PNG "ZLIB;PNG")
112find_feature(USE_LIBZIP "libzip")
113find_feature(USE_MAGICK "MagickWand")
114
115# Platform support
116if(WIN32)
117 set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
118 add_definitions(-D_WIN32_WINNT=0x0600)
119 list(APPEND OS_LIB ws2_32)
120 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/windows/*.c)
121 source_group("Windows-specific code" FILES ${OS_SRC})
122else()
123 add_definitions(-DUSE_PTHREADS)
124
125 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
126 add_definitions(-D_BSD_SOURCE -D_POSIX_SOURCE -D_POSIX_C_SOURCE=200809L)
127 endif()
128 if(NOT APPLE)
129 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
130 endif()
131
132 file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/posix/*.c)
133 source_group("POSIX-specific code" FILES ${OS_SRC})
134endif()
135
136if(APPLE)
137 add_definitions(-D_DARWIN_C_SOURCE)
138 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
139endif()
140
141if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
142 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
143 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
144endif()
145
146if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
147 if(NOT BUILD_EGL)
148 add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
149 endif()
150endif()
151
152if(BUILD_PANDORA)
153 add_definitions(-DBUILD_PANDORA)
154endif()
155
156if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
157 enable_language(ASM)
158endif()
159
160include(CheckFunctionExists)
161check_function_exists(strndup HAVE_STRNDUP)
162check_function_exists(snprintf_l HAVE_SNPRINTF_L)
163if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
164 # The strtof_l on Linux not actually exposed nor actually strtof_l
165 set(HAVE_STRTOF_L OFF)
166else()
167 check_function_exists(strtof_l HAVE_STRTOF_L)
168endif()
169check_function_exists(newlocale HAVE_NEWLOCALE)
170check_function_exists(freelocale HAVE_FREELOCALE)
171check_function_exists(uselocale HAVE_USELOCALE)
172
173if(HAVE_STRNDUP)
174 add_definitions(-DHAVE_STRNDUP)
175endif()
176
177if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE)
178 add_definitions(-DHAVE_LOCALE)
179 if (HAVE_STRTOF_L)
180 add_definitions(-DHAVE_STRTOF_L)
181 endif()
182 if (HAVE_SNPRINTF_L)
183 add_definitions(-DHAVE_SNPRINTF_L)
184 endif()
185endif()
186
187
188# Features
189set(DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/debugger.c ${CMAKE_SOURCE_DIR}/src/debugger/memory-debugger.c)
190set(FEATURE_SRC)
191set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
192
193if(USE_CLI_DEBUGGER)
194 list(APPEND FEATURES CLI_DEBUGGER)
195 list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/debugger/cli-debugger.c)
196 list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/debugger/parser.c)
197 list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/gba/supervisor/cli.c)
198 include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
199 link_directories(${LIBEDIT_LIBRARY_DIRS})
200 set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
201 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
202else()
203 set(DEBUGGER_LIB "")
204endif()
205
206if(USE_GDB_STUB)
207 list(APPEND FEATURES GDB_STUB)
208 list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/gdb-stub.c)
209endif()
210source_group("ARM debugger" FILES ${DEBUGGER_SRC})
211
212if(USE_FFMPEG)
213 list(APPEND FEATURES FFMPEG)
214 pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
215 if(NOT LIBSWRESAMPLE_FOUND)
216 list(APPEND FEATURES LIBAV)
217 endif()
218 include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
219 link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
220 list(APPEND FEATURE_SRC "${CMAKE_SOURCE_DIR}/src/platform/ffmpeg/ffmpeg-encoder.c")
221 string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
222 string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
223 string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
224 string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
225 string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
226 list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
227 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR},libavformat${LIBAVFORMAT_VERSION_MAJOR},libavresample${LIBAVRESAMPLE_VERSION_MAJOR},libavutil${LIBAVUTIL_VERSION_MAJOR},libswscale${LIBSWSCALE_VERSION_MAJOR}")
228 set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra")
229endif()
230
231if(USE_BLIP)
232 list(APPEND THIRD_PARTY_SRC "${CMAKE_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
233 add_definitions(-DRESAMPLE_LIBRARY=RESAMPLE_BLIP_BUF)
234else()
235 add_definitions(-DRESAMPLE_LIBRARY=RESAMPLE_NN)
236endif()
237
238if(USE_MAGICK)
239 list(APPEND FEATURES MAGICK)
240 include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
241 link_directories(${MAGICKWAND_LIBRARY_DIRS})
242 list(APPEND FEATURE_SRC "${CMAKE_SOURCE_DIR}/src/platform/imagemagick/imagemagick-gif-encoder.c")
243 list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
244 string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
245 if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
246 set(MAGICKWAND_DEB_VERSION "5")
247 else()
248 set(MAGICKWAND_DEB_VERSION "-6.q16-2")
249 endif()
250 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
251endif()
252
253if(USE_PNG)
254 list(APPEND FEATURES PNG)
255 include_directories(AFTER ${PNG_INCLUDE_DIRS})
256 list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
257 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng12-0,zlib1g")
258endif()
259
260if(USE_LIBZIP)
261 include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
262 link_directories(${LIBZIP_LIBRARY_DIRS})
263 list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
264 list(APPEND FEATURES LIBZIP)
265 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
266endif()
267
268if (USE_LZMA)
269 include_directories(AFTER ${CMAKE_SOURCE_DIR}/third-party/lzma)
270 add_definitions(-D_7ZIP_PPMD_SUPPPORT)
271 set(LZMA_SRC
272 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
273 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
274 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
275 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
276 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
277 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
278 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zDec.c
279 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
280 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
281 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
282 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bra.c
283 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bra86.c
284 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
285 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
286 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
287 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zFile.c
288 ${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
289 list(APPEND FEATURE_SRC ${LZMA_SRC})
290 list(APPEND FEATURES LZMA)
291endif()
292
293set(FEATURE_DEFINES)
294foreach(FEATURE IN LISTS FEATURES)
295 list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
296endforeach()
297
298# Binaries
299set(CORE_SRC
300 ${ARM_SRC}
301 ${GBA_SRC}
302 ${GBA_RR_SRC}
303 ${GBA_SV_SRC}
304 ${DEBUGGER_SRC}
305 ${RENDERER_SRC}
306 ${SIO_SRC}
307 ${UTIL_SRC}
308 ${VFS_SRC}
309 ${OS_SRC}
310 ${THIRD_PARTY_SRC})
311
312set(SRC
313 ${CORE_SRC}
314 ${FEATURE_SRC})
315
316if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
317 set(BUILD_SHARED ON)
318endif()
319
320if(BUILD_SHARED)
321 add_library(${BINARY_NAME} SHARED ${SRC})
322 if(BUILD_STATIC)
323 add_library(${BINARY_NAME}-static STATIC ${SRC})
324 set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${FEATURE_DEFINES}")
325 install(TARGETS ${BINARY_NAME}-static DESTINATION lib COMPONENT lib${BINARY_NAME})
326 endif()
327else()
328 add_library(${BINARY_NAME} STATIC ${SRC})
329endif()
330
331target_link_libraries(${BINARY_NAME} m ${DEBUGGER_LIB} ${OS_LIB} ${DEPENDENCY_LIB})
332install(TARGETS ${BINARY_NAME} DESTINATION lib COMPONENT lib${BINARY_NAME})
333set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${FEATURE_DEFINES}")
334
335if(BUILD_LIBRETRO)
336 file(GLOB RETRO_SRC ${CMAKE_SOURCE_DIR}/src/platform/libretro/*.c)
337 add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
338 set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5")
339 target_link_libraries(${BINARY_NAME}_libretro m ${OS_LIB})
340endif()
341
342if(BUILD_SDL)
343 add_definitions(-DBUILD_SDL)
344 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/sdl ${CMAKE_BINARY_DIR}/sdl)
345endif()
346
347if(BUILD_QT)
348 add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/qt ${CMAKE_BINARY_DIR}/qt)
349endif()
350
351if(BUILD_PERF)
352 set(PERF_SRC ${CMAKE_SOURCE_DIR}/src/platform/perf-main.c)
353 if(UNIX AND NOT APPLE)
354 list(APPEND PERF_LIB rt)
355 endif()
356
357 add_executable(${BINARY_NAME}-perf ${PERF_SRC})
358 target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB})
359 install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
360 install(FILES ${CMAKE_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
361endif()
362
363# Packaging
364set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
365set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
366set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
367set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_SOURCE_DIR}/LICENSE)
368set(CPACK_RESOURCE_FILE_README ${CMAKE_SOURCE_DIR}/README.md)
369
370set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
371set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
372set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
373set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_SOURCE_DIR}/README.md")
374set(CPACK_DEBIAN_PACKAGE_SECTION "games")
375
376SET(CPACK_DEB_COMPONENT_INSTALL ON)
377
378set(CPACK_STRIP_FILES ${BINARY_NAME})
379
380install(FILES ${CMAKE_SOURCE_DIR}/README.md ${CMAKE_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
381
382include(CPack)
383
384# Summaries
385message(STATUS "Feature summary:")
386message(STATUS " CLI debugger: ${USE_CLI_DEBUGGER}")
387message(STATUS " GDB stub: ${USE_GDB_STUB}")
388message(STATUS " Video recording: ${USE_FFMPEG}")
389message(STATUS " GIF recording: ${USE_MAGICK}")
390message(STATUS " Screenshot/advanced savestate support: ${USE_PNG}")
391message(STATUS " ZIP support: ${USE_LIBZIP}")
392message(STATUS " 7-Zip support: ${USE_LZMA}")
393message(STATUS " Better audio resampling: ${USE_BLIP}")
394message(STATUS "Frontend summary:")
395message(STATUS " Qt: ${BUILD_QT}")
396message(STATUS " SDL (${SDL_VERSION}): ${BUILD_SDL}")
397message(STATUS " Libretro core: ${BUILD_LIBRETRO}")
398message(STATUS " Profiling: ${BUILD_PERF}")
399message(STATUS "Library summary:")
400message(STATUS " Static: ${BUILD_STATIC}")
401message(STATUS " Shared: ${BUILD_SHARED}")